basis/xmode/loader/syntax/syntax.factor

   1 ! Copyright (C) 2007, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs combinators kernel lexer make
   4 namespaces parser sequences splitting xml.data xml.syntax
   5 xml.syntax.private xml.traversal xml.traversal.private
   6 xmode.rules xmode.tokens xmode.utilities ;
   7 IN: xmode.loader.syntax
   8
   9 ! Rule tag parsing utilities
  10 : (parse-rule-tag) ( rule-set tag specs class -- )
  11     new swap init-from-tag swap add-rule ; inline
  12
  13 SYNTAX: RULE:
  14     scan-token scan-word scan-word [
  15         [ parse-definition call( -- ) ] { } make
  16         swap [ (parse-rule-tag) ] 2curry
  17     ] dip swap define-tag ;
  18
  19 ! Attribute utilities
  20 : string>boolean ( string -- ? ) "TRUE" = ;
  21
  22 : string>match-type ( string -- obj )
  23     {
  24         { "RULE" [ f ] }
  25         { "CONTEXT" [ t ] }
  26         [ string>token ]
  27     } case ;
  28
  29 : string>rule-set-name ( string -- name ) "MAIN" or ;
  30
  31 : cdata>string ( tag -- string )
  32     children>> [ dup cdata? [ text>> ] when ] map (children>string) ;
  33
  34 ! PROP, PROPS
  35 : parse-prop-tag ( tag -- key value )
  36     [ "NAME" attr ] [ "VALUE" attr ] bi ;
  37
  38 : parse-props-tag ( tag -- assoc )
  39     children-tags [ parse-prop-tag ] H{ } map>assoc ;
  40
  41 : position-attrs ( tag -- at-line-start? at-whitespace-end? at-word-start? )
  42     ! XXX Wrong logic!
  43     { "AT_LINE_START" "AT_WHITESPACE_END" "AT_WORD_START" }
  44     [ attr string>boolean ] with map first3 ;
  45
  46 : parse-literal-matcher ( tag -- matcher )
  47     dup cdata>string
  48     rule-set get ignore-case?>> <string-matcher>
  49     swap position-attrs <matcher> ;
  50
  51 : parse-regexp-matcher ( tag -- matcher )
  52     dup cdata>string
  53     rule-set get ignore-case?>> <?insensitive-regexp>
  54     swap position-attrs <matcher> ;
  55
  56 : shared-tag-attrs ( -- )
  57     { "TYPE" string>token body-token<< } , ; inline
  58
  59 : parse-delegate ( string -- pair )
  60     "::" split1 [ rule-set get swap ] unless* 2array ;
  61
  62 : delegate-attr ( -- )
  63     { "DELEGATE" f delegate<< } , ;
  64
  65 ! XXX: check HASH_CHAR for full prefix, not just first character
  66
  67 : char<< ( value object -- )
  68     [ ?first ] dip chars<< ;
  69
  70 : regexp-attr ( -- )
  71     { "HASH_CHAR" f char<< } ,
  72     { "HASH_CHARS" f chars<< } , ;
  73
  74 : match-type-attr ( -- )
  75     { "MATCH_TYPE" string>match-type match-token<< } , ;
  76
  77 : string>escape ( str -- escape/f )
  78     [ f ] [ <escape-rule> ] if-empty ;
  79
  80 : span-attrs ( -- )
  81     { "NO_LINE_BREAK" string>boolean no-line-break?<< } ,
  82     { "NO_WORD_BREAK" string>boolean no-word-break?<< } ,
  83     { "ESCAPE" string>escape escape-rule<< } , ;
  84
  85 : literal-start ( -- )
  86     [ parse-literal-matcher >>start drop ] , ;
  87
  88 : regexp-start ( -- )
  89     [ parse-regexp-matcher >>start drop ] , ;
  90
  91 : literal-end ( -- )
  92     [ parse-literal-matcher >>end drop ] , ;
  93
  94 TAGS: parse-begin/end-tag ( rule tag -- )
  95
  96 TAG: BEGIN parse-begin/end-tag
  97     parse-literal-matcher >>start drop ;
  98
  99 TAG: END parse-begin/end-tag
 100     parse-literal-matcher >>end drop ;
 101
 102 : parse-begin/end-tags ( -- )
 103     [ children-tags [ parse-begin/end-tag ] with each ] , ;
 104
 105 TAGS: parse-regexp-begin/end-tag ( rule tag -- )
 106
 107 TAG: BEGIN parse-regexp-begin/end-tag
 108     parse-regexp-matcher >>start drop ;
 109
 110 ! XXX: END AT_WHITESPACE_END="TRUE"?
 111
 112 TAG: END parse-regexp-begin/end-tag
 113     dup "REGEXP" attr string>boolean
 114     [ parse-regexp-matcher ] [ parse-literal-matcher ] if >>end drop ;
 115
 116 : parse-regexp-begin/end-tags ( -- )
 117     [ children-tags [ parse-regexp-begin/end-tag ] with each ] , ;
 118
 119 : init-span-tag ( -- ) [ drop init-span ] , ;
 120
 121 : init-eol-span-tag ( -- ) [ drop init-eol-span ] , ;
 122
 123 : parse-keyword-tag ( tag keyword-map -- )
 124     [ dup main>> string>token swap cdata>string ] dip set-at ;