basis/ui/gadgets/editors/editors.factor

   1 ! Copyright (C) 2006, 2011 Slava Pestov
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs calendar colors combinators
   4 combinators.short-circuit documents documents.elements fonts fry
   5 grouping kernel literals locals make math math.functions
   6 math.order ranges math.rectangles math.vectors models
   7 models.arrow namespaces opengl opengl.gl sequences sorting
   8 splitting system timers ui.baseline-alignment ui.clipboards
   9 ui.commands ui.gadgets ui.gadgets.borders
  10 ui.gadgets.line-support ui.gadgets.menus ui.gadgets.scrollers
  11 prettyprint ui.gadgets.editors.private math.parser
  12 ui.gestures ui.pens.solid ui.render ui.text ui.theme unicode variables ;
  13 IN: ui.gadgets.editors
  14
  15 TUPLE: editor < line-gadget
  16     caret mark
  17     focused? blink blink-timer
  18     default-text
  19     preedit-start
  20     preedit-end
  21     preedit-selected-start
  22     preedit-selected-end
  23     preedit-selection-mode?
  24     preedit-underlines ;
  25
  26 M: editor preedit? preedit-start>> ;
  27
  28 SYMBOL: caret-is-shape
  29 : <caret-shape> ( -- shape )  caret-is-shape get <model> ;
  30
  31 <PRIVATE
  32
  33 : <loc> ( -- loc ) { 0 0 } <model> ;
  34
  35 : init-editor-locs ( editor -- editor )
  36     <loc> >>caret
  37     <caret-shape> >>caret-shape
  38     <loc> >>mark ; inline
  39
  40 : editor-theme ( editor -- editor )
  41     monospace-font >>font ; inline
  42
  43 PRIVATE>
  44
  45 : new-editor ( class -- editor )
  46     new-line-gadget
  47         <document> >>model
  48         init-editor-locs
  49         editor-theme ; inline
  50
  51 : <editor> ( -- editor )
  52     editor new-editor ;
  53
  54 <PRIVATE
  55
  56 : activate-editor-model ( editor model -- )
  57     [ add-connection ]
  58     [ nip activate-model ]
  59     [ swap model>> add-loc ] 2tri ;
  60
  61 : deactivate-editor-model ( editor model -- )
  62     [ remove-connection ]
  63     [ nip deactivate-model ]
  64     [ swap model>> remove-loc ] 2tri ;
  65
  66 : blink-caret ( editor -- )
  67     [ not ] change-blink relayout-1 ;
  68
  69 SYMBOL: blink-interval
  70
  71 750 milliseconds blink-interval set-global
  72
  73 : stop-blinking ( editor -- )
  74     blink-timer>> [ stop-timer ] when* ;
  75
  76 : start-blinking ( editor -- )
  77     t >>blink
  78     blink-timer>> [ restart-timer ] when* ;
  79
  80 : restart-blinking ( editor -- )
  81     dup focused?>> [
  82         [ start-blinking ]
  83         [ relayout-1 ]
  84         bi
  85     ] [ drop ] if ;
  86
  87 PRIVATE>
  88
  89 M: editor graft*
  90     [ dup caret>> activate-editor-model ]
  91     [ dup mark>> activate-editor-model ]
  92     [
  93         [
  94             '[ _ blink-caret ] blink-interval get dup <timer>
  95         ] keep blink-timer<<
  96     ] tri ;
  97
  98 M: editor ungraft*
  99     [ [ stop-blinking ] [ f >>blink-timer drop ] bi ]
 100     [ dup caret>> deactivate-editor-model ]
 101     [ dup mark>> deactivate-editor-model ] tri ;
 102
 103 : editor-caret ( editor -- loc ) caret>> value>> ;
 104
 105 : editor-mark ( editor -- loc ) mark>> value>> ;
 106
 107 : set-caret ( loc editor -- )
 108     [ model>> validate-loc ] [ caret>> ] bi set-model ;
 109
 110 : set-mark ( loc editor -- )
 111     [ model>> validate-loc ] [ mark>> ] bi set-model ;
 112
 113 : change-caret ( editor quot: ( loc document -- newloc ) -- )
 114     [ [ [ editor-caret ] [ model>> ] bi ] dip call ] [ drop ] 2bi
 115     set-caret ; inline
 116
 117 : mark>caret ( editor -- )
 118     [ editor-caret ] [ mark>> ] bi set-model ;
 119
 120 : change-caret&mark ( editor quot: ( loc document -- newloc ) -- )
 121     [ change-caret ] [ drop mark>caret ] 2bi ; inline
 122
 123 : editor-line ( n editor -- str ) control-value nth ;
 124
 125 :: point>loc ( point editor -- loc )
 126     point second editor y>line {
 127         { [ dup 0 < ] [ drop { 0 0 } ] }
 128         { [ dup editor model>> last-line# > ] [ drop editor model>> doc-end ] }
 129         [| n |
 130             n
 131             point first
 132             editor font>>
 133             n editor editor-line
 134             x>offset 2array
 135         ]
 136     } cond ;
 137
 138 : clicked-loc ( editor -- loc )
 139     [ hand-rel ] keep point>loc ;
 140
 141 : click-loc ( editor model -- )
 142     [ clicked-loc ] dip set-model ;
 143
 144 : focus-editor ( editor -- )
 145     [ start-blinking ] [ t >>focused? relayout-1 ] bi ;
 146
 147 : unfocus-editor ( editor -- )
 148     [ stop-blinking ] [ f >>focused? relayout-1 ] bi ;
 149
 150 : loc>x ( loc editor -- x )
 151     [ first2 swap ] dip [ editor-line ] [ font>> ] bi swap offset>x gl-round ;
 152
 153 : loc>point ( loc editor -- loc )
 154     [ loc>x ] [ [ first ] dip line>y gl-ceiling ] 2bi 2array ;
 155
 156 : caret-loc ( editor -- loc )
 157     [ editor-caret ] keep loc>point ;
 158
 159 : caret-dim ( editor -- dim )
 160     [ 0 ] dip line-height 2array ;
 161
 162 : scroll>caret ( editor -- )
 163     dup graft-state>> second [
 164         [
 165             [ caret-loc ] [ caret-dim { 2 1 } v+ ] bi <rect>
 166         ] keep scroll>rect
 167     ] [ drop ] if ;
 168
 169 <PRIVATE
 170
 171 : draw-caret? ( editor -- ? )
 172     { [ focused?>> ] [ blink>> ]
 173       [ [ preedit? not ] [ preedit-selection-mode?>> not ] bi or ] } 1&& ;
 174
 175 : (caret-location) ( editor -- loc dim )
 176     [ caret-loc ] [ caret-dim ] bi ;
 177
 178 : (caret-rect) ( dim -- newdim )
 179     second [ 2 / ] keep 2array ;
 180
 181 : draw-caret-line ( editor -- )
 182     (caret-location) over v+ gl-line ;
 183
 184 : draw-caret-rect ( editor -- )
 185     (caret-location) (caret-rect) gl-rect ;
 186
 187 : draw-caret-rect-filled ( editor -- )
 188     (caret-location) (caret-rect) gl-fill-rect ;
 189
 190 : draw-caret-shape ( editor -- )
 191     dup caret-shape>> value>>
 192     {
 193         { 1 [ draw-caret-rect ] }
 194         { 2 [ draw-caret-rect-filled ] }
 195         [ drop  draw-caret-line ]
 196     } case ;
 197
 198
 199 : draw-caret ( editor -- )
 200     dup draw-caret? [
 201         [ editor-caret-color gl-color ] dip
 202         [ caret-loc ] [ caret-dim ] bi
 203         over v+ gl-line
 204     ] [ drop ] if ;
 205
 206 :: draw-preedit-underlines ( editor -- )
 207     editor [ preedit? ] [ preedit-underlines>> ] bi and [
 208         editor [ caret-loc second ] [ caret-dim second ] bi + 2.0 - :> y
 209         editor editor-caret first :> row
 210         editor font>> foreground>> gl-color
 211         editor preedit-underlines>> [
 212             GL_LINE_BIT [
 213                 dup second glLineWidth
 214                 first editor preedit-start>> second dup 2array v+ first2
 215                 [ row swap 2array editor loc>x 1.0 + y 2array ]
 216                 [ row swap 2array editor loc>x 1.0 - y 2array ]
 217                 bi*
 218                 gl-line
 219             ] do-attribs
 220         ] each
 221     ] when ;
 222
 223 : selection-start/end ( editor -- start end )
 224     [ editor-mark ] [ editor-caret ] bi sort-pair ;
 225
 226 SYMBOL: selected-lines
 227
 228 TUPLE: selected-line start end first? last? ;
 229
 230 : compute-selection ( editor -- assoc )
 231     dup gadget-selection? [
 232         [ selection-start/end [ [ first ] bi@ [a..b] ] [ ] 2bi ]
 233         [ model>> ] bi
 234         '[ [ _ _ ] [ _ start/end-on-line ] bi 2array ] H{ } map>assoc
 235     ] [ drop f ] if ;
 236
 237 :: draw-selection ( line pair editor -- )
 238     pair [ editor font>> line offset>x gl-round ] map :> pair
 239     editor selection-color>> gl-color
 240     pair first 0 2array
 241     pair second pair first - 1 max editor line-height 2array
 242     gl-fill-rect ;
 243
 244 : draw-unselected-line ( line editor -- )
 245     font>> swap draw-text ;
 246
 247 : draw-selected-line ( line pair editor -- )
 248     over all-equal? [
 249         [ nip draw-unselected-line ] [ draw-selection ] 3bi
 250     ] [
 251         [ draw-selection ]
 252         [
 253             [ [ first2 ] [ selection-color>> ] bi* <selection> ]
 254             [ draw-unselected-line ] bi
 255         ] 3bi
 256     ] if ;
 257
 258 : draw-default-text? ( editor -- ? )
 259     { [ default-text>> ] [ model>> doc-string empty? ] } 1&& ;
 260
 261 : draw-default-text ( editor -- )
 262     [ font>> clone line-color >>foreground ]
 263     [ default-text>> ] bi draw-text ;
 264
 265 PRIVATE>
 266
 267 M: editor draw-line
 268     [ selected-lines get at ] dip over
 269     [ draw-selected-line ] [ nip draw-unselected-line ] if ;
 270
 271 M: editor draw-gadget*
 272     dup draw-default-text? [
 273         [ draw-default-text ] [ draw-caret ] [ draw-preedit-underlines ] tri
 274     ] [
 275         dup compute-selection selected-lines [
 276             [ draw-lines ] [ draw-caret ] [ draw-preedit-underlines ] tri
 277         ] with-variable
 278     ] if ;
 279
 280 M: editor pref-dim*
 281     [ call-next-method ] keep ! at least as big as our min-rows/min-cols
 282     ! Add some space for the caret.
 283     [ font>> ] keep dup draw-default-text?
 284     [ default-text>> ] [ control-value ] if
 285     text-dim { 1 0 } v+ vmax ;
 286
 287 M: editor baseline font>> font-metrics ascent>> ;
 288
 289 M: editor cap-height font>> font-metrics cap-height>> ;
 290
 291 <PRIVATE
 292
 293 : contents-changed ( model editor -- )
 294     [ [ nip caret>> ] [ drop ] 2bi '[ _ validate-loc ] (change-model) ]
 295     [ [ nip mark>> ] [ drop ] 2bi '[ _ validate-loc ] (change-model) ]
 296     [ nip relayout ] 2tri ;
 297
 298 : caret/mark-changed ( editor -- )
 299     [ restart-blinking ] keep scroll>caret ;
 300
 301 PRIVATE>
 302
 303 M: editor model-changed
 304     {
 305         { [ 2dup model>> eq? ] [ contents-changed ] }
 306         { [ 2dup caret>> eq? ] [ nip caret/mark-changed ] }
 307         { [ 2dup mark>> eq? ] [ nip caret/mark-changed ] }
 308     } cond ;
 309
 310 M: editor gadget-selection?
 311     selection-start/end = not ;
 312
 313 M: editor gadget-selection
 314     [ selection-start/end ] [ model>> ] bi doc-range ;
 315
 316 : remove-selection ( editor -- )
 317     [ selection-start/end ] [ model>> ] bi remove-doc-range ;
 318
 319 M: editor user-input*
 320     [ selection-start/end ] [ model>> ] bi set-doc-range t ;
 321
 322 M: editor temp-im-input
 323     [ selection-start/end ] [ model>> ] bi set-doc-range* t ;
 324
 325 : editor-string ( editor -- string )
 326     model>> doc-string ;
 327
 328 : set-editor-string ( string editor -- )
 329     model>> set-doc-string ;
 330
 331 M: editor gadget-text* editor-string % ;
 332
 333 : extend-selection ( editor -- )
 334     [ request-focus ]
 335     [ restart-blinking ]
 336     [ dup caret>> click-loc ] tri ;
 337
 338 : remove-preedit-text ( editor -- )
 339     { [ preedit-start>> ] [ set-caret ]
 340       [ preedit-end>> ] [ set-mark ]
 341       [ remove-selection ]
 342     } cleave ;
 343
 344 : remove-preedit-info ( editor -- )
 345     f >>preedit-start
 346     f >>preedit-end
 347     f >>preedit-selected-start
 348     f >>preedit-selected-end
 349     f >>preedit-selection-mode?
 350     f >>preedit-underlines
 351     drop ;
 352
 353 : mouse-elt ( -- element )
 354     hand-click# get {
 355         { 1 one-char-elt }
 356         { 2 one-word-elt }
 357     } at one-line-elt or ;
 358
 359 : drag-direction? ( loc editor -- ? )
 360     editor-mark before? ;
 361
 362 : drag-selection-caret ( loc editor element -- loc )
 363     [
 364         [ drag-direction? ] [ model>> ] 2bi
 365     ] dip prev/next-elt ? ;
 366
 367 : drag-selection-mark ( loc editor element -- loc )
 368     [
 369         [ drag-direction? not ]
 370         [ editor-mark ]
 371         [ model>> ] tri
 372     ] dip prev/next-elt ? ;
 373
 374 : drag-caret&mark ( editor -- caret mark )
 375     [ clicked-loc ] [ mouse-elt ] bi
 376     [ drag-selection-caret ]
 377     [ drag-selection-mark ] 3bi ;
 378
 379 : drag-selection ( editor -- )
 380     [ drag-caret&mark ]
 381     [ mark>> set-model ]
 382     [ caret>> set-model ] tri ;
 383
 384 : editor-cut ( editor clipboard -- )
 385     [ gadget-copy ] [ drop remove-selection ] 2bi ;
 386
 387 : delete/backspace ( editor quot -- )
 388     over gadget-selection? [
 389         drop remove-selection
 390     ] [
 391         [ [ [ editor-caret ] [ model>> ] bi ] dip call ]
 392         [ drop model>> ]
 393         2bi remove-doc-range
 394     ] if ; inline
 395
 396 : editor-delete ( editor elt -- )
 397     '[ dupd _ next-elt ] delete/backspace ;
 398
 399 : editor-backspace ( editor elt -- )
 400     '[ over [ _ prev-elt ] dip ] delete/backspace ;
 401
 402 : editor-select-prev ( editor elt -- )
 403     '[ _ prev-elt ] change-caret ;
 404
 405 : editor-prev ( editor elt -- )
 406     [ editor-select-prev ] [ drop mark>caret ] 2bi ;
 407
 408 : editor-select-next ( editor elt -- )
 409     '[ _ next-elt ] change-caret ;
 410
 411 : editor-next ( editor elt -- )
 412     dupd editor-select-next mark>caret ;
 413
 414 : editor-select ( from to editor -- )
 415     [ mark>> set-model ] [ caret>> set-model ] bi-curry bi* ;
 416
 417 : select-elt ( editor elt -- )
 418     [ [ [ editor-caret ] [ model>> ] bi ] dip prev/next-elt ] [ drop ] 2bi
 419     editor-select ;
 420
 421 : start-of-document ( editor -- ) doc-elt editor-prev ;
 422
 423 : end-of-document ( editor -- ) doc-elt editor-next ;
 424
 425 : position-caret ( editor -- )
 426     mouse-elt dup one-char-elt =
 427     [ drop dup extend-selection dup mark>> click-loc ]
 428     [ select-elt ] if ;
 429
 430 : delete-previous-character ( editor -- )
 431     char-elt editor-backspace ;
 432
 433 : delete-next-character ( editor -- )
 434     char-elt editor-delete ;
 435
 436 : delete-previous-word ( editor -- )
 437     word-elt editor-backspace ;
 438
 439 : delete-next-word ( editor -- )
 440     word-elt editor-delete ;
 441
 442 : delete-to-start-of-line ( editor -- )
 443     one-line-elt editor-backspace ;
 444
 445 : delete-to-end-of-line ( editor -- )
 446     one-line-elt editor-delete ;
 447
 448 : delete-to-start-of-document ( editor -- )
 449     doc-elt editor-delete ;
 450
 451 : delete-to-end-of-document ( editor -- )
 452     doc-elt editor-delete ;
 453
 454 : com-undo ( editor -- ) model>> undo ;
 455
 456 : com-redo ( editor -- ) model>> redo ;
 457
 458 editor "editing" f {
 459     { undo-action com-undo }
 460     { redo-action com-redo }
 461     { T{ key-down f f "DELETE" } delete-next-character }
 462     { T{ key-down f f "BACKSPACE" } delete-previous-character }
 463     { T{ key-down f { S+ } "DELETE" } delete-next-character }
 464     { T{ key-down f { S+ } "BACKSPACE" } delete-previous-character }
 465     { T{ key-down f ${ os macosx? A+ C+ ? } "DELETE" } delete-next-word }
 466     { T{ key-down f ${ os macosx? A+ C+ ? } "BACKSPACE" } delete-previous-word }
 467     { T{ key-down f ${ os macosx? M+ A+ ? } "DELETE" } delete-to-end-of-line }
 468     { T{ key-down f ${ os macosx? M+ A+ ? } "BACKSPACE" } delete-to-start-of-line }
 469 } os macosx? [ {
 470     { T{ key-down f { C+ } "DELETE" } delete-next-character }
 471     { T{ key-down f { C+ } "BACKSPACE" } delete-previous-character }
 472 } append ] when define-command-map
 473
 474 : com-paste ( editor -- ) clipboard get paste-clipboard ;
 475
 476 : paste-selection ( editor -- ) ui.clipboards:selection get paste-clipboard ;
 477
 478 : com-cut ( editor -- ) clipboard get editor-cut ;
 479
 480 editor "clipboard" f {
 481     { cut-action com-cut }
 482     { copy-action com-copy }
 483     { paste-action com-paste }
 484     { T{ button-up } com-copy-selection }
 485     { T{ button-up f f 2 } paste-selection }
 486 } define-command-map
 487
 488 : previous-character ( editor -- )
 489     dup gadget-selection? [
 490         dup selection-start/end drop
 491         over set-caret mark>caret
 492     ] [
 493         char-elt editor-prev
 494     ] if ;
 495
 496 : next-character ( editor -- )
 497     dup gadget-selection? [
 498         dup selection-start/end nip
 499         over set-caret mark>caret
 500     ] [
 501         char-elt editor-next
 502     ] if ;
 503
 504 : previous-word ( editor -- ) word-elt editor-prev ;
 505
 506 : next-word ( editor -- ) word-elt editor-next ;
 507
 508 : start-of-line ( editor -- ) one-line-elt editor-prev ;
 509
 510 : end-of-line ( editor -- ) one-line-elt editor-next ;
 511
 512 : start-of-paragraph ( editor -- ) paragraph-elt editor-prev ;
 513
 514 : end-of-paragraph ( editor -- ) paragraph-elt editor-next ;
 515
 516 editor "caret-motion" f {
 517     { T{ button-down } position-caret }
 518     { T{ key-down f f "LEFT" } previous-character }
 519     { T{ key-down f f "RIGHT" } next-character }
 520     { T{ key-down f ${ os macosx? A+ C+ ? } "LEFT" } previous-word }
 521     { T{ key-down f ${ os macosx? A+ C+ ? } "RIGHT" } next-word }
 522     { T{ key-down f f "HOME" } start-of-line }
 523     { T{ key-down f f "END" } end-of-line }
 524     { T{ key-down f ${ os macosx? A+ C+ ? } "UP" } start-of-paragraph }
 525     { T{ key-down f ${ os macosx? A+ C+ ? } "DOWN" } end-of-paragraph }
 526     { T{ key-down f ${ os macosx? A+ C+ ? } "HOME" } start-of-document }
 527     { T{ key-down f ${ os macosx? A+ C+ ? } "END" } end-of-document }
 528 } os macosx? [ {
 529     { T{ key-down f { M+ } "LEFT" } start-of-line }
 530     { T{ key-down f { M+ } "RIGHT" } end-of-line }
 531     { T{ key-down f { M+ } "UP" } start-of-paragraph }
 532     { T{ key-down f { M+ } "DOWN" } end-of-paragraph }
 533     { T{ key-down f { M+ } "HOME" } start-of-document }
 534     { T{ key-down f { M+ } "END" } end-of-document }
 535 } append ] when define-command-map
 536
 537 : clear-editor ( editor -- )
 538     model>> clear-doc ;
 539
 540 : select-all ( editor -- ) doc-elt select-elt ;
 541
 542 : select-line ( editor -- ) one-line-elt select-elt ;
 543
 544 : select-word ( editor -- ) one-word-elt select-elt ;
 545
 546 : selected-token ( editor -- string )
 547     dup gadget-selection?
 548     [ dup select-word ] unless
 549     gadget-selection ;
 550
 551 : select-previous-character ( editor -- )
 552     char-elt editor-select-prev ;
 553
 554 : select-next-character ( editor -- )
 555     char-elt editor-select-next ;
 556
 557 : select-previous-word ( editor -- )
 558     word-elt editor-select-prev ;
 559
 560 : select-next-word ( editor -- )
 561     word-elt editor-select-next ;
 562
 563 : select-start-of-line ( editor -- )
 564     one-line-elt editor-select-prev ;
 565
 566 : select-end-of-line ( editor -- )
 567     one-line-elt editor-select-next ;
 568
 569 : select-start-of-paragraph ( editor -- )
 570     paragraph-elt editor-select-prev ;
 571
 572 : select-end-of-paragraph ( editor -- )
 573     paragraph-elt editor-select-next ;
 574
 575 : select-start-of-document ( editor -- )
 576     doc-elt editor-select-prev ;
 577
 578 : select-end-of-document ( editor -- )
 579     doc-elt editor-select-next ;
 580
 581 editor "selection" f {
 582     { T{ button-down f { S+ } 1 } extend-selection }
 583     { T{ button-up f { S+ } 1 } com-copy-selection }
 584     { T{ drag { # 1 } } drag-selection }
 585     { gain-focus focus-editor }
 586     { lose-focus unfocus-editor }
 587     { delete-action remove-selection }
 588     { select-all-action select-all }
 589     { T{ key-down f { C+ } "l" } select-line }
 590     { T{ key-down f { S+ } "LEFT" } select-previous-character }
 591     { T{ key-down f { S+ } "RIGHT" } select-next-character }
 592     { T{ key-down f ${ S+ os macosx? A+ C+ ? } "LEFT" } select-previous-word }
 593     { T{ key-down f ${ S+ os macosx? A+ C+ ? } "RIGHT" } select-next-word }
 594     { T{ key-down f { S+ } "HOME" } select-start-of-line }
 595     { T{ key-down f { S+ } "END" } select-end-of-line }
 596     { T{ key-down f ${ S+ os macosx? A+ C+ ? } "UP" } select-start-of-paragraph }
 597     { T{ key-down f ${ S+ os macosx? A+ C+ ? } "DOWN" } select-end-of-paragraph }
 598     { T{ key-down f ${ S+ os macosx? A+ C+ ? } "HOME" } select-start-of-document }
 599     { T{ key-down f ${ S+ os macosx? A+ C+ ? } "END" } select-end-of-document }
 600 } os macosx? [ {
 601     { T{ key-down f { S+ M+ } "LEFT" } select-start-of-line }
 602     { T{ key-down f { S+ M+ } "RIGHT" } select-end-of-line }
 603     { T{ key-down f { S+ M+ } "UP" } select-start-of-paragraph }
 604     { T{ key-down f { S+ M+ } "DOWN" } select-end-of-paragraph }
 605     { T{ key-down f { S+ M+ } "HOME" } select-start-of-document }
 606     { T{ key-down f { S+ M+ } "END" } select-end-of-document }
 607 } append ] when define-command-map
 608
 609 : editor-menu ( editor -- )
 610     {
 611         com-undo
 612         com-redo
 613         ----
 614         com-cut
 615         com-copy
 616         com-paste
 617     } show-commands-menu ;
 618
 619 editor "misc" f {
 620     ! { T{ button-down f f 2 } paste-selection }
 621     { T{ button-down f f 3 } editor-menu }
 622 } define-command-map
 623
 624 ! Multi-line editors
 625 TUPLE: multiline-editor < editor ;
 626
 627 : <multiline-editor> ( -- editor )
 628     multiline-editor new-editor ;
 629
 630 : previous-line ( editor -- ) line-elt editor-prev ;
 631
 632 : next-line ( editor -- ) line-elt editor-next ;
 633
 634 <PRIVATE
 635
 636 : page-elt ( editor n -- editor element )
 637     over visible-lines 1 - min 1 max <page-elt> ;
 638
 639 : prev-page-elt ( editor -- editor element )
 640     dup editor-caret first page-elt ;
 641
 642 : next-page-elt ( editor -- editor element )
 643     dup [ control-value length 1 - ] [ editor-caret first ] bi - page-elt ;
 644
 645 PRIVATE>
 646
 647 : previous-page ( editor -- ) prev-page-elt editor-prev ;
 648
 649 : next-page ( editor -- ) next-page-elt editor-next ;
 650
 651 : select-previous-line ( editor -- ) line-elt editor-select-prev ;
 652
 653 : select-next-line ( editor -- ) line-elt editor-select-next ;
 654
 655 : select-previous-page ( editor -- ) prev-page-elt editor-select-prev ;
 656
 657 : select-next-page ( editor -- ) next-page-elt editor-select-next ;
 658
 659 : insert-newline ( editor -- )
 660     "\n" swap user-input* drop ;
 661
 662 : change-selection ( editor quot -- )
 663     '[ gadget-selection @ ] [ user-input* drop ] bi ; inline
 664
 665 <PRIVATE
 666
 667 : join-lines ( string -- string' )
 668     split-lines
 669     [ rest-slice [ [ blank? ] trim-head-slice ] map! drop ]
 670     [ but-last-slice [ [ blank? ] trim-tail-slice ] map! drop ]
 671     [ join-words ]
 672     tri ;
 673
 674 : last-line? ( document line -- ? )
 675     [ last-line# ] dip = ;
 676
 677 : prev-line-and-this ( document line -- start end )
 678     swap [ drop 1 - 0 2array ] [ line-end ] 2bi ;
 679
 680 : join-with-prev ( document line -- )
 681     [ prev-line-and-this ] [ drop ] 2bi
 682     [ join-lines ] change-doc-range ;
 683
 684 : this-line-and-next ( document line -- start end )
 685     swap [ drop 0 2array ] [ [ 1 + ] dip line-end ] 2bi ;
 686
 687 : join-with-next ( document line -- )
 688     [ this-line-and-next ] [ drop ] 2bi
 689     [ join-lines ] change-doc-range ;
 690
 691 PRIVATE>
 692
 693 : com-join-lines ( editor -- )
 694     dup gadget-selection?
 695     [ [ join-lines ] change-selection ] [
 696         [ model>> ] [ editor-caret first ] bi {
 697             { [ over last-line# 0 = ] [ 2drop ] }
 698             { [ 2dup last-line? ] [ join-with-prev ] }
 699             [ join-with-next ]
 700         } cond
 701     ] if ;
 702
 703 multiline-editor "multiline" f {
 704     { T{ key-down f f "UP" } previous-line }
 705     { T{ key-down f f "DOWN" } next-line }
 706     { T{ key-down f { S+ } "UP" } select-previous-line }
 707     { T{ key-down f { S+ } "DOWN" } select-next-line }
 708     { T{ key-down f f "PAGE_UP" } previous-page }
 709     { T{ key-down f f "PAGE_DOWN" } next-page }
 710     { T{ key-down f { S+ } "PAGE_UP" } select-previous-page }
 711     { T{ key-down f { S+ } "PAGE_DOWN" } select-next-page }
 712     { T{ key-down f f "RET" } insert-newline }
 713     { T{ key-down f { S+ } "RET" } insert-newline }
 714     { T{ key-down f f "ENTER" } insert-newline }
 715     { T{ key-down f { S+ } "ENTER" } insert-newline }
 716     { T{ key-down f { C+ } "j" } com-join-lines }
 717 } define-command-map
 718
 719 TUPLE: source-editor < multiline-editor ;
 720
 721 : <source-editor> ( -- editor )
 722     source-editor new-editor ;
 723
 724 ! A useful model
 725 : <element-model> ( editor element -- model )
 726     [ [ caret>> ] [ model>> ] bi ] dip
 727     '[ _ _ elt-string ] <arrow> ;
 728
 729 ! Fields wrap an editor
 730 TUPLE: field < border editor min-cols max-cols ;
 731
 732 <PRIVATE
 733
 734 : field-theme ( gadget -- gadget )
 735     { 2 2 } >>size
 736     { 1 0 } >>fill
 737     field-border-color <solid> >>boundary ; inline
 738
 739 : <field-border> ( gadget -- border )
 740     border new-border field-theme ;
 741
 742 PRIVATE>
 743
 744 : new-field ( class -- gadget )
 745     [ <editor> ] dip new-border
 746         dup gadget-child >>editor
 747         field-theme ; inline
 748
 749 ! For line-gadget-width
 750 M: field font>> editor>> font>> ;
 751
 752 M: field pref-dim*
 753     [ ]
 754     [ editor>> pref-dim ]
 755     [ [ line-gadget-width ] [ drop second ] 2bi 2array ]
 756     tri border-pref-dim ;
 757
 758 M: field default-text>> editor>> default-text>> ;
 759
 760 M: field default-text<< editor>> default-text<< ;
 761
 762 TUPLE: model-field < field field-model ;
 763
 764 : <model-field> ( model -- gadget )
 765     model-field new-field
 766         swap >>field-model ;
 767
 768 M: model-field graft*
 769     [ [ field-model>> value>> ] [ editor>> ] bi set-editor-string ]
 770     [ dup editor>> model>> add-connection ]
 771     bi ;
 772
 773 M: model-field ungraft*
 774     dup editor>> model>> remove-connection ;
 775
 776 M: model-field model-changed
 777     nip [ editor>> editor-string ] [ field-model>> ] bi set-model ;
 778
 779 TUPLE: action-field < field quot ;
 780
 781 : <action-field> ( quot: ( string -- ) -- gadget )
 782     action-field [ <editor> ] dip new-border
 783         dup gadget-child >>editor
 784         field-theme
 785         swap >>quot ;
 786
 787 : invoke-action-field ( field -- )
 788     [ editor>> editor-string ]
 789     [ editor>> clear-editor ]
 790     [ quot>> ]
 791     tri call( string -- ) ;
 792
 793 action-field H{
 794     { T{ key-down f f "RET" } [ invoke-action-field ] }
 795 } set-gestures
 796
 797 : readline-bindings ( editor-class -- )
 798     "readline" f {
 799         { T{ key-down f { C+ } "p" } previous-line }
 800         { T{ key-down f { C+ } "n" } next-line }
 801         { T{ key-down f { C+ } "b" } previous-character }
 802         { T{ key-down f { C+ } "f" } next-character }
 803         { T{ key-down f { C+ } "a" } start-of-line }
 804         { T{ key-down f { C+ } "e" } end-of-line }
 805         ! { T{ key-down f { C+ } "t" } transpose-character }
 806         { T{ key-down f { C+ } "d" } delete-next-character }
 807         { T{ key-down f { C+ } "h" } delete-previous-character }
 808         { T{ key-down f { C+ } "u" } delete-to-start-of-line }
 809         { T{ key-down f { C+ } "k" } delete-to-end-of-line }
 810         { T{ key-down f { C+ } "w" } delete-previous-word }
 811     } define-command-map ;