basis/ui/gadgets/editors/editors.factor

   1 ! Copyright (C) 2006, 2011 Slava Pestov
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs calendar colors combinators
   4 combinators.short-circuit documents documents.elements fonts fry
   5 grouping kernel literals locals make math math.functions
   6 math.order ranges math.rectangles math.vectors models
   7 models.arrow namespaces opengl opengl.gl sequences sorting
   8 splitting system timers ui.baseline-alignment ui.clipboards
   9 ui.commands ui.gadgets ui.gadgets.borders
  10 ui.gadgets.line-support ui.gadgets.menus ui.gadgets.scrollers
  11 prettyprint math.parser
  12 ui.gestures ui.pens.solid ui.render ui.text ui.theme unicode variables ;
  13 IN: ui.gadgets.editors
  14
  15 TUPLE: editor < line-gadget
  16     caret mark
  17     caret-shape
  18     focused? blink blink-timer
  19     default-text
  20     preedit-start
  21     preedit-end
  22     preedit-selected-start
  23     preedit-selected-end
  24     preedit-selection-mode?
  25     preedit-underlines ;
  26
  27 M: editor preedit? preedit-start>> ;
  28
  29 SYMBOLS: +line+ +box+ +filled+ ;
  30 SYMBOL: caret-style
  31 +line+ caret-style set-global
  32
  33 <PRIVATE
  34
  35 : <loc> ( -- loc ) { 0 0 } <model> ;
  36
  37 : init-editor-locs ( editor -- editor )
  38     <loc> >>caret
  39     <loc> >>mark ; inline
  40
  41 : editor-theme ( editor -- editor )
  42     monospace-font >>font ; inline
  43
  44 PRIVATE>
  45
  46 : new-editor ( class -- editor )
  47     new-line-gadget
  48         <document> >>model
  49         init-editor-locs
  50         editor-theme ; inline
  51
  52 : <editor> ( -- editor )
  53     editor new-editor ;
  54
  55 <PRIVATE
  56
  57 : activate-editor-model ( editor model -- )
  58     [ add-connection ]
  59     [ nip activate-model ]
  60     [ swap model>> add-loc ] 2tri ;
  61
  62 : deactivate-editor-model ( editor model -- )
  63     [ remove-connection ]
  64     [ nip deactivate-model ]
  65     [ swap model>> remove-loc ] 2tri ;
  66
  67 : blink-caret ( editor -- )
  68     [ not ] change-blink relayout-1 ;
  69
  70 SYMBOL: blink-interval
  71
  72 750 milliseconds blink-interval set-global
  73
  74 : stop-blinking ( editor -- )
  75     blink-timer>> [ stop-timer ] when* ;
  76
  77 : start-blinking ( editor -- )
  78     t >>blink
  79     blink-timer>> [ restart-timer ] when* ;
  80
  81 : restart-blinking ( editor -- )
  82     dup focused?>> [
  83         [ start-blinking ]
  84         [ relayout-1 ]
  85         bi
  86     ] [ drop ] if ;
  87
  88 PRIVATE>
  89
  90 M: editor graft*
  91     [ dup caret>> activate-editor-model ]
  92     [ dup mark>> activate-editor-model ]
  93     [
  94         [
  95             '[ _ blink-caret ] blink-interval get dup <timer>
  96         ] keep blink-timer<<
  97     ] tri ;
  98
  99 M: editor ungraft*
 100     [ [ stop-blinking ] [ f >>blink-timer drop ] bi ]
 101     [ dup caret>> deactivate-editor-model ]
 102     [ dup mark>> deactivate-editor-model ] tri ;
 103
 104 : editor-caret ( editor -- loc ) caret>> value>> ;
 105
 106 : editor-mark ( editor -- loc ) mark>> value>> ;
 107
 108 : set-caret ( loc editor -- )
 109     [ model>> validate-loc ] [ caret>> ] bi set-model ;
 110
 111 : set-mark ( loc editor -- )
 112     [ model>> validate-loc ] [ mark>> ] bi set-model ;
 113
 114 : change-caret ( editor quot: ( loc document -- newloc ) -- )
 115     [ [ [ editor-caret ] [ model>> ] bi ] dip call ] [ drop ] 2bi
 116     set-caret ; inline
 117
 118 : mark>caret ( editor -- )
 119     [ editor-caret ] [ mark>> ] bi set-model ;
 120
 121 : change-caret&mark ( editor quot: ( loc document -- newloc ) -- )
 122     [ change-caret ] [ drop mark>caret ] 2bi ; inline
 123
 124 : editor-line ( n editor -- str ) control-value nth ;
 125
 126 :: point>loc ( point editor -- loc )
 127     point second editor y>line {
 128         { [ dup 0 < ] [ drop { 0 0 } ] }
 129         { [ dup editor model>> last-line# > ] [ drop editor model>> doc-end ] }
 130         [| n |
 131             n
 132             point first
 133             editor font>>
 134             n editor editor-line
 135             x>offset 2array
 136         ]
 137     } cond ;
 138
 139 : clicked-loc ( editor -- loc )
 140     [ hand-rel ] keep point>loc ;
 141
 142 : click-loc ( editor model -- )
 143     [ clicked-loc ] dip set-model ;
 144
 145 : focus-editor ( editor -- )
 146     [ start-blinking ] [ t >>focused? relayout-1 ] bi ;
 147
 148 : unfocus-editor ( editor -- )
 149     [ stop-blinking ] [ f >>focused? relayout-1 ] bi ;
 150
 151 : loc>x ( loc editor -- x )
 152     [ first2 swap ] dip [ editor-line ] [ font>> ] bi swap offset>x gl-round ;
 153
 154 : loc>point ( loc editor -- loc )
 155     [ loc>x ] [ [ first ] dip line>y gl-ceiling ] 2bi 2array ;
 156
 157 : caret-loc ( editor -- loc )
 158     [ editor-caret ] keep loc>point ;
 159
 160 : caret-dim ( editor -- dim )
 161     [ 0 ] dip line-height 2array ;
 162
 163 : scroll>caret ( editor -- )
 164     dup graft-state>> second [
 165         [
 166             [ caret-loc ] [ caret-dim { 2 1 } v+ ] bi <rect>
 167         ] keep scroll>rect
 168     ] [ drop ] if ;
 169
 170 <PRIVATE
 171
 172 : draw-caret? ( editor -- ? )
 173     { [ focused?>> ] [ blink>> ]
 174       [ [ preedit? not ] [ preedit-selection-mode?>> not ] bi or ] } 1&& ;
 175
 176 : caret-line ( editor -- loc dim )
 177     [ caret-loc ] [ caret-dim ] bi ;
 178
 179 : caret-rect ( editor -- loc dim )
 180     caret-line second [ 2 / ] keep 2array ;
 181
 182 : draw-caret-line ( editor -- )
 183     caret-line over v+ gl-line ;
 184
 185 : draw-caret-rect ( editor -- )
 186     caret-rect gl-rect ;
 187
 188 : draw-caret-rect-filled ( editor -- )
 189     caret-rect gl-fill-rect ;
 190
 191 : draw-caret-shape ( editor -- )
 192     caret-style get {
 193         { +box+ [ draw-caret-rect ] }
 194         { +filled+ [ draw-caret-rect-filled ] }
 195         [ drop  draw-caret-line ]
 196     } case ;
 197
 198 : draw-caret ( editor -- )
 199     dup draw-caret? [
 200         [ editor-caret-color gl-color ] dip
 201         draw-caret-shape
 202     ] [ drop ] if ;
 203
 204 :: draw-preedit-underlines ( editor -- )
 205     editor [ preedit? ] [ preedit-underlines>> ] bi and [
 206         editor [ caret-loc second ] [ caret-dim second ] bi + 2.0 - :> y
 207         editor editor-caret first :> row
 208         editor font>> foreground>> gl-color
 209         editor preedit-underlines>> [
 210             GL_LINE_BIT [
 211                 dup second glLineWidth
 212                 first editor preedit-start>> second dup 2array v+ first2
 213                 [ row swap 2array editor loc>x 1.0 + y 2array ]
 214                 [ row swap 2array editor loc>x 1.0 - y 2array ]
 215                 bi*
 216                 gl-line
 217             ] do-attribs
 218         ] each
 219     ] when ;
 220
 221 : selection-start/end ( editor -- start end )
 222     [ editor-mark ] [ editor-caret ] bi sort-pair ;
 223
 224 SYMBOL: selected-lines
 225
 226 TUPLE: selected-line start end first? last? ;
 227
 228 : compute-selection ( editor -- assoc )
 229     dup gadget-selection? [
 230         [ selection-start/end [ [ first ] bi@ [a..b] ] [ ] 2bi ]
 231         [ model>> ] bi
 232         '[ [ _ _ ] [ _ start/end-on-line ] bi 2array ] H{ } map>assoc
 233     ] [ drop f ] if ;
 234
 235 :: draw-selection ( line pair editor -- )
 236     pair [ editor font>> line offset>x gl-round ] map :> pair
 237     editor selection-color>> gl-color
 238     pair first 0 2array
 239     pair second pair first - 1 max editor line-height 2array
 240     gl-fill-rect ;
 241
 242 : draw-unselected-line ( line editor -- )
 243     font>> swap draw-text ;
 244
 245 : draw-selected-line ( line pair editor -- )
 246     over all-equal? [
 247         [ nip draw-unselected-line ] [ draw-selection ] 3bi
 248     ] [
 249         [ draw-selection ]
 250         [
 251             [ [ first2 ] [ selection-color>> ] bi* <selection> ]
 252             [ draw-unselected-line ] bi
 253         ] 3bi
 254     ] if ;
 255
 256 : draw-default-text? ( editor -- ? )
 257     { [ default-text>> ] [ model>> doc-string empty? ] } 1&& ;
 258
 259 : draw-default-text ( editor -- )
 260     [ font>> clone line-color >>foreground ]
 261     [ default-text>> ] bi draw-text ;
 262
 263 PRIVATE>
 264
 265 M: editor draw-line
 266     [ selected-lines get at ] dip over
 267     [ draw-selected-line ] [ nip draw-unselected-line ] if ;
 268
 269 M: editor draw-gadget*
 270     dup draw-default-text? [
 271         [ draw-default-text ] [ draw-caret ] [ draw-preedit-underlines ] tri
 272     ] [
 273         dup compute-selection selected-lines [
 274             [ draw-lines ] [ draw-caret ] [ draw-preedit-underlines ] tri
 275         ] with-variable
 276     ] if ;
 277
 278 M: editor pref-dim*
 279     [ call-next-method ] keep ! at least as big as our min-rows/min-cols
 280     ! Add some space for the caret.
 281     [ font>> ] keep dup draw-default-text?
 282     [ default-text>> ] [ control-value ] if
 283     text-dim { 1 0 } v+ vmax ;
 284
 285 M: editor baseline font>> font-metrics ascent>> ;
 286
 287 M: editor cap-height font>> font-metrics cap-height>> ;
 288
 289 <PRIVATE
 290
 291 : contents-changed ( model editor -- )
 292     [ [ nip caret>> ] [ drop ] 2bi '[ _ validate-loc ] (change-model) ]
 293     [ [ nip mark>> ] [ drop ] 2bi '[ _ validate-loc ] (change-model) ]
 294     [ nip relayout ] 2tri ;
 295
 296 : caret/mark-changed ( editor -- )
 297     [ restart-blinking ] keep scroll>caret ;
 298
 299 PRIVATE>
 300
 301 M: editor model-changed
 302     {
 303         { [ 2dup model>> eq? ] [ contents-changed ] }
 304         { [ 2dup caret>> eq? ] [ nip caret/mark-changed ] }
 305         { [ 2dup mark>> eq? ] [ nip caret/mark-changed ] }
 306     } cond ;
 307
 308 M: editor gadget-selection?
 309     selection-start/end = not ;
 310
 311 M: editor gadget-selection
 312     [ selection-start/end ] [ model>> ] bi doc-range ;
 313
 314 : remove-selection ( editor -- )
 315     [ selection-start/end ] [ model>> ] bi remove-doc-range ;
 316
 317 M: editor user-input*
 318     [ selection-start/end ] [ model>> ] bi set-doc-range t ;
 319
 320 M: editor temp-im-input
 321     [ selection-start/end ] [ model>> ] bi set-doc-range* t ;
 322
 323 : editor-string ( editor -- string )
 324     model>> doc-string ;
 325
 326 : set-editor-string ( string editor -- )
 327     model>> set-doc-string ;
 328
 329 M: editor gadget-text* editor-string % ;
 330
 331 : extend-selection ( editor -- )
 332     [ request-focus ]
 333     [ restart-blinking ]
 334     [ dup caret>> click-loc ] tri ;
 335
 336 : remove-preedit-text ( editor -- )
 337     { [ preedit-start>> ] [ set-caret ]
 338       [ preedit-end>> ] [ set-mark ]
 339       [ remove-selection ]
 340     } cleave ;
 341
 342 : remove-preedit-info ( editor -- )
 343     f >>preedit-start
 344     f >>preedit-end
 345     f >>preedit-selected-start
 346     f >>preedit-selected-end
 347     f >>preedit-selection-mode?
 348     f >>preedit-underlines
 349     drop ;
 350
 351 : mouse-elt ( -- element )
 352     hand-click# get {
 353         { 1 one-char-elt }
 354         { 2 one-word-elt }
 355     } at one-line-elt or ;
 356
 357 : drag-direction? ( loc editor -- ? )
 358     editor-mark before? ;
 359
 360 : drag-selection-caret ( loc editor element -- loc )
 361     [
 362         [ drag-direction? ] [ model>> ] 2bi
 363     ] dip prev/next-elt ? ;
 364
 365 : drag-selection-mark ( loc editor element -- loc )
 366     [
 367         [ drag-direction? not ]
 368         [ editor-mark ]
 369         [ model>> ] tri
 370     ] dip prev/next-elt ? ;
 371
 372 : drag-caret&mark ( editor -- caret mark )
 373     [ clicked-loc ] [ mouse-elt ] bi
 374     [ drag-selection-caret ]
 375     [ drag-selection-mark ] 3bi ;
 376
 377 : drag-selection ( editor -- )
 378     [ drag-caret&mark ]
 379     [ mark>> set-model ]
 380     [ caret>> set-model ] tri ;
 381
 382 : editor-cut ( editor clipboard -- )
 383     [ gadget-copy ] [ drop remove-selection ] 2bi ;
 384
 385 : delete/backspace ( editor quot -- )
 386     over gadget-selection? [
 387         drop remove-selection
 388     ] [
 389         [ [ [ editor-caret ] [ model>> ] bi ] dip call ]
 390         [ drop model>> ]
 391         2bi remove-doc-range
 392     ] if ; inline
 393
 394 : editor-delete ( editor elt -- )
 395     '[ dupd _ next-elt ] delete/backspace ;
 396
 397 : editor-backspace ( editor elt -- )
 398     '[ over [ _ prev-elt ] dip ] delete/backspace ;
 399
 400 : editor-select-prev ( editor elt -- )
 401     '[ _ prev-elt ] change-caret ;
 402
 403 : editor-prev ( editor elt -- )
 404     [ editor-select-prev ] [ drop mark>caret ] 2bi ;
 405
 406 : editor-select-next ( editor elt -- )
 407     '[ _ next-elt ] change-caret ;
 408
 409 : editor-next ( editor elt -- )
 410     dupd editor-select-next mark>caret ;
 411
 412 : editor-select ( from to editor -- )
 413     [ mark>> set-model ] [ caret>> set-model ] bi-curry bi* ;
 414
 415 : select-elt ( editor elt -- )
 416     [ [ [ editor-caret ] [ model>> ] bi ] dip prev/next-elt ] [ drop ] 2bi
 417     editor-select ;
 418
 419 : start-of-document ( editor -- ) doc-elt editor-prev ;
 420
 421 : end-of-document ( editor -- ) doc-elt editor-next ;
 422
 423 : position-caret ( editor -- )
 424     mouse-elt dup one-char-elt =
 425     [ drop dup extend-selection dup mark>> click-loc ]
 426     [ select-elt ] if ;
 427
 428 : delete-previous-character ( editor -- )
 429     char-elt editor-backspace ;
 430
 431 : delete-next-character ( editor -- )
 432     char-elt editor-delete ;
 433
 434 : delete-previous-word ( editor -- )
 435     word-elt editor-backspace ;
 436
 437 : delete-next-word ( editor -- )
 438     word-elt editor-delete ;
 439
 440 : delete-to-start-of-line ( editor -- )
 441     one-line-elt editor-backspace ;
 442
 443 : delete-to-end-of-line ( editor -- )
 444     one-line-elt editor-delete ;
 445
 446 : delete-to-start-of-document ( editor -- )
 447     doc-elt editor-delete ;
 448
 449 : delete-to-end-of-document ( editor -- )
 450     doc-elt editor-delete ;
 451
 452 : com-undo ( editor -- ) model>> undo ;
 453
 454 : com-redo ( editor -- ) model>> redo ;
 455
 456 editor "editing" f {
 457     { undo-action com-undo }
 458     { redo-action com-redo }
 459     { T{ key-down f f "DELETE" } delete-next-character }
 460     { T{ key-down f f "BACKSPACE" } delete-previous-character }
 461     { T{ key-down f { S+ } "DELETE" } delete-next-character }
 462     { T{ key-down f { S+ } "BACKSPACE" } delete-previous-character }
 463     { T{ key-down f ${ os macosx? A+ C+ ? } "DELETE" } delete-next-word }
 464     { T{ key-down f ${ os macosx? A+ C+ ? } "BACKSPACE" } delete-previous-word }
 465     { T{ key-down f ${ os macosx? M+ A+ ? } "DELETE" } delete-to-end-of-line }
 466     { T{ key-down f ${ os macosx? M+ A+ ? } "BACKSPACE" } delete-to-start-of-line }
 467 } os macosx? [ {
 468     { T{ key-down f { C+ } "DELETE" } delete-next-character }
 469     { T{ key-down f { C+ } "BACKSPACE" } delete-previous-character }
 470 } append ] when define-command-map
 471
 472 : com-paste ( editor -- ) clipboard get paste-clipboard ;
 473
 474 : paste-selection ( editor -- ) ui.clipboards:selection get paste-clipboard ;
 475
 476 : com-cut ( editor -- ) clipboard get editor-cut ;
 477
 478 editor "clipboard" f {
 479     { cut-action com-cut }
 480     { copy-action com-copy }
 481     { paste-action com-paste }
 482     { T{ button-up } com-copy-selection }
 483     { T{ button-up f f 2 } paste-selection }
 484 } define-command-map
 485
 486 : previous-character ( editor -- )
 487     dup gadget-selection? [
 488         dup selection-start/end drop
 489         over set-caret mark>caret
 490     ] [
 491         char-elt editor-prev
 492     ] if ;
 493
 494 : next-character ( editor -- )
 495     dup gadget-selection? [
 496         dup selection-start/end nip
 497         over set-caret mark>caret
 498     ] [
 499         char-elt editor-next
 500     ] if ;
 501
 502 : previous-word ( editor -- ) word-elt editor-prev ;
 503
 504 : next-word ( editor -- ) word-elt editor-next ;
 505
 506 : start-of-line ( editor -- ) one-line-elt editor-prev ;
 507
 508 : end-of-line ( editor -- ) one-line-elt editor-next ;
 509
 510 : start-of-paragraph ( editor -- ) paragraph-elt editor-prev ;
 511
 512 : end-of-paragraph ( editor -- ) paragraph-elt editor-next ;
 513
 514 editor "caret-motion" f {
 515     { T{ button-down } position-caret }
 516     { T{ key-down f f "LEFT" } previous-character }
 517     { T{ key-down f f "RIGHT" } next-character }
 518     { T{ key-down f ${ os macosx? A+ C+ ? } "LEFT" } previous-word }
 519     { T{ key-down f ${ os macosx? A+ C+ ? } "RIGHT" } next-word }
 520     { T{ key-down f f "HOME" } start-of-line }
 521     { T{ key-down f f "END" } end-of-line }
 522     { T{ key-down f ${ os macosx? A+ C+ ? } "UP" } start-of-paragraph }
 523     { T{ key-down f ${ os macosx? A+ C+ ? } "DOWN" } end-of-paragraph }
 524     { T{ key-down f ${ os macosx? A+ C+ ? } "HOME" } start-of-document }
 525     { T{ key-down f ${ os macosx? A+ C+ ? } "END" } end-of-document }
 526 } os macosx? [ {
 527     { T{ key-down f { M+ } "LEFT" } start-of-line }
 528     { T{ key-down f { M+ } "RIGHT" } end-of-line }
 529     { T{ key-down f { M+ } "UP" } start-of-paragraph }
 530     { T{ key-down f { M+ } "DOWN" } end-of-paragraph }
 531     { T{ key-down f { M+ } "HOME" } start-of-document }
 532     { T{ key-down f { M+ } "END" } end-of-document }
 533 } append ] when define-command-map
 534
 535 : clear-editor ( editor -- )
 536     model>> clear-doc ;
 537
 538 : select-all ( editor -- ) doc-elt select-elt ;
 539
 540 : select-line ( editor -- ) one-line-elt select-elt ;
 541
 542 : select-word ( editor -- ) one-word-elt select-elt ;
 543
 544 : selected-token ( editor -- string )
 545     dup gadget-selection?
 546     [ dup select-word ] unless
 547     gadget-selection ;
 548
 549 : select-previous-character ( editor -- )
 550     char-elt editor-select-prev ;
 551
 552 : select-next-character ( editor -- )
 553     char-elt editor-select-next ;
 554
 555 : select-previous-word ( editor -- )
 556     word-elt editor-select-prev ;
 557
 558 : select-next-word ( editor -- )
 559     word-elt editor-select-next ;
 560
 561 : select-start-of-line ( editor -- )
 562     one-line-elt editor-select-prev ;
 563
 564 : select-end-of-line ( editor -- )
 565     one-line-elt editor-select-next ;
 566
 567 : select-start-of-paragraph ( editor -- )
 568     paragraph-elt editor-select-prev ;
 569
 570 : select-end-of-paragraph ( editor -- )
 571     paragraph-elt editor-select-next ;
 572
 573 : select-start-of-document ( editor -- )
 574     doc-elt editor-select-prev ;
 575
 576 : select-end-of-document ( editor -- )
 577     doc-elt editor-select-next ;
 578
 579 editor "selection" f {
 580     { T{ button-down f { S+ } 1 } extend-selection }
 581     { T{ button-up f { S+ } 1 } com-copy-selection }
 582     { T{ drag { # 1 } } drag-selection }
 583     { gain-focus focus-editor }
 584     { lose-focus unfocus-editor }
 585     { delete-action remove-selection }
 586     { select-all-action select-all }
 587     { T{ key-down f { C+ } "l" } select-line }
 588     { T{ key-down f { S+ } "LEFT" } select-previous-character }
 589     { T{ key-down f { S+ } "RIGHT" } select-next-character }
 590     { T{ key-down f ${ S+ os macosx? A+ C+ ? } "LEFT" } select-previous-word }
 591     { T{ key-down f ${ S+ os macosx? A+ C+ ? } "RIGHT" } select-next-word }
 592     { T{ key-down f { S+ } "HOME" } select-start-of-line }
 593     { T{ key-down f { S+ } "END" } select-end-of-line }
 594     { T{ key-down f ${ S+ os macosx? A+ C+ ? } "UP" } select-start-of-paragraph }
 595     { T{ key-down f ${ S+ os macosx? A+ C+ ? } "DOWN" } select-end-of-paragraph }
 596     { T{ key-down f ${ S+ os macosx? A+ C+ ? } "HOME" } select-start-of-document }
 597     { T{ key-down f ${ S+ os macosx? A+ C+ ? } "END" } select-end-of-document }
 598 } os macosx? [ {
 599     { T{ key-down f { S+ M+ } "LEFT" } select-start-of-line }
 600     { T{ key-down f { S+ M+ } "RIGHT" } select-end-of-line }
 601     { T{ key-down f { S+ M+ } "UP" } select-start-of-paragraph }
 602     { T{ key-down f { S+ M+ } "DOWN" } select-end-of-paragraph }
 603     { T{ key-down f { S+ M+ } "HOME" } select-start-of-document }
 604     { T{ key-down f { S+ M+ } "END" } select-end-of-document }
 605 } append ] when define-command-map
 606
 607 : editor-menu ( editor -- )
 608     {
 609         com-undo
 610         com-redo
 611         ----
 612         com-cut
 613         com-copy
 614         com-paste
 615     } show-commands-menu ;
 616
 617 editor "misc" f {
 618     ! { T{ button-down f f 2 } paste-selection }
 619     { T{ button-down f f 3 } editor-menu }
 620 } define-command-map
 621
 622 ! Multi-line editors
 623 TUPLE: multiline-editor < editor ;
 624
 625 : <multiline-editor> ( -- editor )
 626     multiline-editor new-editor ;
 627
 628 : previous-line ( editor -- ) line-elt editor-prev ;
 629
 630 : next-line ( editor -- ) line-elt editor-next ;
 631
 632 <PRIVATE
 633
 634 : page-elt ( editor n -- editor element )
 635     over visible-lines 1 - min 1 max <page-elt> ;
 636
 637 : prev-page-elt ( editor -- editor element )
 638     dup editor-caret first page-elt ;
 639
 640 : next-page-elt ( editor -- editor element )
 641     dup [ control-value length 1 - ] [ editor-caret first ] bi - page-elt ;
 642
 643 PRIVATE>
 644
 645 : previous-page ( editor -- ) prev-page-elt editor-prev ;
 646
 647 : next-page ( editor -- ) next-page-elt editor-next ;
 648
 649 : select-previous-line ( editor -- ) line-elt editor-select-prev ;
 650
 651 : select-next-line ( editor -- ) line-elt editor-select-next ;
 652
 653 : select-previous-page ( editor -- ) prev-page-elt editor-select-prev ;
 654
 655 : select-next-page ( editor -- ) next-page-elt editor-select-next ;
 656
 657 : insert-newline ( editor -- )
 658     "\n" swap user-input* drop ;
 659
 660 : change-selection ( editor quot -- )
 661     '[ gadget-selection @ ] [ user-input* drop ] bi ; inline
 662
 663 <PRIVATE
 664
 665 : join-lines ( string -- string' )
 666     split-lines
 667     [ rest-slice [ [ blank? ] trim-head-slice ] map! drop ]
 668     [ but-last-slice [ [ blank? ] trim-tail-slice ] map! drop ]
 669     [ join-words ]
 670     tri ;
 671
 672 : last-line? ( document line -- ? )
 673     [ last-line# ] dip = ;
 674
 675 : prev-line-and-this ( document line -- start end )
 676     swap [ drop 1 - 0 2array ] [ line-end ] 2bi ;
 677
 678 : join-with-prev ( document line -- )
 679     [ prev-line-and-this ] [ drop ] 2bi
 680     [ join-lines ] change-doc-range ;
 681
 682 : this-line-and-next ( document line -- start end )
 683     swap [ drop 0 2array ] [ [ 1 + ] dip line-end ] 2bi ;
 684
 685 : join-with-next ( document line -- )
 686     [ this-line-and-next ] [ drop ] 2bi
 687     [ join-lines ] change-doc-range ;
 688
 689 PRIVATE>
 690
 691 : com-join-lines ( editor -- )
 692     dup gadget-selection?
 693     [ [ join-lines ] change-selection ] [
 694         [ model>> ] [ editor-caret first ] bi {
 695             { [ over last-line# 0 = ] [ 2drop ] }
 696             { [ 2dup last-line? ] [ join-with-prev ] }
 697             [ join-with-next ]
 698         } cond
 699     ] if ;
 700
 701 multiline-editor "multiline" f {
 702     { T{ key-down f f "UP" } previous-line }
 703     { T{ key-down f f "DOWN" } next-line }
 704     { T{ key-down f { S+ } "UP" } select-previous-line }
 705     { T{ key-down f { S+ } "DOWN" } select-next-line }
 706     { T{ key-down f f "PAGE_UP" } previous-page }
 707     { T{ key-down f f "PAGE_DOWN" } next-page }
 708     { T{ key-down f { S+ } "PAGE_UP" } select-previous-page }
 709     { T{ key-down f { S+ } "PAGE_DOWN" } select-next-page }
 710     { T{ key-down f f "RET" } insert-newline }
 711     { T{ key-down f { S+ } "RET" } insert-newline }
 712     { T{ key-down f f "ENTER" } insert-newline }
 713     { T{ key-down f { S+ } "ENTER" } insert-newline }
 714     { T{ key-down f { C+ } "j" } com-join-lines }
 715 } define-command-map
 716
 717 TUPLE: source-editor < multiline-editor ;
 718
 719 : <source-editor> ( -- editor )
 720     source-editor new-editor ;
 721
 722 ! A useful model
 723 : <element-model> ( editor element -- model )
 724     [ [ caret>> ] [ model>> ] bi ] dip
 725     '[ _ _ elt-string ] <arrow> ;
 726
 727 ! Fields wrap an editor
 728 TUPLE: field < border editor min-cols max-cols ;
 729
 730 <PRIVATE
 731
 732 : field-theme ( gadget -- gadget )
 733     { 2 2 } >>size
 734     { 1 0 } >>fill
 735     field-border-color <solid> >>boundary ; inline
 736
 737 : <field-border> ( gadget -- border )
 738     border new-border field-theme ;
 739
 740 PRIVATE>
 741
 742 : new-field ( class -- gadget )
 743     [ <editor> ] dip new-border
 744         dup gadget-child >>editor
 745         field-theme ; inline
 746
 747 ! For line-gadget-width
 748 M: field font>> editor>> font>> ;
 749
 750 M: field pref-dim*
 751     [ ]
 752     [ editor>> pref-dim ]
 753     [ [ line-gadget-width ] [ drop second ] 2bi 2array ]
 754     tri border-pref-dim ;
 755
 756 M: field default-text>> editor>> default-text>> ;
 757
 758 M: field default-text<< editor>> default-text<< ;
 759
 760 TUPLE: model-field < field field-model ;
 761
 762 : <model-field> ( model -- gadget )
 763     model-field new-field
 764         swap >>field-model ;
 765
 766 M: model-field graft*
 767     [ [ field-model>> value>> ] [ editor>> ] bi set-editor-string ]
 768     [ dup editor>> model>> add-connection ]
 769     bi ;
 770
 771 M: model-field ungraft*
 772     dup editor>> model>> remove-connection ;
 773
 774 M: model-field model-changed
 775     nip [ editor>> editor-string ] [ field-model>> ] bi set-model ;
 776
 777 TUPLE: action-field < field quot ;
 778
 779 : <action-field> ( quot: ( string -- ) -- gadget )
 780     action-field [ <editor> ] dip new-border
 781         dup gadget-child >>editor
 782         field-theme
 783         swap >>quot ;
 784
 785 : invoke-action-field ( field -- )
 786     [ editor>> editor-string ]
 787     [ editor>> clear-editor ]
 788     [ quot>> ]
 789     tri call( string -- ) ;
 790
 791 action-field H{
 792     { T{ key-down f f "RET" } [ invoke-action-field ] }
 793 } set-gestures
 794
 795 : readline-bindings ( editor-class -- )
 796     "readline" f {
 797         { T{ key-down f { C+ } "p" } previous-line }
 798         { T{ key-down f { C+ } "n" } next-line }
 799         { T{ key-down f { C+ } "b" } previous-character }
 800         { T{ key-down f { C+ } "f" } next-character }
 801         { T{ key-down f { C+ } "a" } start-of-line }
 802         { T{ key-down f { C+ } "e" } end-of-line }
 803         ! { T{ key-down f { C+ } "t" } transpose-character }
 804         { T{ key-down f { C+ } "d" } delete-next-character }
 805         { T{ key-down f { C+ } "h" } delete-previous-character }
 806         { T{ key-down f { C+ } "u" } delete-to-start-of-line }
 807         { T{ key-down f { C+ } "k" } delete-to-end-of-line }
 808         { T{ key-down f { C+ } "w" } delete-previous-word }
 809     } define-command-map ;