basis/compiler/cfg/ssa/destruction/destruction.factor

   1 ! Copyright (C) 2009, 2011 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs combinators compiler.cfg.def-use
   4 compiler.cfg.dominance compiler.cfg.instructions
   5 compiler.cfg.liveness compiler.cfg.parallel-copy
   6 compiler.cfg.registers compiler.cfg.rpo compiler.cfg.ssa.cssa
   7 compiler.cfg.ssa.destruction.leaders
   8 compiler.cfg.ssa.interference
   9 compiler.cfg.ssa.interference.live-ranges compiler.cfg.utilities
  10 cpu.architecture kernel locals make namespaces sequences sets ;
  11 FROM: namespaces => set ;
  12 IN: compiler.cfg.ssa.destruction
  13
  14 SYMBOL: class-element-map
  15
  16 <PRIVATE
  17
  18 ! Sequence of vreg pairs
  19 SYMBOL: copies
  20
  21 : value-of ( vreg -- value )
  22     dup insn-of dup ##tagged>integer? [ nip src>> ] [ drop ] if ;
  23
  24 : init-coalescing ( -- )
  25     defs get
  26     [ keys unique leader-map set ]
  27     [
  28         [ [ dup dup value-of ] dip <vreg-info> 1array ] assoc-map
  29         class-element-map set
  30     ] bi
  31     V{ } clone copies set ;
  32
  33 : coalesce-elements ( merged vreg1 vreg2 -- )
  34     ! delete leader1's class, and set leader2's class to merged.
  35     class-element-map get [ delete-at ] [ set-at ] bi-curry bi* ;
  36
  37 : coalesce-vregs ( merged leader1 leader2 -- )
  38     2dup swap leader-map get set-at coalesce-elements ;
  39
  40 GENERIC: prepare-insn ( insn -- )
  41
  42 M: insn prepare-insn drop ;
  43
  44 M: alien-call-insn prepare-insn drop ;
  45
  46 M: vreg-insn prepare-insn
  47     [ temp-vregs [ leader-map get conjoin ] each ]
  48     [
  49         [ defs-vregs ] [ uses-vregs ] bi
  50         2dup [ empty? not ] both? [
  51             [ first ] bi@
  52             2dup [ rep-of reg-class-of ] bi@ eq?
  53             [ 2array copies get push ] [ 2drop ] if
  54         ] [ 2drop ] if
  55     ] bi ;
  56
  57 M: ##copy prepare-insn
  58     [ dst>> ] [ src>> ] bi 2array copies get push ;
  59
  60 M: ##parallel-copy prepare-insn
  61     values>> copies get push-all ;
  62
  63 : leaders ( vreg1 vreg2 -- vreg1' vreg2' )
  64     [ leader ] bi@ ;
  65
  66 : vregs-interfere? ( vreg1 vreg2 -- merged/f ? )
  67     [ class-element-map get at ] bi@ sets-interfere? ;
  68
  69 ERROR: vregs-shouldn't-interfere vreg1 vreg2 ;
  70
  71 :: must-eliminate-copy ( vreg1 vreg2 -- )
  72     vreg1 vreg2 = [
  73         vreg1 vreg2 vregs-interfere?
  74         [ vreg1 vreg2 vregs-shouldn't-interfere ]
  75         [ vreg1 vreg2 coalesce-vregs ]
  76         if
  77     ] unless ;
  78
  79 M: ##tagged>integer prepare-insn
  80     [ dst>> ] [ src>> ] bi leaders must-eliminate-copy ;
  81
  82 M: ##phi prepare-insn
  83     [ dst>> ] [ inputs>> values ] bi
  84     [ leaders must-eliminate-copy ] with each ;
  85
  86 : prepare-coalescing ( cfg -- )
  87     init-coalescing [ [ prepare-insn ] each ] simple-analysis ;
  88
  89 :: maybe-eliminate-copy ( vreg1 vreg2 -- )
  90     vreg1 vreg2 = [
  91         vreg1 vreg2 vregs-interfere?
  92         [ drop ] [ vreg1 vreg2 coalesce-vregs ] if
  93     ] unless ;
  94
  95 : process-copies ( copies -- )
  96     [ leaders maybe-eliminate-copy ] assoc-each ;
  97
  98 : perform-coalescing ( cfg -- )
  99     prepare-coalescing copies get process-copies ;
 100
 101 GENERIC: cleanup-insn ( insn -- )
 102
 103 : useful-copy? ( insn -- ? )
 104     [ dst>> ] [ src>> ] bi leaders = not ; inline
 105
 106 M: ##copy cleanup-insn
 107     dup useful-copy? [ , ] [ drop ] if ;
 108
 109 M: ##parallel-copy cleanup-insn
 110     values>> [ leaders ] assoc-map [ first2 = ] reject
 111     parallel-copy-rep % ;
 112
 113 M: ##tagged>integer cleanup-insn
 114     dup useful-copy? [ , ] [ drop ] if ;
 115
 116 M: ##phi cleanup-insn drop ;
 117
 118 M: insn cleanup-insn , ;
 119
 120 : cleanup-cfg ( cfg -- )
 121     [ [ [ cleanup-insn ] each ] V{ } make ] simple-optimization ;
 122
 123 PRIVATE>
 124
 125 : destruct-ssa ( cfg -- )
 126     f leader-map set
 127     {
 128         needs-dominance
 129         construct-cssa
 130         compute-defs
 131         compute-insns
 132         compute-live-sets
 133         compute-live-ranges
 134         perform-coalescing
 135         cleanup-cfg
 136         compute-live-sets
 137     } apply-passes ;