basis/compiler/codegen/codegen.factor

   1 ! Copyright (C) 2008, 2011 Slava Pestov.
   2 ! See https://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs byte-arrays combinators
   4 compiler.cfg compiler.cfg.comparisons compiler.cfg.instructions
   5 compiler.cfg.linearization compiler.codegen.gc-maps
   6 compiler.codegen.labels compiler.codegen.relocation
   7 compiler.constants cpu.architecture generic.parser kernel
   8 layouts make math namespaces parser quotations sequences
   9 sequences.generalizations slots words ;
  10 IN: compiler.codegen
  11
  12 GENERIC: generate-insn ( insn -- )
  13
  14 ! Control flow
  15 SYMBOL: labels
  16
  17 : lookup-label ( bb -- label )
  18     labels get [ drop <label> ] cache ;
  19
  20 : useless-branch? ( bb successor -- ? )
  21     [ number>> ] bi@ 1 - = ; inline
  22
  23 : emit-branch ( bb successor -- )
  24     2dup useless-branch?
  25     [ 2drop ] [ nip lookup-label %jump-label ] if ;
  26
  27 M: ##branch generate-insn
  28     drop basic-block get dup successors>> first emit-branch ;
  29
  30 GENERIC: generate-conditional-insn ( label insn -- )
  31
  32 GENERIC: negate-insn-cc ( insn -- )
  33
  34 M: conditional-branch-insn negate-insn-cc
  35     [ negate-cc ] change-cc drop ;
  36
  37 M: ##test-vector-branch negate-insn-cc
  38     [ negate-vcc ] change-vcc drop ;
  39
  40 M:: conditional-branch-insn generate-insn ( insn -- )
  41     basic-block get :> bb
  42     bb successors>> first2 :> ( first second )
  43     bb second useless-branch?
  44     [ bb second first ]
  45     [ bb first second insn negate-insn-cc ] if
  46     lookup-label insn generate-conditional-insn
  47     emit-branch ;
  48
  49 : %dispatch-label ( label -- )
  50     cell 0 <repetition> %
  51     rc-absolute-cell label-fixup ;
  52
  53 M: ##dispatch generate-insn
  54     [ src>> ] [ temp>> ] bi %dispatch
  55     basic-block get successors>>
  56     [ lookup-label %dispatch-label ] each ;
  57
  58 : generate-block ( bb -- )
  59     [ basic-block set ]
  60     [ lookup-label resolve-label ]
  61     [
  62         instructions>> [ generate-insn ] each
  63     ] tri ;
  64
  65 : check-fixup ( seq -- )
  66     length data-alignment get mod 0 assert= ;
  67
  68 : with-fixup ( quot -- code )
  69     '[
  70         init-relocation
  71         V{ } clone return-addresses set
  72         V{ } clone gc-maps set
  73         V{ } clone label-table set
  74         V{ } clone binary-literal-table set
  75         [
  76             @
  77             emit-binary-literals
  78             emit-gc-maps
  79             label-table [ compute-labels ] change
  80             parameter-table get >array
  81             literal-table get >array
  82             relocation-table get >byte-array
  83             label-table get
  84         ] B{ } make
  85         dup check-fixup
  86         cfg get [ stack-frame>> [ total-size>> ] [ 0 ] if* ] [ 0 ] if*
  87     ] call 6 narray ; inline
  88
  89 : generate ( cfg -- code )
  90     [
  91         H{ } clone labels set
  92         linearization-order
  93         [ number-blocks ] [ [ generate-block ] each ] bi
  94     ] with-fixup ;
  95
  96 ! Special cases
  97 M: ##no-tco generate-insn drop ;
  98
  99 M: ##prologue generate-insn
 100     drop
 101     cfg get stack-frame>> [ total-size>> %prologue ] when* ;
 102
 103 M: ##epilogue generate-insn
 104     drop
 105     cfg get stack-frame>> [ total-size>> %epilogue ] when* ;
 106
 107 ! Some meta-programming to generate simple code generators, where
 108 ! the instruction is unpacked and then a %word is called
 109 <<
 110
 111 : insn-slot-quot ( spec -- quot )
 112     name>> reader-word 1quotation ;
 113
 114 : codegen-method-body ( class word -- quot )
 115     [
 116         "insn-slots" word-prop
 117         [ insn-slot-quot ] map cleave>quot
 118     ] dip suffix ;
 119
 120 SYNTAX: CODEGEN:
 121     scan-word [ \ generate-insn create-method-in ] keep scan-word
 122     codegen-method-body define ;
 123
 124 >>
 125
 126 CODEGEN: ##load-integer %load-immediate
 127 CODEGEN: ##load-tagged %load-immediate
 128 CODEGEN: ##load-reference %load-reference
 129 CODEGEN: ##load-float %load-float
 130 CODEGEN: ##load-double %load-double
 131 CODEGEN: ##load-vector %load-vector
 132 CODEGEN: ##peek %peek
 133 CODEGEN: ##replace %replace
 134 CODEGEN: ##replace-imm %replace-imm
 135 CODEGEN: ##clear %clear
 136 CODEGEN: ##inc %inc
 137 CODEGEN: ##call %call
 138 CODEGEN: ##jump %jump
 139 CODEGEN: ##return %return
 140 CODEGEN: ##safepoint %safepoint
 141 CODEGEN: ##slot %slot
 142 CODEGEN: ##slot-imm %slot-imm
 143 CODEGEN: ##set-slot %set-slot
 144 CODEGEN: ##set-slot-imm %set-slot-imm
 145 CODEGEN: ##add %add
 146 CODEGEN: ##add-imm %add-imm
 147 CODEGEN: ##sub %sub
 148 CODEGEN: ##sub-imm %sub-imm
 149 CODEGEN: ##mul %mul
 150 CODEGEN: ##mul-imm %mul-imm
 151 CODEGEN: ##and %and
 152 CODEGEN: ##and-imm %and-imm
 153 CODEGEN: ##or %or
 154 CODEGEN: ##or-imm %or-imm
 155 CODEGEN: ##xor %xor
 156 CODEGEN: ##xor-imm %xor-imm
 157 CODEGEN: ##shl %shl
 158 CODEGEN: ##shl-imm %shl-imm
 159 CODEGEN: ##shr %shr
 160 CODEGEN: ##shr-imm %shr-imm
 161 CODEGEN: ##sar %sar
 162 CODEGEN: ##sar-imm %sar-imm
 163 CODEGEN: ##min %min
 164 CODEGEN: ##max %max
 165 CODEGEN: ##not %not
 166 CODEGEN: ##neg %neg
 167 CODEGEN: ##log2 %log2
 168 CODEGEN: ##bit-count %bit-count
 169 CODEGEN: ##bit-test %bit-test
 170 CODEGEN: ##copy %copy
 171 CODEGEN: ##tagged>integer %tagged>integer
 172 CODEGEN: ##add-float %add-float
 173 CODEGEN: ##sub-float %sub-float
 174 CODEGEN: ##mul-float %mul-float
 175 CODEGEN: ##div-float %div-float
 176 CODEGEN: ##min-float %min-float
 177 CODEGEN: ##max-float %max-float
 178 CODEGEN: ##sqrt %sqrt
 179 CODEGEN: ##single>double-float %single>double-float
 180 CODEGEN: ##double>single-float %double>single-float
 181 CODEGEN: ##integer>float %integer>float
 182 CODEGEN: ##float>integer %float>integer
 183 CODEGEN: ##zero-vector %zero-vector
 184 CODEGEN: ##fill-vector %fill-vector
 185 CODEGEN: ##gather-vector-2 %gather-vector-2
 186 CODEGEN: ##gather-vector-4 %gather-vector-4
 187 CODEGEN: ##gather-int-vector-2 %gather-int-vector-2
 188 CODEGEN: ##gather-int-vector-4 %gather-int-vector-4
 189 CODEGEN: ##select-vector %select-vector
 190 CODEGEN: ##shuffle-vector-imm %shuffle-vector-imm
 191 CODEGEN: ##shuffle-vector-halves-imm %shuffle-vector-halves-imm
 192 CODEGEN: ##shuffle-vector %shuffle-vector
 193 CODEGEN: ##tail>head-vector %tail>head-vector
 194 CODEGEN: ##merge-vector-head %merge-vector-head
 195 CODEGEN: ##merge-vector-tail %merge-vector-tail
 196 CODEGEN: ##float-pack-vector %float-pack-vector
 197 CODEGEN: ##signed-pack-vector %signed-pack-vector
 198 CODEGEN: ##unsigned-pack-vector %unsigned-pack-vector
 199 CODEGEN: ##unpack-vector-head %unpack-vector-head
 200 CODEGEN: ##unpack-vector-tail %unpack-vector-tail
 201 CODEGEN: ##integer>float-vector %integer>float-vector
 202 CODEGEN: ##float>integer-vector %float>integer-vector
 203 CODEGEN: ##compare-vector %compare-vector
 204 CODEGEN: ##move-vector-mask %move-vector-mask
 205 CODEGEN: ##test-vector %test-vector
 206 CODEGEN: ##add-vector %add-vector
 207 CODEGEN: ##saturated-add-vector %saturated-add-vector
 208 CODEGEN: ##add-sub-vector %add-sub-vector
 209 CODEGEN: ##sub-vector %sub-vector
 210 CODEGEN: ##saturated-sub-vector %saturated-sub-vector
 211 CODEGEN: ##mul-vector %mul-vector
 212 CODEGEN: ##mul-high-vector %mul-high-vector
 213 CODEGEN: ##mul-horizontal-add-vector %mul-horizontal-add-vector
 214 CODEGEN: ##saturated-mul-vector %saturated-mul-vector
 215 CODEGEN: ##div-vector %div-vector
 216 CODEGEN: ##min-vector %min-vector
 217 CODEGEN: ##max-vector %max-vector
 218 CODEGEN: ##avg-vector %avg-vector
 219 CODEGEN: ##dot-vector %dot-vector
 220 CODEGEN: ##sad-vector %sad-vector
 221 CODEGEN: ##sqrt-vector %sqrt-vector
 222 CODEGEN: ##horizontal-add-vector %horizontal-add-vector
 223 CODEGEN: ##horizontal-sub-vector %horizontal-sub-vector
 224 CODEGEN: ##horizontal-shl-vector-imm %horizontal-shl-vector-imm
 225 CODEGEN: ##horizontal-shr-vector-imm %horizontal-shr-vector-imm
 226 CODEGEN: ##abs-vector %abs-vector
 227 CODEGEN: ##and-vector %and-vector
 228 CODEGEN: ##andn-vector %andn-vector
 229 CODEGEN: ##or-vector %or-vector
 230 CODEGEN: ##xor-vector %xor-vector
 231 CODEGEN: ##not-vector %not-vector
 232 CODEGEN: ##shl-vector-imm %shl-vector-imm
 233 CODEGEN: ##shr-vector-imm %shr-vector-imm
 234 CODEGEN: ##shl-vector %shl-vector
 235 CODEGEN: ##shr-vector %shr-vector
 236 CODEGEN: ##integer>scalar %integer>scalar
 237 CODEGEN: ##scalar>integer %scalar>integer
 238 CODEGEN: ##vector>scalar %vector>scalar
 239 CODEGEN: ##scalar>vector %scalar>vector
 240 CODEGEN: ##box-alien %box-alien
 241 CODEGEN: ##box-displaced-alien %box-displaced-alien
 242 CODEGEN: ##unbox-alien %unbox-alien
 243 CODEGEN: ##unbox-any-c-ptr %unbox-any-c-ptr
 244 CODEGEN: ##convert-integer %convert-integer
 245 CODEGEN: ##load-memory %load-memory
 246 CODEGEN: ##load-memory-imm %load-memory-imm
 247 CODEGEN: ##store-memory %store-memory
 248 CODEGEN: ##store-memory-imm %store-memory-imm
 249 CODEGEN: ##allot %allot
 250 CODEGEN: ##write-barrier %write-barrier
 251 CODEGEN: ##write-barrier-imm %write-barrier-imm
 252 CODEGEN: ##compare %compare
 253 CODEGEN: ##compare-imm %compare-imm
 254 CODEGEN: ##test %test
 255 CODEGEN: ##test-imm %test-imm
 256 CODEGEN: ##compare-integer %compare
 257 CODEGEN: ##compare-integer-imm %compare-integer-imm
 258 CODEGEN: ##compare-float-ordered %compare-float-ordered
 259 CODEGEN: ##compare-float-unordered %compare-float-unordered
 260 CODEGEN: ##save-context %save-context
 261 CODEGEN: ##vm-field %vm-field
 262 CODEGEN: ##set-vm-field %set-vm-field
 263 CODEGEN: ##alien-global %alien-global
 264 CODEGEN: ##call-gc %call-gc
 265 CODEGEN: ##spill %spill
 266 CODEGEN: ##reload %reload
 267
 268 ! Conditional branches
 269 <<
 270
 271 SYNTAX: CONDITIONAL:
 272     scan-word [ \ generate-conditional-insn create-method-in ] keep scan-word
 273     codegen-method-body define ;
 274
 275 >>
 276
 277 CONDITIONAL: ##compare-branch %compare-branch
 278 CONDITIONAL: ##compare-imm-branch %compare-imm-branch
 279 CONDITIONAL: ##compare-integer-branch %compare-branch
 280 CONDITIONAL: ##compare-integer-imm-branch %compare-integer-imm-branch
 281 CONDITIONAL: ##test-branch %test-branch
 282 CONDITIONAL: ##test-imm-branch %test-imm-branch
 283 CONDITIONAL: ##compare-float-ordered-branch %compare-float-ordered-branch
 284 CONDITIONAL: ##compare-float-unordered-branch %compare-float-unordered-branch
 285 CONDITIONAL: ##test-vector-branch %test-vector-branch
 286 CONDITIONAL: ##check-nursery-branch %check-nursery-branch
 287 CONDITIONAL: ##fixnum-add %fixnum-add
 288 CONDITIONAL: ##fixnum-sub %fixnum-sub
 289 CONDITIONAL: ##fixnum-mul %fixnum-mul
 290
 291 ! FFI
 292 CODEGEN: ##unbox %unbox
 293 CODEGEN: ##unbox-long-long %unbox-long-long
 294 CODEGEN: ##local-allot %local-allot
 295 CODEGEN: ##box %box
 296 CODEGEN: ##box-long-long %box-long-long
 297 CODEGEN: ##alien-invoke %alien-invoke
 298 CODEGEN: ##alien-indirect %alien-indirect
 299 CODEGEN: ##alien-assembly %alien-assembly
 300 CODEGEN: ##callback-inputs %callback-inputs
 301 CODEGEN: ##callback-outputs %callback-outputs