basis/ui/gadgets/editors/editors.factor

   1 ! Copyright (C) 2006, 2011 Slava Pestov
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs calendar colors combinators
   4 combinators.short-circuit documents documents.elements fonts fry
   5 grouping kernel literals locals make math math.functions
   6 math.order ranges math.rectangles math.vectors models
   7 models.arrow namespaces opengl opengl.gl sequences sorting
   8 splitting system timers ui.baseline-alignment ui.clipboards
   9 ui.commands ui.gadgets ui.gadgets.borders
  10 ui.gadgets.line-support ui.gadgets.menus ui.gadgets.scrollers
  11 ui.gestures ui.pens.solid ui.render ui.text ui.theme unicode ;
  12 IN: ui.gadgets.editors
  13
  14 TUPLE: editor < line-gadget
  15     caret mark
  16     focused? blink blink-timer
  17     default-text
  18     preedit-start
  19     preedit-end
  20     preedit-selected-start
  21     preedit-selected-end
  22     preedit-selection-mode?
  23     preedit-underlines ;
  24
  25 M: editor preedit? preedit-start>> ;
  26
  27 <PRIVATE
  28
  29 : <loc> ( -- loc ) { 0 0 } <model> ;
  30
  31 : init-editor-locs ( editor -- editor )
  32     <loc> >>caret
  33     <loc> >>mark ; inline
  34
  35 : editor-theme ( editor -- editor )
  36     monospace-font >>font ; inline
  37
  38 PRIVATE>
  39
  40 : new-editor ( class -- editor )
  41     new-line-gadget
  42         <document> >>model
  43         init-editor-locs
  44         editor-theme ; inline
  45
  46 : <editor> ( -- editor )
  47     editor new-editor ;
  48
  49 <PRIVATE
  50
  51 : activate-editor-model ( editor model -- )
  52     [ add-connection ]
  53     [ nip activate-model ]
  54     [ swap model>> add-loc ] 2tri ;
  55
  56 : deactivate-editor-model ( editor model -- )
  57     [ remove-connection ]
  58     [ nip deactivate-model ]
  59     [ swap model>> remove-loc ] 2tri ;
  60
  61 : blink-caret ( editor -- )
  62     [ not ] change-blink relayout-1 ;
  63
  64 SYMBOL: blink-interval
  65
  66 750 milliseconds blink-interval set-global
  67
  68 : stop-blinking ( editor -- )
  69     blink-timer>> [ stop-timer ] when* ;
  70
  71 : start-blinking ( editor -- )
  72     t >>blink
  73     blink-timer>> [ restart-timer ] when* ;
  74
  75 : restart-blinking ( editor -- )
  76     dup focused?>> [
  77         [ start-blinking ]
  78         [ relayout-1 ]
  79         bi
  80     ] [ drop ] if ;
  81
  82 PRIVATE>
  83
  84 M: editor graft*
  85     [ dup caret>> activate-editor-model ]
  86     [ dup mark>> activate-editor-model ]
  87     [
  88         [
  89             '[ _ blink-caret ] blink-interval get dup <timer>
  90         ] keep blink-timer<<
  91     ] tri ;
  92
  93 M: editor ungraft*
  94     [ [ stop-blinking ] [ f >>blink-timer drop ] bi ]
  95     [ dup caret>> deactivate-editor-model ]
  96     [ dup mark>> deactivate-editor-model ] tri ;
  97
  98 : editor-caret ( editor -- loc ) caret>> value>> ;
  99
 100 : editor-mark ( editor -- loc ) mark>> value>> ;
 101
 102 : set-caret ( loc editor -- )
 103     [ model>> validate-loc ] [ caret>> ] bi set-model ;
 104
 105 : set-mark ( loc editor -- )
 106     [ model>> validate-loc ] [ mark>> ] bi set-model ;
 107
 108 : change-caret ( editor quot: ( loc document -- newloc ) -- )
 109     [ [ [ editor-caret ] [ model>> ] bi ] dip call ] [ drop ] 2bi
 110     set-caret ; inline
 111
 112 : mark>caret ( editor -- )
 113     [ editor-caret ] [ mark>> ] bi set-model ;
 114
 115 : change-caret&mark ( editor quot: ( loc document -- newloc ) -- )
 116     [ change-caret ] [ drop mark>caret ] 2bi ; inline
 117
 118 : editor-line ( n editor -- str ) control-value nth ;
 119
 120 :: point>loc ( point editor -- loc )
 121     point second editor y>line {
 122         { [ dup 0 < ] [ drop { 0 0 } ] }
 123         { [ dup editor model>> last-line# > ] [ drop editor model>> doc-end ] }
 124         [| n |
 125             n
 126             point first
 127             editor font>>
 128             n editor editor-line
 129             x>offset 2array
 130         ]
 131     } cond ;
 132
 133 : clicked-loc ( editor -- loc )
 134     [ hand-rel ] keep point>loc ;
 135
 136 : click-loc ( editor model -- )
 137     [ clicked-loc ] dip set-model ;
 138
 139 : focus-editor ( editor -- )
 140     [ start-blinking ] [ t >>focused? relayout-1 ] bi ;
 141
 142 : unfocus-editor ( editor -- )
 143     [ stop-blinking ] [ f >>focused? relayout-1 ] bi ;
 144
 145 : loc>x ( loc editor -- x )
 146     [ first2 swap ] dip [ editor-line ] [ font>> ] bi swap offset>x gl-round ;
 147
 148 : loc>point ( loc editor -- loc )
 149     [ loc>x ] [ [ first ] dip line>y gl-ceiling ] 2bi 2array ;
 150
 151 : caret-loc ( editor -- loc )
 152     [ editor-caret ] keep loc>point ;
 153
 154 : caret-dim ( editor -- dim )
 155     [ 0 ] dip line-height 2array ;
 156
 157 : scroll>caret ( editor -- )
 158     dup graft-state>> second [
 159         [
 160             [ caret-loc ] [ caret-dim { 2 1 } v+ ] bi <rect>
 161         ] keep scroll>rect
 162     ] [ drop ] if ;
 163
 164 <PRIVATE
 165
 166 : draw-caret? ( editor -- ? )
 167     { [ focused?>> ] [ blink>> ]
 168       [ [ preedit? not ] [ preedit-selection-mode?>> not ] bi or ] } 1&& ;
 169
 170 : draw-caret ( editor -- )
 171     dup draw-caret? [
 172         [ editor-caret-color gl-color ] dip
 173         [ caret-loc ] [ caret-dim ] bi
 174         over v+ gl-line
 175     ] [ drop ] if ;
 176
 177 :: draw-preedit-underlines ( editor -- )
 178     editor [ preedit? ] [ preedit-underlines>> ] bi and [
 179         editor [ caret-loc second ] [ caret-dim second ] bi + 2.0 - :> y
 180         editor editor-caret first :> row
 181         editor font>> foreground>> gl-color
 182         editor preedit-underlines>> [
 183             GL_LINE_BIT [
 184                 dup second glLineWidth
 185                 first editor preedit-start>> second dup 2array v+ first2
 186                 [ row swap 2array editor loc>x 1.0 + y 2array ]
 187                 [ row swap 2array editor loc>x 1.0 - y 2array ]
 188                 bi*
 189                 gl-line
 190             ] do-attribs
 191         ] each
 192     ] when ;
 193
 194 : selection-start/end ( editor -- start end )
 195     [ editor-mark ] [ editor-caret ] bi sort-pair ;
 196
 197 SYMBOL: selected-lines
 198
 199 TUPLE: selected-line start end first? last? ;
 200
 201 : compute-selection ( editor -- assoc )
 202     dup gadget-selection? [
 203         [ selection-start/end [ [ first ] bi@ [a..b] ] [ ] 2bi ]
 204         [ model>> ] bi
 205         '[ [ _ _ ] [ _ start/end-on-line ] bi 2array ] H{ } map>assoc
 206     ] [ drop f ] if ;
 207
 208 :: draw-selection ( line pair editor -- )
 209     pair [ editor font>> line offset>x gl-round ] map :> pair
 210     editor selection-color>> gl-color
 211     pair first 0 2array
 212     pair second pair first - 1 max editor line-height 2array
 213     gl-fill-rect ;
 214
 215 : draw-unselected-line ( line editor -- )
 216     font>> swap draw-text ;
 217
 218 : draw-selected-line ( line pair editor -- )
 219     over all-equal? [
 220         [ nip draw-unselected-line ] [ draw-selection ] 3bi
 221     ] [
 222         [ draw-selection ]
 223         [
 224             [ [ first2 ] [ selection-color>> ] bi* <selection> ]
 225             [ draw-unselected-line ] bi
 226         ] 3bi
 227     ] if ;
 228
 229 : draw-default-text? ( editor -- ? )
 230     { [ default-text>> ] [ model>> doc-string empty? ] } 1&& ;
 231
 232 : draw-default-text ( editor -- )
 233     [ font>> clone line-color >>foreground ]
 234     [ default-text>> ] bi draw-text ;
 235
 236 PRIVATE>
 237
 238 M: editor draw-line
 239     [ selected-lines get at ] dip over
 240     [ draw-selected-line ] [ nip draw-unselected-line ] if ;
 241
 242 M: editor draw-gadget*
 243     dup draw-default-text? [
 244         [ draw-default-text ] [ draw-caret ] [ draw-preedit-underlines ] tri
 245     ] [
 246         dup compute-selection selected-lines [
 247             [ draw-lines ] [ draw-caret ] [ draw-preedit-underlines ] tri
 248         ] with-variable
 249     ] if ;
 250
 251 M: editor pref-dim*
 252     [ call-next-method ] keep ! at least as big as our min-rows/min-cols
 253     ! Add some space for the caret.
 254     [ font>> ] keep dup draw-default-text?
 255     [ default-text>> ] [ control-value ] if
 256     text-dim { 1 0 } v+ vmax ;
 257
 258 M: editor baseline font>> font-metrics ascent>> ;
 259
 260 M: editor cap-height font>> font-metrics cap-height>> ;
 261
 262 <PRIVATE
 263
 264 : contents-changed ( model editor -- )
 265     [ [ nip caret>> ] [ drop ] 2bi '[ _ validate-loc ] (change-model) ]
 266     [ [ nip mark>> ] [ drop ] 2bi '[ _ validate-loc ] (change-model) ]
 267     [ nip relayout ] 2tri ;
 268
 269 : caret/mark-changed ( editor -- )
 270     [ restart-blinking ] keep scroll>caret ;
 271
 272 PRIVATE>
 273
 274 M: editor model-changed
 275     {
 276         { [ 2dup model>> eq? ] [ contents-changed ] }
 277         { [ 2dup caret>> eq? ] [ nip caret/mark-changed ] }
 278         { [ 2dup mark>> eq? ] [ nip caret/mark-changed ] }
 279     } cond ;
 280
 281 M: editor gadget-selection?
 282     selection-start/end = not ;
 283
 284 M: editor gadget-selection
 285     [ selection-start/end ] [ model>> ] bi doc-range ;
 286
 287 : remove-selection ( editor -- )
 288     [ selection-start/end ] [ model>> ] bi remove-doc-range ;
 289
 290 M: editor user-input*
 291     [ selection-start/end ] [ model>> ] bi set-doc-range t ;
 292
 293 M: editor temp-im-input
 294     [ selection-start/end ] [ model>> ] bi set-doc-range* t ;
 295
 296 : editor-string ( editor -- string )
 297     model>> doc-string ;
 298
 299 : set-editor-string ( string editor -- )
 300     model>> set-doc-string ;
 301
 302 M: editor gadget-text* editor-string % ;
 303
 304 : extend-selection ( editor -- )
 305     [ request-focus ]
 306     [ restart-blinking ]
 307     [ dup caret>> click-loc ] tri ;
 308
 309 : remove-preedit-text ( editor -- )
 310     { [ preedit-start>> ] [ set-caret ]
 311       [ preedit-end>> ] [ set-mark ]
 312       [ remove-selection ]
 313     } cleave ;
 314
 315 : remove-preedit-info ( editor -- )
 316     f >>preedit-start
 317     f >>preedit-end
 318     f >>preedit-selected-start
 319     f >>preedit-selected-end
 320     f >>preedit-selection-mode?
 321     f >>preedit-underlines
 322     drop ;
 323
 324 : mouse-elt ( -- element )
 325     hand-click# get {
 326         { 1 one-char-elt }
 327         { 2 one-word-elt }
 328     } at one-line-elt or ;
 329
 330 : drag-direction? ( loc editor -- ? )
 331     editor-mark before? ;
 332
 333 : drag-selection-caret ( loc editor element -- loc )
 334     [
 335         [ drag-direction? ] [ model>> ] 2bi
 336     ] dip prev/next-elt ? ;
 337
 338 : drag-selection-mark ( loc editor element -- loc )
 339     [
 340         [ drag-direction? not ]
 341         [ editor-mark ]
 342         [ model>> ] tri
 343     ] dip prev/next-elt ? ;
 344
 345 : drag-caret&mark ( editor -- caret mark )
 346     [ clicked-loc ] [ mouse-elt ] bi
 347     [ drag-selection-caret ]
 348     [ drag-selection-mark ] 3bi ;
 349
 350 : drag-selection ( editor -- )
 351     [ drag-caret&mark ]
 352     [ mark>> set-model ]
 353     [ caret>> set-model ] tri ;
 354
 355 : editor-cut ( editor clipboard -- )
 356     [ gadget-copy ] [ drop remove-selection ] 2bi ;
 357
 358 : delete/backspace ( editor quot -- )
 359     over gadget-selection? [
 360         drop remove-selection
 361     ] [
 362         [ [ [ editor-caret ] [ model>> ] bi ] dip call ]
 363         [ drop model>> ]
 364         2bi remove-doc-range
 365     ] if ; inline
 366
 367 : editor-delete ( editor elt -- )
 368     '[ dupd _ next-elt ] delete/backspace ;
 369
 370 : editor-backspace ( editor elt -- )
 371     '[ over [ _ prev-elt ] dip ] delete/backspace ;
 372
 373 : editor-select-prev ( editor elt -- )
 374     '[ _ prev-elt ] change-caret ;
 375
 376 : editor-prev ( editor elt -- )
 377     [ editor-select-prev ] [ drop mark>caret ] 2bi ;
 378
 379 : editor-select-next ( editor elt -- )
 380     '[ _ next-elt ] change-caret ;
 381
 382 : editor-next ( editor elt -- )
 383     dupd editor-select-next mark>caret ;
 384
 385 : editor-select ( from to editor -- )
 386     [ mark>> set-model ] [ caret>> set-model ] bi-curry bi* ;
 387
 388 : select-elt ( editor elt -- )
 389     [ [ [ editor-caret ] [ model>> ] bi ] dip prev/next-elt ] [ drop ] 2bi
 390     editor-select ;
 391
 392 : start-of-document ( editor -- ) doc-elt editor-prev ;
 393
 394 : end-of-document ( editor -- ) doc-elt editor-next ;
 395
 396 : position-caret ( editor -- )
 397     mouse-elt dup one-char-elt =
 398     [ drop dup extend-selection dup mark>> click-loc ]
 399     [ select-elt ] if ;
 400
 401 : delete-previous-character ( editor -- )
 402     char-elt editor-backspace ;
 403
 404 : delete-next-character ( editor -- )
 405     char-elt editor-delete ;
 406
 407 : delete-previous-word ( editor -- )
 408     word-elt editor-backspace ;
 409
 410 : delete-next-word ( editor -- )
 411     word-elt editor-delete ;
 412
 413 : delete-to-start-of-line ( editor -- )
 414     one-line-elt editor-backspace ;
 415
 416 : delete-to-end-of-line ( editor -- )
 417     one-line-elt editor-delete ;
 418
 419 : delete-to-start-of-document ( editor -- )
 420     doc-elt editor-delete ;
 421
 422 : delete-to-end-of-document ( editor -- )
 423     doc-elt editor-delete ;
 424
 425 : com-undo ( editor -- ) model>> undo ;
 426
 427 : com-redo ( editor -- ) model>> redo ;
 428
 429 editor "editing" f {
 430     { undo-action com-undo }
 431     { redo-action com-redo }
 432     { T{ key-down f f "DELETE" } delete-next-character }
 433     { T{ key-down f f "BACKSPACE" } delete-previous-character }
 434     { T{ key-down f { S+ } "DELETE" } delete-next-character }
 435     { T{ key-down f { S+ } "BACKSPACE" } delete-previous-character }
 436     { T{ key-down f ${ os macosx? A+ C+ ? } "DELETE" } delete-next-word }
 437     { T{ key-down f ${ os macosx? A+ C+ ? } "BACKSPACE" } delete-previous-word }
 438     { T{ key-down f ${ os macosx? M+ A+ ? } "DELETE" } delete-to-end-of-line }
 439     { T{ key-down f ${ os macosx? M+ A+ ? } "BACKSPACE" } delete-to-start-of-line }
 440 } os macosx? [ {
 441     { T{ key-down f { C+ } "DELETE" } delete-next-character }
 442     { T{ key-down f { C+ } "BACKSPACE" } delete-previous-character }
 443 } append ] when define-command-map
 444
 445 : com-paste ( editor -- ) clipboard get paste-clipboard ;
 446
 447 : paste-selection ( editor -- ) ui.clipboards:selection get paste-clipboard ;
 448
 449 : com-cut ( editor -- ) clipboard get editor-cut ;
 450
 451 editor "clipboard" f {
 452     { cut-action com-cut }
 453     { copy-action com-copy }
 454     { paste-action com-paste }
 455     { T{ button-up } com-copy-selection }
 456     { T{ button-up f f 2 } paste-selection }
 457 } define-command-map
 458
 459 : previous-character ( editor -- )
 460     dup gadget-selection? [
 461         dup selection-start/end drop
 462         over set-caret mark>caret
 463     ] [
 464         char-elt editor-prev
 465     ] if ;
 466
 467 : next-character ( editor -- )
 468     dup gadget-selection? [
 469         dup selection-start/end nip
 470         over set-caret mark>caret
 471     ] [
 472         char-elt editor-next
 473     ] if ;
 474
 475 : previous-word ( editor -- ) word-elt editor-prev ;
 476
 477 : next-word ( editor -- ) word-elt editor-next ;
 478
 479 : start-of-line ( editor -- ) one-line-elt editor-prev ;
 480
 481 : end-of-line ( editor -- ) one-line-elt editor-next ;
 482
 483 : start-of-paragraph ( editor -- ) paragraph-elt editor-prev ;
 484
 485 : end-of-paragraph ( editor -- ) paragraph-elt editor-next ;
 486
 487 editor "caret-motion" f {
 488     { T{ button-down } position-caret }
 489     { T{ key-down f f "LEFT" } previous-character }
 490     { T{ key-down f f "RIGHT" } next-character }
 491     { T{ key-down f ${ os macosx? A+ C+ ? } "LEFT" } previous-word }
 492     { T{ key-down f ${ os macosx? A+ C+ ? } "RIGHT" } next-word }
 493     { T{ key-down f f "HOME" } start-of-line }
 494     { T{ key-down f f "END" } end-of-line }
 495     { T{ key-down f ${ os macosx? A+ C+ ? } "UP" } start-of-paragraph }
 496     { T{ key-down f ${ os macosx? A+ C+ ? } "DOWN" } end-of-paragraph }
 497     { T{ key-down f ${ os macosx? A+ C+ ? } "HOME" } start-of-document }
 498     { T{ key-down f ${ os macosx? A+ C+ ? } "END" } end-of-document }
 499 } os macosx? [ {
 500     { T{ key-down f { M+ } "LEFT" } start-of-line }
 501     { T{ key-down f { M+ } "RIGHT" } end-of-line }
 502     { T{ key-down f { M+ } "UP" } start-of-paragraph }
 503     { T{ key-down f { M+ } "DOWN" } end-of-paragraph }
 504     { T{ key-down f { M+ } "HOME" } start-of-document }
 505     { T{ key-down f { M+ } "END" } end-of-document }
 506 } append ] when define-command-map
 507
 508 : clear-editor ( editor -- )
 509     model>> clear-doc ;
 510
 511 : select-all ( editor -- ) doc-elt select-elt ;
 512
 513 : select-line ( editor -- ) one-line-elt select-elt ;
 514
 515 : select-word ( editor -- ) one-word-elt select-elt ;
 516
 517 : selected-token ( editor -- string )
 518     dup gadget-selection?
 519     [ dup select-word ] unless
 520     gadget-selection ;
 521
 522 : select-previous-character ( editor -- )
 523     char-elt editor-select-prev ;
 524
 525 : select-next-character ( editor -- )
 526     char-elt editor-select-next ;
 527
 528 : select-previous-word ( editor -- )
 529     word-elt editor-select-prev ;
 530
 531 : select-next-word ( editor -- )
 532     word-elt editor-select-next ;
 533
 534 : select-start-of-line ( editor -- )
 535     one-line-elt editor-select-prev ;
 536
 537 : select-end-of-line ( editor -- )
 538     one-line-elt editor-select-next ;
 539
 540 : select-start-of-paragraph ( editor -- )
 541     paragraph-elt editor-select-prev ;
 542
 543 : select-end-of-paragraph ( editor -- )
 544     paragraph-elt editor-select-next ;
 545
 546 : select-start-of-document ( editor -- )
 547     doc-elt editor-select-prev ;
 548
 549 : select-end-of-document ( editor -- )
 550     doc-elt editor-select-next ;
 551
 552 editor "selection" f {
 553     { T{ button-down f { S+ } 1 } extend-selection }
 554     { T{ button-up f { S+ } 1 } com-copy-selection }
 555     { T{ drag { # 1 } } drag-selection }
 556     { gain-focus focus-editor }
 557     { lose-focus unfocus-editor }
 558     { delete-action remove-selection }
 559     { select-all-action select-all }
 560     { T{ key-down f { C+ } "l" } select-line }
 561     { T{ key-down f { S+ } "LEFT" } select-previous-character }
 562     { T{ key-down f { S+ } "RIGHT" } select-next-character }
 563     { T{ key-down f ${ S+ os macosx? A+ C+ ? } "LEFT" } select-previous-word }
 564     { T{ key-down f ${ S+ os macosx? A+ C+ ? } "RIGHT" } select-next-word }
 565     { T{ key-down f { S+ } "HOME" } select-start-of-line }
 566     { T{ key-down f { S+ } "END" } select-end-of-line }
 567     { T{ key-down f ${ S+ os macosx? A+ C+ ? } "UP" } select-start-of-paragraph }
 568     { T{ key-down f ${ S+ os macosx? A+ C+ ? } "DOWN" } select-end-of-paragraph }
 569     { T{ key-down f ${ S+ os macosx? A+ C+ ? } "HOME" } select-start-of-document }
 570     { T{ key-down f ${ S+ os macosx? A+ C+ ? } "END" } select-end-of-document }
 571 } os macosx? [ {
 572     { T{ key-down f { S+ M+ } "LEFT" } select-start-of-line }
 573     { T{ key-down f { S+ M+ } "RIGHT" } select-end-of-line }
 574     { T{ key-down f { S+ M+ } "UP" } select-start-of-paragraph }
 575     { T{ key-down f { S+ M+ } "DOWN" } select-end-of-paragraph }
 576     { T{ key-down f { S+ M+ } "HOME" } select-start-of-document }
 577     { T{ key-down f { S+ M+ } "END" } select-end-of-document }
 578 } append ] when define-command-map
 579
 580 : editor-menu ( editor -- )
 581     {
 582         com-undo
 583         com-redo
 584         ----
 585         com-cut
 586         com-copy
 587         com-paste
 588     } show-commands-menu ;
 589
 590 editor "misc" f {
 591     ! { T{ button-down f f 2 } paste-selection }
 592     { T{ button-down f f 3 } editor-menu }
 593 } define-command-map
 594
 595 ! Multi-line editors
 596 TUPLE: multiline-editor < editor ;
 597
 598 : <multiline-editor> ( -- editor )
 599     multiline-editor new-editor ;
 600
 601 : previous-line ( editor -- ) line-elt editor-prev ;
 602
 603 : next-line ( editor -- ) line-elt editor-next ;
 604
 605 <PRIVATE
 606
 607 : page-elt ( editor n -- editor element )
 608     over visible-lines 1 - min 1 max <page-elt> ;
 609
 610 : prev-page-elt ( editor -- editor element )
 611     dup editor-caret first page-elt ;
 612
 613 : next-page-elt ( editor -- editor element )
 614     dup [ control-value length 1 - ] [ editor-caret first ] bi - page-elt ;
 615
 616 PRIVATE>
 617
 618 : previous-page ( editor -- ) prev-page-elt editor-prev ;
 619
 620 : next-page ( editor -- ) next-page-elt editor-next ;
 621
 622 : select-previous-line ( editor -- ) line-elt editor-select-prev ;
 623
 624 : select-next-line ( editor -- ) line-elt editor-select-next ;
 625
 626 : select-previous-page ( editor -- ) prev-page-elt editor-select-prev ;
 627
 628 : select-next-page ( editor -- ) next-page-elt editor-select-next ;
 629
 630 : insert-newline ( editor -- )
 631     "\n" swap user-input* drop ;
 632
 633 : change-selection ( editor quot -- )
 634     '[ gadget-selection @ ] [ user-input* drop ] bi ; inline
 635
 636 <PRIVATE
 637
 638 : join-lines ( string -- string' )
 639     split-lines
 640     [ rest-slice [ [ blank? ] trim-head-slice ] map! drop ]
 641     [ but-last-slice [ [ blank? ] trim-tail-slice ] map! drop ]
 642     [ join-words ]
 643     tri ;
 644
 645 : last-line? ( document line -- ? )
 646     [ last-line# ] dip = ;
 647
 648 : prev-line-and-this ( document line -- start end )
 649     swap [ drop 1 - 0 2array ] [ line-end ] 2bi ;
 650
 651 : join-with-prev ( document line -- )
 652     [ prev-line-and-this ] [ drop ] 2bi
 653     [ join-lines ] change-doc-range ;
 654
 655 : this-line-and-next ( document line -- start end )
 656     swap [ drop 0 2array ] [ [ 1 + ] dip line-end ] 2bi ;
 657
 658 : join-with-next ( document line -- )
 659     [ this-line-and-next ] [ drop ] 2bi
 660     [ join-lines ] change-doc-range ;
 661
 662 PRIVATE>
 663
 664 : com-join-lines ( editor -- )
 665     dup gadget-selection?
 666     [ [ join-lines ] change-selection ] [
 667         [ model>> ] [ editor-caret first ] bi {
 668             { [ over last-line# 0 = ] [ 2drop ] }
 669             { [ 2dup last-line? ] [ join-with-prev ] }
 670             [ join-with-next ]
 671         } cond
 672     ] if ;
 673
 674 multiline-editor "multiline" f {
 675     { T{ key-down f f "UP" } previous-line }
 676     { T{ key-down f f "DOWN" } next-line }
 677     { T{ key-down f { S+ } "UP" } select-previous-line }
 678     { T{ key-down f { S+ } "DOWN" } select-next-line }
 679     { T{ key-down f f "PAGE_UP" } previous-page }
 680     { T{ key-down f f "PAGE_DOWN" } next-page }
 681     { T{ key-down f { S+ } "PAGE_UP" } select-previous-page }
 682     { T{ key-down f { S+ } "PAGE_DOWN" } select-next-page }
 683     { T{ key-down f f "RET" } insert-newline }
 684     { T{ key-down f { S+ } "RET" } insert-newline }
 685     { T{ key-down f f "ENTER" } insert-newline }
 686     { T{ key-down f { S+ } "ENTER" } insert-newline }
 687     { T{ key-down f { C+ } "j" } com-join-lines }
 688 } define-command-map
 689
 690 TUPLE: source-editor < multiline-editor ;
 691
 692 : <source-editor> ( -- editor )
 693     source-editor new-editor ;
 694
 695 ! A useful model
 696 : <element-model> ( editor element -- model )
 697     [ [ caret>> ] [ model>> ] bi ] dip
 698     '[ _ _ elt-string ] <arrow> ;
 699
 700 ! Fields wrap an editor
 701 TUPLE: field < border editor min-cols max-cols ;
 702
 703 <PRIVATE
 704
 705 : field-theme ( gadget -- gadget )
 706     { 2 2 } >>size
 707     { 1 0 } >>fill
 708     field-border-color <solid> >>boundary ; inline
 709
 710 : <field-border> ( gadget -- border )
 711     border new-border field-theme ;
 712
 713 PRIVATE>
 714
 715 : new-field ( class -- gadget )
 716     [ <editor> ] dip new-border
 717         dup gadget-child >>editor
 718         field-theme ; inline
 719
 720 ! For line-gadget-width
 721 M: field font>> editor>> font>> ;
 722
 723 M: field pref-dim*
 724     [ ]
 725     [ editor>> pref-dim ]
 726     [ [ line-gadget-width ] [ drop second ] 2bi 2array ]
 727     tri border-pref-dim ;
 728
 729 M: field default-text>> editor>> default-text>> ;
 730
 731 M: field default-text<< editor>> default-text<< ;
 732
 733 TUPLE: model-field < field field-model ;
 734
 735 : <model-field> ( model -- gadget )
 736     model-field new-field
 737         swap >>field-model ;
 738
 739 M: model-field graft*
 740     [ [ field-model>> value>> ] [ editor>> ] bi set-editor-string ]
 741     [ dup editor>> model>> add-connection ]
 742     bi ;
 743
 744 M: model-field ungraft*
 745     dup editor>> model>> remove-connection ;
 746
 747 M: model-field model-changed
 748     nip [ editor>> editor-string ] [ field-model>> ] bi set-model ;
 749
 750 TUPLE: action-field < field quot ;
 751
 752 : <action-field> ( quot: ( string -- ) -- gadget )
 753     action-field [ <editor> ] dip new-border
 754         dup gadget-child >>editor
 755         field-theme
 756         swap >>quot ;
 757
 758 : invoke-action-field ( field -- )
 759     [ editor>> editor-string ]
 760     [ editor>> clear-editor ]
 761     [ quot>> ]
 762     tri call( string -- ) ;
 763
 764 action-field H{
 765     { T{ key-down f f "RET" } [ invoke-action-field ] }
 766 } set-gestures
 767
 768 : readline-bindings ( editor-class -- )
 769     "readline" f {
 770         { T{ key-down f { C+ } "p" } previous-line }
 771         { T{ key-down f { C+ } "n" } next-line }
 772         { T{ key-down f { C+ } "b" } previous-character }
 773         { T{ key-down f { C+ } "f" } next-character }
 774         { T{ key-down f { C+ } "a" } start-of-line }
 775         { T{ key-down f { C+ } "e" } end-of-line }
 776         ! { T{ key-down f { C+ } "t" } transpose-character }
 777         { T{ key-down f { C+ } "d" } delete-next-character }
 778         { T{ key-down f { C+ } "h" } delete-previous-character }
 779         { T{ key-down f { C+ } "u" } delete-to-start-of-line }
 780         { T{ key-down f { C+ } "k" } delete-to-end-of-line }
 781         { T{ key-down f { C+ } "w" } delete-previous-word }
 782     } define-command-map ;