basis/compiler/cfg/ssa/destruction/destruction.factor

   1 ! Copyright (C) 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs fry kernel namespaces
   4 sequences sequences.deep
   5 sets vectors
   6 compiler.cfg.rpo
   7 compiler.cfg.def-use
   8 compiler.cfg.renaming
   9 compiler.cfg.dominance
  10 compiler.cfg.instructions
  11 compiler.cfg.ssa.liveness
  12 compiler.cfg.ssa.cssa
  13 compiler.cfg.ssa.interference
  14 compiler.cfg.ssa.interference.live-ranges
  15 compiler.cfg.utilities
  16 compiler.utilities ;
  17 IN: compiler.cfg.ssa.destruction
  18
  19 ! Maps vregs to leaders.
  20 SYMBOL: leader-map
  21
  22 : leader ( vreg -- vreg' ) leader-map get compress-path ;
  23
  24 ! Maps leaders to equivalence class elements.
  25 SYMBOL: class-element-map
  26
  27 : class-elements ( vreg -- elts ) class-element-map get at ;
  28
  29 ! Sequence of vreg pairs
  30 SYMBOL: copies
  31
  32 : init-coalescing ( -- )
  33     H{ } clone leader-map set
  34     H{ } clone class-element-map set
  35     V{ } clone copies set ;
  36
  37 : classes-interfere? ( vreg1 vreg2 -- ? )
  38     [ leader ] bi@ 2dup eq? [ 2drop f ] [
  39         [ class-elements flatten ] bi@ sets-interfere?
  40     ] if ;
  41
  42 : update-leaders ( vreg1 vreg2 -- )
  43     swap leader-map get set-at ;
  44
  45 : merge-classes ( vreg1 vreg2 -- )
  46     [ [ class-elements ] bi@ push ]
  47     [ drop class-element-map get delete-at ] 2bi ;
  48
  49 : eliminate-copy ( vreg1 vreg2 -- )
  50     [ leader ] bi@
  51     2dup eq? [ 2drop ] [
  52         [ update-leaders ] [ merge-classes ] 2bi
  53     ] if ;
  54
  55 : introduce-vreg ( vreg -- )
  56     [ leader-map get conjoin ]
  57     [ [ 1vector ] keep class-element-map get set-at ] bi ;
  58
  59 GENERIC: prepare-insn ( insn -- )
  60
  61 M: ##copy prepare-insn
  62     [ dst>> ] [ src>> ] bi 2array copies get push ;
  63
  64 M: ##phi prepare-insn
  65     [ dst>> ] [ inputs>> values ] bi
  66     [ eliminate-copy ] with each ;
  67
  68 M: insn prepare-insn drop ;
  69
  70 : prepare-block ( bb -- )
  71     instructions>> [ prepare-insn ] each ;
  72
  73 : prepare-coalescing ( cfg -- )
  74     init-coalescing
  75     defs get keys [ introduce-vreg ] each
  76     [ prepare-block ] each-basic-block ;
  77
  78 : process-copies ( -- )
  79     copies get [
  80         2dup classes-interfere?
  81         [ 2drop ] [ eliminate-copy ] if
  82     ] assoc-each ;
  83
  84 : useless-copy? ( ##copy -- ? )
  85     dup ##copy? [ [ dst>> ] [ src>> ] bi eq? ] [ drop f ] if ;
  86
  87 : perform-renaming ( cfg -- )
  88     leader-map get keys [ dup leader ] H{ } map>assoc renamings set
  89     [
  90         instructions>> [
  91             [ rename-insn-defs ]
  92             [ rename-insn-uses ]
  93             [ [ useless-copy? ] [ ##phi? ] bi or not ] tri
  94         ] filter-here
  95     ] each-basic-block ;
  96
  97 : destruct-ssa ( cfg -- cfg' )
  98     dup cfg-has-phis? [
  99         dup construct-cssa
 100         dup precompute-liveness
 101         dup compute-defs
 102         dup compute-dominance
 103         dup compute-live-ranges
 104         dup prepare-coalescing
 105         process-copies
 106         dup perform-renaming
 107     ] when ;