basis/io/sockets/sockets.factor

   1 ! Copyright (C) 2007, 2011 Slava Pestov, Doug Coleman,
   2 ! Daniel Ehrenberg.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: accessors alien.c-types alien.data alien.strings arrays
   5 byte-arrays classes classes.struct combinators
   6 combinators.short-circuit continuations destructors endian fry
   7 grouping init io.backend io.encodings.ascii
   8 io.encodings.binary io.pathnames io.ports io.streams.duplex
   9 kernel locals math math.parser memoize namespaces present
  10 sequences sequences.private splitting strings summary system
  11 vocabs vocabs.parser ip-parser ip-parser.private random ;
  12 IN: io.sockets
  13
  14 << {
  15     { [ os windows? ] [ "windows.winsock" ] }
  16     { [ os unix? ] [ "unix.ffi" ] }
  17 } cond use-vocab >>
  18
  19 GENERIC#: with-port 1 ( addrspec port -- addrspec )
  20
  21 ! Addressing
  22 <PRIVATE
  23
  24 GENERIC: protocol ( addrspec -- n )
  25
  26 GENERIC: protocol-family ( addrspec -- af )
  27
  28 GENERIC: sockaddr-size ( addrspec -- n )
  29
  30 GENERIC: make-sockaddr ( addrspec -- sockaddr )
  31
  32 GENERIC: make-sockaddr-outgoing ( addrspec -- sockaddr )
  33
  34 GENERIC: empty-sockaddr ( addrspec -- sockaddr )
  35
  36 GENERIC: address-size ( addrspec -- n )
  37
  38 GENERIC: inet-ntop ( data addrspec -- str )
  39
  40 GENERIC: inet-pton ( str addrspec -- data )
  41
  42 : make-sockaddr/size-outgoing ( addrspec -- sockaddr size )
  43     [ make-sockaddr-outgoing ] [ sockaddr-size ] bi ;
  44
  45 : make-sockaddr/size ( addrspec -- sockaddr size )
  46     [ make-sockaddr ] [ sockaddr-size ] bi ;
  47
  48 : empty-sockaddr/size ( addrspec -- sockaddr size )
  49     [ empty-sockaddr ] [ sockaddr-size ] bi ;
  50
  51 M: object make-sockaddr-outgoing make-sockaddr ;
  52
  53 GENERIC: parse-sockaddr ( sockaddr addrspec -- newaddrspec )
  54
  55 M: f parse-sockaddr nip ;
  56
  57 HOOK: sockaddr-of-family os ( alien af -- sockaddr )
  58
  59 HOOK: addrspec-of-family os ( af -- addrspec )
  60
  61 PRIVATE>
  62
  63 TUPLE: local { path string read-only } ;
  64
  65 : <local> ( path -- addrspec )
  66     absolute-path local boa ;
  67
  68 M: local present path>> "Unix domain socket: " prepend ;
  69
  70 M: local protocol drop 0 ;
  71
  72 SLOT: port
  73
  74 TUPLE: ipv4 { host maybe{ string } read-only } ;
  75
  76 <PRIVATE
  77
  78 ERROR: invalid-ipv4 host reason ;
  79
  80 M: invalid-ipv4 summary drop "Invalid IPv4 address" ;
  81
  82 : ?parse-ipv4 ( string -- seq/f )
  83     [ f ] [ parse-ipv4 ] if-empty ;
  84
  85 : check-ipv4 ( host -- )
  86     [ ?parse-ipv4 drop ] [ invalid-ipv4 ] recover ;
  87
  88 PRIVATE>
  89
  90 : <ipv4> ( host -- ipv4 ) dup check-ipv4 ipv4 boa ;
  91
  92 M: ipv4 inet-ntop
  93     drop 4 memory>byte-array join-ipv4 ;
  94
  95 M: ipv4 inet-pton
  96     drop [ ?parse-ipv4 ] [ invalid-ipv4 ] recover ;
  97
  98 M: ipv4 address-size drop 4 ;
  99
 100 M: ipv4 protocol-family drop PF_INET ;
 101
 102 M: ipv4 sockaddr-size drop sockaddr-in heap-size ;
 103
 104 M: ipv4 empty-sockaddr drop sockaddr-in new ;
 105
 106 : make-sockaddr-part ( inet -- sockaddr )
 107     sockaddr-in new
 108         AF_INET >>family
 109         swap
 110         port>> 0 or htons >>port ; inline
 111
 112 M: ipv4 make-sockaddr
 113     [ make-sockaddr-part ]
 114     [ host>> "0.0.0.0" or ]
 115     [ inet-pton uint deref >>addr ] tri ;
 116
 117 M: ipv4 make-sockaddr-outgoing
 118     [ make-sockaddr-part ]
 119     [ host>> dup { f "0.0.0.0" } member? [ drop "127.0.0.1" ] when ]
 120     [ inet-pton uint deref >>addr ] tri ;
 121
 122 M: ipv4 parse-sockaddr
 123     [ addr>> uint <ref> ] dip inet-ntop <ipv4> ;
 124
 125 TUPLE: inet4 < ipv4 { port maybe{ integer } read-only } ;
 126
 127 : <inet4> ( host port -- inet4 )
 128     over check-ipv4 inet4 boa ;
 129
 130 M: ipv4 with-port [ host>> ] dip <inet4> ;
 131
 132 M: inet4 parse-sockaddr
 133     [ call-next-method ] [ drop port>> ntohs ] 2bi with-port ;
 134
 135 M: inet4 present
 136     [ host>> ] [ port>> number>string ] bi ":" glue ;
 137
 138 M: inet4 protocol drop 0 ;
 139
 140 TUPLE: ipv6
 141 { host maybe{ string } read-only }
 142 { scope-id integer read-only } ;
 143
 144 <PRIVATE
 145
 146 ERROR: invalid-ipv6 host reason ;
 147
 148 M: invalid-ipv6 summary drop "Invalid IPv6 address" ;
 149
 150 : check-ipv6 ( host -- )
 151     [ parse-ipv6 drop ] [ invalid-ipv6 ] recover ;
 152
 153 PRIVATE>
 154
 155 : <ipv6> ( host -- ipv6 ) dup check-ipv6 0 ipv6 boa ;
 156
 157 M: ipv6 inet-ntop
 158     drop 16 memory>byte-array 2 <groups> [ be> >hex ] map ":" join ;
 159
 160 <PRIVATE
 161
 162 : ipv6-bytes ( seq -- bytes )
 163     [ 2 >be ] { } map-as B{ } concat-as ;
 164
 165 PRIVATE>
 166
 167 M: ipv6 inet-pton
 168     drop [ parse-ipv6 ipv6-bytes ] [ invalid-ipv6 ] recover ;
 169
 170 M: ipv6 address-size drop 16 ;
 171
 172 M: ipv6 protocol-family drop PF_INET6 ;
 173
 174 M: ipv6 sockaddr-size drop sockaddr-in6 heap-size ;
 175
 176 M: ipv6 empty-sockaddr drop sockaddr-in6 new ;
 177
 178 : make-sockaddr-in6-part ( inet -- sockaddr )
 179     sockaddr-in6 new
 180         AF_INET6 >>family
 181         swap
 182         port>> 0 or htons >>port ; inline
 183
 184 M: ipv6 make-sockaddr
 185     [ make-sockaddr-in6-part ]
 186     [ [ host>> "::" or ] keep inet-pton >>addr ]
 187     [ scope-id>> >>scopeid ]
 188     tri ;
 189
 190 M: ipv6 make-sockaddr-outgoing
 191     [ make-sockaddr-in6-part ]
 192     [ [ host>> dup { f "::" } member? [ drop "::1" ] when ] keep inet-pton >>addr ]
 193     [ scope-id>> >>scopeid ]
 194     tri ;
 195
 196 M: ipv6 parse-sockaddr
 197     [ [ addr>> ] dip inet-ntop ] [ drop scopeid>> ] 2bi
 198     ipv6 boa ;
 199
 200 M: ipv6 present
 201     [ host>> ] [ scope-id>> ] bi
 202     [ number>string "%" glue ] unless-zero ;
 203
 204 TUPLE: inet6 < ipv6 { port maybe{ integer } read-only } ;
 205
 206 : <inet6> ( host port -- inet6 )
 207     [ dup check-ipv6 0 ] dip inet6 boa ;
 208
 209 M: ipv6 with-port
 210     [ [ host>> ] [ scope-id>> ] bi ] dip
 211     inet6 boa ;
 212
 213 M: inet6 parse-sockaddr
 214     [ call-next-method ] [ drop port>> ntohs ] 2bi with-port ;
 215
 216 M: inet6 present
 217     [ call-next-method "[" "]" surround ] [ port>> number>string ] bi ":" glue ;
 218
 219 M: inet6 protocol drop 0 ;
 220
 221 ERROR: addrinfo-error n string host ;
 222
 223 <PRIVATE
 224
 225 GENERIC: (get-local-address) ( handle remote -- sockaddr )
 226
 227 : get-local-address ( handle remote -- local )
 228     [ (get-local-address) ] keep parse-sockaddr ;
 229
 230 GENERIC: (get-remote-address) ( handle remote -- sockaddr )
 231
 232 : get-remote-address ( handle local -- remote )
 233     [ (get-remote-address) ] keep parse-sockaddr ;
 234
 235 : <ports> ( handle -- input-port output-port )
 236     [
 237         [ <input-port> |dispose ] [ <output-port> |dispose ] bi
 238     ] with-destructors ;
 239
 240 SYMBOL: bind-local-address
 241
 242 GENERIC: establish-connection ( client-out remote -- )
 243
 244 GENERIC: remote>handle ( remote -- handle )
 245
 246 GENERIC: (client) ( remote -- client-in client-out local )
 247
 248 M: array (client) [ (client) 3array ] attempt-all first3 ;
 249
 250 M: object (client)
 251     [
 252         [ remote>handle ] keep
 253         [
 254             [ <ports> [ |dispose ] bi@ dup ] dip
 255             establish-connection
 256         ]
 257         [ get-local-address ]
 258         2bi
 259     ] with-destructors ;
 260
 261 TUPLE: server-port < port addr encoding ;
 262
 263 GENERIC: (server) ( addrspec -- handle )
 264
 265 GENERIC: (accept) ( server addrspec -- handle sockaddr )
 266
 267 TUPLE: datagram-port < port addr ;
 268
 269 HOOK: (datagram) io-backend ( addr -- datagram )
 270
 271 TUPLE: raw-port < port addr ;
 272
 273 HOOK: (raw) io-backend ( addr -- raw )
 274
 275 HOOK: (broadcast) io-backend ( datagram -- datagram )
 276
 277 HOOK: (receive-unsafe) io-backend ( n buf datagram -- count addrspec )
 278
 279 ERROR: invalid-port object ;
 280
 281 : check-port ( bytes addrspec port -- bytes addrspec port )
 282     2dup addr>> [ class-of ] bi@ assert=
 283     pick class-of byte-array assert= ;
 284
 285 : check-connectionless-port ( port -- port )
 286     dup { [ datagram-port? ] [ raw-port? ] } 1|| [ invalid-port ] unless ;
 287
 288 : check-send ( bytes addrspec port -- bytes addrspec port )
 289     check-connectionless-port check-disposed check-port ;
 290
 291 : check-receive ( port -- port )
 292     check-connectionless-port check-disposed ;
 293
 294 HOOK: (send) io-backend ( bytes addrspec datagram -- )
 295
 296 : addrinfo>addrspec ( addrinfo -- addrspec )
 297     [ [ addr>> ] [ family>> ] bi sockaddr-of-family ]
 298     [ family>> addrspec-of-family ] bi
 299     parse-sockaddr ;
 300
 301 : parse-addrinfo-list ( addrinfo -- seq )
 302     [ next>> ] follow
 303     [ addrinfo>addrspec ] map
 304     sift ;
 305
 306 HOOK: addrinfo-error-string io-backend ( n -- string )
 307
 308 : prepare-addrinfo ( -- addrinfo )
 309     addrinfo new
 310         PF_UNSPEC >>family
 311         IPPROTO_TCP >>protocol ;
 312
 313 PRIVATE>
 314
 315 : <client> ( remote encoding -- stream local )
 316     [ (client) ] dip swap [ <encoder-duplex> ] dip ;
 317
 318 SYMBOL: local-address
 319
 320 SYMBOL: remote-address
 321
 322 : with-client ( remote encoding quot -- )
 323     [
 324         [
 325             over remote-address set
 326             <client> local-address set
 327         ] dip with-stream
 328     ] with-scope ; inline
 329
 330 : <server> ( addrspec encoding -- server )
 331     [
 332         [ (server) ] keep
 333         [ drop server-port <port> ] [ get-local-address ] 2bi
 334         >>addr
 335     ] dip >>encoding ;
 336
 337 : accept ( server -- client remote )
 338     [
 339         dup addr>>
 340         [ (accept) ] keep
 341         parse-sockaddr swap
 342         <ports>
 343     ] [ encoding>> ] bi <encoder-duplex> swap ;
 344
 345 : <datagram> ( addrspec -- datagram )
 346     [
 347         [ (datagram) |dispose ] keep
 348         [ drop datagram-port <port> ] [ get-local-address ] 2bi
 349         >>addr
 350     ] with-destructors ;
 351
 352 : <raw> ( addrspec -- datagram )
 353     [
 354         [ (raw) |dispose ] keep
 355         [ drop raw-port <port> ] [ get-local-address ] 2bi
 356         >>addr
 357     ] with-destructors ;
 358
 359 : <broadcast> ( addrspec -- datagram )
 360     <datagram> (broadcast) ;
 361
 362 : receive-unsafe ( n buf datagram -- count addrspec )
 363     check-receive
 364     [ (receive-unsafe) ] [ addr>> ] bi parse-sockaddr ; inline
 365
 366 CONSTANT: datagram-size 65536
 367
 368 :: receive ( datagram -- bytes addrspec )
 369     datagram-size (byte-array) :> buf
 370     datagram-size buf datagram
 371     receive-unsafe :> ( count addrspec )
 372     count buf resize addrspec ; inline
 373
 374 :: receive-into ( buf datagram -- buf-slice addrspec )
 375     buf length :> n
 376     n buf datagram receive-unsafe :> ( count addrspec )
 377     buf count head-slice addrspec ; inline
 378
 379 : send ( bytes addrspec datagram -- )
 380     check-send (send) ; inline
 381
 382 MEMO: ipv6-supported? ( -- ? )
 383     [ "::1" 0 <inet6> binary <server> dispose t ] [ drop f ] recover ;
 384
 385 STARTUP-HOOK: [ \ ipv6-supported? reset-memoized ]
 386
 387 GENERIC: resolve-host ( addrspec -- seq )
 388
 389 HOOK: resolve-localhost os ( -- obj )
 390
 391 TUPLE: hostname { host maybe{ string } read-only } ;
 392
 393 TUPLE: inet < hostname port ;
 394
 395 M: inet present
 396     [ host>> ] [ port>> number>string ] bi ":" glue ;
 397
 398 C: <inet> inet
 399
 400 M:: string resolve-host ( host -- seq )
 401     host f prepare-addrinfo f void* <ref> [
 402         getaddrinfo [
 403             dup addrinfo-error-string host addrinfo-error
 404         ] unless-zero
 405     ] keep void* deref addrinfo memory>struct
 406     [ parse-addrinfo-list ] keep freeaddrinfo ;
 407
 408 M: string with-port <inet> ;
 409
 410 M: hostname resolve-host
 411     host>> resolve-host ;
 412
 413 M: hostname with-port
 414     [ host>> ] dip <inet> ;
 415
 416 M: inet resolve-host
 417     [ call-next-method ] [ port>> ] bi '[ _ with-port ] map ;
 418
 419 M: inet4 resolve-host 1array ;
 420
 421 M: inet6 resolve-host 1array ;
 422
 423 M: local resolve-host 1array ;
 424
 425 M: f resolve-host
 426     drop resolve-localhost ;
 427
 428 M: object resolve-localhost
 429     ipv6-supported?
 430     { T{ ipv4 f "0.0.0.0" } T{ ipv6 f "::" } }
 431     { T{ ipv4 f "0.0.0.0" } }
 432     ? ;
 433
 434 HOOK: host-name os ( -- string )
 435
 436 M: inet (client) resolve-host (client) ;
 437
 438 ERROR: invalid-inet-server addrspec ;
 439
 440 M: invalid-inet-server summary
 441     drop "Cannot use <server> with <inet>; use <inet4> or <inet6> instead" ;
 442
 443 M: inet (server)
 444     invalid-inet-server ;
 445
 446 ERROR: invalid-local-address addrspec ;
 447
 448 M: invalid-local-address summary
 449     drop "Cannot use with-local-address with <inet>; use <inet4> or <inet6> instead" ;
 450
 451 : with-local-address ( addr quot -- )
 452     [
 453         [ ] [ inet4? ] [ inet6? ] tri or
 454         [ bind-local-address ]
 455         [ invalid-local-address ] if
 456     ] dip with-variable ; inline
 457
 458 : protocol-port ( protocol -- port )
 459     [ f getservbyname [ port>> htons ] [ f ] if* ] [ f ] if* ;
 460
 461 : port-protocol ( port -- protocol )
 462     [ htons f getservbyport [ name>> ] [ f ] if* ] [ f ] if* ;
 463
 464 : <any-port-local-inet4> ( -- inet4 ) f 0 <inet4> ;
 465 : <any-port-local-inet6> ( -- inet6 ) f 0 <inet6> ;
 466
 467 GENERIC: <any-port-local-inet> ( inet -- inet4 )
 468 M: inet4 <any-port-local-inet> drop <any-port-local-inet4> ;
 469 M: inet6 <any-port-local-inet> drop f 0 <inet6> ;
 470
 471 : <any-port-local-datagram> ( inet -- datagram )
 472     <any-port-local-inet> <datagram> ;
 473
 474 : <any-port-local-broadcast> ( inet -- datagram )
 475     <any-port-local-inet> <broadcast> ;
 476
 477 : with-any-port-local-datagram ( quot -- )
 478     [ dup <any-port-local-datagram> ] dip with-disposal ; inline
 479
 480 : with-any-port-local-broadcast ( quot -- )
 481     [ dup <any-port-local-broadcast> ] dip with-disposal ; inline
 482
 483 : send-once ( bytes addrspec -- )
 484     [ send ] with-any-port-local-datagram ;
 485
 486 : broadcast-once ( bytes addrspec -- )
 487     [ send ] with-any-port-local-broadcast ;
 488
 489 {
 490     { [ os unix? ] [ "io.sockets.unix" require ] }
 491     { [ os windows? ] [ "io.sockets.windows" require ] }
 492 } cond