core/memoize/memoize.factor

   1 ! Copyright (C) 2007, 2010 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs definitions effects hashtables
   4 kernel kernel.private math sequences sequences.private words ;
   5 IN: memoize
   6
   7 <PRIVATE
   8
   9 ! We can't use n*quot, narray and firstn from generalizations because
  10 ! they're macros, and macros use memoize!
  11 : (n*quot) ( n quot -- quotquot )
  12     <repetition> [ ] concat-as ;
  13
  14 : [nsequence] ( length exemplar -- quot )
  15     [ [ [ 1 - ] keep ] dip '[ _ _ _ new-sequence ] ]
  16     [ drop [ [ set-nth-unsafe ] 2keep [ 1 - ] dip ] (n*quot) ] 2bi
  17     [ nip ] 3append ;
  18
  19 : [firstn] ( length -- quot )
  20     [ 0 swap ] swap
  21     [ [ nth-unsafe ] 2keep [ 1 + ] dip ] (n*quot)
  22     [ 2drop ] 3append ;
  23
  24 : packer ( seq -- quot )
  25     length dup 4 <=
  26     [ { [ f ] [ ] [ 2array ] [ 3array ] [ 4array ] } nth ]
  27     [ { } [nsequence] ] if ;
  28
  29 : unpacker ( seq -- quot )
  30     length dup dup 4 <=
  31     [ { [ drop ] [ ] [ first2-unsafe ] [ first3-unsafe ] [ first4-unsafe ] } nth ]
  32     [ [firstn] ] if swap 1 >
  33     [ [ { array } declare ] prepose ] when ;
  34
  35 : pack/unpack ( quot effect -- newquot )
  36     [ in>> packer ] [ out>> unpacker ] bi surround ;
  37
  38 : unpack/pack ( quot effect -- newquot )
  39     [ in>> unpacker ] [ out>> packer ] bi surround ;
  40
  41 : make/n ( table quot effect -- quot )
  42     [ unpack/pack '[ _ _ cache ] ] keep pack/unpack ;
  43
  44 : make/0 ( table quot effect -- quot )
  45     out>> [
  46         packer '[
  47             _ dup first-unsafe
  48             [ ] [ @ @ [ 0 rot set-nth-unsafe ] keep ] ?if
  49         ]
  50     ] keep unpacker compose ;
  51
  52 : make-memoizer ( table quot effect -- quot )
  53     dup in>> length zero? [ make/0 ] [ make/n ] if ;
  54
  55 PRIVATE>
  56
  57 : (define-memoized) ( word quot effect hashtable -- )
  58     [ [ drop "memo-quot" set-word-prop ] ] dip
  59     '[ 2drop _ "memoize" set-word-prop ]
  60     [ [ [ dup "memoize" word-prop ] 2dip make-memoizer ] keep define-declared ]
  61     3tri ;
  62
  63 : define-memoized ( word quot effect -- )
  64     dup in>> length zero? [ f 1array ] [ H{ } clone ] if
  65     (define-memoized) ;
  66
  67 : define-identity-memoized ( word quot effect -- )
  68     dup in>> length zero? [ f 1array ] [ IH{ } clone ] if
  69     (define-memoized) ;
  70
  71 PREDICATE: memoized < word "memoize" word-prop >boolean ;
  72
  73 M: memoized definer
  74     def>> 3 from-tail swap ?nth hashtable?
  75     \ MEMO: \ IDENTITY-MEMO: ? \ ; ;
  76
  77 M: memoized definition "memo-quot" word-prop ;
  78
  79 M: memoized reset-word
  80     [ call-next-method ]
  81     [ { "memoize" "memo-quot" } remove-word-props ]
  82     bi ;
  83
  84 : memoize-quot ( quot effect -- memo-quot )
  85     dup in>> length zero? [ f 1array ] [ H{ } clone ] if
  86     -rot make-memoizer ;
  87
  88 : reset-memoized ( word -- )
  89     "memoize" word-prop dup sequence?
  90     [ f swap set-first ] [ clear-assoc ] if ;
  91
  92 : invalidate-memoized ( inputs... word -- )
  93     [ stack-effect in>> packer call ]
  94     [
  95         "memoize" word-prop dup sequence?
  96         [ f swap set-first ] [ delete-at ] if
  97     ]
  98     bi ;
  99
 100 \ invalidate-memoized t "no-compile" set-word-prop