basis/alien/c-types/c-types-docs.factor

   1 USING: alien alien.complex help.syntax help.markup libc kernel.private
   2 byte-arrays strings hashtables alien.syntax alien.strings sequences
   3 io.encodings.string debugger destructors vocabs.loader
   4 classes.struct math kernel ;
   5 QUALIFIED: math
   6 QUALIFIED: sequences
   7 IN: alien.c-types
   8
   9 HELP: heap-size
  10 { $values { "name" c-type-name } { "size" math:integer } }
  11 { $description "Outputs the number of bytes needed for a heap-allocated value of this C type." }
  12 { $examples
  13     { $example "USING: alien alien.c-types prettyprint ;\nint heap-size ." "4" }
  14 }
  15 { $errors "Throws a " { $link no-c-type } " error if the type does not exist." } ;
  16
  17 HELP: <c-type>
  18 { $values { "c-type" c-type } }
  19 { $description "Creates a prototypical C type. User code should use higher-level facilities to define C types; see " { $link "c-data" } "." } ;
  20
  21 HELP: no-c-type
  22 { $values { "name" c-type-name } }
  23 { $description "Throws a " { $link no-c-type } " error." }
  24 { $error-description "Thrown by " { $link c-type } " if a given string does not name a C type. When thrown during compile time, indicates a typo in an " { $link alien-invoke } " or " { $link alien-callback } " form." } ;
  25
  26 HELP: c-type
  27 { $values { "name" c-type-name } { "c-type" c-type } }
  28 { $description "Looks up a C type by name." }
  29 { $errors "Throws a " { $link no-c-type } " error if the type does not exist, or the word is not a C type." } ;
  30
  31 HELP: alien-value
  32 { $values { "c-ptr" c-ptr } { "offset" integer } { "c-type" c-type-name } { "value" object } }
  33 { $description "Loads a value at a byte offset from a base C pointer." }
  34 { $errors "Throws a " { $link no-c-type } " error if the type does not exist." } ;
  35
  36 HELP: set-alien-value
  37 { $values { "value" object } { "c-ptr" c-ptr } { "offset" integer } { "c-type" c-type-name } }
  38 { $description "Stores a value at a byte offset from a base C pointer." }
  39 { $errors "Throws a " { $link no-c-type } " error if the type does not exist." } ;
  40
  41 HELP: define-deref
  42 { $values { "c-type" "a C type" } }
  43 { $description "Defines a word " { $snippet "*name" } " with stack effect " { $snippet "( c-ptr -- value )" } " for reading a value with C type " { $snippet "name" } " stored at an alien pointer." }
  44 { $notes "This is an internal word called when defining C types, there is no need to call it on your own." } ;
  45
  46 HELP: define-out
  47 { $values { "c-type" "a C type" } }
  48 { $description "Defines a word " { $snippet "<" { $emphasis "name" } ">" } " with stack effect " { $snippet "( value -- array )" } ". This word allocates a byte array large enough to hold a value with C type " { $snippet "name" } ", and writes the value at the top of the stack to the array." }
  49 { $notes "This is an internal word called when defining C types, there is no need to call it on your own." } ;
  50
  51 HELP: char
  52 { $description "This C type represents a one-byte signed integer type. Input values will be converted to " { $link math:integer } "s and truncated to eight bits; output values will be returned as " { $link math:fixnum } "s." } ;
  53 HELP: uchar
  54 { $description "This C type represents a one-byte unsigned integer type. Input values will be converted to " { $link math:integer } "s and truncated to eight bits; output values will be returned as " { $link math:fixnum } "s." } ;
  55 HELP: short
  56 { $description "This C type represents a two-byte signed integer type. Input values will be converted to " { $link math:integer } "s and truncated to sixteen bits; output values will be returned as " { $link math:fixnum } "s." } ;
  57 HELP: ushort
  58 { $description "This C type represents a two-byte unsigned integer type. Input values will be converted to " { $link math:integer } "s and truncated to sixteen bits; output values will be returned as " { $link math:fixnum } "s." } ;
  59 HELP: int
  60 { $description "This C type represents a four-byte signed integer type. Input values will be converted to " { $link math:integer } "s and truncated to 32 bits; output values will be returned as " { $link math:integer } "s." } ;
  61 HELP: uint
  62 { $description "This C type represents a four-byte unsigned integer type. Input values will be converted to " { $link math:integer } "s and truncated to 32 bits; output values will be returned as " { $link math:integer } "s." } ;
  63 HELP: long
  64 { $description "This C type represents a four- or eight-byte signed integer type. On Windows and on 32-bit Unix platforms, it will be four bytes. On 64-bit Unix platforms, it will be eight bytes. Input values will be converted to " { $link math:integer } "s and truncated to 32 or 64 bits; output values will be returned as " { $link math:integer } "s." } ;
  65 HELP: intptr_t
  66 { $description "This C type represents a signed integer type large enough to hold any pointer value; that is, on 32-bit platforms, it will be four bytes, and on 64-bit platforms, it will be eight bytes. Input values will be converted to " { $link math:integer } "s and truncated to 32 or 64 bits; output values will be returned as " { $link math:integer } "s." } ;
  67 HELP: ulong
  68 { $description "This C type represents a four- or eight-byte unsigned integer type. On Windows and on 32-bit Unix platforms, it will be four bytes. On 64-bit Unix platforms, it will be eight bytes. Input values will be converted to " { $link math:integer } "s and truncated to 32 or 64 bits; output values will be returned as " { $link math:integer } "s." } ;
  69 HELP: uintptr_t
  70 { $description "This C type represents an unsigned integer type large enough to hold any pointer value; that is, on 32-bit platforms, it will be four bytes, and on 64-bit platforms, it will be eight bytes. Input values will be converted to " { $link math:integer } "s and truncated to 32 or 64 bits; output values will be returned as " { $link math:integer } "s." } ;
  71 HELP: ptrdiff_t
  72 { $description "This C type represents a signed integer type large enough to hold the distance between two pointer values; that is, on 32-bit platforms, it will be four bytes, and on 64-bit platforms, it will be eight bytes. Input values will be converted to " { $link math:integer } "s and truncated to 32 or 64 bits; output values will be returned as " { $link math:integer } "s." } ;
  73 HELP: size_t
  74 { $description "This C type represents unsigned size values of the size expected by the platform's standard C library (usually four bytes on a 32-bit platform, and eight on a 64-bit platform). Input values will be converted to " { $link math:integer } "s and truncated to the appropriate size; output values will be returned as " { $link math:integer } "s." } ;
  75 HELP: longlong
  76 { $description "This C type represents an eight-byte signed integer type. Input values will be converted to " { $link math:integer } "s and truncated to 64 bits; output values will be returned as " { $link math:integer } "s." } ;
  77 HELP: ulonglong
  78 { $description "This C type represents an eight-byte unsigned integer type. Input values will be converted to " { $link math:integer } "s and truncated to 64 bits; output values will be returned as " { $link math:integer } "s." } ;
  79 HELP: void
  80 { $description "This symbol is not a valid C type, but it can be used as the return type for a " { $link POSTPONE: FUNCTION: } " or " { $link POSTPONE: CALLBACK: } " definition or for an " { $link alien-invoke } " or " { $link alien-callback } " call." } ;
  81 HELP: void*
  82 { $description "This C type represents a generic pointer to C memory. See " { $link pointer } " for information on pointer C types." } ;
  83 HELP: c-string
  84 { $description "This C type represents a pointer to a C string. See " { $link "c-strings" } " for details about using strings with the FFI." } ;
  85 HELP: float
  86 { $description "This C type represents a single-precision IEEE 754 floating-point type. Input values will be converted to Factor " { $link math:float } "s and demoted to single-precision; output values will be returned as Factor " { $link math:float } "s." } ;
  87 HELP: double
  88 { $description "This C type represents a double-precision IEEE 754 floating-point type. Input values will be converted to Factor " { $link math:float } "s; output values will be returned as Factor " { $link math:float } "s." } ;
  89 HELP: complex-float
  90 { $description "This C type represents a single-precision IEEE 754 floating-point complex type. Input values will be converted from Factor " { $link math:complex } " objects into a single-precision complex float type; output values will be returned as Factor " { $link math:complex } " objects." } ;
  91 HELP: complex-double
  92 { $description "This C type represents a double-precision IEEE 754 floating-point complex type. Input values will be converted from Factor " { $link math:complex } " objects into a double-precision complex float type; output values will be returned as Factor " { $link math:complex } " objects." } ;
  93
  94 HELP: pointer:
  95 { $syntax "pointer: c-type" }
  96 { $description "Constructs a " { $link pointer } " C type." } ;
  97
  98 HELP: pointer
  99 { $class-description "Represents a pointer C type. The " { $snippet "to" } " slot contains the C type being pointed to." { $link byte-array } " and " { $link alien } " values can be provided as pointer function inputs, but see " { $link "byte-arrays-gc" } " for notes about passing byte arrays into C functions. Objects with methods on " { $link >c-ptr } ", such as structs and specialized arrays, may also be used as pointer inputs."
 100 $nl
 101 "Pointer output values are represented in Factor as " { $link alien } "s. If the pointed-to type is a struct, the alien will automatically be wrapped in a struct object if it is not null."
 102 $nl
 103 "In " { $link POSTPONE: TYPEDEF: } ", " { $link POSTPONE: FUNCTION: } ", " { $link POSTPONE: CALLBACK: } ", and " { $link POSTPONE: STRUCT: } " definitions, pointer types can be created by suffixing " { $snippet "*" } " to a C type name. Outside of FFI definitions, a pointer C type can be created using the " { $link POSTPONE: pointer: } " syntax word:"
 104 { $unchecked-example "FUNCTION: int* foo ( char* bar ) ;" }
 105 { $unchecked-example """: foo ( bar -- int* )
 106     pointer: int f \"foo\" { pointer: char } alien-invoke ;""" } } ;
 107
 108 ARTICLE: "byte-arrays-gc" "Byte arrays and the garbage collector"
 109 "The Factor garbage collector can move byte arrays around, and it is only safe to pass byte arrays to C functions if the garbage collector will not run while C code still has a reference to the data."
 110 $nl
 111 "In particular, a byte array can only be passed as a parameter if the the C function does not use the parameter after one of the following occurs:"
 112 { $list
 113     "the C function returns"
 114     "the C function calls Factor code via a callback"
 115 }
 116 "Returning from C to Factor, as well as invoking Factor code via a callback, may trigger garbage collection, and if the function had stored a pointer to the byte array somewhere, this pointer may cease to be valid."
 117 $nl
 118 "If this condition is not satisfied, " { $link "malloc" } " must be used instead."
 119 { $warning "Failure to comply with these requirements can lead to crashes, data corruption, and security exploits." } ;
 120
 121 ARTICLE: "c-out-params" "Output parameters in C"
 122 "A frequently-occurring idiom in C code is the \"out parameter\". If a C function returns more than one value, the caller passes pointers of the correct type, and the C function writes its return values to those locations."
 123 $nl
 124 "To wrap Factor data for consumption by the FFI, we use a utility word that constructs a byte array of the correct size and converts the Factor object to a C value stored into that byte array:"
 125 { $subsections <ref> }
 126 "You call the out parameter constructor with the required initial value, then pass the byte array to the C function, which receives a pointer to the start of the byte array's data area. The C function then returns, leaving the result in the byte array; you read it back using this word:"
 127 { $subsections deref } ;
 128
 129 ARTICLE: "c-types.primitives" "Primitive C types"
 130 "The following numerical types are defined in the " { $vocab-link "alien.c-types" } " vocabulary; a " { $snippet "u" } " prefix denotes an unsigned type:"
 131 { $table
 132     { "C type" "Notes" }
 133     { { $link char } "always 1 byte" }
 134     { { $link uchar } { } }
 135     { { $link short } "always 2 bytes" }
 136     { { $link ushort } { } }
 137     { { $link int } "always 4 bytes" }
 138     { { $link uint } { } }
 139     { { $link long } { "same size as CPU word size and " { $link void* } ", except on 64-bit Windows, where it is 4 bytes" } }
 140     { { $link ulong } { } }
 141     { { $link longlong } "always 8 bytes" }
 142     { { $link ulonglong } { } }
 143     { { $link float } { "single-precision float (not the same as Factor's " { $link math:float } " class!)" } }
 144     { { $link double } { "double-precision float (the same format as Factor's " { $link math:float } " objects)" } }
 145 }
 146 "The following C99 complex number types are defined in the " { $vocab-link "alien.complex" } " vocabulary:"
 147 { $table
 148     { { $link complex-float } { "C99 or Fortran " { $snippet "complex float" } " type, converted to and from Factor " { $link math:complex } " values" } }
 149     { { $link complex-double } { "C99 or Fortran " { $snippet "complex double" } " type, converted to and from Factor " { $link math:complex } " values" } }
 150 }
 151 "When making alien calls, Factor numbers are converted to and from the above types in a canonical way. Converting a Factor number to a C value may result in a loss of precision." ;
 152
 153 ARTICLE: "c-types.pointers" "Pointer and array types"
 154 "Pointer types are specified by suffixing a C type with " { $snippet "*" } ", for example " { $snippet "float*" } ". One special case is " { $link void* } ", which denotes a generic pointer; " { $link void } " by itself is not a valid C type specifier. This syntax constructs a " { $link pointer } " object to represent the C type."
 155 $nl
 156 "Fixed-size array types are supported; the syntax consists of a C type name followed by dimension sizes in brackets; the following denotes a 3 by 4 array of integers:"
 157 { $code "int[3][4]" }
 158 "Fixed-size arrays differ from pointers in that they are allocated inside structures and unions; however, when used as function parameters, they behave exactly like pointers with the dimensions only serving as documentation." ;
 159
 160 ARTICLE: "c-types.ambiguity" "Word name clashes with C types"
 161 "Note that some of the C type word names clash with commonly-used Factor words:"
 162 { $list
 163   { { $link short } " clashes with the " { $link sequences:short } " word in the " { $vocab-link "sequences" } " vocabulary" }
 164   { { $link float } " clashes with the " { $link math:float } " word in the " { $vocab-link "math" } " vocabulary" }
 165 }
 166 "If you use the wrong vocabulary, you will see a " { $link no-c-type } " error. For example, the following is " { $strong "not" } " valid, and will raise an error because the " { $link math:float } " word from the " { $vocab-link "math" } " vocabulary is not a C type:"
 167 { $code
 168   "USING: alien.syntax math prettyprint ;"
 169   "FUNCTION: float magic_number ( ) ;"
 170   "magic_number 3.0 + ."
 171 }
 172 "The following won't work either; now the problem is that there are two vocabularies in the search path that define a word named " { $snippet "float" } ":"
 173 { $code
 174   "USING: alien.c-types alien.syntax math prettyprint ;"
 175   "FUNCTION: float magic_number ( ) ;"
 176   "magic_number 3.0 + ."
 177 }
 178 "The correct solution is to use one of " { $link POSTPONE: FROM: } ", " { $link POSTPONE: QUALIFIED: } " or " { $link POSTPONE: QUALIFIED-WITH: } " to disambiguate word lookup:"
 179 { $code
 180   "USING: alien.syntax math prettyprint ;"
 181   "QUALIFIED-WITH: alien.c-types c"
 182   "FUNCTION: c:float magic_number ( ) ;"
 183   "magic_number 3.0 + ."
 184 }
 185 "See " { $link "word-search-semantics" } " for details." ;
 186
 187 ARTICLE: "c-types.structs" "Struct and union types"
 188 "Struct and union types are identified by their class word. See " { $link "classes.struct" } "." ;
 189
 190 ARTICLE: "c-types-specs" "C type specifiers"
 191 "C types are identified by special words. Type names occur as parameters to the " { $link alien-invoke } ", " { $link alien-indirect } " and " { $link alien-callback } " words."
 192 $nl
 193 "Defining new C types:"
 194 { $subsections
 195     POSTPONE: STRUCT:
 196     POSTPONE: UNION-STRUCT:
 197     POSTPONE: CALLBACK:
 198     POSTPONE: TYPEDEF:
 199 }
 200 { $heading "Related articles" }
 201 { $subsections
 202     "c-types.primitives"
 203     "c-types.pointers"
 204     "c-types.ambiguity"
 205     "c-types.structs"
 206 }
 207 ;
 208
 209 ABOUT: "c-types-specs"