basis/compiler/cfg/ssa/destruction/destruction.factor

   1 ! Copyright (C) 2009, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs fry kernel namespaces
   4 sequences sequences.deep
   5 sets vectors
   6 compiler.cfg.rpo
   7 compiler.cfg.def-use
   8 compiler.cfg.renaming
   9 compiler.cfg.registers
  10 compiler.cfg.dominance
  11 compiler.cfg.instructions
  12 compiler.cfg.liveness.ssa
  13 compiler.cfg.ssa.cssa
  14 compiler.cfg.ssa.interference
  15 compiler.cfg.ssa.interference.live-ranges
  16 compiler.cfg.utilities
  17 compiler.utilities ;
  18 FROM: namespaces => set ;
  19 IN: compiler.cfg.ssa.destruction
  20
  21 ! Maps vregs to leaders.
  22 SYMBOL: leader-map
  23
  24 : leader ( vreg -- vreg' ) leader-map get compress-path ;
  25
  26 ! Maps basic blocks to ##phi instruction outputs
  27 SYMBOL: phi-sets
  28
  29 : phi-set ( bb -- vregs ) phi-sets get at ;
  30
  31 ! Maps leaders to equivalence class elements.
  32 SYMBOL: class-element-map
  33
  34 : class-elements ( vreg -- elts ) class-element-map get at ;
  35
  36 ! Sequence of vreg pairs
  37 SYMBOL: copies
  38
  39 : init-coalescing ( -- )
  40     H{ } clone leader-map set
  41     H{ } clone class-element-map set
  42     V{ } clone copies set ;
  43
  44 : classes-interfere? ( vreg1 vreg2 -- ? )
  45     [ leader ] bi@ 2dup eq? [ 2drop f ] [
  46         [ class-elements flatten ] bi@ sets-interfere?
  47     ] if ;
  48
  49 : update-leaders ( vreg1 vreg2 -- )
  50     swap leader-map get set-at ;
  51
  52 : merge-classes ( vreg1 vreg2 -- )
  53     [ [ class-elements ] bi@ push ]
  54     [ drop class-element-map get delete-at ] 2bi ;
  55
  56 : eliminate-copy ( vreg1 vreg2 -- )
  57     [ leader ] bi@
  58     2dup eq? [ 2drop ] [
  59         [ update-leaders ]
  60         [ merge-classes ]
  61         2bi
  62     ] if ;
  63
  64 : introduce-vreg ( vreg -- )
  65     [ leader-map get conjoin ]
  66     [ [ 1vector ] keep class-element-map get set-at ] bi ;
  67
  68 GENERIC: prepare-insn ( insn -- )
  69
  70 : try-to-coalesce ( dst src -- ) 2array copies get push ;
  71
  72 M: insn prepare-insn
  73     [ defs-vreg ] [ uses-vregs ] bi
  74     2dup empty? not and [
  75         first
  76         2dup [ rep-of ] bi@ eq?
  77         [ try-to-coalesce ] [ 2drop ] if
  78     ] [ 2drop ] if ;
  79
  80 M: ##copy prepare-insn
  81     [ dst>> ] [ src>> ] bi try-to-coalesce ;
  82
  83 M: ##phi prepare-insn
  84     [ dst>> ] [ inputs>> values ] bi
  85     [ eliminate-copy ] with each ;
  86
  87 : prepare-block ( bb -- )
  88     instructions>> [ prepare-insn ] each ;
  89
  90 : prepare-coalescing ( cfg -- )
  91     init-coalescing
  92     defs get keys [ introduce-vreg ] each
  93     [ prepare-block ] each-basic-block ;
  94
  95 : process-copies ( -- )
  96     copies get [
  97         2dup classes-interfere?
  98         [ 2drop ] [ eliminate-copy ] if
  99     ] assoc-each ;
 100
 101 GENERIC: rename-insn ( insn -- keep? )
 102
 103 M: vreg-insn rename-insn
 104     [ rename-insn-defs ] [ rename-insn-uses ] bi t ;
 105
 106 M: ##copy rename-insn
 107     [ call-next-method drop ]
 108     [ [ dst>> ] [ src>> ] bi eq? not ] bi ;
 109
 110 SYMBOL: current-phi-set
 111
 112 M: ##phi rename-insn dst>> current-phi-set get push f ;
 113
 114 M: ##call-gc rename-insn
 115     [ renamings get '[ _ at ] map members ] change-gc-roots drop t ;
 116
 117 M: insn rename-insn drop t ;
 118
 119 : renaming-in-block ( bb -- )
 120     V{ } clone current-phi-set set
 121     [ [ current-phi-set ] dip phi-sets get set-at ]
 122     [ instructions>> [ rename-insn ] filter! drop ]
 123     bi ;
 124
 125 : perform-renaming ( cfg -- )
 126     H{ } clone phi-sets set
 127     leader-map get keys [ dup leader ] H{ } map>assoc renamings set
 128     [ renaming-in-block ] each-basic-block ;
 129
 130 : destruct-ssa ( cfg -- cfg' )
 131     needs-dominance
 132
 133     dup construct-cssa
 134     dup compute-defs
 135     dup compute-ssa-live-sets
 136     dup compute-live-ranges
 137     dup prepare-coalescing
 138     process-copies
 139     dup perform-renaming ;