core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private math math.order
   4 math.private slots.private ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ; inline
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  27 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  28
  29 : empty? ( seq -- ? ) length 0 = ; inline
  30
  31 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  32     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  33
  34 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  35
  36 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  37
  38 : delete-all ( seq -- ) 0 swap set-length ;
  39
  40 : first ( seq -- first ) 0 swap nth ; inline
  41 : second ( seq -- second ) 1 swap nth ; inline
  42 : third ( seq -- third ) 2 swap nth ; inline
  43 : fourth ( seq -- fourth ) 3 swap nth ; inline
  44
  45 : set-first ( first seq -- ) 0 swap set-nth ; inline
  46 : set-second ( second seq -- ) 1 swap set-nth ; inline
  47 : set-third ( third seq -- ) 2 swap set-nth ; inline
  48 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  49
  50 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  51
  52 ERROR: bounds-error index seq ;
  53
  54 GENERIC#: bounds-check? 1 ( n seq -- ? )
  55
  56 M: integer bounds-check?
  57     dupd length < [ 0 >= ] [ drop f ] if ; inline
  58
  59 : bounds-check ( n seq -- n seq )
  60     2dup bounds-check? [ bounds-error ] unless ; inline
  61
  62 MIXIN: immutable-sequence
  63
  64 ERROR: immutable element index sequence ;
  65
  66 M: immutable-sequence set-nth immutable ;
  67
  68 INSTANCE: immutable-sequence sequence
  69
  70 <PRIVATE
  71
  72 : array-nth ( n array -- elt )
  73     swap 2 fixnum+fast slot ; inline
  74
  75 : set-array-nth ( elt n array -- )
  76     swap 2 fixnum+fast set-slot ; inline
  77
  78 : dispatch ( n array -- ) array-nth call ;
  79
  80 GENERIC: resize ( n seq -- newseq ) flushable
  81
  82 ! Unsafe sequence protocol for inner loops
  83 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  84 GENERIC: set-nth-unsafe ( elt n seq -- )
  85
  86 M: sequence nth bounds-check nth-unsafe ; inline
  87 M: sequence set-nth bounds-check set-nth-unsafe ; inline
  88
  89 M: sequence nth-unsafe nth ; inline
  90 M: sequence set-nth-unsafe set-nth ; inline
  91
  92 : change-nth-unsafe ( i seq quot -- )
  93     [ [ nth-unsafe ] dip call ] 2keepd set-nth-unsafe ; inline
  94
  95 PRIVATE>
  96
  97 ! The f object supports the sequence protocol trivially
  98 M: f length drop 0 ; inline
  99 M: f nth-unsafe nip ; inline
 100 M: f like drop [ f ] when-empty ; inline
 101
 102 INSTANCE: f immutable-sequence
 103
 104 ! Integer sequences
 105 TUPLE: iota { n integer read-only } ;
 106
 107 ERROR: non-negative-integer-expected n ;
 108
 109 : <iota> ( n -- iota )
 110     dup 0 < [ non-negative-integer-expected ] when
 111     iota boa ; inline
 112
 113 M: iota length n>> ; inline
 114 M: iota nth-unsafe drop ; inline
 115
 116 INSTANCE: iota immutable-sequence
 117
 118 <PRIVATE
 119
 120 : first-unsafe ( seq -- first ) 0 swap nth-unsafe ; inline
 121 : second-unsafe ( seq -- second ) 1 swap nth-unsafe ; inline
 122 : third-unsafe ( seq -- third ) 2 swap nth-unsafe ; inline
 123 : fourth-unsafe ( seq -- fourth ) 3 swap nth-unsafe ; inline
 124
 125 : first2-unsafe ( seq -- first second )
 126     [ first-unsafe ] [ second-unsafe ] bi ; inline
 127
 128 : first3-unsafe ( seq -- first second third )
 129     [ first2-unsafe ] [ third-unsafe ] bi ; inline
 130
 131 : first4-unsafe ( seq -- first second third fourth )
 132     [ first3-unsafe ] [ fourth-unsafe ] bi ; inline
 133
 134 : exchange-unsafe ( m n seq -- )
 135     [ [ nth-unsafe ] curry bi@ ]
 136     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 137
 138 : (1sequence) ( obj seq -- seq )
 139     [ 0 swap set-nth-unsafe ] keep ; inline
 140
 141 : (2sequence) ( obj1 obj2 seq -- seq )
 142     [ 1 swap set-nth-unsafe ] keep (1sequence) ; inline
 143
 144 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 145     [ 2 swap set-nth-unsafe ] keep (2sequence) ; inline
 146
 147 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 148     [ 3 swap set-nth-unsafe ] keep (3sequence) ; inline
 149
 150 PRIVATE>
 151
 152 : head-to-index ( seq to -- zero to seq ) [ 0 ] 2dip swap ; inline
 153
 154 : index-to-tail ( seq from -- from length seq ) swap [ length ] keep ; inline
 155
 156 : from-tail ( seq n -- seq n' ) [ dup length ] dip - ; inline
 157
 158 : 1sequence ( obj exemplar -- seq )
 159     1 swap [ (1sequence) ] new-like ; inline
 160
 161 : 2sequence ( obj1 obj2 exemplar -- seq )
 162     2 swap [ (2sequence) ] new-like ; inline
 163
 164 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 165     3 swap [ (3sequence) ] new-like ; inline
 166
 167 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 168     4 swap [ (4sequence) ] new-like ; inline
 169
 170 : first2 ( seq -- first second )
 171     1 swap bounds-check nip first2-unsafe ; inline
 172
 173 : first3 ( seq -- first second third )
 174     2 swap bounds-check nip first3-unsafe ; inline
 175
 176 : first4 ( seq -- first second third fourth )
 177     3 swap bounds-check nip first4-unsafe ; inline
 178
 179 : ?nth ( n seq -- elt/f )
 180     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 181
 182 : ?set-nth ( elt n seq -- )
 183     2dup bounds-check? [ set-nth-unsafe ] [ 3drop ] if ; inline
 184
 185 : index-or-length ( seq n -- seq n' ) over length min ; inline
 186
 187 : index-of-last ( seq -- n seq ) [ length 1 - ] keep ; inline
 188
 189 : ?first ( seq -- elt/f ) 0 swap ?nth ; inline
 190 : ?second ( seq -- elt/f ) 1 swap ?nth ; inline
 191 : ?last ( seq -- elt/f )
 192     index-of-last over 0 <
 193     [ 2drop f ] [ nth-unsafe ] if ; inline
 194
 195 MIXIN: virtual-sequence
 196 GENERIC: virtual-exemplar ( seq -- seq' )
 197 GENERIC: virtual@ ( n seq -- n' seq' )
 198
 199 M: virtual-sequence nth virtual@ nth ; inline
 200 M: virtual-sequence set-nth virtual@ set-nth ; inline
 201 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 202 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 203 M: virtual-sequence like virtual-exemplar like ; inline
 204 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 205
 206 INSTANCE: virtual-sequence sequence
 207
 208 ! A reversal of an underlying sequence.
 209 TUPLE: reversed { seq read-only } ;
 210
 211 C: <reversed> reversed
 212
 213 M: reversed virtual-exemplar seq>> ; inline
 214 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 215 M: reversed length seq>> length ; inline
 216
 217 INSTANCE: reversed virtual-sequence
 218
 219 ! A slice of another sequence.
 220 TUPLE: slice
 221     { from integer read-only }
 222     { to integer read-only }
 223     { seq read-only } ;
 224
 225 : >slice< ( slice -- from to seq )
 226     [ from>> ] [ to>> ] [ seq>> ] tri ; inline
 227
 228 : collapse-slice ( m n slice -- m' n' seq )
 229     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 230
 231 ERROR: slice-error from to seq ;
 232
 233 : check-slice ( from to seq -- from to seq )
 234     pick 0 < [ slice-error ] when
 235     2dup length > [ slice-error ] when
 236     2over > [ slice-error ] when ; inline
 237
 238 <PRIVATE
 239
 240 : <slice-unsafe> ( from to seq -- slice )
 241     dup slice? [ collapse-slice ] when slice boa ; inline
 242
 243 PRIVATE>
 244
 245 : <slice> ( from to seq -- slice )
 246     check-slice <slice-unsafe> ; inline
 247
 248 M: slice virtual-exemplar seq>> ; inline
 249
 250 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 251
 252 M: slice length [ to>> ] [ from>> ] bi - ; inline
 253
 254 : head-slice ( seq n -- slice ) head-to-index <slice> ; inline
 255
 256 : tail-slice ( seq n -- slice ) index-to-tail <slice> ; inline
 257
 258 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 259
 260 : head-slice* ( seq n -- slice ) from-tail head-slice ; inline
 261
 262 : tail-slice* ( seq n -- slice ) from-tail tail-slice ; inline
 263
 264 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 265
 266 INSTANCE: slice virtual-sequence
 267
 268 ! One element repeated many times
 269 TUPLE: repetition
 270     { length integer read-only }
 271     { elt read-only } ;
 272
 273 : <repetition> ( len elt -- repetition )
 274     over 0 < [ non-negative-integer-expected ] when
 275     repetition boa ; inline
 276
 277 M: repetition length length>> ; inline
 278 M: repetition nth-unsafe nip elt>> ; inline
 279
 280 INSTANCE: repetition immutable-sequence
 281
 282 <PRIVATE
 283
 284 ERROR: integer-length-expected obj ;
 285
 286 ! The check-length call forces partial dispatch
 287 : check-length ( n -- n )
 288     dup integer? [ integer-length-expected ] unless ; inline
 289
 290 : >sequence< ( seq -- i n seq )
 291     [ drop 0 ] [ length check-length ] [ ] tri ; inline
 292
 293 : length-sequence ( seq -- n seq )
 294     [ length check-length ] [ ] bi ; inline
 295
 296 : >underlying< ( slice/seq -- i n slice/seq )
 297     dup slice? [ >slice< ] [ >sequence< ] if ; inline
 298
 299 TUPLE: copier
 300     { src-i integer read-only }
 301     { src read-only }
 302     { dst-i integer read-only }
 303     { dst read-only } ;
 304
 305 C: <copier> copier
 306
 307 : copy-nth-unsafe ( n copy -- )
 308     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 309     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 310
 311 : (copy) ( n copy -- dst )
 312     over 0 <= [ nip dst>> ] [
 313         [ 1 - ] dip [ copy-nth-unsafe ] [ (copy) ] 2bi
 314     ] if ; inline recursive
 315
 316 : subseq>copy ( from to seq -- n copy )
 317     [ over - check-length swap ] dip
 318     3dup nip new-sequence 0 swap <copier> ; inline
 319
 320 : bounds-check-head ( n seq -- n seq )
 321     over 0 < [ bounds-error ] when ; inline
 322
 323 : check-copy ( src n dst -- src n dst )
 324     3dup bounds-check-head
 325     [ swap length + ] dip lengthen ; inline
 326
 327 : copy-unsafe ( src i dst -- )
 328     [ [ length check-length 0 ] keep ] 2dip <copier> (copy) drop ; inline
 329
 330 : subseq-unsafe-as ( from to seq exemplar -- subseq )
 331     [ subseq>copy (copy) ] dip like ; inline
 332
 333 : subseq-unsafe ( from to seq -- subseq )
 334     dup subseq-unsafe-as ; inline
 335
 336 PRIVATE>
 337
 338 : subseq-as ( from to seq exemplar -- subseq )
 339     [ check-slice ] dip subseq-unsafe-as ;
 340
 341 : subseq ( from to seq -- subseq )
 342     dup subseq-as ;
 343
 344 : head ( seq n -- headseq ) head-to-index subseq ;
 345
 346 : tail ( seq n -- tailseq ) index-to-tail subseq ;
 347
 348 : rest ( seq -- tailseq ) 1 tail ;
 349
 350 : head* ( seq n -- headseq ) from-tail head ;
 351
 352 : tail* ( seq n -- tailseq ) from-tail tail ;
 353
 354 : but-last ( seq -- headseq ) 1 head* ;
 355
 356 : copy ( src i dst -- ) check-copy copy-unsafe ; inline
 357
 358 M: sequence clone-like
 359     [ dup length ] dip new-sequence [ 0 swap copy-unsafe ] keep ; inline
 360
 361 M: immutable-sequence clone-like like ; inline
 362
 363 : push-all ( src dst -- ) [ length ] [ copy ] bi ; inline
 364
 365 <PRIVATE
 366
 367 : (append) ( seq1 seq2 accum -- accum )
 368     [ [ over length ] dip copy-unsafe ]
 369     [ 0 swap copy-unsafe ]
 370     [ ] tri ; inline
 371
 372 PRIVATE>
 373
 374 : append-as ( seq1 seq2 exemplar -- newseq )
 375     [ 2dup [ length ] bi@ + ] dip
 376     [ (append) ] new-like ; inline
 377
 378 : append ( seq1 seq2 -- newseq ) over append-as ;
 379
 380 : prepend-as ( seq1 seq2 exemplar -- newseq ) swapd append-as ; inline
 381
 382 : prepend ( seq1 seq2 -- newseq ) over prepend-as ;
 383
 384 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 385     [ 3dup [ length ] tri@ + + ] dip [
 386         [ [ 2over [ length ] bi@ + ] dip copy-unsafe ]
 387         [ (append) ] bi
 388     ] new-like ; inline
 389
 390 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 391
 392 : surround-as ( seq1 seq2 seq3 exemplar -- newseq )
 393     [ swap ] 2dip 3append-as ; inline
 394
 395 : surround ( seq1 seq2 seq3 -- newseq ) over surround-as ; inline
 396
 397 : 1surround-as ( seq1 seq2 exemplar  -- newseq ) dupd surround-as ; inline
 398
 399 : 1surround ( seq1 seq2 -- newseq ) dup 1surround-as ; inline
 400
 401 : glue-as ( seq1 seq2 seq3 exemplar -- newseq ) swapd 3append-as ; inline
 402
 403 : glue ( seq1 seq2 seq3 -- newseq ) pick glue-as ; inline
 404
 405 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 406     [ [ nth ] dip call ] 2keepd set-nth-unsafe ; inline
 407
 408 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 409
 410 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 411
 412 <PRIVATE
 413
 414 : sequence-operator ( seq quot -- i n quot' )
 415     [ >underlying< [ nth-unsafe ] curry ] dip compose ; inline
 416
 417 : length-iterator ( seq -- n quot' )
 418     length-sequence [ nth-unsafe ] curry ; inline
 419
 420 : length-operator ( seq quot -- n quot' )
 421     [ length-iterator ] dip compose ; inline
 422
 423 : collect-into ( quot into -- quot' )
 424     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 425
 426 : collect-from ( i n quot into -- )
 427     collect-into each-integer-from ; inline
 428
 429 : collect ( n quot into -- )
 430     collect-into each-integer ; inline
 431
 432 : sequence-index-operator ( seq quot -- n quot' )
 433     [ length-iterator [ keep ] curry ] dip compose ; inline
 434
 435 : map-into ( seq quot into -- )
 436     [ length-operator ] dip collect ; inline
 437
 438 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 439     [ nth-unsafe ] bi-curry@ bi ; inline
 440
 441 : setup-2each ( seq1 seq2 -- n quot )
 442     [ min-length check-length ] 2keep [ 2nth-unsafe ] 2curry ; inline
 443
 444 : (2each) ( seq1 seq2 quot -- n quot' )
 445     [ setup-2each ] dip compose ; inline
 446
 447 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 448     [ nth-unsafe ] tri-curry@ tri ; inline
 449
 450 : setup-3each ( seq1 seq2 seq3 -- n quot )
 451     [ [ length ] tri@ min min check-length ]
 452     [ [ 3nth-unsafe ] 3curry ] 3bi ; inline
 453
 454 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 455     [ setup-3each ] dip compose ; inline
 456
 457 : element/index ( i/f seq -- elt/f i/f )
 458     '[ [ _ nth ] [ f ] if* ] keep ;
 459
 460 : index/element ( i/f seq -- i/f elt/f )
 461     dupd '[ _ nth ] [ f ] if* ;
 462
 463 : (accumulate) ( seq identity quot -- identity seq quot' )
 464     swapd [ keepd ] curry ; inline
 465
 466 : (accumulate*) ( seq identity quot -- identity seq quot' )
 467     swapd [ dup ] compose ; inline
 468
 469 PRIVATE>
 470
 471 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 472     sequence-operator each-integer-from ; inline
 473
 474 : each-from ( ... seq quot: ( ... x -- ... ) i -- ... )
 475     -rot length-operator each-integer-from ; inline
 476
 477 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 478     swapd each ; inline
 479
 480 : map-integers-from-as ( ... from len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 481     overd [ [ collect-from ] keep ] new-like ; inline
 482
 483 : map-integers-as ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 484     overd [ [ collect ] keep ] new-like ; inline
 485
 486 : map-integers ( ... len quot: ( ... i -- ... elt ) -- ... newseq )
 487     { } map-integers-as ; inline
 488
 489 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 490     [ length-operator ] dip map-integers-as ; inline
 491
 492 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 493     over map-as ; inline
 494
 495 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 496     [ [ drop ] prepose ] dip map-integers-as ; inline
 497
 498 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 499     { } replicate-as ; inline
 500
 501 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 502     over [ map-into ] keep ; inline
 503
 504 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 505     [ (accumulate) ] dip map-as ; inline
 506
 507 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 508     pick accumulate-as ; inline
 509
 510 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 511     (accumulate) map! ; inline
 512
 513 : accumulate*-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 514     [ (accumulate*) ] dip map-as nip ; inline
 515
 516 : accumulate* ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... newseq )
 517     pick accumulate*-as ; inline
 518
 519 : accumulate*! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... seq )
 520     (accumulate*) map! nip ; inline
 521
 522 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 523     (2each) each-integer ; inline
 524
 525 : 2each-from ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) i -- ... )
 526     [ (2each) ] dip -rot each-integer-from ; inline
 527
 528 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 529     -rotd 2each ; inline
 530
 531 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 532     [ (2each) ] dip map-integers-as ; inline
 533
 534 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 535     pick 2map-as ; inline
 536
 537 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 538     (2each) all-integers? ; inline
 539
 540 : 2any? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 541     negate 2all? not ; inline
 542
 543 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 544     (3each) each-integer ; inline
 545
 546 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 547     [ (3each) ] dip map-integers-as ; inline
 548
 549 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 550     pickd swap 3map-as ; inline
 551
 552 <PRIVATE
 553
 554 : bounds-check-call ( n seq quot -- elt i )
 555     2over bounds-check? [ call ] [ 3drop f f ] if ; inline
 556
 557 : find-from-unsafe ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 558     [ length-operator find-integer-from ] keepd
 559     index/element ; inline
 560
 561 : find-last-from-unsafe ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 562     [ length-operator nip find-last-integer ] keepd
 563     index/element ; inline
 564
 565 PRIVATE>
 566
 567 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 568     '[ _ find-from-unsafe ] bounds-check-call ; inline
 569
 570 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 571     [ 0 ] 2dip find-from-unsafe ; inline
 572
 573 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 574     '[ _ find-last-from-unsafe ] bounds-check-call ; inline
 575
 576 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 577     [ index-of-last ] dip find-last-from ; inline
 578
 579 : find-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 580     '[
 581         _ [ sequence-index-operator find-integer-from ] keepd
 582         index/element
 583     ] bounds-check-call ; inline
 584
 585 : find-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 586     [ 0 ] 2dip find-index-from ; inline
 587
 588 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 589     sequence-operator all-integers-from? ; inline
 590
 591 : push-if ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 592     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 593
 594 <PRIVATE
 595
 596 : (selector-as) ( quot length exemplar -- selector accum )
 597     new-resizable [ [ push-if ] 2curry ] keep ; inline
 598
 599 PRIVATE>
 600
 601 : selector-as ( quot exemplar -- selector accum )
 602     [ length ] keep (selector-as) ; inline
 603
 604 : selector ( quot -- selector accum )
 605     V{ } selector-as ; inline
 606
 607 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 608     pick length over [ (selector-as) [ each ] dip ] 2curry dip like ; inline
 609
 610 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 611     over filter-as ; inline
 612
 613 : reject-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 614     [ negate ] [ filter-as ] bi* ; inline
 615
 616 : reject ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 617     over reject-as ; inline
 618
 619 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 620     [ keep swap ] 2dip ? push ; inline
 621
 622 : 2selector ( quot -- selector accum1 accum2 )
 623     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 624
 625 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 626     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 627
 628 : collector-for-as ( seq quot exemplar -- seq quot' vec )
 629     [ over length ] dip new-resizable [ [ push ] curry compose ] keep ; inline
 630
 631 : collector-as ( quot exemplar -- quot' vec )
 632     [ length ] keep new-resizable [ [ push ] curry compose ] keep ; inline
 633
 634 : collector-for ( seq quot -- seq quot' vec )
 635     V{ } collector-for-as ; inline
 636
 637 : collector ( quot -- quot' vec )
 638     V{ } collector-as ; inline
 639
 640 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 641     dup [ collector-as [ while ] dip ] curry dip like ; inline
 642
 643 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 644     { } produce-as ; inline
 645
 646 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 647     [ dup ] swap [ keep ] curry produce nip ; inline
 648
 649 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 650     sequence-index-operator each-integer ; inline
 651
 652 : map-index-as ( ... seq quot: ( ... elt index -- ... newelt ) exemplar -- ... newseq )
 653     [ dup length <iota> ] 2dip 2map-as ; inline
 654
 655 : map-index ( ... seq quot: ( ... elt index -- ... newelt ) -- ... newseq )
 656     over map-index-as ; inline
 657
 658 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 659     pick empty? [ 3drop ] [
 660         [ [ drop first-unsafe ] dip call ]
 661         [ [ bi* ] 2curry 1 each-from ]
 662         3bi
 663     ] if ; inline
 664
 665 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 666     swapd each-index ; inline
 667
 668 : index ( obj seq -- n )
 669     [ = ] with find drop ;
 670
 671 : index-from ( obj i seq -- n )
 672     rot [ = ] curry find-from drop ;
 673
 674 : last-index ( obj seq -- n )
 675     [ = ] with find-last drop ;
 676
 677 : last-index-from ( obj i seq -- n )
 678     rot [ = ] curry find-last-from drop ;
 679
 680 : indices ( obj seq -- indices )
 681     swap [ = ] curry [ swap ] prepose V{ } clone [
 682         [ push ] curry [ [ drop ] if ] curry compose each-index
 683     ] keep ;
 684
 685 <PRIVATE
 686
 687 : nths-unsafe ( indices seq -- seq' )
 688     [ [ nth-unsafe ] curry ] keep map-as ;
 689
 690 PRIVATE>
 691
 692 : nths ( indices seq -- seq' )
 693     [ [ nth ] curry ] keep map-as ;
 694
 695 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 696     find drop >boolean ; inline
 697
 698 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 699     any? not ; inline
 700
 701 : member? ( elt seq -- ? )
 702     [ = ] with any? ;
 703
 704 : member-eq? ( elt seq -- ? )
 705     [ eq? ] with any? ;
 706
 707 : remove ( elt seq -- newseq )
 708     [ = ] with reject ;
 709
 710 : remove-eq ( elt seq -- newseq )
 711     [ eq? ] with reject ;
 712
 713 : sift ( seq -- newseq )
 714     [ ] filter ;
 715
 716 : harvest ( seq -- newseq )
 717     [ empty? ] reject ;
 718
 719 <PRIVATE
 720
 721 : mismatch-unsafe ( n seq1 seq2 -- i )
 722     [ 2nth-unsafe = not ] 2curry find-integer ; inline
 723
 724 PRIVATE>
 725
 726 : mismatch ( seq1 seq2 -- i )
 727     [ min-length ] 2keep mismatch-unsafe ;
 728
 729 M: sequence <=>
 730     [ mismatch ] 2keep pick
 731     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 732
 733 : sequence= ( seq1 seq2 -- ? )
 734     2dup [ length ] bi@ dupd =
 735     [ -rot mismatch-unsafe not ] [ 3drop f ] if ; inline
 736
 737 ERROR: assert-sequence got expected ;
 738
 739 : assert-sequence= ( a b -- )
 740     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 741
 742 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 743
 744 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 745
 746 <PRIVATE
 747
 748 : sequence-hashcode-step ( oldhash newpart -- newhash )
 749     integer>fixnum swap [
 750         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 751         fixnum+fast fixnum+fast
 752     ] keep fixnum-bitxor ; inline
 753
 754 PRIVATE>
 755
 756 : sequence-hashcode ( n seq -- x )
 757     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 758
 759 M: sequence hashcode* [ sequence-hashcode ] recursive-hashcode ;
 760
 761 M: iota hashcode*
 762     over 0 <= [ 2drop 0 ] [
 763         nip length 0 swap [ sequence-hashcode-step ] each-integer
 764     ] if ;
 765
 766 M: reversed hashcode* [ sequence-hashcode ] recursive-hashcode ;
 767
 768 M: slice hashcode* [ sequence-hashcode ] recursive-hashcode ;
 769
 770 : move ( to from seq -- )
 771     2over =
 772     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 773
 774 <PRIVATE
 775
 776 : move-unsafe* ( to from seq -- from-nth )
 777     2over =
 778     [ nth-unsafe nip ]
 779     [ [ nth-unsafe tuck swap ] [ set-nth-unsafe ] bi ] if ; inline
 780
 781 : filter-from! ( store from seq quot: ( ... elt -- ... ? ) -- seq )
 782     2over length < [
 783         [ [ move-unsafe* ] dip call ] 4keep
 784         [ swap [ 1 + ] when ] 3dip
 785         [ 1 + ] 2dip filter-from!
 786     ] [ drop [ nip set-length ] keep ] if ; inline recursive
 787
 788 : move-unsafe ( to from seq -- )
 789     2over =
 790     [ 3drop ] [ [ nth-unsafe swap ] [ set-nth-unsafe ] bi ] if ; inline
 791
 792 PRIVATE>
 793
 794 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 795     [ 0 0 ] 2dip filter-from! ; inline
 796
 797 : reject! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 798     negate filter! ; inline
 799
 800 : remove! ( elt seq -- seq )
 801     [ = ] with reject! ;
 802
 803 : remove-eq! ( elt seq -- seq )
 804     [ eq? ] with reject! ;
 805
 806 : prefix ( seq elt -- newseq )
 807     over [ over length 1 + ] dip [
 808         (1sequence) [ 1 swap copy-unsafe ] keep
 809     ] new-like ;
 810
 811 : suffix ( seq elt -- newseq )
 812     over [ over length 1 + ] dip [
 813         [ [ over length ] dip set-nth-unsafe ] keep
 814         [ 0 swap copy-unsafe ] keep
 815     ] new-like ;
 816
 817 : suffix! ( seq elt -- seq ) over push ; inline
 818
 819 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 820
 821 : last ( seq -- elt )
 822     index-of-last
 823     over 0 < [ bounds-error ] [ nth-unsafe ] if ; inline
 824
 825 <PRIVATE
 826
 827 : last-unsafe ( seq -- elt )
 828     index-of-last nth-unsafe ; inline
 829
 830 PRIVATE>
 831
 832 : set-last ( elt seq -- )
 833     index-of-last
 834     over 0 < [ bounds-error ] [ set-nth-unsafe ] if ; inline
 835
 836 : pop* ( seq -- ) index-of-last shorten ;
 837
 838 <PRIVATE
 839
 840 : move-backward ( shift from to seq -- )
 841     2over = [
 842         4drop
 843     ] [
 844         [ [ 2over + pick ] dip move-unsafe [ 1 + ] dip ] keep
 845         move-backward
 846     ] if ;
 847
 848 : move-forward ( shift from to seq -- )
 849     2over = [
 850         4drop
 851     ] [
 852         [ [ [ ] [ nip + ] [ 2nip ] 3tri ] dip move-unsafe 1 - ] keep
 853         move-forward
 854     ] if ;
 855
 856 : (open-slice) ( shift from to seq ? -- )
 857     [
 858         [ [ 1 - ] bi@ ] dip move-forward
 859     ] [
 860         [ over - ] 2dip move-backward
 861     ] if ;
 862
 863 : open-slice ( shift from seq -- )
 864     pick 0 = [
 865         3drop
 866     ] [
 867         [ ] [ nip length + ] [ 2nip ] 3tri
 868         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 869         set-length
 870     ] if ;
 871
 872 PRIVATE>
 873
 874 : delete-slice ( from to seq -- )
 875     check-slice [ over [ - ] dip ] dip open-slice ;
 876
 877 : remove-nth! ( n seq -- seq )
 878     [ [ dup 1 + ] dip delete-slice ] keep ;
 879
 880 : snip ( from to seq -- head tail )
 881     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 882
 883 : snip-slice ( from to seq -- head tail )
 884     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 885
 886 : replace-slice ( new from to seq -- seq' )
 887     snip-slice surround ;
 888
 889 : remove-nth ( n seq -- seq' )
 890     [ [ dup 1 + ] dip snip-slice ] keep append-as ;
 891
 892 : pop ( seq -- elt )
 893     index-of-last over 0 >=
 894     [ [ nth-unsafe ] [ shorten ] 2bi ]
 895     [ bounds-error ] if ;
 896
 897 : exchange ( m n seq -- )
 898     [ nip bounds-check 2drop ]
 899     [ bounds-check 3drop ]
 900     [ exchange-unsafe ]
 901     3tri ;
 902
 903 : midpoint@ ( seq -- n ) length 2/ ; inline
 904
 905 : reverse! ( seq -- seq )
 906     [
 907         [ midpoint@ ] [ length ] [ ] tri
 908         [ [ over - 1 - ] dip exchange-unsafe ] 2curry
 909         each-integer
 910     ] keep ;
 911
 912 : reverse ( seq -- newseq )
 913      [
 914         dup [ length ] keep new-sequence
 915         [ 0 swap copy-unsafe ] keep reverse!
 916     ] keep like ;
 917
 918 GENERIC: sum-lengths ( seq -- n )
 919
 920 M: object sum-lengths
 921     0 [ length + ] reduce ;
 922
 923 M: repetition sum-lengths
 924     [ length>> ] [ elt>> length ] bi * ;
 925
 926 : concat-as ( seq exemplar -- newseq )
 927     [
 928         [ dup sum-lengths ] dip new-resizable
 929         [ [ push-all ] curry each ] keep
 930     ] keep like ; inline
 931
 932 : concat ( seq -- newseq )
 933     [ { } ] [ dup first concat-as ] if-empty ;
 934
 935 <PRIVATE
 936
 937 : joined-length ( seq glue -- n )
 938     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 939
 940 PRIVATE>
 941
 942 : join-as ( seq glue exemplar -- newseq )
 943     over empty? [ nip concat-as ] [
 944         [
 945             2dup joined-length over new-resizable [
 946                 [ [ push-all ] 2curry ]
 947                 [ nip [ push-all ] curry ] 2bi
 948                 interleave
 949             ] keep
 950         ] dip like
 951     ] if ;
 952
 953 : join ( seq glue -- newseq )
 954     dup join-as ; inline
 955
 956 <PRIVATE
 957
 958 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
 959     [
 960         [ over length [-] dup 0 = [ drop ] ] dip
 961         [ <repetition> ] curry
 962     ] dip compose if ; inline
 963
 964 PRIVATE>
 965
 966 : pad-head ( seq n elt -- padded )
 967     [ swap dup append-as ] padding ;
 968
 969 : pad-tail ( seq n elt -- padded )
 970     [ append ] padding ;
 971
 972 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ; inline
 973 : longer? ( seq1 seq2 -- ? ) [ length ] bi@ > ; inline
 974 : shorter ( seq1 seq2 -- seq ) [ [ length ] bi@ <= ] 2keep ? ; inline
 975 : longer ( seq1 seq2 -- seq ) [ [ length ] bi@ >= ] 2keep ? ; inline
 976
 977 : head? ( seq begin -- ? )
 978     2dup shorter? [
 979         2drop f
 980     ] [
 981         [ length [ head-slice ] keep swap ] keep
 982         mismatch-unsafe not
 983     ] if ;
 984
 985 : tail? ( seq end -- ? )
 986     2dup shorter? [
 987         2drop f
 988     ] [
 989         [ length [ tail-slice* ] keep swap ] keep
 990         mismatch-unsafe not
 991     ] if ;
 992
 993 : cut-slice ( seq n -- before-slice after-slice )
 994     [ head-slice ] [ tail-slice ] 2bi ; inline
 995
 996 : cut-slice* ( seq n -- before-slice after-slice )
 997     [ head-slice* ] [ tail-slice* ] 2bi ;
 998
 999 : insert-nth ( elt n seq -- seq' )
1000     swap cut-slice [ swap suffix ] dip append ;
1001
1002 : halves ( seq -- first-slice second-slice )
1003     dup midpoint@ cut-slice ; inline
1004
1005 <PRIVATE
1006
1007 : nth2-unsafe ( n seq -- a b )
1008     [ nth-unsafe ] [ [ 1 + ] dip nth-unsafe ] 2bi ; inline
1009
1010 : nth3-unsafe ( n seq -- a b c )
1011     [ nth2-unsafe ] [ [ 2 + ] dip nth-unsafe ] 2bi ; inline
1012
1013 : (binary-reduce) ( seq start quot: ( elt1 elt2 -- newelt ) from length -- value )
1014     ! We can't use case here since combinators depends on
1015     ! sequences
1016     dup 4 < [
1017         integer>fixnum {
1018             [ 2drop nip ]
1019             [ 2nip swap nth-unsafe ]
1020             [ -rot [ drop swap nth2-unsafe ] dip call ]
1021             [ -rot [ drop swap nth3-unsafe ] dip bi@ ]
1022         } dispatch
1023     ] [
1024         [ 2/ ] [ over - ] bi [ 2dup + ] dip
1025         [ (binary-reduce) ] [ 2curry ] curry 2bi@
1026         pick [ 3bi ] dip call
1027     ] if ; inline recursive
1028
1029 PRIVATE>
1030
1031 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
1032     pick dup slice? [
1033         [ seq>> ] 3dip [ from>> 0 max ] [ to>> 0 max over - ] bi
1034     ] [
1035         length 0 max 0 swap
1036     ] if (binary-reduce) ; inline
1037
1038 : cut ( seq n -- before after )
1039     [ head ] [ tail ] 2bi ;
1040
1041 : cut* ( seq n -- before after )
1042     [ head* ] [ tail* ] 2bi ;
1043
1044 : subseq-starts-at? ( i seq subseq -- ? )
1045     [ length swap ] keep
1046     '[
1047         [ + _ nth-unsafe ] keep _ nth-unsafe =
1048     ] with all-integers? ; inline
1049
1050 : subseq-index-from ( n seq subseq -- i/f )
1051     [ [ length ] bi@ - 1 + ] 2keep
1052     '[ _ _ subseq-starts-at? ] find-integer-from ; inline
1053
1054 : subseq-index ( seq subseq -- i/f ) [ 0 ] 2dip subseq-index-from ; inline
1055
1056 : subseq-index? ( seq subseq -- ? ) subseq-index >boolean ; inline
1057
1058 : subseq-start-from ( subseq seq n -- i/f )
1059     spin subseq-index-from ; inline deprecated
1060
1061 : subseq-start ( subseq seq -- i/f ) swap subseq-index ; inline deprecated
1062
1063 : subseq? ( subseq seq -- ? ) subseq-start >boolean ; inline deprecated
1064
1065 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
1066     2dup mismatch [ 2dup min-length ] unless*
1067     [ tail-slice ] curry bi@ ;
1068
1069 : unclip ( seq -- rest first )
1070     [ rest ] [ first-unsafe ] bi ;
1071
1072 : unclip-last ( seq -- butlast last )
1073     [ but-last ] [ last-unsafe ] bi ;
1074
1075 : unclip-slice ( seq -- rest-slice first )
1076     [ rest-slice ] [ first-unsafe ] bi ; inline
1077
1078 : map-reduce ( ..a seq map-quot: ( ..a elt -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1079     [ [ [ first ] keep ] dip [ dip ] keep ] dip
1080     '[ swap _ dip swap @ ] 1 each-from ; inline
1081
1082 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1083     [ [ [ [ first ] bi@ ] 2keep ] dip [ 2dip ] keep ] dip
1084     '[ rot _ dip swap @ ] 1 2each-from ; inline
1085
1086 <PRIVATE
1087
1088 : (map-find) ( seq quot find-quot -- result elt )
1089     [ [ f ] 2dip [ nip ] prepose [ dup ] compose ] dip call nip ; inline
1090
1091 PRIVATE>
1092
1093 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1094     [ find ] (map-find) ; inline
1095
1096 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1097     [ find-last ] (map-find) ; inline
1098
1099 : unclip-last-slice ( seq -- butlast-slice last )
1100     [ but-last-slice ] [ last-unsafe ] bi ; inline
1101
1102 <PRIVATE
1103
1104 : (trim-head) ( seq quot -- seq n )
1105     over [ negate find drop ] dip swap
1106     [ dup length ] unless* ; inline
1107
1108 : (trim-tail) ( seq quot -- seq n )
1109     over [ negate find-last drop ?1+ ] dip
1110     swap ; inline
1111
1112 PRIVATE>
1113
1114 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1115     (trim-head) tail-slice ; inline
1116
1117 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1118     (trim-head) tail ; inline
1119
1120 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1121     (trim-tail) head-slice ; inline
1122
1123 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1124     (trim-tail) head ; inline
1125
1126 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1127     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
1128
1129 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1130     [ trim-slice ] [ drop ] 2bi like ; inline
1131
1132 GENERIC: sum ( seq -- n )
1133 M: object sum 0 [ + ] binary-reduce ; inline
1134 M: iota sum length dup 1 - * 2/ ; inline
1135 M: repetition sum [ elt>> ] [ length>> ] bi * ; inline
1136
1137 : product ( seq -- n ) 1 [ * ] binary-reduce ;
1138
1139 : infimum ( seq -- elt ) [ ] [ min ] map-reduce ;
1140
1141 : supremum ( seq -- elt ) [ ] [ max ] map-reduce ;
1142
1143 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
1144     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
1145
1146 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n )
1147     [ 1 0 ? ] compose map-sum ; inline
1148
1149 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
1150     [ with each ] 2curry each ; inline
1151
1152 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
1153     [ with { } map-as ] 2curry { } map-as ; inline
1154
1155 : cartesian-product-as ( seq1 seq2 exemplar -- newseq )
1156     [ 2sequence ] curry cartesian-map ; inline
1157
1158 : cartesian-product ( seq1 seq2 -- newseq )
1159     dup cartesian-product-as ; inline
1160
1161 : cartesian-find ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... elt1 elt2 )
1162     [ f ] 3dip [ with find swap ] 2curry [ nip ] prepose find nip swap ; inline
1163
1164 <PRIVATE
1165
1166 : select-by ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... elt )
1167     [
1168         [ keep swap ] curry [ [ first ] dip call ] 2keep
1169         [ curry 2dip pick over ] curry
1170     ] [
1171         [ [ 2drop ] [ 2nipd ] if ] compose
1172     ] bi* compose 1 each-from drop ; inline
1173
1174 PRIVATE>
1175
1176 : supremum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1177     [ after? ] select-by ; inline
1178
1179 : infimum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1180     [ before? ] select-by ; inline
1181
1182 : shortest ( seqs -- elt ) [ length ] infimum-by ;
1183
1184 : longest ( seqs -- elt ) [ length ] supremum-by ;
1185
1186 ! We hand-optimize flip to such a degree because type hints
1187 ! cannot express that an array is an array of arrays yet, and
1188 ! this word happens to be performance-critical since the compiler
1189 ! itself uses it. Optimizing it like this reduced compile time.
1190 <PRIVATE
1191
1192 : generic-flip ( matrix -- newmatrix )
1193     [ [ length ] [ min ] map-reduce ] keep
1194     '[ _ [ nth-unsafe ] with { } map-as ] map-integers ; inline
1195
1196 USE: arrays
1197
1198 : array-flip ( matrix -- newmatrix )
1199     { array } declare
1200     [ [ { array } declare length>> ] [ min ] map-reduce ] keep
1201     '[ _ [ { array } declare array-nth ] with { } map-as ] map-integers ;
1202
1203 PRIVATE>
1204
1205 : flip ( matrix -- newmatrix )
1206     dup empty? [
1207         dup array? [
1208             dup [ array? ] all?
1209             [ array-flip ] [ generic-flip ] if
1210         ] [ generic-flip ] if
1211     ] unless ;