basis/alien/c-types/c-types-docs.factor

   1 USING: alien alien.complex help.syntax help.markup libc kernel.private
   2 byte-arrays strings hashtables alien.syntax alien.strings sequences
   3 io.encodings.string debugger destructors vocabs.loader
   4 classes.struct ;
   5 QUALIFIED: math
   6 IN: alien.c-types
   7
   8 HELP: byte-length
   9 { $values { "seq" "A byte array or float array" } { "n" "a non-negative integer" } }
  10 { $contract "Outputs the size of the byte array, struct, or specialized array data in bytes." } ;
  11
  12 HELP: heap-size
  13 { $values { "type" string } { "size" math:integer } }
  14 { $description "Outputs the number of bytes needed for a heap-allocated value of this C type." }
  15 { $examples
  16     "On a 32-bit system, you will get the following output:"
  17     { $unchecked-example "USE: alien\n\"void*\" heap-size ." "4" }
  18 }
  19 { $errors "Throws a " { $link no-c-type } " error if the type does not exist." } ;
  20
  21 HELP: stack-size
  22 { $values { "type" string } { "size" math:integer } }
  23 { $description "Outputs the number of bytes to reserve on the C stack by a value of this C type. In most cases this is equal to " { $link heap-size } ", except on some platforms where C structs are passed by invisible reference, in which case a C struct type only uses as much space as a pointer on the C stack." }
  24 { $errors "Throws a " { $link no-c-type } " error if the type does not exist." } ;
  25
  26 HELP: <c-type>
  27 { $values { "type" hashtable } }
  28 { $description "Creates a prototypical C type. User code should use higher-level facilities to define C types; see " { $link "c-data" } "." } ;
  29
  30 HELP: no-c-type
  31 { $values { "type" string } }
  32 { $description "Throws a " { $link no-c-type } " error." }
  33 { $error-description "Thrown by " { $link c-type } " if a given string does not name a C type. When thrown during compile time, indicates a typo in an " { $link alien-invoke } " or " { $link alien-callback } " form." } ;
  34
  35 HELP: c-types
  36 { $var-description "Global variable holding a hashtable mapping C type names to C types. Use the " { $link c-type } " word to look up C types." } ;
  37
  38 HELP: c-type
  39 { $values { "name" string } { "type" hashtable } }
  40 { $description "Looks up a C type by name." }
  41 { $errors "Throws a " { $link no-c-type } " error if the type does not exist." } ;
  42
  43 HELP: c-getter
  44 { $values { "name" string } { "quot" { $quotation "( c-ptr n -- obj )" } } }
  45 { $description "Outputs a quotation which reads values of this C type from a C structure." }
  46 { $errors "Throws a " { $link no-c-type } " error if the type does not exist." } ;
  47
  48 HELP: c-setter
  49 { $values { "name" string } { "quot" { $quotation "( obj c-ptr n -- )" } } }
  50 { $description "Outputs a quotation which writes values of this C type to a C structure." }
  51 { $errors "Throws an error if the type does not exist." } ;
  52
  53 HELP: box-parameter
  54 { $values { "n" math:integer } { "ctype" string } }
  55 { $description "Generates code for converting a C value stored at  offset " { $snippet "n" } " from the top of the stack into a Factor object to be pushed on the data stack." }
  56 { $notes "This is an internal word used by the compiler when compiling callbacks." } ;
  57
  58 HELP: box-return
  59 { $values { "ctype" string } }
  60 { $description "Generates code for converting a C value stored in return registers into a Factor object to be pushed on the data stack." }
  61 { $notes "This is an internal word used by the compiler when compiling alien calls." } ;
  62
  63 HELP: unbox-return
  64 { $values { "ctype" string } }
  65 { $description "Generates code for converting a Factor value on the data stack into a C value to be stored in the return registers." }
  66 { $notes "This is an internal word used by the compiler when compiling callbacks." } ;
  67
  68 HELP: define-deref
  69 { $values { "name" "a word name" } }
  70 { $description "Defines a word " { $snippet "*name" } " with stack effect " { $snippet "( c-ptr -- value )" } " for reading a value with C type " { $snippet "name" } " stored at an alien pointer." }
  71 { $notes "This is an internal word called when defining C types, there is no need to call it on your own." } ;
  72
  73 HELP: define-out
  74 { $values { "name" "a word name" } }
  75 { $description "Defines a word " { $snippet "<" { $emphasis "name" } ">" } " with stack effect " { $snippet "( value -- array )" } ". This word allocates a byte array large enough to hold a value with C type " { $snippet "name" } ", and writes the value at the top of the stack to the array." }
  76 { $notes "This is an internal word called when defining C types, there is no need to call it on your own." } ;
  77
  78 HELP: char
  79 { $description "This C type represents a one-byte signed integer type. Input values will be converted to " { $link math:integer } "s and truncated to eight bits; output values will be returned as " { $link math:fixnum } "s." } ;
  80 HELP: uchar
  81 { $description "This C type represents a one-byte unsigned integer type. Input values will be converted to " { $link math:integer } "s and truncated to eight bits; output values will be returned as " { $link math:fixnum } "s." } ;
  82 HELP: short
  83 { $description "This C type represents a two-byte signed integer type. Input values will be converted to " { $link math:integer } "s and truncated to sixteen bits; output values will be returned as " { $link math:fixnum } "s." } ;
  84 HELP: ushort
  85 { $description "This C type represents a two-byte unsigned integer type. Input values will be converted to " { $link math:integer } "s and truncated to sixteen bits; output values will be returned as " { $link math:fixnum } "s." } ;
  86 HELP: int
  87 { $description "This C type represents a four-byte signed integer type. Input values will be converted to " { $link math:integer } "s and truncated to 32 bits; output values will be returned as " { $link math:integer } "s." } ;
  88 HELP: uint
  89 { $description "This C type represents a four-byte unsigned integer type. Input values will be converted to " { $link math:integer } "s and truncated to 32 bits; output values will be returned as " { $link math:integer } "s." } ;
  90 HELP: long
  91 { $description "This C type represents a four- or eight-byte signed integer type. On Windows and on 32-bit Unix platforms, it will be four bytes. On 64-bit Unix platforms, it will be eight bytes. Input values will be converted to " { $link math:integer } "s and truncated to 32 or 64 bits; output values will be returned as " { $link math:integer } "s." } ;
  92 HELP: ulong
  93 { $description "This C type represents a four- or eight-byte unsigned integer type. On Windows and on 32-bit Unix platforms, it will be four bytes. On 64-bit Unix platforms, it will be eight bytes. Input values will be converted to " { $link math:integer } "s and truncated to 32 or 64 bits; output values will be returned as " { $link math:integer } "s." } ;
  94 HELP: longlong
  95 { $description "This C type represents an eight-byte signed integer type. Input values will be converted to " { $link math:integer } "s and truncated to 64 bits; output values will be returned as " { $link math:integer } "s." } ;
  96 HELP: ulonglong
  97 { $description "This C type represents an eight-byte unsigned integer type. Input values will be converted to " { $link math:integer } "s and truncated to 64 bits; output values will be returned as " { $link math:integer } "s." } ;
  98 HELP: void
  99 { $description "This symbol is not a valid C type, but it can be used as the return type for a " { $link POSTPONE: FUNCTION: } " or " { $link POSTPONE: CALLBACK: } " definition, or an " { $link alien-invoke } " or " { $link alien-callback } " call." } ;
 100 HELP: void*
 101 { $description "This C type represents a pointer to C memory. " { $link byte-array } " and " { $link alien } " values can be passed as inputs, but see " { $link "byte-arrays-gc" } " for notes about passing byte arrays into C functions. Output values are returned as " { $link alien } "s." } ;
 102 HELP: char*
 103 { $description "This C type represents a pointer to a C string. See " { $link "c-strings" } " for details about using strings with the FFI." } ;
 104 HELP: float
 105 { $description "This C type represents a single-precision IEEE 754 floating-point type. Input values will be converted to Factor " { $link math:float } "s and demoted to single-precision; output values will be returned as Factor " { $link math:float } "s." } ;
 106 HELP: double
 107 { $description "This C type represents a double-precision IEEE 754 floating-point type. Input values will be converted to Factor " { $link math:float } "s; output values will be returned as Factor " { $link math:float } "s." } ;
 108 HELP: complex-float
 109 { $description "This C type represents a single-precision IEEE 754 floating-point complex type. Input values will be converted from Factor " { $link math:complex } " objects into a single-precision complex float type; output values will be returned as Factor " { $link math:complex } " objects." } ;
 110 HELP: complex-double
 111 { $description "This C type represents a double-precision IEEE 754 floating-point complex type. Input values will be converted from Factor " { $link math:complex } " objects into a double-precision complex float type; output values will be returned as Factor " { $link math:complex } " objects." } ;
 112
 113
 114 ARTICLE: "byte-arrays-gc" "Byte arrays and the garbage collector"
 115 "The Factor garbage collector can move byte arrays around, and it is only safe to pass byte arrays to C functions if the garbage collector will not run while C code still has a reference to the data."
 116 $nl
 117 "In particular, a byte array can only be passed as a parameter if the the C function does not use the parameter after one of the following occurs:"
 118 { $list
 119     "the C function returns"
 120     "the C function calls Factor code via a callback"
 121 }
 122 "Returning from C to Factor, as well as invoking Factor code via a callback, may trigger garbage collection, and if the function had stored a pointer to the byte array somewhere, this pointer may cease to be valid."
 123 $nl
 124 "If this condition is not satisfied, " { $link "malloc" } " must be used instead."
 125 { $warning "Failure to comply with these requirements can lead to crashes, data corruption, and security exploits." } ;
 126
 127 ARTICLE: "c-out-params" "Output parameters in C"
 128 "A frequently-occurring idiom in C code is the \"out parameter\". If a C function returns more than one value, the caller passes pointers of the correct type, and the C function writes its return values to those locations."
 129 $nl
 130 "Each numerical C type, together with " { $snippet "void*" } ", has an associated " { $emphasis "out parameter constructor" } " word which takes a Factor object as input, constructs a byte array of the correct size, and converts the Factor object to a C value stored into the byte array:"
 131 { $subsection <char> }
 132 { $subsection <uchar> }
 133 { $subsection <short> }
 134 { $subsection <ushort> }
 135 { $subsection <int> }
 136 { $subsection <uint> }
 137 { $subsection <long> }
 138 { $subsection <ulong> }
 139 { $subsection <longlong> }
 140 { $subsection <ulonglong> }
 141 { $subsection <float> }
 142 { $subsection <double> }
 143 { $subsection <void*> }
 144 "You call the out parameter constructor with the required initial value, then pass the byte array to the C function, which receives a pointer to the start of the byte array's data area. The C function then returns, leaving the result in the byte array; you read it back using the next set of words:"
 145 { $subsection *char }
 146 { $subsection *uchar }
 147 { $subsection *short }
 148 { $subsection *ushort }
 149 { $subsection *int }
 150 { $subsection *uint }
 151 { $subsection *long }
 152 { $subsection *ulong }
 153 { $subsection *longlong }
 154 { $subsection *ulonglong }
 155 { $subsection *float }
 156 { $subsection *double }
 157 { $subsection *void* }
 158 "Note that while structure and union types do not get these words defined for them, there is no loss of generality since " { $link <void*> } " and " { $link *void* } " may be used." ;
 159
 160 ARTICLE: "c-types-specs" "C type specifiers"
 161 "C types are identified by special words, and type names occur as parameters to the " { $link alien-invoke } ", " { $link alien-indirect } " and " { $link alien-callback } " words. New C types can be defined by the words " { $link POSTPONE: STRUCT: } ", " { $link POSTPONE: UNION-STRUCT: } ", " { $link POSTPONE: CALLBACK: } ", and " { $link POSTPONE: TYPEDEF: } "."
 162 $nl
 163 "The following numerical types are available; a " { $snippet "u" } " prefix denotes an unsigned type:"
 164 { $table
 165     { "C type" "Notes" }
 166     { { $link char } "always 1 byte" }
 167     { { $link uchar } { } }
 168     { { $link short } "always 2 bytes" }
 169     { { $link ushort } { } }
 170     { { $link int } "always 4 bytes" }
 171     { { $link uint } { } }
 172     { { $link long } { "same size as CPU word size and " { $link void* } ", except on 64-bit Windows, where it is 4 bytes" } }
 173     { { $link ulong } { } }
 174     { { $link longlong } "always 8 bytes" }
 175     { { $link ulonglong } { } }
 176     { { $link float } { "single-precision float (not the same as Factor's " { $link math:float } " class!)" } }
 177     { { $link double } { "double-precision float (the same format as Factor's " { $link math:float } " objects)" } }
 178     { { $link complex-float } { "C99 or Fortran " { $snippet "complex float" } " type, converted to and from Factor " { $link math:complex } " values" } }
 179     { { $link complex-double } { "C99 or Fortran " { $snippet "complex double" } " type, converted to and from Factor " { $link math:complex } " values" } }
 180 }
 181 "When making alien calls, Factor numbers are converted to and from the above types in a canonical way. Converting a Factor number to a C value may result in a loss of precision."
 182 $nl
 183 "Pointer types are specified by suffixing a C type with " { $snippet "*" } ", for example " { $snippet "float*" } ". One special case is " { $link void* } ", which denotes a generic pointer; " { $link void } " by itself is not a valid C type specifier. With the exception of strings (see " { $link "c-strings" } "), all pointer types are identical to " { $snippet "void*" } " as far as the C library interface is concerned."
 184 $nl
 185 "Fixed-size array types are supported; the syntax consists of a C type name followed by dimension sizes in brackets; the following denotes a 3 by 4 array of integers:"
 186 { $code "int[3][4]" }
 187 "Fixed-size arrays differ from pointers in that they are allocated inside structures and unions; however when used as function parameters they behave exactly like pointers and thus the dimensions only serve as documentation."
 188 $nl
 189 "Structure and union types are specified by the name of the structure or union." ;