basis/compiler/cfg/ssa/destruction/destruction.factor

   1 ! Copyright (C) 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs fry kernel namespaces
   4 sequences sequences.deep
   5 sets vectors
   6 compiler.cfg.rpo
   7 compiler.cfg.def-use
   8 compiler.cfg.renaming
   9 compiler.cfg.dominance
  10 compiler.cfg.instructions
  11 compiler.cfg.liveness.ssa
  12 compiler.cfg.ssa.cssa
  13 compiler.cfg.ssa.interference
  14 compiler.cfg.ssa.interference.live-ranges
  15 compiler.cfg.utilities
  16 compiler.utilities ;
  17 IN: compiler.cfg.ssa.destruction
  18
  19 ! Maps vregs to leaders.
  20 SYMBOL: leader-map
  21
  22 : leader ( vreg -- vreg' ) leader-map get compress-path ;
  23
  24 ! Maps leaders to equivalence class elements.
  25 SYMBOL: class-element-map
  26
  27 : class-elements ( vreg -- elts ) class-element-map get at ;
  28
  29 ! Sequence of vreg pairs
  30 SYMBOL: copies
  31
  32 : init-coalescing ( -- )
  33     H{ } clone leader-map set
  34     H{ } clone class-element-map set
  35     V{ } clone copies set ;
  36
  37 : classes-interfere? ( vreg1 vreg2 -- ? )
  38     [ leader ] bi@ 2dup eq? [ 2drop f ] [
  39         [ class-elements flatten ] bi@ sets-interfere?
  40     ] if ;
  41
  42 : update-leaders ( vreg1 vreg2 -- )
  43     swap leader-map get set-at ;
  44
  45 : merge-classes ( vreg1 vreg2 -- )
  46     [ [ class-elements ] bi@ push ]
  47     [ drop class-element-map get delete-at ] 2bi ;
  48
  49 : eliminate-copy ( vreg1 vreg2 -- )
  50     [ leader ] bi@
  51     2dup eq? [ 2drop ] [
  52         [ [ rep>> ] bi@ assert= ]
  53         [ update-leaders ]
  54         [ merge-classes ]
  55         2tri
  56     ] if ;
  57
  58 : introduce-vreg ( vreg -- )
  59     [ leader-map get conjoin ]
  60     [ [ 1vector ] keep class-element-map get set-at ] bi ;
  61
  62 GENERIC: prepare-insn ( insn -- )
  63
  64 M: ##copy prepare-insn
  65     [ dst>> ] [ src>> ] bi 2array copies get push ;
  66
  67 M: ##phi prepare-insn
  68     [ dst>> ] [ inputs>> values ] bi
  69     [ eliminate-copy ] with each ;
  70
  71 M: insn prepare-insn drop ;
  72
  73 : prepare-block ( bb -- )
  74     instructions>> [ prepare-insn ] each ;
  75
  76 : prepare-coalescing ( cfg -- )
  77     init-coalescing
  78     defs get keys [ introduce-vreg ] each
  79     [ prepare-block ] each-basic-block ;
  80
  81 : process-copies ( -- )
  82     copies get [
  83         2dup classes-interfere?
  84         [ 2drop ] [ eliminate-copy ] if
  85     ] assoc-each ;
  86
  87 : useless-copy? ( ##copy -- ? )
  88     dup ##copy? [ [ dst>> ] [ src>> ] bi eq? ] [ drop f ] if ;
  89
  90 : perform-renaming ( cfg -- )
  91     leader-map get keys [ dup leader ] H{ } map>assoc renamings set
  92     [
  93         instructions>> [
  94             [ rename-insn-defs ]
  95             [ rename-insn-uses ]
  96             [ [ useless-copy? ] [ ##phi? ] bi or not ] tri
  97         ] filter-here
  98     ] each-basic-block ;
  99
 100 : destruct-ssa ( cfg -- cfg' )
 101     dup construct-cssa
 102     dup compute-defs
 103     dup compute-dominance
 104     compute-ssa-live-sets
 105     dup compute-live-ranges
 106     dup prepare-coalescing
 107     process-copies
 108     dup perform-renaming ;