basis/ui/backend/cocoa/tools/tools.factor

   1 ! Copyright (C) 2006, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: alien.syntax cocoa cocoa.application cocoa.classes
   4 cocoa.dialogs cocoa.nibs cocoa.pasteboard cocoa.runtime
   5 cocoa.subclassing core-foundation.strings eval kernel listener
   6 locals memory namespaces system ui.backend.cocoa
   7 ui.theme.switching ui.tools.browser ui.tools.listener
   8 vocabs.refresh ;
   9 FROM: alien.c-types => int void ;
  10 IN: ui.backend.cocoa.tools
  11
  12 : finder-run-files ( alien -- )
  13     CF>string-array listener-run-files
  14     NSApp NSApplicationDelegateReplySuccess
  15     -> replyToOpenOrPrint: ;
  16
  17 : menu-run-files ( -- )
  18     open-panel [ listener-run-files ] when* ;
  19
  20 : menu-save-image ( -- )
  21     image-path save-panel [ save-image ] when* ;
  22
  23 ! Handle Open events from the Finder
  24 <CLASS: FactorWorkspaceApplicationDelegate < FactorApplicationDelegate
  25
  26     METHOD: void application: id app openFiles: id files [ files finder-run-files ] ;
  27
  28     METHOD: int applicationShouldHandleReopen: id app hasVisibleWindows: int flag [ flag 0 = [ show-listener ] when 1 ] ;
  29
  30     METHOD: id showFactorListener: id app [ show-listener f ] ;
  31
  32     METHOD: id showFactorBrowser: id app [ show-browser f ] ;
  33
  34     METHOD: id newFactorListener: id app [ listener-window f ] ;
  35
  36     METHOD: id newFactorBrowser: id app [ browser-window f ] ;
  37
  38     METHOD: id runFactorFile: id app [ menu-run-files f ] ;
  39
  40     METHOD: id saveFactorImage: id app [ save f ] ;
  41
  42     METHOD: id saveFactorImageAs: id app [ menu-save-image f ] ;
  43
  44     METHOD: id switchLightTheme: id app [ light-mode f ] ;
  45
  46     METHOD: id switchDarkTheme: id app [ dark-mode f ] ;
  47
  48     METHOD: id refreshAll: id app [ [ refresh-all ] \ refresh-all call-listener f ] ;
  49 ;CLASS>
  50
  51 : install-workspace-delegate ( -- )
  52     NSApp FactorWorkspaceApplicationDelegate install-delegate ;
  53
  54 ! Service support; evaluate Factor code from other apps
  55 :: do-service ( pboard error quot -- )
  56     pboard error ?pasteboard-string
  57     dup [ quot call( string -- result/f ) ] when
  58     [ pboard set-pasteboard-string ] when* ;
  59
  60 <CLASS: FactorServiceProvider < NSObject
  61
  62     METHOD: void evalInListener: id pboard userData: id userData error: id error
  63     [ pboard error [ eval-listener f ] do-service ] ;
  64
  65     METHOD: void evalToString: id pboard userData: id userData error: id error
  66     [
  67         pboard error
  68         [ [ (eval>string) ] with-interactive-vocabs ] do-service
  69     ] ;
  70 ;CLASS>
  71
  72 : register-services ( -- )
  73     NSApp
  74     FactorServiceProvider -> alloc -> init
  75     -> setServicesProvider: ;
  76
  77 FUNCTION: void NSUpdateDynamicServices ( )
  78
  79 [
  80     install-workspace-delegate
  81     "Factor.nib" load-nib
  82     register-services
  83 ] cocoa-startup-hook set-global