extra/morse/morse.factor

   1 ! Copyright (C) 2007, 2008, 2009 Alex Chapman, 2009 Diego Martinelli
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors ascii assocs biassocs combinators kernel
   4 literals math multiline namespaces openal openal.alut sequences
   5 splitting strings synth synth.buffers ;
   6 IN: morse
   7
   8 ERROR: no-morse-ch ch ;
   9
  10 <PRIVATE
  11
  12 CONSTANT: dot-char CHAR: .
  13 CONSTANT: dash-char CHAR: -
  14 CONSTANT: char-gap-char CHAR: \s
  15 CONSTANT: word-gap-char CHAR: /
  16 CONSTANT: unknown-char CHAR: ?
  17
  18 PRIVATE>
  19
  20 CONSTANT: morse-code-table $[
  21     H{
  22         { CHAR: a ".-"    }
  23         { CHAR: b "-..."  }
  24         { CHAR: c "-.-."  }
  25         { CHAR: d "-.."   }
  26         { CHAR: e "."     }
  27         { CHAR: f "..-."  }
  28         { CHAR: g "--."   }
  29         { CHAR: h "...."  }
  30         { CHAR: i ".."    }
  31         { CHAR: j ".---"  }
  32         { CHAR: k "-.-"   }
  33         { CHAR: l ".-.."  }
  34         { CHAR: m "--"    }
  35         { CHAR: n "-."    }
  36         { CHAR: o "---"   }
  37         { CHAR: p ".--."  }
  38         { CHAR: q "--.-"  }
  39         { CHAR: r ".-."   }
  40         { CHAR: s "..."   }
  41         { CHAR: t "-"     }
  42         { CHAR: u "..-"   }
  43         { CHAR: v "...-"  }
  44         { CHAR: w ".--"   }
  45         { CHAR: x "-..-"  }
  46         { CHAR: y "-.--"  }
  47         { CHAR: z "--.."  }
  48         { CHAR: 1 ".----" }
  49         { CHAR: 2 "..---" }
  50         { CHAR: 3 "...--" }
  51         { CHAR: 4 "....-" }
  52         { CHAR: 5 "....." }
  53         { CHAR: 6 "-...." }
  54         { CHAR: 7 "--..." }
  55         { CHAR: 8 "---.." }
  56         { CHAR: 9 "----." }
  57         { CHAR: 0 "-----" }
  58         { CHAR: . ".-.-.-" }
  59         { CHAR: , "--..--" }
  60         { CHAR: ? "..--.." }
  61         { CHAR: ' ".----." }
  62         { CHAR: ! "-.-.--" }
  63         { CHAR: / "-..-."  }
  64         { CHAR: ( "-.--."  }
  65         { CHAR: ) "-.--.-" }
  66         { CHAR: & ".-..."  }
  67         { CHAR: : "---..." }
  68         { CHAR: ; "-.-.-." }
  69         { CHAR: = "-...- " }
  70         { CHAR: + ".-.-."  }
  71         { CHAR: - "-....-" }
  72         { CHAR: _ "..--.-" }
  73         { CHAR: \" ".-..-." }
  74         { CHAR: $ "...-..-" }
  75         { CHAR: @ ".--.-." }
  76         { CHAR: \s "/" }
  77     } >biassoc
  78 ]
  79
  80 : ch>morse ( ch -- morse )
  81     ch>lower morse-code-table at unknown-char 1string or ;
  82
  83 : morse>ch ( str -- ch )
  84     morse-code-table value-at char-gap-char or ;
  85
  86 <PRIVATE
  87
  88 : word>morse ( str -- morse )
  89     [ ch>morse ] { } map-as join-words ;
  90
  91 : sentence>morse ( str -- morse )
  92     split-words [ word>morse ] map " / " join ;
  93
  94 : trim-blanks ( str -- newstr )
  95     [ blank? ] trim ; inline
  96
  97 : morse>word ( morse -- str )
  98     split-words [ morse>ch ] "" map-as ;
  99
 100 : morse>sentence ( morse -- sentence )
 101     "/" split [ trim-blanks morse>word ] map join-words ;
 102
 103 : replace-underscores ( str -- str' )
 104     [ dup CHAR: _ = [ drop CHAR: - ] when ] map ;
 105
 106 PRIVATE>
 107
 108 : >morse ( str -- newstr )
 109     trim-blanks sentence>morse ;
 110
 111 : morse> ( morse -- plain )
 112     replace-underscores morse>sentence ;
 113
 114 SYNTAX: [MORSE "MORSE]" parse-multiline-string morse> suffix! ;
 115
 116 <PRIVATE
 117
 118 SYMBOLS: source dot-buffer dash-buffer intra-char-gap-buffer letter-gap-buffer ;
 119
 120 : queue ( symbol -- )
 121     get source get swap queue-buffer ;
 122
 123 : dot ( -- ) dot-buffer queue ;
 124 : dash ( -- ) dash-buffer queue ;
 125 : intra-char-gap ( -- ) intra-char-gap-buffer queue ;
 126 : letter-gap ( -- ) letter-gap-buffer queue ;
 127
 128 CONSTANT: beep-freq 880
 129
 130 : <morse-buffer> ( -- buffer )
 131     half-sample-freq <8-bit-mono-buffer> ;
 132
 133 : sine-buffer ( seconds -- id )
 134     beep-freq swap <morse-buffer> >sine-wave-buffer
 135     send-buffer id>> ;
 136
 137 : silent-buffer ( seconds -- id )
 138     <morse-buffer> >silent-buffer send-buffer id>> ;
 139
 140 : make-buffers ( unit-length -- )
 141     {
 142         [ sine-buffer dot-buffer set ]
 143         [ 3 * sine-buffer dash-buffer set ]
 144         [ silent-buffer intra-char-gap-buffer set ]
 145         [ 3 * silent-buffer letter-gap-buffer set ]
 146     } cleave ;
 147
 148 : playing-morse ( quot unit-length -- )
 149     [
 150         init-openal 1 gen-sources first source set make-buffers
 151         call
 152         source get source-play
 153     ] with-scope ; inline
 154
 155 : play-char ( string -- )
 156     [ intra-char-gap ] [
 157         {
 158             { dot-char [ dot ] }
 159             { dash-char [ dash ] }
 160             { word-gap-char [ intra-char-gap ] }
 161             { unknown-char [ intra-char-gap ] }
 162             [ no-morse-ch ]
 163         } case
 164     ] interleave ;
 165
 166 PRIVATE>
 167
 168 : play-as-morse* ( str unit-length -- )
 169     [
 170         [ letter-gap ] [ ch>morse play-char ] interleave
 171     ] swap playing-morse ; inline
 172
 173 : play-as-morse ( str -- )
 174     0.05 play-as-morse* ; inline