basis/compiler/cfg/ssa/destruction/destruction.factor

   1 ! Copyright (C) 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs fry kernel namespaces
   4 sequences sequences.deep
   5 sets vectors
   6 compiler.cfg.rpo
   7 compiler.cfg.def-use
   8 compiler.cfg.renaming
   9 compiler.cfg.dominance
  10 compiler.cfg.instructions
  11 compiler.cfg.liveness.ssa
  12 compiler.cfg.ssa.cssa
  13 compiler.cfg.ssa.interference
  14 compiler.cfg.ssa.interference.live-ranges
  15 compiler.cfg.utilities
  16 compiler.utilities ;
  17 IN: compiler.cfg.ssa.destruction
  18
  19 ! Maps vregs to leaders.
  20 SYMBOL: leader-map
  21
  22 : leader ( vreg -- vreg' ) leader-map get compress-path ;
  23
  24 ! Maps leaders to equivalence class elements.
  25 SYMBOL: class-element-map
  26
  27 : class-elements ( vreg -- elts ) class-element-map get at ;
  28
  29 ! Sequence of vreg pairs
  30 SYMBOL: copies
  31
  32 : init-coalescing ( -- )
  33     H{ } clone leader-map set
  34     H{ } clone class-element-map set
  35     V{ } clone copies set ;
  36
  37 : classes-interfere? ( vreg1 vreg2 -- ? )
  38     [ leader ] bi@ 2dup eq? [ 2drop f ] [
  39         [ class-elements flatten ] bi@ sets-interfere?
  40     ] if ;
  41
  42 : update-leaders ( vreg1 vreg2 -- )
  43     swap leader-map get set-at ;
  44
  45 : merge-classes ( vreg1 vreg2 -- )
  46     [ [ class-elements ] bi@ push ]
  47     [ drop class-element-map get delete-at ] 2bi ;
  48
  49 : eliminate-copy ( vreg1 vreg2 -- )
  50     [ leader ] bi@
  51     2dup eq? [ 2drop ] [
  52         [ update-leaders ]
  53         [ merge-classes ]
  54         2bi
  55     ] if ;
  56
  57 : introduce-vreg ( vreg -- )
  58     [ leader-map get conjoin ]
  59     [ [ 1vector ] keep class-element-map get set-at ] bi ;
  60
  61 GENERIC: prepare-insn ( insn -- )
  62
  63 M: ##copy prepare-insn
  64     [ dst>> ] [ src>> ] bi 2array copies get push ;
  65
  66 M: ##phi prepare-insn
  67     [ dst>> ] [ inputs>> values ] bi
  68     [ eliminate-copy ] with each ;
  69
  70 M: insn prepare-insn drop ;
  71
  72 : prepare-block ( bb -- )
  73     instructions>> [ prepare-insn ] each ;
  74
  75 : prepare-coalescing ( cfg -- )
  76     init-coalescing
  77     defs get keys [ introduce-vreg ] each
  78     [ prepare-block ] each-basic-block ;
  79
  80 : process-copies ( -- )
  81     copies get [
  82         2dup classes-interfere?
  83         [ 2drop ] [ eliminate-copy ] if
  84     ] assoc-each ;
  85
  86 : useless-copy? ( ##copy -- ? )
  87     dup ##copy? [ [ dst>> ] [ src>> ] bi eq? ] [ drop f ] if ;
  88
  89 : perform-renaming ( cfg -- )
  90     leader-map get keys [ dup leader ] H{ } map>assoc renamings set
  91     [
  92         instructions>> [
  93             [ rename-insn-defs ]
  94             [ rename-insn-uses ]
  95             [ [ useless-copy? ] [ ##phi? ] bi or not ] tri
  96         ] filter-here
  97     ] each-basic-block ;
  98
  99 : destruct-ssa ( cfg -- cfg' )
 100     needs-dominance
 101
 102     dup construct-cssa
 103     dup compute-defs
 104     compute-ssa-live-sets
 105     dup compute-live-ranges
 106     dup prepare-coalescing
 107     process-copies
 108     dup perform-renaming ;