core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private math math.order
   4 math.private slots.private ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ; inline
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  27 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  28
  29 : empty? ( seq -- ? ) length 0 = ; inline
  30
  31 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  32     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  33
  34 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  35
  36 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  37
  38 : delete-all ( seq -- ) 0 swap set-length ;
  39
  40 : first ( seq -- first ) 0 swap nth ; inline
  41 : second ( seq -- second ) 1 swap nth ; inline
  42 : third ( seq -- third ) 2 swap nth ; inline
  43 : fourth ( seq -- fourth ) 3 swap nth ; inline
  44
  45 : set-first ( first seq -- ) 0 swap set-nth ; inline
  46 : set-second ( second seq -- ) 1 swap set-nth ; inline
  47 : set-third ( third seq -- ) 2 swap set-nth ; inline
  48 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  49
  50 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  51
  52 ERROR: bounds-error index seq ;
  53
  54 GENERIC#: bounds-check? 1 ( n seq -- ? )
  55
  56 M: integer bounds-check?
  57     dupd length < [ 0 >= ] [ drop f ] if ; inline
  58
  59 : bounds-check ( n seq -- n seq )
  60     2dup bounds-check? [ bounds-error ] unless ; inline
  61
  62 MIXIN: immutable-sequence
  63
  64 ERROR: immutable element index sequence ;
  65
  66 M: immutable-sequence set-nth immutable ;
  67
  68 INSTANCE: immutable-sequence sequence
  69
  70 <PRIVATE
  71
  72 : array-nth ( n array -- elt )
  73     swap 2 fixnum+fast slot ; inline
  74
  75 : set-array-nth ( elt n array -- )
  76     swap 2 fixnum+fast set-slot ; inline
  77
  78 : dispatch ( n array -- ) array-nth call ;
  79
  80 GENERIC: resize ( n seq -- newseq ) flushable
  81
  82 ! Unsafe sequence protocol for inner loops
  83 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  84 GENERIC: set-nth-unsafe ( elt n seq -- )
  85
  86 M: sequence nth bounds-check nth-unsafe ; inline
  87 M: sequence set-nth bounds-check set-nth-unsafe ; inline
  88
  89 M: sequence nth-unsafe nth ; inline
  90 M: sequence set-nth-unsafe set-nth ; inline
  91
  92 : change-nth-unsafe ( i seq quot -- )
  93     [ [ nth-unsafe ] dip call ] 2keepd set-nth-unsafe ; inline
  94
  95 PRIVATE>
  96
  97 ! The f object supports the sequence protocol trivially
  98 M: f length drop 0 ; inline
  99 M: f nth-unsafe nip ; inline
 100 M: f like drop [ f ] when-empty ; inline
 101
 102 INSTANCE: f immutable-sequence
 103
 104 ! Integer sequences
 105 TUPLE: iota { n integer read-only } ;
 106
 107 ERROR: non-negative-integer-expected n ;
 108
 109 : <iota> ( n -- iota )
 110     dup 0 < [ non-negative-integer-expected ] when
 111     iota boa ; inline
 112
 113 M: iota length n>> ; inline
 114 M: iota nth-unsafe drop ; inline
 115
 116 INSTANCE: iota immutable-sequence
 117
 118 <PRIVATE
 119
 120 : first-unsafe ( seq -- first ) 0 swap nth-unsafe ; inline
 121 : second-unsafe ( seq -- second ) 1 swap nth-unsafe ; inline
 122 : third-unsafe ( seq -- third ) 2 swap nth-unsafe ; inline
 123 : fourth-unsafe ( seq -- fourth ) 3 swap nth-unsafe ; inline
 124
 125 : first2-unsafe ( seq -- first second )
 126     [ first-unsafe ] [ second-unsafe ] bi ; inline
 127
 128 : first3-unsafe ( seq -- first second third )
 129     [ first2-unsafe ] [ third-unsafe ] bi ; inline
 130
 131 : first4-unsafe ( seq -- first second third fourth )
 132     [ first3-unsafe ] [ fourth-unsafe ] bi ; inline
 133
 134 : exchange-unsafe ( m n seq -- )
 135     [ [ nth-unsafe ] curry bi@ ]
 136     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 137
 138 : (1sequence) ( obj seq -- seq )
 139     [ 0 swap set-nth-unsafe ] keep ; inline
 140
 141 : (2sequence) ( obj1 obj2 seq -- seq )
 142     [ 1 swap set-nth-unsafe ] keep (1sequence) ; inline
 143
 144 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 145     [ 2 swap set-nth-unsafe ] keep (2sequence) ; inline
 146
 147 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 148     [ 3 swap set-nth-unsafe ] keep (3sequence) ; inline
 149
 150 PRIVATE>
 151
 152 : head-to-index ( seq to -- zero to seq ) [ 0 ] 2dip swap ; inline
 153
 154 : index-to-tail ( seq from -- from length seq ) swap [ length ] keep ; inline
 155
 156 : from-tail ( seq n -- seq n' ) [ dup length ] dip - ; inline
 157
 158 : 1sequence ( obj exemplar -- seq )
 159     1 swap [ (1sequence) ] new-like ; inline
 160
 161 : 2sequence ( obj1 obj2 exemplar -- seq )
 162     2 swap [ (2sequence) ] new-like ; inline
 163
 164 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 165     3 swap [ (3sequence) ] new-like ; inline
 166
 167 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 168     4 swap [ (4sequence) ] new-like ; inline
 169
 170 : first2 ( seq -- first second )
 171     1 swap bounds-check nip first2-unsafe ; inline
 172
 173 : first3 ( seq -- first second third )
 174     2 swap bounds-check nip first3-unsafe ; inline
 175
 176 : first4 ( seq -- first second third fourth )
 177     3 swap bounds-check nip first4-unsafe ; inline
 178
 179 : ?nth ( n seq -- elt/f )
 180     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 181
 182 : ?set-nth ( elt n seq -- )
 183     2dup bounds-check? [ set-nth-unsafe ] [ 3drop ] if ; inline
 184
 185 : index-or-length ( seq n -- seq n' ) over length min ; inline
 186
 187 : index-of-last ( seq -- n seq ) [ length 1 - ] keep ; inline
 188
 189 : ?first ( seq -- elt/f ) 0 swap ?nth ; inline
 190 : ?second ( seq -- elt/f ) 1 swap ?nth ; inline
 191 : ?last ( seq -- elt/f )
 192     index-of-last over 0 <
 193     [ 2drop f ] [ nth-unsafe ] if ; inline
 194
 195 MIXIN: virtual-sequence
 196 GENERIC: virtual-exemplar ( seq -- seq' )
 197 GENERIC: virtual@ ( n seq -- n' seq' )
 198
 199 M: virtual-sequence nth virtual@ nth ; inline
 200 M: virtual-sequence set-nth virtual@ set-nth ; inline
 201 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 202 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 203 M: virtual-sequence like virtual-exemplar like ; inline
 204 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 205
 206 INSTANCE: virtual-sequence sequence
 207
 208 ! A reversal of an underlying sequence.
 209 TUPLE: reversed { seq read-only } ;
 210
 211 C: <reversed> reversed
 212
 213 M: reversed virtual-exemplar seq>> ; inline
 214 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 215 M: reversed length seq>> length ; inline
 216
 217 INSTANCE: reversed virtual-sequence
 218
 219 ! A slice of another sequence.
 220 TUPLE: slice
 221     { from integer read-only }
 222     { to integer read-only }
 223     { seq read-only } ;
 224
 225 : >slice< ( slice -- from to seq )
 226     [ from>> ] [ to>> ] [ seq>> ] tri ; inline
 227
 228 : collapse-slice ( m n slice -- m' n' seq )
 229     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 230
 231 ERROR: slice-error from to seq ;
 232
 233 : check-slice ( from to seq -- from to seq )
 234     pick 0 < [ slice-error ] when
 235     2dup length > [ slice-error ] when
 236     2over > [ slice-error ] when ; inline
 237
 238 <PRIVATE
 239
 240 : <slice-unsafe> ( from to seq -- slice )
 241     dup slice? [ collapse-slice ] when slice boa ; inline
 242
 243 PRIVATE>
 244
 245 : <slice> ( from to seq -- slice )
 246     check-slice <slice-unsafe> ; inline
 247
 248 M: slice virtual-exemplar seq>> ; inline
 249
 250 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 251
 252 M: slice length [ to>> ] [ from>> ] bi - ; inline
 253
 254 : head-slice ( seq n -- slice ) head-to-index <slice> ; inline
 255
 256 : tail-slice ( seq n -- slice ) index-to-tail <slice> ; inline
 257
 258 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 259
 260 : head-slice* ( seq n -- slice ) from-tail head-slice ; inline
 261
 262 : tail-slice* ( seq n -- slice ) from-tail tail-slice ; inline
 263
 264 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 265
 266 INSTANCE: slice virtual-sequence
 267
 268 ! One element repeated many times
 269 TUPLE: repetition
 270     { length integer read-only }
 271     { elt read-only } ;
 272
 273 : <repetition> ( len elt -- repetition )
 274     over 0 < [ non-negative-integer-expected ] when
 275     repetition boa ; inline
 276
 277 M: repetition length length>> ; inline
 278 M: repetition nth-unsafe nip elt>> ; inline
 279
 280 INSTANCE: repetition immutable-sequence
 281
 282 <PRIVATE
 283
 284 ERROR: integer-length-expected obj ;
 285
 286 ! The check-length call forces partial dispatch
 287 : check-length ( n -- n )
 288     dup integer? [ integer-length-expected ] unless ; inline
 289
 290 : >sequence< ( seq -- i n seq )
 291     [ drop 0 ] [ length check-length ] [ ] tri ; inline
 292
 293 : length-sequence ( seq -- n seq )
 294     [ length check-length ] [ ] bi ; inline
 295
 296 : >underlying< ( slice/seq -- i n slice/seq )
 297     dup slice? [ >slice< ] [ >sequence< ] if ; inline
 298
 299 TUPLE: copier
 300     { src-i integer read-only }
 301     { src read-only }
 302     { dst-i integer read-only }
 303     { dst read-only } ;
 304
 305 C: <copier> copier
 306
 307 : copy-nth-unsafe ( n copy -- )
 308     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 309     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 310
 311 : (copy) ( n copy -- dst )
 312     over 0 <= [ nip dst>> ] [
 313         [ 1 - ] dip [ copy-nth-unsafe ] [ (copy) ] 2bi
 314     ] if ; inline recursive
 315
 316 : subseq>copy ( from to seq -- n copy )
 317     [ over - check-length swap ] dip
 318     3dup nip new-sequence 0 swap <copier> ; inline
 319
 320 : bounds-check-head ( n seq -- n seq )
 321     over 0 < [ bounds-error ] when ; inline
 322
 323 : check-copy ( src n dst -- src n dst )
 324     3dup bounds-check-head
 325     [ swap length + ] dip lengthen ; inline
 326
 327 : copy-unsafe ( src i dst -- )
 328     [ [ length check-length 0 ] keep ] 2dip <copier> (copy) drop ; inline
 329
 330 : subseq-unsafe-as ( from to seq exemplar -- subseq )
 331     [ subseq>copy (copy) ] dip like ; inline
 332
 333 : subseq-unsafe ( from to seq -- subseq )
 334     dup subseq-unsafe-as ; inline
 335
 336 PRIVATE>
 337
 338 : subseq-as ( from to seq exemplar -- subseq )
 339     [ check-slice ] dip subseq-unsafe-as ;
 340
 341 : subseq ( from to seq -- subseq )
 342     dup subseq-as ;
 343
 344 : head ( seq n -- headseq ) head-to-index subseq ;
 345
 346 : tail ( seq n -- tailseq ) index-to-tail subseq ;
 347
 348 : rest ( seq -- tailseq ) 1 tail ;
 349
 350 : head* ( seq n -- headseq ) from-tail head ;
 351
 352 : tail* ( seq n -- tailseq ) from-tail tail ;
 353
 354 : but-last ( seq -- headseq ) 1 head* ;
 355
 356 : copy ( src i dst -- ) check-copy copy-unsafe ; inline
 357
 358 M: sequence clone-like
 359     [ dup length ] dip new-sequence [ 0 swap copy-unsafe ] keep ; inline
 360
 361 M: immutable-sequence clone-like like ; inline
 362
 363 : push-all ( src dst -- ) [ length ] [ copy ] bi ; inline
 364
 365 <PRIVATE
 366
 367 : (append) ( seq1 seq2 accum -- accum )
 368     [ [ over length ] dip copy-unsafe ]
 369     [ 0 swap copy-unsafe ]
 370     [ ] tri ; inline
 371
 372 PRIVATE>
 373
 374 : append-as ( seq1 seq2 exemplar -- newseq )
 375     [ 2dup [ length ] bi@ + ] dip
 376     [ (append) ] new-like ; inline
 377
 378 : append ( seq1 seq2 -- newseq ) over append-as ;
 379
 380 : prepend-as ( seq1 seq2 exemplar -- newseq ) swapd append-as ; inline
 381
 382 : prepend ( seq1 seq2 -- newseq ) over prepend-as ;
 383
 384 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 385     [ 3dup [ length ] tri@ + + ] dip [
 386         [ [ 2over [ length ] bi@ + ] dip copy-unsafe ]
 387         [ (append) ] bi
 388     ] new-like ; inline
 389
 390 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 391
 392 : surround-as ( seq1 seq2 seq3 exemplar -- newseq )
 393     [ swap ] 2dip 3append-as ; inline
 394
 395 : surround ( seq1 seq2 seq3 -- newseq ) over surround-as ; inline
 396
 397 : 1surround-as ( seq1 seq2 exemplar  -- newseq ) dupd surround-as ; inline
 398
 399 : 1surround ( seq1 seq2 -- newseq ) dup 1surround-as ; inline
 400
 401 : glue-as ( seq1 seq2 seq3 exemplar -- newseq ) swapd 3append-as ; inline
 402
 403 : glue ( seq1 seq2 seq3 -- newseq ) pick glue-as ; inline
 404
 405 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 406     [ [ nth ] dip call ] 2keepd set-nth-unsafe ; inline
 407
 408 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 409
 410 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 411
 412 <PRIVATE
 413
 414 : sequence-operator ( seq quot -- i n quot' )
 415     [ >underlying< [ nth-unsafe ] curry ] dip compose ; inline
 416
 417 : length-iterator ( seq -- n quot' )
 418     length-sequence [ nth-unsafe ] curry ; inline
 419
 420 : length-operator ( seq quot -- n quot' )
 421     [ length-iterator ] dip compose ; inline
 422
 423 : length-operator-last ( seq quot -- n quot' )
 424     length-operator [ 1 - ] dip ; inline
 425
 426 : collect-into ( quot into -- quot' )
 427     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 428
 429 : collect-from ( i n quot into -- )
 430     collect-into each-integer-from ; inline
 431
 432 : collect ( n quot into -- )
 433     collect-into each-integer ; inline
 434
 435 : sequence-index-operator ( seq quot -- n quot' )
 436     [ length-iterator [ keep ] curry ] dip compose ; inline
 437
 438 : map-into ( seq quot into -- )
 439     [ length-operator ] dip collect ; inline
 440
 441 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 442     [ nth-unsafe ] bi-curry@ bi ; inline
 443
 444 : setup-2each ( seq1 seq2 -- n quot )
 445     [ min-length check-length ] 2keep [ 2nth-unsafe ] 2curry ; inline
 446
 447 : (2each) ( seq1 seq2 quot -- n quot' )
 448     [ setup-2each ] dip compose ; inline
 449
 450 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 451     [ nth-unsafe ] tri-curry@ tri ; inline
 452
 453 : setup-3each ( seq1 seq2 seq3 -- n quot )
 454     [ [ length ] tri@ min min check-length ]
 455     [ [ 3nth-unsafe ] 3curry ] 3bi ; inline
 456
 457 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 458     [ setup-3each ] dip compose ; inline
 459
 460 : element/index ( i/f seq -- elt/f i/f )
 461     '[ [ _ nth ] [ f ] if* ] keep ;
 462
 463 : index/element ( i/f seq -- i/f elt/f )
 464     dupd '[ _ nth ] [ f ] if* ;
 465
 466 : (accumulate) ( seq identity quot -- identity seq quot' )
 467     swapd [ keepd ] curry ; inline
 468
 469 : (accumulate*) ( seq identity quot -- identity seq quot' )
 470     swapd [ dup ] compose ; inline
 471
 472 PRIVATE>
 473
 474 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 475     sequence-operator each-integer-from ; inline
 476
 477 : each-from ( ... seq quot: ( ... x -- ... ) i -- ... )
 478     -rot length-operator each-integer-from ; inline
 479
 480 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 481     swapd each ; inline
 482
 483 : map-integers-from-as ( ... from len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 484     overd [ [ collect-from ] keep ] new-like ; inline
 485
 486 : map-integers-as ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 487     overd [ [ collect ] keep ] new-like ; inline
 488
 489 : map-integers ( ... len quot: ( ... i -- ... elt ) -- ... newseq )
 490     { } map-integers-as ; inline
 491
 492 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 493     [ length-operator ] dip map-integers-as ; inline
 494
 495 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 496     over map-as ; inline
 497
 498 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 499     [ [ drop ] prepose ] dip map-integers-as ; inline
 500
 501 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 502     { } replicate-as ; inline
 503
 504 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 505     over [ map-into ] keep ; inline
 506
 507 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 508     [ (accumulate) ] dip map-as ; inline
 509
 510 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 511     pick accumulate-as ; inline
 512
 513 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 514     (accumulate) map! ; inline
 515
 516 : accumulate*-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 517     [ (accumulate*) ] dip map-as nip ; inline
 518
 519 : accumulate* ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... newseq )
 520     pick accumulate*-as ; inline
 521
 522 : accumulate*! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... seq )
 523     (accumulate*) map! nip ; inline
 524
 525 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 526     (2each) each-integer ; inline
 527
 528 : 2each-from ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) i -- ... )
 529     [ (2each) ] dip -rot each-integer-from ; inline
 530
 531 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 532     -rotd 2each ; inline
 533
 534 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 535     [ (2each) ] dip map-integers-as ; inline
 536
 537 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 538     pick 2map-as ; inline
 539
 540 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 541     (2each) all-integers? ; inline
 542
 543 : 2any? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 544     negate 2all? not ; inline
 545
 546 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 547     (3each) each-integer ; inline
 548
 549 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 550     [ (3each) ] dip map-integers-as ; inline
 551
 552 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 553     pickd swap 3map-as ; inline
 554
 555 <PRIVATE
 556
 557 : bounds-check-call ( n seq quot -- elt i )
 558     2over bounds-check? [ call ] [ 3drop f f ] if ; inline
 559
 560 : find-from-unsafe ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 561     [ length-operator find-integer-from ] keepd
 562     index/element ; inline
 563
 564 : find-last-from-unsafe ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 565     [ length-operator-last nip find-last-integer ] keepd
 566     index/element ; inline
 567
 568 PRIVATE>
 569
 570 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 571     '[ _ find-from-unsafe ] bounds-check-call ; inline
 572
 573 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 574     [ 0 ] 2dip find-from-unsafe ; inline
 575
 576 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 577     '[ _ find-last-from-unsafe ] bounds-check-call ; inline
 578
 579 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 580     [ index-of-last ] dip find-last-from ; inline
 581
 582 : find-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 583     '[
 584         _ [ sequence-index-operator find-integer-from ] keepd
 585         index/element
 586     ] bounds-check-call ; inline
 587
 588 : find-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 589     [ 0 ] 2dip find-index-from ; inline
 590
 591 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 592     sequence-operator all-integers-from? ; inline
 593
 594 : push-if ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 595     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 596
 597 <PRIVATE
 598
 599 : (selector-as) ( quot length exemplar -- selector accum )
 600     new-resizable [ [ push-if ] 2curry ] keep ; inline
 601
 602 PRIVATE>
 603
 604 : selector-as ( quot exemplar -- selector accum )
 605     [ length ] keep (selector-as) ; inline
 606
 607 : selector ( quot -- selector accum )
 608     V{ } selector-as ; inline
 609
 610 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 611     pick length over [ (selector-as) [ each ] dip ] 2curry dip like ; inline
 612
 613 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 614     over filter-as ; inline
 615
 616 : reject-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 617     [ negate ] [ filter-as ] bi* ; inline
 618
 619 : reject ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 620     over reject-as ; inline
 621
 622 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 623     [ keep swap ] 2dip ? push ; inline
 624
 625 : 2selector ( quot -- selector accum1 accum2 )
 626     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 627
 628 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 629     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 630
 631 : collector-for-as ( seq quot exemplar -- seq quot' vec )
 632     [ over length ] dip new-resizable [ [ push ] curry compose ] keep ; inline
 633
 634 : collector-as ( quot exemplar -- quot' vec )
 635     [ length ] keep new-resizable [ [ push ] curry compose ] keep ; inline
 636
 637 : collector-for ( seq quot -- seq quot' vec )
 638     V{ } collector-for-as ; inline
 639
 640 : collector ( quot -- quot' vec )
 641     V{ } collector-as ; inline
 642
 643 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 644     dup [ collector-as [ while ] dip ] curry dip like ; inline
 645
 646 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 647     { } produce-as ; inline
 648
 649 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 650     [ dup ] swap [ keep ] curry produce nip ; inline
 651
 652 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 653     sequence-index-operator each-integer ; inline
 654
 655 : map-index-as ( ... seq quot: ( ... elt index -- ... newelt ) exemplar -- ... newseq )
 656     [ dup length <iota> ] 2dip 2map-as ; inline
 657
 658 : map-index ( ... seq quot: ( ... elt index -- ... newelt ) -- ... newseq )
 659     over map-index-as ; inline
 660
 661 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 662     pick empty? [ 3drop ] [
 663         [ [ drop first-unsafe ] dip call ]
 664         [ [ bi* ] 2curry 1 each-from ]
 665         3bi
 666     ] if ; inline
 667
 668 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 669     swapd each-index ; inline
 670
 671 : index ( obj seq -- n )
 672     [ = ] with find drop ;
 673
 674 : index-from ( obj i seq -- n )
 675     rot [ = ] curry find-from drop ;
 676
 677 : last-index ( obj seq -- n )
 678     [ = ] with find-last drop ;
 679
 680 : last-index-from ( obj i seq -- n )
 681     rot [ = ] curry find-last-from drop ;
 682
 683 : indices ( obj seq -- indices )
 684     swap [ = ] curry [ swap ] prepose V{ } clone [
 685         [ push ] curry [ [ drop ] if ] curry compose each-index
 686     ] keep ;
 687
 688 <PRIVATE
 689
 690 : nths-unsafe ( indices seq -- seq' )
 691     [ [ nth-unsafe ] curry ] keep map-as ;
 692
 693 PRIVATE>
 694
 695 : nths ( indices seq -- seq' )
 696     [ [ nth ] curry ] keep map-as ;
 697
 698 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 699     find drop >boolean ; inline
 700
 701 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 702     any? not ; inline
 703
 704 : member? ( elt seq -- ? )
 705     [ = ] with any? ;
 706
 707 : member-eq? ( elt seq -- ? )
 708     [ eq? ] with any? ;
 709
 710 : remove ( elt seq -- newseq )
 711     [ = ] with reject ;
 712
 713 : remove-eq ( elt seq -- newseq )
 714     [ eq? ] with reject ;
 715
 716 : sift ( seq -- newseq )
 717     [ ] filter ;
 718
 719 : harvest ( seq -- newseq )
 720     [ empty? ] reject ;
 721
 722 <PRIVATE
 723
 724 : mismatch-unsafe ( n seq1 seq2 -- i )
 725     [ 2nth-unsafe = not ] 2curry find-integer ; inline
 726
 727 PRIVATE>
 728
 729 : mismatch ( seq1 seq2 -- i )
 730     [ min-length ] 2keep mismatch-unsafe ;
 731
 732 M: sequence <=>
 733     [ mismatch ] 2keep pick
 734     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 735
 736 : sequence= ( seq1 seq2 -- ? )
 737     2dup [ length ] bi@ dupd =
 738     [ -rot mismatch-unsafe not ] [ 3drop f ] if ; inline
 739
 740 ERROR: assert-sequence got expected ;
 741
 742 : assert-sequence= ( a b -- )
 743     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 744
 745 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 746
 747 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 748
 749 <PRIVATE
 750
 751 : sequence-hashcode-step ( oldhash newpart -- newhash )
 752     integer>fixnum swap [
 753         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 754         fixnum+fast fixnum+fast
 755     ] keep fixnum-bitxor ; inline
 756
 757 PRIVATE>
 758
 759 : sequence-hashcode ( n seq -- x )
 760     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 761
 762 M: sequence hashcode* [ sequence-hashcode ] recursive-hashcode ;
 763
 764 M: iota hashcode*
 765     over 0 <= [ 2drop 0 ] [
 766         nip length 0 swap [ sequence-hashcode-step ] each-integer
 767     ] if ;
 768
 769 M: reversed hashcode* [ sequence-hashcode ] recursive-hashcode ;
 770
 771 M: slice hashcode* [ sequence-hashcode ] recursive-hashcode ;
 772
 773 : move ( to from seq -- )
 774     2over =
 775     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 776
 777 <PRIVATE
 778
 779 : move-unsafe* ( to from seq -- from-nth )
 780     2over =
 781     [ nth-unsafe nip ]
 782     [ [ nth-unsafe tuck swap ] [ set-nth-unsafe ] bi ] if ; inline
 783
 784 : filter-from! ( store from seq quot: ( ... elt -- ... ? ) -- seq )
 785     2over length < [
 786         [ [ move-unsafe* ] dip call ] 4keep
 787         [ swap [ 1 + ] when ] 3dip
 788         [ 1 + ] 2dip filter-from!
 789     ] [ drop [ nip set-length ] keep ] if ; inline recursive
 790
 791 : move-unsafe ( to from seq -- )
 792     2over =
 793     [ 3drop ] [ [ nth-unsafe swap ] [ set-nth-unsafe ] bi ] if ; inline
 794
 795 PRIVATE>
 796
 797 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 798     [ 0 0 ] 2dip filter-from! ; inline
 799
 800 : reject! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 801     negate filter! ; inline
 802
 803 : remove! ( elt seq -- seq )
 804     [ = ] with reject! ;
 805
 806 : remove-eq! ( elt seq -- seq )
 807     [ eq? ] with reject! ;
 808
 809 : prefix ( seq elt -- newseq )
 810     over [ over length 1 + ] dip [
 811         (1sequence) [ 1 swap copy-unsafe ] keep
 812     ] new-like ;
 813
 814 : suffix ( seq elt -- newseq )
 815     over [ over length 1 + ] dip [
 816         [ [ over length ] dip set-nth-unsafe ] keep
 817         [ 0 swap copy-unsafe ] keep
 818     ] new-like ;
 819
 820 : suffix! ( seq elt -- seq ) over push ; inline
 821
 822 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 823
 824 : last ( seq -- elt )
 825     index-of-last
 826     over 0 < [ bounds-error ] [ nth-unsafe ] if ; inline
 827
 828 <PRIVATE
 829
 830 : last-unsafe ( seq -- elt )
 831     index-of-last nth-unsafe ; inline
 832
 833 PRIVATE>
 834
 835 : set-last ( elt seq -- )
 836     index-of-last
 837     over 0 < [ bounds-error ] [ set-nth-unsafe ] if ; inline
 838
 839 : pop* ( seq -- ) index-of-last shorten ;
 840
 841 <PRIVATE
 842
 843 : move-backward ( shift from to seq -- )
 844     2over = [
 845         4drop
 846     ] [
 847         [ [ 2over + pick ] dip move-unsafe [ 1 + ] dip ] keep
 848         move-backward
 849     ] if ;
 850
 851 : move-forward ( shift from to seq -- )
 852     2over = [
 853         4drop
 854     ] [
 855         [ [ [ ] [ nip + ] [ 2nip ] 3tri ] dip move-unsafe 1 - ] keep
 856         move-forward
 857     ] if ;
 858
 859 : (open-slice) ( shift from to seq ? -- )
 860     [
 861         [ [ 1 - ] bi@ ] dip move-forward
 862     ] [
 863         [ over - ] 2dip move-backward
 864     ] if ;
 865
 866 : open-slice ( shift from seq -- )
 867     pick 0 = [
 868         3drop
 869     ] [
 870         [ ] [ nip length + ] [ 2nip ] 3tri
 871         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 872         set-length
 873     ] if ;
 874
 875 PRIVATE>
 876
 877 : delete-slice ( from to seq -- )
 878     check-slice [ over [ - ] dip ] dip open-slice ;
 879
 880 : remove-nth! ( n seq -- seq )
 881     [ [ dup 1 + ] dip delete-slice ] keep ;
 882
 883 : snip ( from to seq -- head tail )
 884     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 885
 886 : snip-slice ( from to seq -- head tail )
 887     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 888
 889 : replace-slice ( new from to seq -- seq' )
 890     snip-slice surround ;
 891
 892 : remove-nth ( n seq -- seq' )
 893     [ [ dup 1 + ] dip snip-slice ] keep append-as ;
 894
 895 : pop ( seq -- elt )
 896     index-of-last over 0 >=
 897     [ [ nth-unsafe ] [ shorten ] 2bi ]
 898     [ bounds-error ] if ;
 899
 900 : exchange ( m n seq -- )
 901     [ nip bounds-check 2drop ]
 902     [ bounds-check 3drop ]
 903     [ exchange-unsafe ]
 904     3tri ;
 905
 906 : midpoint@ ( seq -- n ) length 2/ ; inline
 907
 908 : reverse! ( seq -- seq )
 909     [
 910         [ midpoint@ ] [ length ] [ ] tri
 911         [ [ over - 1 - ] dip exchange-unsafe ] 2curry
 912         each-integer
 913     ] keep ;
 914
 915 : reverse ( seq -- newseq )
 916      [
 917         dup [ length ] keep new-sequence
 918         [ 0 swap copy-unsafe ] keep reverse!
 919     ] keep like ;
 920
 921 GENERIC: sum-lengths ( seq -- n )
 922
 923 M: object sum-lengths
 924     0 [ length + ] reduce ;
 925
 926 M: repetition sum-lengths
 927     [ length>> ] [ elt>> length ] bi * ;
 928
 929 : concat-as ( seq exemplar -- newseq )
 930     [
 931         [ dup sum-lengths ] dip new-resizable
 932         [ [ push-all ] curry each ] keep
 933     ] keep like ; inline
 934
 935 : concat ( seq -- newseq )
 936     [ { } ] [ dup first concat-as ] if-empty ;
 937
 938 <PRIVATE
 939
 940 : joined-length ( seq glue -- n )
 941     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 942
 943 PRIVATE>
 944
 945 : join-as ( seq glue exemplar -- newseq )
 946     over empty? [ nip concat-as ] [
 947         [
 948             2dup joined-length over new-resizable [
 949                 [ [ push-all ] 2curry ]
 950                 [ nip [ push-all ] curry ] 2bi
 951                 interleave
 952             ] keep
 953         ] dip like
 954     ] if ;
 955
 956 : join ( seq glue -- newseq )
 957     dup join-as ; inline
 958
 959 <PRIVATE
 960
 961 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
 962     [
 963         [ over length [-] dup 0 = [ drop ] ] dip
 964         [ <repetition> ] curry
 965     ] dip compose if ; inline
 966
 967 PRIVATE>
 968
 969 : pad-head ( seq n elt -- padded )
 970     [ swap dup append-as ] padding ;
 971
 972 : pad-tail ( seq n elt -- padded )
 973     [ append ] padding ;
 974
 975 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ; inline
 976 : longer? ( seq1 seq2 -- ? ) [ length ] bi@ > ; inline
 977 : shorter ( seq1 seq2 -- seq ) [ [ length ] bi@ <= ] 2keep ? ; inline
 978 : longer ( seq1 seq2 -- seq ) [ [ length ] bi@ >= ] 2keep ? ; inline
 979
 980 : head? ( seq begin -- ? )
 981     2dup shorter? [
 982         2drop f
 983     ] [
 984         [ length [ head-slice ] keep swap ] keep
 985         mismatch-unsafe not
 986     ] if ;
 987
 988 : tail? ( seq end -- ? )
 989     2dup shorter? [
 990         2drop f
 991     ] [
 992         [ length [ tail-slice* ] keep swap ] keep
 993         mismatch-unsafe not
 994     ] if ;
 995
 996 : cut-slice ( seq n -- before-slice after-slice )
 997     [ head-slice ] [ tail-slice ] 2bi ; inline
 998
 999 : cut-slice* ( seq n -- before-slice after-slice )
1000     [ head-slice* ] [ tail-slice* ] 2bi ;
1001
1002 : insert-nth ( elt n seq -- seq' )
1003     swap cut-slice [ swap suffix ] dip append ;
1004
1005 : halves ( seq -- first-slice second-slice )
1006     dup midpoint@ cut-slice ; inline
1007
1008 <PRIVATE
1009
1010 : nth2-unsafe ( n seq -- a b )
1011     [ nth-unsafe ] [ [ 1 + ] dip nth-unsafe ] 2bi ; inline
1012
1013 : nth3-unsafe ( n seq -- a b c )
1014     [ nth2-unsafe ] [ [ 2 + ] dip nth-unsafe ] 2bi ; inline
1015
1016 : (binary-reduce) ( seq start quot: ( elt1 elt2 -- newelt ) from length -- value )
1017     ! We can't use case here since combinators depends on
1018     ! sequences
1019     dup 4 < [
1020         integer>fixnum {
1021             [ 2drop nip ]
1022             [ 2nip swap nth-unsafe ]
1023             [ -rot [ drop swap nth2-unsafe ] dip call ]
1024             [ -rot [ drop swap nth3-unsafe ] dip bi@ ]
1025         } dispatch
1026     ] [
1027         [ 2/ ] [ over - ] bi [ 2dup + ] dip
1028         [ (binary-reduce) ] [ 2curry ] curry 2bi@
1029         pick [ 3bi ] dip call
1030     ] if ; inline recursive
1031
1032 PRIVATE>
1033
1034 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
1035     pick dup slice? [
1036         [ seq>> ] 3dip [ from>> 0 max ] [ to>> 0 max over - ] bi
1037     ] [
1038         length 0 max 0 swap
1039     ] if (binary-reduce) ; inline
1040
1041 : cut ( seq n -- before after )
1042     [ head ] [ tail ] 2bi ;
1043
1044 : cut* ( seq n -- before after )
1045     [ head* ] [ tail* ] 2bi ;
1046
1047 : subseq-starts-at? ( i seq subseq -- ? )
1048     [ length swap ] keep
1049     '[
1050         [ + _ nth-unsafe ] keep _ nth-unsafe =
1051     ] with all-integers? ; inline
1052
1053 : subseq-index-from ( n seq subseq -- i/f )
1054     [ [ length ] bi@ - 1 + ] 2keep
1055     '[ _ _ subseq-starts-at? ] find-integer-from ; inline
1056
1057 : subseq-index ( seq subseq -- i/f ) [ 0 ] 2dip subseq-index-from ; inline
1058
1059 : subseq-index? ( seq subseq -- ? ) subseq-index >boolean ; inline
1060
1061 : subseq-start-from ( subseq seq n -- i/f )
1062     spin subseq-index-from ; inline deprecated
1063
1064 : subseq-start ( subseq seq -- i/f ) swap subseq-index ; inline deprecated
1065
1066 : subseq? ( subseq seq -- ? ) subseq-start >boolean ; inline deprecated
1067
1068 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
1069     2dup mismatch [ 2dup min-length ] unless*
1070     [ tail-slice ] curry bi@ ;
1071
1072 : unclip ( seq -- rest first )
1073     [ rest ] [ first-unsafe ] bi ;
1074
1075 : unclip-last ( seq -- butlast last )
1076     [ but-last ] [ last-unsafe ] bi ;
1077
1078 : unclip-slice ( seq -- rest-slice first )
1079     [ rest-slice ] [ first-unsafe ] bi ; inline
1080
1081 : map-reduce ( ..a seq map-quot: ( ..a elt -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1082     [ [ [ first ] keep ] dip [ dip ] keep ] dip
1083     '[ swap _ dip swap @ ] 1 each-from ; inline
1084
1085 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1086     [ [ [ [ first ] bi@ ] 2keep ] dip [ 2dip ] keep ] dip
1087     '[ rot _ dip swap @ ] 1 2each-from ; inline
1088
1089 <PRIVATE
1090
1091 : (map-find) ( seq quot find-quot -- result elt )
1092     [ [ f ] 2dip [ nip ] prepose [ dup ] compose ] dip call nip ; inline
1093
1094 PRIVATE>
1095
1096 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1097     [ find ] (map-find) ; inline
1098
1099 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1100     [ find-last ] (map-find) ; inline
1101
1102 : unclip-last-slice ( seq -- butlast-slice last )
1103     [ but-last-slice ] [ last-unsafe ] bi ; inline
1104
1105 <PRIVATE
1106
1107 : (trim-head) ( seq quot -- seq n )
1108     over [ negate find drop ] dip swap
1109     [ dup length ] unless* ; inline
1110
1111 : (trim-tail) ( seq quot -- seq n )
1112     over [ negate find-last drop ?1+ ] dip
1113     swap ; inline
1114
1115 PRIVATE>
1116
1117 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1118     (trim-head) tail-slice ; inline
1119
1120 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1121     (trim-head) tail ; inline
1122
1123 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1124     (trim-tail) head-slice ; inline
1125
1126 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1127     (trim-tail) head ; inline
1128
1129 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1130     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
1131
1132 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1133     [ trim-slice ] [ drop ] 2bi like ; inline
1134
1135 GENERIC: sum ( seq -- n )
1136 M: object sum 0 [ + ] binary-reduce ; inline
1137 M: iota sum length dup 1 - * 2/ ; inline
1138 M: repetition sum [ elt>> ] [ length>> ] bi * ; inline
1139
1140 : product ( seq -- n ) 1 [ * ] binary-reduce ;
1141
1142 : infimum ( seq -- elt ) [ ] [ min ] map-reduce ;
1143
1144 : supremum ( seq -- elt ) [ ] [ max ] map-reduce ;
1145
1146 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
1147     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
1148
1149 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n )
1150     [ 1 0 ? ] compose map-sum ; inline
1151
1152 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
1153     [ with each ] 2curry each ; inline
1154
1155 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
1156     [ with { } map-as ] 2curry { } map-as ; inline
1157
1158 : cartesian-product-as ( seq1 seq2 exemplar -- newseq )
1159     [ 2sequence ] curry cartesian-map ; inline
1160
1161 : cartesian-product ( seq1 seq2 -- newseq )
1162     dup cartesian-product-as ; inline
1163
1164 : cartesian-find ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... elt1 elt2 )
1165     [ f ] 3dip [ with find swap ] 2curry [ nip ] prepose find nip swap ; inline
1166
1167 <PRIVATE
1168
1169 : select-by ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... elt )
1170     [
1171         [ keep swap ] curry [ [ first ] dip call ] 2keep
1172         [ curry 2dip pick over ] curry
1173     ] [
1174         [ [ 2drop ] [ 2nipd ] if ] compose
1175     ] bi* compose 1 each-from drop ; inline
1176
1177 PRIVATE>
1178
1179 : supremum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1180     [ after? ] select-by ; inline
1181
1182 : infimum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1183     [ before? ] select-by ; inline
1184
1185 : shortest ( seqs -- elt ) [ length ] infimum-by ;
1186
1187 : longest ( seqs -- elt ) [ length ] supremum-by ;
1188
1189 ! We hand-optimize flip to such a degree because type hints
1190 ! cannot express that an array is an array of arrays yet, and
1191 ! this word happens to be performance-critical since the compiler
1192 ! itself uses it. Optimizing it like this reduced compile time.
1193 <PRIVATE
1194
1195 : generic-flip ( matrix -- newmatrix )
1196     [ [ length ] [ min ] map-reduce ] keep
1197     '[ _ [ nth-unsafe ] with { } map-as ] map-integers ; inline
1198
1199 USE: arrays
1200
1201 : array-flip ( matrix -- newmatrix )
1202     { array } declare
1203     [ [ { array } declare length>> ] [ min ] map-reduce ] keep
1204     '[ _ [ { array } declare array-nth ] with { } map-as ] map-integers ;
1205
1206 PRIVATE>
1207
1208 : flip ( matrix -- newmatrix )
1209     dup empty? [
1210         dup array? [
1211             dup [ array? ] all?
1212             [ array-flip ] [ generic-flip ] if
1213         ] [ generic-flip ] if
1214     ] unless ;