basis/compiler/cfg/ssa/destruction/destruction.factor

   1 ! Copyright (C) 2009, 2011 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs combinators compiler.cfg.def-use
   4 compiler.cfg.dominance compiler.cfg.instructions
   5 compiler.cfg.liveness compiler.cfg.parallel-copy
   6 compiler.cfg.registers compiler.cfg.rpo compiler.cfg.ssa.cssa
   7 compiler.cfg.ssa.destruction.leaders
   8 compiler.cfg.ssa.interference
   9 compiler.cfg.ssa.interference.live-ranges compiler.cfg.utilities
  10 cpu.architecture kernel make namespaces sequences sets ;
  11 FROM: namespaces => set ;
  12 IN: compiler.cfg.ssa.destruction
  13
  14 SYMBOL: class-element-map
  15
  16 <PRIVATE
  17
  18 SYMBOL: copies
  19
  20 : value-of ( vreg -- value )
  21     dup insn-of dup ##tagged>integer? [ nip src>> ] [ drop ] if ;
  22
  23 : init-coalescing ( -- )
  24     defs get
  25     [ keys unique leader-map set ]
  26     [
  27         [ [ dup dup value-of ] dip <vreg-info> 1array ] assoc-map
  28         class-element-map set
  29     ] bi
  30     V{ } clone copies set ;
  31
  32 : coalesce-elements ( merged follower leader -- )
  33     class-element-map get [ delete-at ] [ set-at ] bi-curry bi* ;
  34
  35 : coalesce-vregs ( merged follower leader -- )
  36     2dup swap leader-map get set-at coalesce-elements ;
  37
  38 GENERIC: prepare-insn ( insn -- )
  39
  40 M: insn prepare-insn drop ;
  41
  42 M: alien-call-insn prepare-insn drop ;
  43
  44 M: vreg-insn prepare-insn
  45     [ temp-vregs [ leader-map get conjoin ] each ]
  46     [
  47         [ defs-vregs ] [ uses-vregs ] bi
  48         2dup [ empty? not ] both? [
  49             [ first ] bi@
  50             2dup [ rep-of reg-class-of ] bi@ eq?
  51             [ 2array copies get push ] [ 2drop ] if
  52         ] [ 2drop ] if
  53     ] bi ;
  54
  55 M: ##copy prepare-insn
  56     [ dst>> ] [ src>> ] bi 2array copies get push ;
  57
  58 M: ##parallel-copy prepare-insn
  59     values>> copies get push-all ;
  60
  61 : leaders ( vreg1 vreg2 -- vreg1' vreg2' )
  62     [ leader ] bi@ ;
  63
  64 : vregs-interfere? ( vreg1 vreg2 -- merged/f ? )
  65     [ class-element-map get at ] bi@ sets-interfere? ;
  66
  67 ERROR: vregs-shouldn't-interfere vreg1 vreg2 ;
  68
  69 : try-eliminate-copy ( follower leader must? -- )
  70     -rot leaders 2dup = [ 3drop ] [
  71         2dup vregs-interfere? [
  72             drop rot [ vregs-shouldn't-interfere ] [ 2drop ] if
  73         ] [ -rot coalesce-vregs drop ] if
  74     ] if ;
  75
  76 M: ##tagged>integer prepare-insn
  77     [ dst>> ] [ src>> ] bi t try-eliminate-copy ;
  78
  79 M: ##phi prepare-insn
  80     [ dst>> ] [ inputs>> values ] bi [ t try-eliminate-copy ] with each ;
  81
  82 : prepare-coalescing ( cfg -- )
  83     init-coalescing [ [ prepare-insn ] each ] simple-analysis ;
  84
  85 : process-copies ( copies -- )
  86     [ f try-eliminate-copy ] assoc-each ;
  87
  88 : perform-coalescing ( cfg -- )
  89     prepare-coalescing copies get process-copies ;
  90
  91 GENERIC: cleanup-insn ( insn -- )
  92
  93 : useful-copy? ( insn -- ? )
  94     [ dst>> ] [ src>> ] bi leaders = not ; inline
  95
  96 M: ##copy cleanup-insn
  97     dup useful-copy? [ , ] [ drop ] if ;
  98
  99 M: ##parallel-copy cleanup-insn
 100     values>> [ leaders ] assoc-map [ first2 = ] reject
 101     parallel-copy-rep % ;
 102
 103 M: ##tagged>integer cleanup-insn
 104     dup useful-copy? [ , ] [ drop ] if ;
 105
 106 M: ##phi cleanup-insn drop ;
 107
 108 M: insn cleanup-insn , ;
 109
 110 : cleanup-cfg ( cfg -- )
 111     [ [ [ cleanup-insn ] each ] V{ } make ] simple-optimization ;
 112
 113 PRIVATE>
 114
 115 : destruct-ssa ( cfg -- )
 116     f leader-map set
 117     {
 118         needs-dominance
 119         construct-cssa
 120         compute-defs
 121         compute-insns
 122         compute-live-sets
 123         compute-live-ranges
 124         perform-coalescing
 125         cleanup-cfg
 126         compute-live-sets
 127     } apply-passes ;