basis/hash-sets/sequences/sequences.factor

   1 ! Copyright (C) 2013 John Benediktsson
   2 ! See http://factorcode.org/license.txt for BSD license
   3
   4 USING: accessors hash-sets hash-sets.wrapped kernel math parser
   5 sequences vocabs.loader ;
   6
   7 IN: hash-sets.sequences
   8
   9 <PRIVATE
  10
  11 TUPLE: sequence-wrapper
  12     { underlying sequence read-only } ;
  13
  14 C: <sequence-wrapper> sequence-wrapper
  15
  16 M: sequence-wrapper equal?
  17     over sequence-wrapper?
  18     [ [ underlying>> ] bi@ sequence= ]
  19     [ 2drop f ] if ; inline
  20
  21 M: sequence-wrapper hashcode*
  22     underlying>> [ sequence-hashcode ] recursive-hashcode ; inline
  23
  24 PRIVATE>
  25
  26 TUPLE: sequence-hash-set < wrapped-hash-set ;
  27
  28 : <sequence-hash-set> ( n -- shash-set )
  29     <hash-set> sequence-hash-set boa ; inline
  30
  31 M: sequence-hash-set wrap-key drop <sequence-wrapper> ;
  32
  33 M: sequence-hash-set clone
  34     underlying>> clone sequence-hash-set boa ; inline
  35
  36 : >sequence-hash-set ( members -- shash-set )
  37     [ <sequence-wrapper> ] map >hash-set sequence-hash-set boa ;
  38
  39 SYNTAX: SHS{ \ } [ >sequence-hash-set ] parse-literal ;
  40
  41 { "hash-sets.sequences" "prettyprint" } "hash-sets.sequences.prettyprint" require-when