basis/alien/c-types/c-types-docs.factor

   1 USING: alien help.syntax help.markup libc kernel.private
   2 byte-arrays math strings hashtables alien.syntax alien.strings sequences
   3 io.encodings.string debugger destructors vocabs.loader ;
   4 IN: alien.c-types
   5
   6 HELP: byte-length
   7 { $values { "seq" "A byte array or float array" } { "n" "a non-negative integer" } }
   8 { $contract "Outputs the size of the byte array, struct, or specialized array data in bytes." } ;
   9
  10 HELP: heap-size
  11 { $values { "type" string } { "size" integer } }
  12 { $description "Outputs the number of bytes needed for a heap-allocated value of this C type." }
  13 { $examples
  14     "On a 32-bit system, you will get the following output:"
  15     { $unchecked-example "USE: alien\n\"void*\" heap-size ." "4" }
  16 }
  17 { $errors "Throws a " { $link no-c-type } " error if the type does not exist." } ;
  18
  19 HELP: stack-size
  20 { $values { "type" string } { "size" integer } }
  21 { $description "Outputs the number of bytes to reserve on the C stack by a value of this C type. In most cases this is equal to " { $link heap-size } ", except on some platforms where C structs are passed by invisible reference, in which case a C struct type only uses as much space as a pointer on the C stack." }
  22 { $errors "Throws a " { $link no-c-type } " error if the type does not exist." } ;
  23
  24 HELP: <c-type>
  25 { $values { "type" hashtable } }
  26 { $description "Creates a prototypical C type. User code should use higher-level facilities to define C types; see " { $link "c-data" } "." } ;
  27
  28 HELP: no-c-type
  29 { $values { "type" string } }
  30 { $description "Throws a " { $link no-c-type } " error." }
  31 { $error-description "Thrown by " { $link c-type } " if a given string does not name a C type. When thrown during compile time, indicates a typo in an " { $link alien-invoke } " or " { $link alien-callback } " form." } ;
  32
  33 HELP: c-types
  34 { $var-description "Global variable holding a hashtable mapping C type names to C types. Use the " { $link c-type } " word to look up C types." } ;
  35
  36 HELP: c-type
  37 { $values { "name" string } { "type" hashtable } }
  38 { $description "Looks up a C type by name." }
  39 { $errors "Throws a " { $link no-c-type } " error if the type does not exist." } ;
  40
  41 HELP: c-getter
  42 { $values { "name" string } { "quot" { $quotation "( c-ptr n -- obj )" } } }
  43 { $description "Outputs a quotation which reads values of this C type from a C structure." }
  44 { $errors "Throws a " { $link no-c-type } " error if the type does not exist." } ;
  45
  46 HELP: c-setter
  47 { $values { "name" string } { "quot" { $quotation "( obj c-ptr n -- )" } } }
  48 { $description "Outputs a quotation which writes values of this C type to a C structure." }
  49 { $errors "Throws an error if the type does not exist." } ;
  50
  51 HELP: box-parameter
  52 { $values { "n" integer } { "ctype" string } }
  53 { $description "Generates code for converting a C value stored at  offset " { $snippet "n" } " from the top of the stack into a Factor object to be pushed on the data stack." }
  54 { $notes "This is an internal word used by the compiler when compiling callbacks." } ;
  55
  56 HELP: box-return
  57 { $values { "ctype" string } }
  58 { $description "Generates code for converting a C value stored in return registers into a Factor object to be pushed on the data stack." }
  59 { $notes "This is an internal word used by the compiler when compiling alien calls." } ;
  60
  61 HELP: unbox-return
  62 { $values { "ctype" string } }
  63 { $description "Generates code for converting a Factor value on the data stack into a C value to be stored in the return registers." }
  64 { $notes "This is an internal word used by the compiler when compiling callbacks." } ;
  65
  66 HELP: define-deref
  67 { $values { "name" "a word name" } }
  68 { $description "Defines a word " { $snippet "*name" } " with stack effect " { $snippet "( c-ptr -- value )" } " for reading a value with C type " { $snippet "name" } " stored at an alien pointer." }
  69 { $notes "This is an internal word called when defining C types, there is no need to call it on your own." } ;
  70
  71 HELP: define-out
  72 { $values { "name" "a word name" } }
  73 { $description "Defines a word " { $snippet "<" { $emphasis "name" } ">" } " with stack effect " { $snippet "( value -- array )" } ". This word allocates a byte array large enough to hold a value with C type " { $snippet "name" } ", and writes the value at the top of the stack to the array." }
  74 { $notes "This is an internal word called when defining C types, there is no need to call it on your own." } ;
  75
  76 ARTICLE: "byte-arrays-gc" "Byte arrays and the garbage collector"
  77 "The Factor garbage collector can move byte arrays around, and it is only safe to pass byte arrays to C functions if the garbage collector will not run while C code still has a reference to the data."
  78 $nl
  79 "In particular, a byte array can only be passed as a parameter if the the C function does not use the parameter after one of the following occurs:"
  80 { $list
  81     "the C function returns"
  82     "the C function calls Factor code via a callback"
  83 }
  84 "Returning from C to Factor, as well as invoking Factor code via a callback, may trigger garbage collection, and if the function had stored a pointer to the byte array somewhere, this pointer may cease to be valid."
  85 $nl
  86 "If this condition is not satisfied, " { $link "malloc" } " must be used instead."
  87 { $warning "Failure to comply with these requirements can lead to crashes, data corruption, and security exploits." } ;
  88
  89 ARTICLE: "c-out-params" "Output parameters in C"
  90 "A frequently-occurring idiom in C code is the \"out parameter\". If a C function returns more than one value, the caller passes pointers of the correct type, and the C function writes its return values to those locations."
  91 $nl
  92 "Each numerical C type, together with " { $snippet "void*" } ", has an associated " { $emphasis "out parameter constructor" } " word which takes a Factor object as input, constructs a byte array of the correct size, and converts the Factor object to a C value stored into the byte array:"
  93 { $subsection <char> }
  94 { $subsection <uchar> }
  95 { $subsection <short> }
  96 { $subsection <ushort> }
  97 { $subsection <int> }
  98 { $subsection <uint> }
  99 { $subsection <long> }
 100 { $subsection <ulong> }
 101 { $subsection <longlong> }
 102 { $subsection <ulonglong> }
 103 { $subsection <float> }
 104 { $subsection <double> }
 105 { $subsection <void*> }
 106 "You call the out parameter constructor with the required initial value, then pass the byte array to the C function, which receives a pointer to the start of the byte array's data area. The C function then returns, leaving the result in the byte array; you read it back using the next set of words:"
 107 { $subsection *char }
 108 { $subsection *uchar }
 109 { $subsection *short }
 110 { $subsection *ushort }
 111 { $subsection *int }
 112 { $subsection *uint }
 113 { $subsection *long }
 114 { $subsection *ulong }
 115 { $subsection *longlong }
 116 { $subsection *ulonglong }
 117 { $subsection *float }
 118 { $subsection *double }
 119 { $subsection *void* }
 120 "Note that while structure and union types do not get these words defined for them, there is no loss of generality since " { $link <void*> } " and " { $link *void* } " may be used." ;
 121
 122 ARTICLE: "c-types-specs" "C type specifiers"
 123 "C types are identified by strings, and type names occur as parameters to the " { $link alien-invoke } ", " { $link alien-indirect } " and " { $link alien-callback } " words, as well as " { $link POSTPONE: C-STRUCT: } ", " { $link POSTPONE: C-UNION: } " and " { $link POSTPONE: TYPEDEF: } "."
 124 $nl
 125 "The following numerical types are available; a " { $snippet "u" } " prefix denotes an unsigned type:"
 126 { $table
 127     { "C type" "Notes" }
 128     { { $snippet "char" } "always 1 byte" }
 129     { { $snippet "uchar" } { } }
 130     { { $snippet "short" } "always 2 bytes" }
 131     { { $snippet "ushort" } { } }
 132     { { $snippet "int" } "always 4 bytes" }
 133     { { $snippet "uint" } { } }
 134     { { $snippet "long" } { "same size as CPU word size and " { $snippet "void*" } ", except on 64-bit Windows, where it is 4 bytes" } }
 135     { { $snippet "ulong" } { } }
 136     { { $snippet "longlong" } "always 8 bytes" }
 137     { { $snippet "ulonglong" } { } }
 138     { { $snippet "float" } { } }
 139     { { $snippet "double" } { "same format as " { $link float } " objects" } }
 140     { { $snippet "complex-float" } { "C99 " { $snippet "complex float" } " type, converted to and from " { $link complex } " values" } }
 141     { { $snippet "complex-double" } { "C99 " { $snippet "complex double" } " type, converted to and from " { $link complex } " values" } }
 142 }
 143 "When making alien calls, Factor numbers are converted to and from the above types in a canonical way. Converting a Factor number to a C value may result in a loss of precision."
 144 $nl
 145 "Pointer types are specified by suffixing a C type with " { $snippet "*" } ", for example " { $snippet "float*" } ". One special case is " { $snippet "void*" } ", which denotes a generic pointer; " { $snippet "void" } " by itself is not a valid C type specifier. With the exception of strings (see " { $link "c-strings" } "), all pointer types are identical to " { $snippet "void*" } " as far as the C library interface is concerned."
 146 $nl
 147 "Fixed-size array types are supported; the syntax consists of a C type name followed by dimension sizes in brackets; the following denotes a 3 by 4 array of integers:"
 148 { $code "int[3][4]" }
 149 "Fixed-size arrays differ from pointers in that they are allocated inside structures and unions; however when used as function parameters they behave exactly like pointers and thus the dimensions only serve as documentation."
 150 $nl
 151 "Structure and union types are specified by the name of the structure or union." ;