From d45d63715b0eb653bc76ca87b99c8de64d482d51 Mon Sep 17 00:00:00 2001
From: Bruno Deferrari <utizoc@gmail.com>
Date: Mon, 11 May 2009 00:08:34 -0300
Subject: [PATCH] extra.redis.assoc: Assoc protocol implementation for Redis

---
 extra/redis/assoc/assoc.factor | 41 ++++++++++++++++++++++++++++++++++
 extra/redis/assoc/authors.txt  |  1 +
 extra/redis/assoc/summary.txt  |  1 +
 3 files changed, 43 insertions(+)
 create mode 100644 extra/redis/assoc/assoc.factor
 create mode 100644 extra/redis/assoc/authors.txt
 create mode 100644 extra/redis/assoc/summary.txt

diff --git a/extra/redis/assoc/assoc.factor b/extra/redis/assoc/assoc.factor
new file mode 100644
index 0000000000..2ddf746344
--- /dev/null
+++ b/extra/redis/assoc/assoc.factor
@@ -0,0 +1,41 @@
+! Copyright (C) 2009 Bruno Deferrari
+! See http://factorcode.org/license.txt for BSD license.
+USING: accessors assocs io.encodings.8-bit io.sockets
+io.streams.duplex kernel redis sequences ;
+IN: redis.assoc
+
+TUPLE: redis-assoc host port encoding password ;
+
+CONSTANT: default-redis-port 6379
+
+: <redis-assoc> ( -- redis-assoc )
+    redis-assoc new
+        "127.0.0.1" >>host
+        default-redis-port >>port
+        latin1 >>encoding ;
+
+INSTANCE: redis-assoc assoc
+
+: with-redis-assoc ( redis-assoc quot -- )
+    [
+        [ host>> ] [ port>> ] [ encoding>> ] tri
+        [ <inet> ] dip <client> drop
+    ] dip with-stream ; inline
+
+M: redis-assoc at* [ redis-get dup >boolean ] with-redis-assoc ;
+
+M: redis-assoc assoc-size [ redis-dbsize ] with-redis-assoc ;
+
+M: redis-assoc >alist
+    [ "*" redis-keys dup redis-mget zip ] with-redis-assoc ;
+
+M: redis-assoc set-at [ redis-set drop ] with-redis-assoc ;
+
+M: redis-assoc delete-at [ redis-del drop ] with-redis-assoc ;
+
+M: redis-assoc clear-assoc
+    [ "*" redis-keys [ redis-del drop ] each ] with-redis-assoc ;
+
+M: redis-assoc equal? assoc= ;
+
+M: redis-assoc hashcode* assoc-hashcode ;
diff --git a/extra/redis/assoc/authors.txt b/extra/redis/assoc/authors.txt
new file mode 100644
index 0000000000..f4a8cb1dc2
--- /dev/null
+++ b/extra/redis/assoc/authors.txt
@@ -0,0 +1 @@
+Bruno Deferrari
diff --git a/extra/redis/assoc/summary.txt b/extra/redis/assoc/summary.txt
new file mode 100644
index 0000000000..72a76ab9f0
--- /dev/null
+++ b/extra/redis/assoc/summary.txt
@@ -0,0 +1 @@
+Assoc protocol implementation for Redis
-- 
2.34.1