extra/sequences/extras/extras.factor

   1 USING: accessors arrays assocs combinators generalizations
   2 grouping growable heaps kernel math math.order ranges sequences
   3 sequences.private shuffle sorting splitting vectors ;
   4 IN: sequences.extras
   5
   6 : find-all ( ... seq quot: ( ... elt -- ... ? ) -- ... elts )
   7     [ <enumerated> ] dip '[ nip @ ] assoc-filter ; inline
   8
   9 : reduce-from ( ... seq identity quot: ( ... prev elt -- ... next ) i -- ... result )
  10     [ swap ] 2dip each-from ; inline
  11
  12 :: subseq* ( from to seq -- subseq )
  13     seq length :> len
  14     from [ dup 0 < [ len + ] when ] [ 0 ] if*
  15     to [ dup 0 < [ len + ] when ] [ len ] if*
  16     [ 0 len clamp ] bi@ dupd max seq subseq ;
  17
  18 : safe-subseq ( from to seq -- subseq )
  19     [ length '[ 0 _ clamp ] bi@ ] keep subseq ;
  20
  21 : all-subseqs ( seq -- seqs )
  22     dup length [1..b] [ clump ] with map concat ;
  23
  24 : each-subseq ( ... seq quot: ( ... subseq -- ... ) -- ... )
  25     [ dup length [ [0..b] ] [ ] bi ] dip '[
  26         dup _ (a..b] [ rot [ subseq _ call ] keep ] with each
  27     ] each drop ; inline
  28
  29 : map-like ( seq exemplar -- seq' )
  30     '[ _ like ] map ; inline
  31
  32 : filter-all-subseqs-range ( ... seq range quot: ( ... subseq -- ... ? ) -- seq )
  33     [
  34         '[ <clumps> _ filter ] with map concat
  35     ] keepdd map-like ; inline
  36
  37 : filter-all-subseqs ( ... seq quot: ( ... subseq -- ... ? ) -- seq )
  38     [ dup length [1..b] ] dip filter-all-subseqs-range ; inline
  39
  40 :: longest-subseq ( seq1 seq2 -- subseq )
  41     seq1 length :> len1
  42     seq2 length :> len2
  43     0 :> n!
  44     0 :> end!
  45     len1 1 + [ len2 1 + 0 <array> ] replicate :> table
  46     len1 [1..b] [| x |
  47         len2 [1..b] [| y |
  48             x 1 - seq1 nth-unsafe
  49             y 1 - seq2 nth-unsafe = [
  50                 y 1 - x 1 - table nth-unsafe nth-unsafe 1 + :> len
  51                 len y x table nth-unsafe set-nth-unsafe
  52                 len n > [ len n! x end! ] when
  53             ] [ 0 y x table nth-unsafe set-nth-unsafe ] if
  54         ] each
  55     ] each end n - end seq1 subseq ;
  56
  57 : pad-longest ( seq1 seq2 elt -- seq1 seq2 )
  58     [ 2dup max-length ] dip [ pad-tail ] 2curry bi@ ;
  59
  60 : pad-center ( seq n elt -- padded )
  61     swap pick length [-] [ drop ] [
  62         [ 2/ ] [ over - ] bi rot '[ _ <repetition> ] bi@
  63         pick surround-as
  64     ] if-zero ;
  65
  66 : change-nths ( ... indices seq quot: ( ... elt -- ... elt' ) -- ... )
  67     [ change-nth ] 2curry each ; inline
  68
  69 : push-if-index ( ..a elt i quot: ( ..a elt i -- ..b ? ) accum -- ..b )
  70     [ keepd ] dip rot [ push ] [ 2drop ] if ; inline
  71
  72 : push-if* ( ..a elt quot: ( ..a elt -- ..b obj/f ) accum -- ..b )
  73     [ call ] dip [ push ] [ drop ] if* ; inline
  74
  75 <PRIVATE
  76
  77 : (index-selector-as) ( quot length exampler -- selector accum )
  78     new-resizable [ [ push-if-index ] 2curry ] keep ; inline
  79
  80 : (selector-as*) ( quot length exemplar -- selector accum )
  81     new-resizable [ [ push-if* ] 2curry ] keep ; inline
  82
  83 PRIVATE>
  84
  85 : index-selector-as ( quot exemplar -- selector accum )
  86     [ length ] keep (index-selector-as) ; inline
  87
  88 : index-selector ( quot -- selector accum )
  89     V{ } index-selector-as ; inline
  90
  91 : selector-as* ( quot exemplar -- selector accum )
  92     [ length ] keep (selector-as*) ; inline
  93
  94 : selector* ( quot -- selector accum ) V{ } selector-as* ; inline
  95
  96 : filter-index-as ( ... seq quot: ( ... elt i -- ... ? ) exemplar -- ... seq' )
  97     pick length over [ (index-selector-as) [ each-index ] dip ] 2curry dip like ; inline
  98
  99 : filter-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... seq' )
 100     over filter-index-as ; inline
 101
 102 : even-indices ( seq -- seq' )
 103     [ length 1 + 2/ ] keep [
 104         [ [ 2 * ] dip nth-unsafe ] curry
 105     ] keep map-integers-as ;
 106
 107 : odd-indices ( seq -- seq' )
 108     [ length 2/ ] keep [
 109         [ [ 2 * 1 + ] dip nth-unsafe ] curry
 110     ] keep map-integers-as ;
 111
 112 : compact ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 113     [ split-when harvest ] dip join ; inline
 114
 115 : collapse ( ... seq quot: ( ... elt -- ... ? ) elt -- ... seq' )
 116     [ split-when ] dip
 117     [ [ harvest ] dip join ]
 118     [ [ first empty? ] dip [ prepend ] curry when ]
 119     [ [ last empty? ] dip [ append ] curry when ]
 120     2tri ; inline
 121
 122 :: slice-when ( seq quot: ( elt -- ? ) -- seq' )
 123     seq length :> len
 124     0 [ len dupd < ] [
 125         dup seq quot find-from drop
 126         [ 2dup = [ 1 + ] when ] [ len ] if*
 127         [ seq <slice> ] keep len or swap
 128     ] produce nip ; inline
 129
 130 : ?<slice> ( from/f to/f sequence -- slice )
 131     [ [ 0 ] unless* ] 2dip
 132     over [ nip [ length ] [ ] bi ] unless
 133     <slice> ; inline
 134
 135 : sequence>slice ( sequence -- slice )
 136     [ drop 0 ] [ length ] [ ] tri <slice> ; inline
 137
 138 : slice-order-by-from ( slice1 slice2 -- slice-lt slice-gt )
 139     2dup [ from>> ] bi@ > [ swap ] when ; inline
 140
 141 : ordered-slices-range ( slice-lt slice-gt -- to from )
 142     [ to>> ] [ from>> ] bi* ;
 143
 144 : unordered-slices-range ( slice1 slice2 -- to from )
 145     slice-order-by-from ordered-slices-range ;
 146
 147 : ordered-slices-overlap? ( slice-lt slice-gt -- ? )
 148     ordered-slices-range > ; inline
 149
 150 : unordered-slices-overlap? ( slice1 slice2 -- ? )
 151     unordered-slices-range > ; inline
 152
 153 : slices-overlap? ( slice1 slice2 -- ? )
 154     unordered-slices-overlap? ;
 155
 156 : ordered-slices-touch? ( slice-lt slice-gt -- ? )
 157     ordered-slices-range >= ; inline
 158
 159 : unordered-slices-touch? ( slice1 slice2 -- ? )
 160     unordered-slices-range >= ; inline
 161
 162 : slices-touch? ( slice1 slice2 -- ? )
 163     unordered-slices-touch? ;
 164
 165 ERROR: slices-don't-touch slice1 slice2 ;
 166
 167 : merge-slices ( slice1 slice2 -- slice/* )
 168     slice-order-by-from
 169     2dup ordered-slices-touch? [
 170         [ from>> ] [ [ to>> ] [ seq>> ] bi ] bi* <slice>
 171     ] [
 172         slices-don't-touch
 173     ] if ;
 174
 175 : rotate ( seq n -- seq' )
 176     over length mod dup 0 >= [ cut ] [ abs cut* ] if prepend ;
 177
 178 ERROR: underlying-mismatch slice1 slice2 ;
 179
 180 : ensure-same-underlying ( slice1 slice2 -- slice1 slice2 )
 181     2dup [ seq>> ] bi@ eq? [ underlying-mismatch ] unless ;
 182
 183 : span-slices ( slice1 slice2 -- slice )
 184     ensure-same-underlying
 185     [ [ from>> ] bi@ min ]
 186     [ [ to>> ] bi@ max ]
 187     [ drop seq>> ] 2tri <slice> ;
 188
 189 : ?span-slices ( slice1/f slice2/f -- slice )
 190     2dup and [ span-slices ] [ or ] if ;
 191
 192 :: rotate! ( seq n -- )
 193     seq length :> len
 194     n len mod dup 0 < [ len + ] when seq bounds-check drop 0 over
 195     [ 2dup = ] [
 196         [ seq exchange-unsafe ] [ [ 1 + ] bi@ ] 2bi
 197         dup len = [ drop over ] when
 198         2over = [ -rot nip over ] when
 199     ] until 3drop ;
 200
 201 : all-rotations ( seq -- seq' )
 202     dup length <iota> [ rotate ] with map ;
 203
 204 <PRIVATE
 205
 206 : (appender-for) ( quot length exemplar -- appender accum )
 207     new-resizable [ [ push-all ] curry compose ] keep ; inline
 208
 209 PRIVATE>
 210
 211 : appender-for ( quot exemplar -- appender accum )
 212     [ length ] keep (appender-for) ; inline
 213
 214 : appender ( quot -- appender accum )
 215     V{ } appender-for ; inline
 216
 217 : map-concat-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 218     [ appender-for [ each ] dip ] keep like ; inline
 219
 220 : >resizable ( seq -- accum ) ! fixes map-concat "cannot apply call to run-time..."
 221     [ length ] keep [ new-resizable ] [ append! ] bi ;
 222
 223 : map-concat ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 224     over empty? [ 2drop { } ] [
 225         [ [ first ] dip call ] 2keep rot [
 226             >resizable [ '[ @ _ push-all ] 1 each-from ] keep
 227         ] keep like
 228     ] if ; inline
 229
 230 : map-filter-as ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) exemplar -- ... subseq )
 231     reach length over
 232     [ (selector-as) [ compose each ] dip ] 2curry dip like ; inline
 233
 234 : map-filter ( ... seq map-quot: ( ... elt -- ... newelt ) filter-quot: ( ... newelt -- ... ? ) -- ... subseq )
 235     pick map-filter-as ; inline
 236
 237 : map-sift ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 238     [ ] map-filter ; inline
 239
 240 : map-harvest ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 241     [ empty? not ] map-filter ; inline
 242
 243 : (each-integer-with-previous) ( ... prev i n quot: ( ... i -- ... ) -- ... )
 244     2over < [
 245         [ nip call ] 4keep nipdd
 246         [ 1 + ] 2dip (each-integer-with-previous)
 247     ] [
 248         4drop
 249     ] if ; inline recursive
 250
 251 : each-integer-with-previous ( ... n quot: ( ... i -- ... ) -- ... )
 252     [ f 0 ] 2dip (each-integer-with-previous) ; inline
 253
 254 : (collect-with-previous) ( quot into -- quot' )
 255     [ [ keep ] dip [ set-nth-unsafe ] keepdd ] 2curry ; inline
 256
 257 : collect-with-previous ( n quot into --  )
 258     (collect-with-previous) each-integer-with-previous ; inline
 259
 260 : map-integers-with ( ... len quot: ( ... prev i -- ... elt ) exemplar -- ... newseq )
 261     overd [ [ collect-with-previous ] keep ] new-like ; inline
 262
 263 : map-with-previous-as ( ... seq quot: ( ... elt prev/f -- ... newelt ) exemplar -- ... newseq )
 264     [ length-operator ] dip map-integers-with ; inline
 265
 266 : map-with-previous ( ... seq quot: ( ... elt prev/f -- ... newelt ) -- ... newseq )
 267     over map-with-previous-as ; inline
 268
 269 <PRIVATE
 270
 271 : (setup-each-from) ( i seq -- n quot )
 272     [ length over [-] swap ] keep '[ _ + _ nth-unsafe ] ; inline
 273
 274 : setup-each-from ( i seq quot -- n quot' )
 275     [ (setup-each-from) ] dip compose ; inline
 276
 277 PRIVATE>
 278
 279 : map-from-as ( ... seq quot: ( ... elt -- ... newelt ) i exemplar -- ... newseq )
 280     [ -rot setup-each-from ] dip map-integers-as ; inline
 281
 282 : map-from ( ... seq quot: ( ... elt -- ... newelt ) i -- ... newseq )
 283     pick map-from-as ; inline
 284
 285 : map-if ( ... seq if-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 286     '[ dup @ _ when ] map ; inline
 287
 288 <PRIVATE
 289
 290 : push-map-if ( ..a elt filter-quot: ( ..a elt -- ..b ? ) map-quot: ( ..a elt -- ..b newelt ) accum -- ..b )
 291     [ keep over ] 2dip [ when ] dip rot [ push ] [ 2drop ] if ; inline
 292
 293 : (filter-mapper-for) ( filter-quot map-quot length exempler -- filter-mapper accum )
 294     new-resizable [ [ push-map-if ] 3curry ] keep ; inline
 295
 296 : filter-mapper-for ( filter-quot map-quot exemplar -- filter-mapper accum )
 297     [ length ] keep (filter-mapper-for) ; inline
 298
 299 : filter-mapper ( filter-quot map-quot -- filter-mapper accum )
 300     V{ } filter-mapper-for ; inline
 301
 302 PRIVATE>
 303
 304 : filter-map-as ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 305     reach length over
 306     [ (filter-mapper-for) [ each ] dip ] 2curry dip like ; inline
 307
 308 : filter-map ( ... seq filter-quot: ( ... elt -- ... ? ) map-quot: ( ... elt -- ... newelt ) -- ... newseq )
 309     pick filter-map-as ; inline
 310
 311 : 2map-sum ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... n ) -- ... n )
 312     [ 0 ] 3dip [ dip + ] curry [ rot ] prepose 2each ; inline
 313
 314 : 2count ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... n )
 315     [ 1 0 ? ] compose 2map-sum ; inline
 316
 317 : 3each-from
 318     ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) i -- ... )
 319     [ (3each) ] dip -rot each-integer-from ; inline
 320
 321 : 3map-reduce
 322     ( ..a seq1 seq2 seq3 map-quot: ( ..a elt1 elt2 elt3 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 323     [ [ [ [ first ] tri@ ] 3keep ] dip [ 3dip ] keep ] dip compose 1 3each-from ; inline
 324
 325 : round-robin ( seq -- newseq )
 326     [ { } ] [
 327         [ longest length <iota> ] keep
 328         [ [ ?nth ] with map ] curry map concat sift
 329     ] if-empty ;
 330
 331 : sift-as ( seq exemplar -- newseq )
 332     [ ] swap filter-as ;
 333
 334 : sift! ( seq -- newseq )
 335     [ ] filter! ;
 336
 337 : harvest-as ( seq exemplar -- newseq )
 338     [ empty? not ] swap filter-as ;
 339
 340 : harvest! ( seq -- newseq )
 341     [ empty? ] reject! ;
 342
 343 : head-as ( seq n exemplar -- seq' )
 344     [ head-slice ] [ like ] bi* ; inline
 345
 346 : head*-as ( seq n exemplar -- seq' )
 347     [ head-slice* ] [ like ] bi* ; inline
 348
 349 : tail-as ( seq n exemplar -- seq' )
 350     [ tail-slice ] [ like ] bi* ; inline
 351
 352 : tail*-as ( seq n exemplar -- seq' )
 353     [ tail-slice* ] [ like ] bi* ; inline
 354
 355 : trim-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... newseq )
 356     [ trim-slice ] [ like ] bi* ; inline
 357
 358 : ?trim ( seq quot: ( elt -- ? ) -- seq/newseq )
 359     over empty? [ drop ] [
 360         over [ first-unsafe ] [ last-unsafe ] bi pick either?
 361         [ trim ] [ drop ] if
 362     ] if ; inline
 363
 364 : ?trim-head ( seq quot: ( elt -- ? ) -- seq/newseq )
 365     over empty? [ drop ] [
 366         over first-unsafe over call
 367         [ trim-head ] [ drop ] if
 368     ] if ; inline
 369
 370 : ?trim-tail ( seq quot: ( elt -- ? ) -- seq/newseq )
 371     over empty? [ drop ] [
 372         over last-unsafe over call
 373         [ trim-tail ] [ drop ] if
 374     ] if ; inline
 375
 376 : unsurround ( newseq seq2 seq3 -- seq1 )
 377    [ ?head drop ] [ ?tail drop ] bi* ;
 378
 379 : >string-list ( seq -- seq' )
 380     [ "\"" 1surround ] map "," join ;
 381
 382 : one? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 383     [ find ] 2keep rot [
 384         [ 1 + ] 2dip find-from drop not
 385     ] [ 3drop f ] if ; inline
 386
 387 : map-index! ( ... seq quot: ( ... elt index -- ... newelt ) -- ... seq )
 388     over [ [ sequence-index-operator ] dip collect ] keep ; inline
 389
 390 <PRIVATE
 391
 392 : (2each-index) ( seq1 seq2 quot -- n quot' )
 393     [ setup-2each [ keep ] curry ] dip compose ; inline
 394
 395 PRIVATE>
 396
 397 : 2each-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... ) -- ... )
 398     (2each-index) each-integer ; inline
 399
 400 : 2map-into ( seq1 seq2 quot into -- )
 401     [ (2each) ] dip collect ; inline
 402
 403 : 2map! ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... seq1 )
 404     pick [ 2map-into ] keep ; inline
 405
 406 : 2map-index ( ... seq1 seq2 quot: ( ... elt1 elt2 index -- ... newelt ) -- ... newseq )
 407     pick [ (2each-index) ] dip map-integers-as ; inline
 408
 409 TUPLE: evens { seq read-only } ;
 410
 411 C: <evens> evens
 412
 413 M: evens length seq>> length 1 + 2/ ; inline
 414
 415 M: evens virtual@ [ 2 * ] [ seq>> ] bi* ; inline
 416
 417 M: evens virtual-exemplar seq>> ; inline
 418
 419 INSTANCE: evens virtual-sequence
 420
 421 TUPLE: odds { seq read-only } ;
 422
 423 C: <odds> odds
 424
 425 M: odds length seq>> length 2/ ; inline
 426
 427 M: odds virtual@ [ 2 * 1 + ] [ seq>> ] bi* ; inline
 428
 429 M: odds virtual-exemplar seq>> ; inline
 430
 431 INSTANCE: odds virtual-sequence
 432
 433 : until-empty ( seq quot -- )
 434     [ dup empty? ] swap until drop ; inline
 435
 436 <PRIVATE
 437
 438 : push-index-if ( ..a elt i quot: ( ..a elt -- ..b ? ) accum -- ..b )
 439     [ dip ] dip rot [ push ] [ 2drop ] if ; inline
 440
 441 PRIVATE>
 442
 443 : arg-where ( ... seq quot: ( ... elt -- ... ? ) -- ... indices )
 444     over length <vector> [
 445         [ push-index-if ] 2curry each-index
 446     ] keep ; inline
 447
 448 : arg-sort ( seq -- indices )
 449     zip-index sort-keys values ;
 450
 451 : first= ( seq elt -- ? ) [ first ] dip = ; inline
 452 : second= ( seq elt -- ? ) [ second ] dip = ; inline
 453 : third= ( seq elt -- ? ) [ third ] dip = ; inline
 454 : fourth= ( seq elt -- ? ) [ fourth ] dip = ; inline
 455 : last= ( seq elt -- ? ) [ last ] dip = ; inline
 456 : nth= ( n seq elt -- ? ) [ nth ] dip = ; inline
 457
 458 : first? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ first ] dip call ; inline
 459 : second? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ second ] dip call ; inline
 460 : third? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ third ] dip call ; inline
 461 : fourth? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ fourth ] dip call ; inline
 462 : last? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? ) [ last ] dip call ; inline
 463 : nth? ( ... n seq quot: ( ... elt -- ... ? ) -- ... ? ) [ nth ] dip call ; inline
 464
 465 : loop>sequence** ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 466     [ ] swap produce-as nip ; inline
 467
 468 : loop>array** ( ... quot: ( ... -- ... obj ? ) -- ... array )
 469     { } loop>sequence** ; inline
 470
 471 : loop>sequence* ( ... quot: ( ... -- ... obj ? ) exemplar -- ... seq )
 472     [ t ] [ '[ [ _ dip ] [ f f f ] if* ] [ swap ] ] [ produce-as 2nip ] tri* ; inline
 473
 474 : loop>array* ( ... quot: ( ... -- ... obj ? ) -- ... array )
 475     { } loop>sequence* ; inline
 476
 477 : loop>sequence ( ... quot: ( ... -- ... obj/f ) exemplar -- ... seq )
 478     [ [ dup ] compose [ ] ] dip produce-as nip ; inline
 479
 480 : loop>array ( ... quot: ( ... -- ... obj/f ) -- ... array )
 481    { } loop>sequence ; inline
 482
 483 : zero-loop>sequence ( ... quot: ( ... n -- ... obj/f ) exemplar -- ... seq )
 484     [ 0 ] [ '[ _ keep 1 + swap ] ] [ loop>sequence ] tri* nip ; inline
 485
 486 : zero-loop>array ( quot: ( ..a n -- ..a obj ) -- seq )
 487     { } zero-loop>sequence ; inline
 488
 489 : iterate-heap-while ( heap quot1: ( value key -- slurp? ) quot2: ( value key -- obj/f ) -- obj/f loop? )
 490     pick heap-empty?
 491     [ 3drop f f ]
 492     [
 493         [ [ heap-peek ] 2dip drop 2keep ]
 494         [
 495             nip ! ( pop? value key heap quot2 )
 496             5roll [
 497                 swap heap-pop* call( value key -- obj/f ) t
 498             ] [
 499                 4drop f f
 500             ] if
 501         ] 3bi
 502     ] if ; inline
 503
 504 : slurp-heap-while-map ( heap quot1: ( value key -- slurp? ) quot2: ( value key -- obj/f ) -- seq )
 505     '[ _ _ _ iterate-heap-while ] loop>array* ; inline
 506
 507 : heap>pairs ( heap -- pairs )
 508     [ 2drop t ] [ swap 2array ] slurp-heap-while-map ;
 509
 510 : map-zip-swap ( quot: ( x -- y ) -- alist )
 511     '[ _ keep ] map>alist ; inline
 512
 513 : ?heap-pop-value>array ( heap -- array )
 514     dup heap-empty? [ drop { } ] [ heap-pop drop 1array ] if ;
 515
 516 <PRIVATE
 517
 518 : (reverse) ( seq -- newseq )
 519     dup [ length ] keep new-sequence
 520     [ 0 swap copy-unsafe ] keep reverse! ;
 521
 522 PRIVATE>
 523
 524 : reverse-as ( seq exemplar -- newseq )
 525     [ (reverse) ] [ like ] bi* ;
 526
 527 : map-product ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 528     [ 1 ] 2dip [ dip * ] curry [ swap ] prepose each ; inline
 529
 530 : insert-nth! ( elt n seq -- )
 531     [ length ] keep ensure swap pick (a..b]
 532     over '[ [ 1 + ] keep _ move-unsafe ] each
 533     set-nth-unsafe ;
 534
 535 : set-nths ( value indices seq -- )
 536     swapd '[ _ swap _ set-nth ] each ; inline
 537
 538 : set-nths-unsafe ( value indices seq -- )
 539     swapd '[ _ swap _ set-nth-unsafe ] each ; inline
 540
 541 <PRIVATE
 542
 543 : (map-find-index) ( seq quot find-quot -- result i elt )
 544     [ [ f ] 2dip [ [ nip ] 2dip call dup ] curry ] dip call
 545     [ [ [ drop f ] unless ] keep ] dip ; inline
 546
 547 PRIVATE>
 548
 549 : map-find-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 550     [ find-index ] (map-find-index) ; inline
 551
 552 : filter-length ( seq n -- seq' ) '[ length _ = ] filter ;
 553
 554 : all-shortest ( seqs -- seqs' ) dup shortest length filter-length ;
 555
 556 : all-longest ( seqs -- seqs' ) dup longest length filter-length ;
 557
 558 : remove-first ( obj seq -- seq' )
 559     [ index ] keep over [ remove-nth ] [ nip ] if ;
 560
 561 : remove-first! ( obj seq -- seq )
 562     [ index ] keep over [ remove-nth! ] [ nip ] if ;
 563
 564 : remove-last ( obj seq -- seq' )
 565     [ last-index ] keep over [ remove-nth ] [ nip ] if ;
 566
 567 : remove-last! ( obj seq -- seq )
 568     [ last-index ] keep over [ remove-nth! ] [ nip ] if ;
 569
 570 : ?first2 ( seq -- first/f second/f )
 571     dup length {
 572         { 0 [ drop f f ] }
 573         { 1 [ first-unsafe f ] }
 574         [ drop first2-unsafe ]
 575     } case ;
 576
 577 : ?first3 ( seq -- first/f second/f third/f )
 578     dup length {
 579         { 0 [ drop f f f ] }
 580         { 1 [ first-unsafe f f ] }
 581         { 2 [ first2-unsafe f ] }
 582         [ drop first3-unsafe ]
 583     } case ;
 584
 585 : ?first4 ( seq -- first/f second/f third/f fourth/f )
 586     dup length {
 587         { 0 [ drop f f f f ] }
 588         { 1 [ first-unsafe f f f ] }
 589         { 2 [ first2-unsafe f f ] }
 590         { 3 [ first3-unsafe f ] }
 591         [ drop first4-unsafe ]
 592     } case ;
 593
 594 : cut-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
 595     [ find drop ] keepd swap
 596     [ cut ] [ f over like ] if* ; inline
 597
 598 : nth* ( n seq -- elt )
 599     [ length 1 - swap - ] [ nth ] bi ; inline
 600
 601 : each-index-from ( ... seq quot: ( ... elt index -- ... ) i -- ... )
 602     -rot sequence-index-operator each-integer-from ; inline
 603
 604 <PRIVATE
 605
 606 : select-by* ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... i elt )
 607     [
 608         [ keep swap ] curry [ dip ] curry
 609         [ [ first 0 ] dip call ] 2keep
 610         [ 2curry 3dip 5 npick pick ] curry
 611     ] [
 612         [ [ 3drop ] [ [ 3drop ] 3dip ] if ] compose
 613     ] bi* compose 1 each-index-from nip swap ; inline
 614
 615 PRIVATE>
 616
 617 : supremum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 618     [ after? ] select-by* ; inline
 619
 620 : infimum-by* ( ... seq quot: ( ... elt -- ... x ) -- ... i elt )
 621     [ before? ] select-by* ; inline
 622
 623 : arg-max ( seq -- n )
 624     [ ] supremum-by* drop ;
 625
 626 : arg-min ( seq -- n )
 627     [ ] infimum-by* drop ;
 628
 629 : ?supremum ( seq/f -- elt/f )
 630     [ f ] [
 631         [ ] [ 2dup and [ max ] [ dupd ? ] if ] map-reduce
 632     ] if-empty ;
 633
 634 : ?infimum ( seq/f -- elt/f )
 635     [ f ] [
 636         [ ] [ 2dup and [ min ] [ dupd ? ] if ] map-reduce
 637     ] if-empty ;
 638
 639 : change-last ( seq quot -- )
 640     [ index-of-last ] [ change-nth ] bi* ; inline
 641
 642 : change-last-unsafe ( seq quot -- )
 643     [ index-of-last ] [ change-nth-unsafe ] bi* ; inline
 644
 645 : replicate-into ( ... seq quot: ( ... -- ... newelt ) -- ... )
 646     over [ length ] 2dip '[ _ dip _ set-nth-unsafe ] each-integer ; inline
 647
 648 : count* ( ... seq quot: ( ... elt -- ... ? ) -- ... % )
 649     over [ count ] [ length ] bi* / ; inline
 650
 651 : sequence-index-operator-last ( n seq quot -- n quot' )
 652     [ [ nth-unsafe ] curry [ keep ] curry ] dip compose ; inline
 653
 654 : find-last-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 655     '[
 656         _ [ sequence-index-operator-last find-last-integer ] keepd
 657         index/element
 658     ] bounds-check-call ; inline
 659
 660 : find-last-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 661     [ index-of-last ] dip find-last-index-from ; inline
 662
 663 : map-find-last-index ( ... seq quot: ( ... elt index -- ... result/f ) -- ... result i elt )
 664     [ find-last-index ] (map-find-index) ; inline
 665
 666 :: (start-all) ( seq subseq increment -- indices )
 667     0
 668     [ seq subseq subseq-index-from dup ]
 669     [ [ increment + ] keep ] produce nip ;
 670
 671 : start-all ( seq subseq -- indices )
 672     dup length (start-all) ; inline
 673
 674 : start-all* ( seq subseq -- indices )
 675     1 (start-all) ; inline
 676
 677 : count-subseq ( seq subseq -- n )
 678     start-all length ; inline
 679
 680 : count-subseq* ( seq subseq -- n )
 681     start-all* length ; inline
 682
 683 : assoc-zip-with ( quot: ( key value -- calc ) -- alist )
 684     '[ _ 2keep 2array swap ] assoc-map ; inline
 685
 686 : take-while ( ... seq quot: ( ... elt -- ... ? ) -- head-slice )
 687     [ '[ @ not ] find drop ] keepd swap
 688     [ dup length ] unless* head-slice ; inline
 689
 690 : drop-while ( ... seq quot: ( ... elt -- ... ? ) -- tail-slice )
 691     [ '[ @ not ] find drop ] keepd swap
 692     [ dup length ] unless* tail-slice ; inline
 693
 694 : count-head ( seq quot -- n )
 695     [ not ] compose [ find drop ] keepd length or ; inline
 696
 697 : count-tail ( seq quot -- n )
 698     [ not ] compose [ find-last drop ] keepd
 699     length swap [ - 1 - ] when* ; inline
 700
 701 :: shorten* ( vector n -- seq )
 702     vector n tail
 703     n vector shorten ;
 704
 705 :: interleaved-as ( seq glue exemplar -- newseq )
 706     seq length dup 1 - + 0 max exemplar new-sequence :> newseq
 707     seq [ 2 * newseq set-nth-unsafe ] each-index
 708     seq length 1 - [ 2 * 1 + glue swap newseq set-nth-unsafe ] each-integer
 709     newseq ;
 710
 711 : interleaved ( seq glue -- newseq )
 712     over interleaved-as ;
 713
 714 : extract! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 715     [ dup ] compose over [ length ] keep new-resizable
 716     [ [ push-if ] 2curry reject! ] keep swap like ; inline
 717
 718 : find-pred-loop ( ... i n seq quot: ( ... elt -- ... calc ? ) -- ... calc/f i/f elt/f )
 719     2pick < [
 720         [ nipd call ] 4keep
 721         3 7 0 nrotated
 722         [ [ 3drop ] 2dip rot ]
 723         [ 2drop [ 1 + ] 3dip find-pred-loop ] if
 724     ] [
 725         4drop f f f
 726     ] if ; inline recursive
 727
 728 : find-pred ( ... seq quot: ( ... elt -- ... calc ) pred: ( ... calc -- ... ? ) -- ... calc/f i/f elt/f )
 729     [ 0 ] 3dip
 730     [ [ length check-length ] keep ] 2dip
 731     '[ nth-unsafe _ keep swap _ keep swap ] find-pred-loop swapd ; inline
 732
 733 ! https://en.wikipedia.org/wiki/Maximum_subarray_problem
 734 ! Kadane's algorithm O(n) largest sum in subarray
 735 : max-subarray-sum ( seq -- sum )
 736     [ -1/0. 0 ] dip
 737     [ [ + ] keep max [ max ] keep ] each drop ;
 738
 739 TUPLE: step-slice
 740     { from integer read-only initial: 0 }
 741     { to integer read-only initial: 0 }
 742     { seq read-only }
 743     { step integer read-only } ;
 744
 745 :: <step-slice> ( from to step seq -- step-slice )
 746     step zero? [ "can't be zero" throw ] when
 747     seq length :> len
 748     step 0 > [
 749         from [ 0 ] unless*
 750         to [ len ] unless*
 751     ] [
 752         from [ len ] unless*
 753         to [ 0 ] unless*
 754     ] if
 755     [ dup 0 < [ len + ] when 0 len clamp ] bi@
 756     ! FIXME: make this work with steps
 757     seq dup slice? [ collapse-slice ] when
 758     step step-slice boa ;
 759
 760 M: step-slice virtual-exemplar seq>> ; inline
 761
 762 M: step-slice virtual@
 763     [ step>> * ] [ from>> + ] [ seq>> ] tri ; inline
 764
 765 M: step-slice length
 766     [ to>> ] [ from>> - ] [ step>> ] tri
 767     dup 0 < [ [ neg 0 max ] dip neg ] when /mod
 768     zero? [ 1 + ] unless ; inline
 769
 770 INSTANCE: step-slice virtual-sequence