basis/compiler/cfg/dataflow-analysis/dataflow-analysis.factor

   1 ! Copyright (C) 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs compiler.cfg.predecessors
   4 compiler.cfg.rpo deques dlists functors kernel lexer locals
   5 namespaces sequences ;
   6 IN: compiler.cfg.dataflow-analysis
   7
   8 GENERIC: join-sets ( sets bb dfa -- set )
   9 GENERIC: transfer-set ( in-set bb dfa -- out-set )
  10 GENERIC: block-order ( cfg dfa -- bbs )
  11 GENERIC: successors ( bb dfa -- seq )
  12 GENERIC: predecessors ( bb dfa -- seq )
  13 GENERIC: ignore-block? ( bb dfa -- ? )
  14
  15 <PRIVATE
  16
  17 MIXIN: dataflow-analysis
  18
  19 : <dfa-worklist> ( cfg dfa -- queue )
  20     block-order <hashed-dlist> [ push-all-front ] keep ;
  21
  22 :: compute-in-set ( bb out-sets dfa -- set )
  23     ! Only consider initialized sets.
  24     bb dfa ignore-block? [ f ] [
  25         bb dfa predecessors
  26         [ out-sets key? ] filter
  27         [ out-sets at ] map
  28         bb dfa join-sets
  29     ] if ;
  30
  31 :: update-in-set ( bb in-sets out-sets dfa -- ? )
  32     bb out-sets dfa compute-in-set
  33     bb in-sets maybe-set-at ; inline
  34
  35 :: compute-out-set ( bb in-sets dfa -- set )
  36     bb dfa ignore-block? [ f ] [ bb in-sets at bb dfa transfer-set ] if ;
  37
  38 :: update-out-set ( bb in-sets out-sets dfa -- ? )
  39     bb in-sets dfa compute-out-set
  40     bb out-sets maybe-set-at ; inline
  41
  42 :: dfa-step ( bb in-sets out-sets dfa work-list -- )
  43     bb in-sets out-sets dfa update-in-set [
  44         bb in-sets out-sets dfa update-out-set [
  45             bb dfa successors work-list push-all-front
  46         ] when
  47     ] when ; inline
  48
  49 :: run-dataflow-analysis ( cfg dfa -- in-sets out-sets )
  50     cfg needs-predecessors
  51     H{ } clone :> in-sets
  52     H{ } clone :> out-sets
  53     cfg dfa <dfa-worklist> :> work-list
  54     work-list [ in-sets out-sets dfa work-list dfa-step ] slurp-deque
  55     in-sets
  56     out-sets ; inline
  57
  58 M: dataflow-analysis join-sets 2drop assoc-refine ;
  59 M: dataflow-analysis ignore-block? drop kill-block?>> ;
  60
  61 FUNCTOR: define-analysis ( name -- )
  62
  63 name-analysis DEFINES-CLASS ${name}-analysis
  64 name-ins DEFINES ${name}-ins
  65 name-outs DEFINES ${name}-outs
  66 name-in DEFINES ${name}-in
  67 name-out DEFINES ${name}-out
  68
  69 WHERE
  70
  71 SINGLETON: name-analysis
  72
  73 SYMBOL: name-ins
  74
  75 : name-in ( bb -- set ) name-ins get at ;
  76
  77 SYMBOL: name-outs
  78
  79 : name-out ( bb -- set ) name-outs get at ;
  80
  81 ;FUNCTOR
  82
  83 ! ! ! Forward dataflow analysis
  84
  85 MIXIN: forward-analysis
  86 INSTANCE: forward-analysis dataflow-analysis
  87
  88 M: forward-analysis block-order  drop reverse-post-order ;
  89 M: forward-analysis successors   drop successors>> ;
  90 M: forward-analysis predecessors drop predecessors>> ;
  91
  92 FUNCTOR: define-forward-analysis ( name -- )
  93
  94 name-analysis IS ${name}-analysis
  95 name-ins IS ${name}-ins
  96 name-outs IS ${name}-outs
  97 compute-name-sets DEFINES compute-${name}-sets
  98
  99 WHERE
 100
 101 INSTANCE: name-analysis forward-analysis
 102
 103 : compute-name-sets ( cfg -- )
 104     name-analysis run-dataflow-analysis
 105     [ name-ins set ] [ name-outs set ] bi* ;
 106
 107 ;FUNCTOR
 108
 109 ! ! ! Backward dataflow analysis
 110
 111 MIXIN: backward-analysis
 112 INSTANCE: backward-analysis dataflow-analysis
 113
 114 M: backward-analysis block-order  drop post-order ;
 115 M: backward-analysis successors   drop predecessors>> ;
 116 M: backward-analysis predecessors drop successors>> ;
 117
 118 FUNCTOR: define-backward-analysis ( name -- )
 119
 120 name-analysis IS ${name}-analysis
 121 name-ins IS ${name}-ins
 122 name-outs IS ${name}-outs
 123 compute-name-sets DEFINES compute-${name}-sets
 124
 125 WHERE
 126
 127 INSTANCE: name-analysis backward-analysis
 128
 129 : compute-name-sets ( cfg -- )
 130     \ name-analysis run-dataflow-analysis
 131     [ name-outs set ] [ name-ins set ] bi* ;
 132
 133 ;FUNCTOR
 134
 135 PRIVATE>
 136
 137 SYNTAX: FORWARD-ANALYSIS:
 138     scan-token [ define-analysis ] [ define-forward-analysis ] bi ;
 139
 140 SYNTAX: BACKWARD-ANALYSIS:
 141     scan-token [ define-analysis ] [ define-backward-analysis ] bi ;