basis/compiler/cfg/ssa/destruction/destruction.factor

   1 ! Copyright (C) 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs fry kernel namespaces
   4 sequences sequences.deep
   5 sets vectors
   6 compiler.cfg.rpo
   7 compiler.cfg.def-use
   8 compiler.cfg.renaming
   9 compiler.cfg.registers
  10 compiler.cfg.dominance
  11 compiler.cfg.instructions
  12 compiler.cfg.liveness.ssa
  13 compiler.cfg.ssa.cssa
  14 compiler.cfg.ssa.interference
  15 compiler.cfg.ssa.interference.live-ranges
  16 compiler.cfg.utilities
  17 compiler.utilities ;
  18 IN: compiler.cfg.ssa.destruction
  19
  20 ! Maps vregs to leaders.
  21 SYMBOL: leader-map
  22
  23 : leader ( vreg -- vreg' ) leader-map get compress-path ;
  24
  25 ! Maps leaders to equivalence class elements.
  26 SYMBOL: class-element-map
  27
  28 : class-elements ( vreg -- elts ) class-element-map get at ;
  29
  30 ! Sequence of vreg pairs
  31 SYMBOL: copies
  32
  33 : init-coalescing ( -- )
  34     H{ } clone leader-map set
  35     H{ } clone class-element-map set
  36     V{ } clone copies set ;
  37
  38 : classes-interfere? ( vreg1 vreg2 -- ? )
  39     [ leader ] bi@ 2dup eq? [ 2drop f ] [
  40         [ class-elements flatten ] bi@ sets-interfere?
  41     ] if ;
  42
  43 : update-leaders ( vreg1 vreg2 -- )
  44     swap leader-map get set-at ;
  45
  46 : merge-classes ( vreg1 vreg2 -- )
  47     [ [ class-elements ] bi@ push ]
  48     [ drop class-element-map get delete-at ] 2bi ;
  49
  50 : eliminate-copy ( vreg1 vreg2 -- )
  51     [ leader ] bi@
  52     2dup eq? [ 2drop ] [
  53         [ update-leaders ]
  54         [ merge-classes ]
  55         2bi
  56     ] if ;
  57
  58 : introduce-vreg ( vreg -- )
  59     [ leader-map get conjoin ]
  60     [ [ 1vector ] keep class-element-map get set-at ] bi ;
  61
  62 GENERIC: prepare-insn ( insn -- )
  63
  64 : try-to-coalesce ( dst src -- ) 2array copies get push ;
  65
  66 M: insn prepare-insn
  67     [ defs-vreg ] [ uses-vregs ] bi
  68     2dup empty? not and [
  69         first
  70         2dup [ rep-of ] bi@ eq?
  71         [ try-to-coalesce ] [ 2drop ] if
  72     ] [ 2drop ] if ;
  73
  74 M: ##copy prepare-insn
  75     [ dst>> ] [ src>> ] bi try-to-coalesce ;
  76
  77 M: ##phi prepare-insn
  78     [ dst>> ] [ inputs>> values ] bi
  79     [ eliminate-copy ] with each ;
  80
  81     : prepare-block ( bb -- )
  82     instructions>> [ prepare-insn ] each ;
  83
  84 : prepare-coalescing ( cfg -- )
  85     init-coalescing
  86     defs get keys [ introduce-vreg ] each
  87     [ prepare-block ] each-basic-block ;
  88
  89 : process-copies ( -- )
  90     copies get [
  91         2dup classes-interfere?
  92         [ 2drop ] [ eliminate-copy ] if
  93     ] assoc-each ;
  94
  95 : useless-copy? ( ##copy -- ? )
  96     dup ##copy? [ [ dst>> ] [ src>> ] bi eq? ] [ drop f ] if ;
  97
  98 : perform-renaming ( cfg -- )
  99     leader-map get keys [ dup leader ] H{ } map>assoc renamings set
 100     [
 101         instructions>> [
 102             [ rename-insn-defs ]
 103             [ rename-insn-uses ]
 104             [ [ useless-copy? ] [ ##phi? ] bi or not ] tri
 105         ] filter-here
 106     ] each-basic-block ;
 107
 108 : destruct-ssa ( cfg -- cfg' )
 109     needs-dominance
 110
 111     dup construct-cssa
 112     dup compute-defs
 113     compute-ssa-live-sets
 114     dup compute-live-ranges
 115     dup prepare-coalescing
 116     process-copies
 117     dup perform-renaming ;