extra/contributors/contributors.factor

   1 ! Copyright (C) 2007, 2008 Slava Pestov, 2020 Alexander Ilin.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: assocs fry io io.directories io.encodings.utf8
   4 io.launcher io.pathnames kernel math.statistics prettyprint
   5 sequences sorting system ;
   6 IN: contributors
   7
   8 CONSTANT: aliases {
   9     { "Alexander Ilin" "Alexander Iljin" }
  10     { "Björn Lindqvist" "bjourne@gmail.com" }
  11     { "Cat Stevens" "catb0t" }
  12     { "Daniel Ehrenberg" "Dan Ehrenberg" }
  13     { "Doug Coleman" "U-FROGGER\\erg" "erg" }
  14     { "Erik Charlebois" "erikc" }
  15     { "KUSUMOTO Norio" "kusumotonorio" }
  16     { "Mighty Sheeple" "sheeple" "U-ENCHILADA\\sheeple" }
  17     { "Nicolas Pénet" "nicolas-p" }
  18     { "Slava Pestov" "slava" "Slava"
  19         "U-SLAVA-FB3999113\\Slava" "U-SLAVA-DFB8FF805\\Slava" }
  20     { "dharmatech" "U-CUTLER\\dharmatech" }
  21 }
  22
  23 : changelog ( -- authors )
  24     image-path parent-directory [
  25         "git log --no-merges --pretty=format:%an"
  26         utf8 [ read-lines ] with-process-reader
  27     ] with-directory ;
  28
  29 : merge-aliases ( authors -- authors' )
  30     aliases [
  31         unclip '[ over delete-at* [ _ pick at+ ] [ drop ] if ] each
  32     ] each ;
  33
  34 : contributors ( -- )
  35     changelog histogram merge-aliases
  36     sort-values <reversed>
  37     simple-table. ;
  38
  39 MAIN: contributors