core/alien/alien.factor

   1 ! Copyright (C) 2004, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs byte-arrays byte-vectors continuations
   4 continuations.private init kernel kernel.private math namespaces
   5 sequences ;
   6 IN: alien
   7
   8 BUILTIN: alien { underlying c-ptr read-only initial: f } expired ;
   9 BUILTIN: dll { path byte-array read-only initial: B{ } } ;
  10
  11 PRIMITIVE: <callback> ( word return-rewind -- alien )
  12 PRIMITIVE: <displaced-alien> ( displacement c-ptr -- alien )
  13 PRIMITIVE: alien-address ( c-ptr -- addr )
  14 PRIMITIVE: free-callback ( alien -- )
  15
  16 <PRIVATE
  17 PRIMITIVE: current-callback ( -- n )
  18 PRIVATE>
  19
  20 PREDICATE: pinned-alien < alien underlying>> not ;
  21
  22 UNION: pinned-c-ptr pinned-alien POSTPONE: f ;
  23
  24 GENERIC: element-size ( seq -- n ) flushable
  25
  26 M: byte-array element-size drop 1 ; inline
  27
  28 M: byte-vector element-size drop 1 ; inline
  29
  30 M: slice element-size seq>> element-size ; inline
  31
  32 M: f element-size drop 1 ; inline
  33
  34 GENERIC: byte-length ( obj -- n ) flushable
  35
  36 M: object byte-length [ length ] [ element-size ] bi * ; inline
  37
  38 GENERIC: >c-ptr ( obj -- c-ptr ) flushable
  39
  40 M: c-ptr >c-ptr ; inline
  41
  42 M: slice >c-ptr
  43     [ [ from>> ] [ element-size ] bi * ] [ seq>> >c-ptr ] bi
  44     <displaced-alien> ; inline
  45
  46 SLOT: underlying
  47
  48 M: object >c-ptr underlying>> ; inline
  49
  50 : binary-object ( obj -- c-ptr n )
  51     [ >c-ptr ] [ byte-length ] bi ; inline
  52
  53 GENERIC: expired? ( c-ptr -- ? ) flushable
  54
  55 M: alien expired? expired>> ;
  56
  57 M: f expired? drop t ;
  58
  59 : <alien> ( address -- alien )
  60     f <displaced-alien> { pinned-c-ptr } declare ; inline
  61
  62 : <bad-alien> ( -- alien )
  63     -1 <alien> t >>expired ; inline
  64
  65 M: alien equal?
  66     over alien? [
  67         2dup [ expired? ] either? [
  68             [ expired? ] both?
  69         ] [
  70             [ alien-address ] same?
  71         ] if
  72     ] [
  73         2drop f
  74     ] if ;
  75
  76 M: pinned-alien hashcode*
  77     nip dup expired>> [ drop 1234 ] [ alien-address ] if ;
  78
  79 SINGLETONS: stdcall thiscall fastcall cdecl mingw ;
  80
  81 UNION: abi stdcall thiscall fastcall cdecl mingw ;
  82
  83 : callee-cleanup? ( abi -- ? )
  84     { stdcall fastcall thiscall } member? ;
  85
  86 ERROR: callsite-not-compiled word ;
  87
  88 : alien-assembly ( args... return parameters abi quot -- return... )
  89     \ alien-assembly callsite-not-compiled ;
  90
  91 : alien-callback ( return parameters abi quot -- alien )
  92     \ alien-callback callsite-not-compiled ;
  93
  94 : alien-indirect ( args... funcptr return parameters abi -- return... )
  95     \ alien-indirect callsite-not-compiled ;
  96
  97 : alien-invoke ( args... return library function parameters varargs? -- return... )
  98     \ alien-invoke callsite-not-compiled ;
  99
 100 <PRIVATE
 101
 102 ! Callbacks are registered in a global hashtable. Note that they
 103 ! are also pinned in a special callback area, so clearing this
 104 ! hashtable will not reclaim callbacks. It should only be
 105 ! cleared on startup.
 106 SYMBOL: callbacks
 107
 108 STARTUP-HOOK: [ H{ } clone callbacks set-global ]
 109
 110 ! Used by compiler.codegen to wrap callback bodies
 111 : do-callback ( callback-quot wait-quot: ( callback -- ) -- )
 112     t CONTEXT-OBJ-IN-CALLBACK-P set-context-object
 113     init-namestack
 114     init-catchstack
 115     current-callback
 116     [ 2drop call ] [ swap call( callback -- ) drop ] 3bi ; inline
 117
 118 ! A utility for defining global variables that are recompiled in
 119 ! every session
 120 TUPLE: expiry-check object alien ;
 121
 122 : recompute-value? ( check -- ? )
 123     [ alien>> expired? ] [ t ] if* ;
 124
 125 : delete-values ( value assoc -- )
 126     [ rot drop = ] with assoc-reject! drop ;
 127
 128 PRIVATE>
 129
 130 : unregister-and-free-callback ( alien -- )
 131     [ callbacks get delete-values ] [ free-callback ] bi ;
 132
 133 : with-callback ( alien quot -- )
 134     over [ unregister-and-free-callback ] curry finally ; inline
 135
 136 : initialize-alien ( symbol quot -- )
 137     swap dup get-global dup recompute-value?
 138     [ drop [ call dup 31337 <alien> expiry-check boa ] dip set-global ]
 139     [ 2nip object>> ] if ; inline