basis/compiler/cfg/liveness/liveness.factor

   1 ! Copyright (C) 2009, 2010 Slava Pestov.
   2 ! See https://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs combinators combinators.short-circuit
   4 compiler.cfg.def-use compiler.cfg.instructions
   5 compiler.cfg.predecessors compiler.cfg.registers
   6 compiler.cfg.rpo compiler.cfg.ssa.destruction.leaders
   7 compiler.cfg.utilities compiler.utilities cpu.architecture
   8 deques dlists kernel namespaces sequences sets ;
   9 IN: compiler.cfg.liveness
  10
  11 SYMBOL: live-ins
  12
  13 : live-in ( bb -- set )
  14     live-ins get at ;
  15
  16 SYMBOL: live-outs
  17
  18 : live-out ( bb -- set )
  19     live-outs get at ;
  20
  21 SYMBOL: edge-live-ins
  22
  23 : edge-live-in ( predecessor basic-block -- set )
  24     edge-live-ins get at at ;
  25
  26 SYMBOL: base-pointers
  27
  28 GENERIC: visit-insn ( live-set insn -- )
  29
  30 ! This would be much better if live-set was a real set
  31 : kill-defs ( live-set insn -- )
  32     defs-vregs [ ?leader ] map
  33     '[ drop ?leader _ in? ] assoc-reject! drop ; inline
  34
  35 : gen-uses ( live-set insn -- )
  36     uses-vregs [ swap conjoin ] with each ; inline
  37
  38 M: vreg-insn visit-insn
  39     [ kill-defs ] [ gen-uses ] 2bi ;
  40
  41 DEFER: lookup-base-pointer
  42
  43 GENERIC: lookup-base-pointer* ( vreg insn -- vreg/f )
  44
  45 M: ##tagged>integer lookup-base-pointer* nip src>> ;
  46
  47 M: ##unbox-any-c-ptr lookup-base-pointer*
  48     ! If the input to unbox-any-c-ptr was an alien and not a
  49     ! byte array, then the derived pointer will be outside of
  50     ! the data heap. The GC has to handle this case and ignore
  51     ! it.
  52     nip src>> ;
  53
  54 M: ##copy lookup-base-pointer* nip src>> lookup-base-pointer ;
  55
  56 M: ##add-imm lookup-base-pointer* nip src1>> lookup-base-pointer ;
  57
  58 M: ##sub-imm lookup-base-pointer* nip src1>> lookup-base-pointer ;
  59
  60 M: ##parallel-copy lookup-base-pointer* values>> value-at ;
  61
  62 M: ##add lookup-base-pointer*
  63     ! If both operands have a base pointer, then the user better
  64     ! not be doing memory reads and writes on the object, since
  65     ! we don't give it a base pointer in that case at all.
  66     nip [ src1>> ] [ src2>> ] bi [ lookup-base-pointer ] bi@ xor ;
  67
  68 M: ##sub lookup-base-pointer*
  69     nip src1>> lookup-base-pointer ;
  70
  71 M: vreg-insn lookup-base-pointer* 2drop f ;
  72
  73 : lookup-base-pointer ( vreg -- vreg/f )
  74     base-pointers get ?at [
  75         f over base-pointers get set-at
  76         [ dup ?leader insn-of lookup-base-pointer* ] keep
  77         dupd base-pointers get set-at
  78     ] unless ;
  79
  80 :: visit-derived-root ( vreg derived-roots gc-roots -- )
  81     vreg lookup-base-pointer :> base
  82     base [
  83         { vreg base } derived-roots push
  84         base gc-roots adjoin
  85     ] when ;
  86
  87 : visit-gc-root ( vreg derived-roots gc-roots -- )
  88     pick rep-of {
  89         { tagged-rep [ nip adjoin ] }
  90         { int-rep [ visit-derived-root ] }
  91         [ 4drop ]
  92     } case ;
  93
  94 : gc-roots ( live-set -- derived-roots gc-roots )
  95     keys V{ } clone HS{ } clone
  96     [ '[ _ _ visit-gc-root ] each ] 2keep members ;
  97
  98 : fill-gc-map ( live-set gc-map -- )
  99     [ gc-roots ] dip [ gc-roots<< ] [ derived-roots<< ] bi ;
 100
 101 M: gc-map-insn visit-insn
 102     [ kill-defs ] [ gc-map>> fill-gc-map ] [ gen-uses ] 2tri ;
 103
 104 M: ##phi visit-insn kill-defs ;
 105
 106 M: insn visit-insn 2drop ;
 107
 108 : transfer-liveness ( live-set insns -- )
 109     <reversed> [ visit-insn ] with each ;
 110
 111 : compute-live-in ( basic-block -- live-in )
 112     [ live-out clone dup ] keep instructions>> transfer-liveness ;
 113
 114 : compute-edge-live-in ( basic-block -- edge-live-in )
 115     H{ } clone [
 116         '[ inputs>> [ swap _ conjoin-at ] assoc-each ] each-phi
 117     ] keep ;
 118
 119 : update-live-in ( basic-block -- changed? )
 120     [ [ compute-live-in ] keep live-ins get maybe-set-at ]
 121     [ [ compute-edge-live-in ] keep edge-live-ins get maybe-set-at ]
 122     bi or ;
 123
 124 : compute-live-out ( basic-block -- live-out )
 125     [ successors>> [ live-in ] map ]
 126     [ dup successors>> [ edge-live-in ] with map ] bi
 127     append assoc-union-all ;
 128
 129 : update-live-out ( basic-block -- changed? )
 130     [ compute-live-out ] keep
 131     live-outs get maybe-set-at ;
 132
 133 : update-live-out/in ( basic-block -- changed? )
 134     { [ update-live-out ] [ update-live-in ] } 1&& ;
 135
 136 : liveness-step ( basic-block -- basic-blocks )
 137     [ update-live-out/in ] keep predecessors>> { } ? ;
 138
 139 : init-liveness ( -- )
 140     H{ } clone live-ins namespaces:set
 141     H{ } clone edge-live-ins namespaces:set
 142     H{ } clone live-outs namespaces:set
 143     H{ } clone base-pointers namespaces:set ;
 144
 145 : compute-live-sets ( cfg -- )
 146     init-liveness
 147     dup needs-predecessors dup compute-insns
 148     post-order <hashed-dlist> [ push-all-front ] keep
 149     [ liveness-step ] slurp/replenish-deque ;
 150
 151 : live-in? ( vreg bb -- ? ) live-in key? ;
 152
 153 : live-out? ( vreg bb -- ? ) live-out key? ;