basis/alien/c-types/c-types-docs.factor

   1 USING: alien alien.complex help.syntax help.markup libc kernel.private
   2 byte-arrays strings hashtables alien.syntax alien.strings sequences
   3 io.encodings.string debugger destructors vocabs.loader
   4 classes.struct ;
   5 QUALIFIED: math
   6 QUALIFIED: sequences
   7 IN: alien.c-types
   8
   9 HELP: byte-length
  10 { $values { "seq" "A byte array or float array" } { "n" "a non-negative integer" } }
  11 { $contract "Outputs the size of the byte array, struct, or specialized array data in bytes." } ;
  12
  13 HELP: heap-size
  14 { $values { "name" "a C type name" } { "size" math:integer } }
  15 { $description "Outputs the number of bytes needed for a heap-allocated value of this C type." }
  16 { $examples
  17     { $example "USING: alien alien.c-types prettyprint ;\nint heap-size ." "4" }
  18 }
  19 { $errors "Throws a " { $link no-c-type } " error if the type does not exist." } ;
  20
  21 HELP: stack-size
  22 { $values { "name" "a C type name" } { "size" math:integer } }
  23 { $description "Outputs the number of bytes to reserve on the C stack by a value of this C type. In most cases this is equal to " { $link heap-size } ", except on some platforms where C structs are passed by invisible reference, in which case a C struct type only uses as much space as a pointer on the C stack." }
  24 { $errors "Throws a " { $link no-c-type } " error if the type does not exist." } ;
  25
  26 HELP: <c-type>
  27 { $values { "c-type" c-type } }
  28 { $description "Creates a prototypical C type. User code should use higher-level facilities to define C types; see " { $link "c-data" } "." } ;
  29
  30 HELP: no-c-type
  31 { $values { "name" "a C type name" } }
  32 { $description "Throws a " { $link no-c-type } " error." }
  33 { $error-description "Thrown by " { $link c-type } " if a given string does not name a C type. When thrown during compile time, indicates a typo in an " { $link alien-invoke } " or " { $link alien-callback } " form." } ;
  34
  35 HELP: c-types
  36 { $var-description "Global variable holding a hashtable mapping C type names to C types. Use the " { $link c-type } " word to look up C types." } ;
  37
  38 HELP: c-type
  39 { $values { "name" "a C type" } { "c-type" c-type } }
  40 { $description "Looks up a C type by name." }
  41 { $errors "Throws a " { $link no-c-type } " error if the type does not exist." } ;
  42
  43 HELP: c-getter
  44 { $values { "name" "a C type" } { "quot" { $quotation "( c-ptr n -- obj )" } } }
  45 { $description "Outputs a quotation which reads values of this C type from a C structure." }
  46 { $errors "Throws a " { $link no-c-type } " error if the type does not exist." } ;
  47
  48 HELP: c-setter
  49 { $values { "name" "a C type" } { "quot" { $quotation "( obj c-ptr n -- )" } } }
  50 { $description "Outputs a quotation which writes values of this C type to a C structure." }
  51 { $errors "Throws an error if the type does not exist." } ;
  52
  53 HELP: box-parameter
  54 { $values { "n" math:integer } { "c-type" "a C type" } }
  55 { $description "Generates code for converting a C value stored at  offset " { $snippet "n" } " from the top of the stack into a Factor object to be pushed on the data stack." }
  56 { $notes "This is an internal word used by the compiler when compiling callbacks." } ;
  57
  58 HELP: box-return
  59 { $values { "c-type" "a C type" } }
  60 { $description "Generates code for converting a C value stored in return registers into a Factor object to be pushed on the data stack." }
  61 { $notes "This is an internal word used by the compiler when compiling alien calls." } ;
  62
  63 HELP: unbox-return
  64 { $values { "c-type" "a C type" } }
  65 { $description "Generates code for converting a Factor value on the data stack into a C value to be stored in the return registers." }
  66 { $notes "This is an internal word used by the compiler when compiling callbacks." } ;
  67
  68 HELP: define-deref
  69 { $values { "c-type" "a C type" } }
  70 { $description "Defines a word " { $snippet "*name" } " with stack effect " { $snippet "( c-ptr -- value )" } " for reading a value with C type " { $snippet "name" } " stored at an alien pointer." }
  71 { $notes "This is an internal word called when defining C types, there is no need to call it on your own." } ;
  72
  73 HELP: define-out
  74 { $values { "c-type" "a C type" } }
  75 { $description "Defines a word " { $snippet "<" { $emphasis "name" } ">" } " with stack effect " { $snippet "( value -- array )" } ". This word allocates a byte array large enough to hold a value with C type " { $snippet "name" } ", and writes the value at the top of the stack to the array." }
  76 { $notes "This is an internal word called when defining C types, there is no need to call it on your own." } ;
  77
  78 HELP: char
  79 { $description "This C type represents a one-byte signed integer type. Input values will be converted to " { $link math:integer } "s and truncated to eight bits; output values will be returned as " { $link math:fixnum } "s." } ;
  80 HELP: uchar
  81 { $description "This C type represents a one-byte unsigned integer type. Input values will be converted to " { $link math:integer } "s and truncated to eight bits; output values will be returned as " { $link math:fixnum } "s." } ;
  82 HELP: short
  83 { $description "This C type represents a two-byte signed integer type. Input values will be converted to " { $link math:integer } "s and truncated to sixteen bits; output values will be returned as " { $link math:fixnum } "s." } ;
  84 HELP: ushort
  85 { $description "This C type represents a two-byte unsigned integer type. Input values will be converted to " { $link math:integer } "s and truncated to sixteen bits; output values will be returned as " { $link math:fixnum } "s." } ;
  86 HELP: int
  87 { $description "This C type represents a four-byte signed integer type. Input values will be converted to " { $link math:integer } "s and truncated to 32 bits; output values will be returned as " { $link math:integer } "s." } ;
  88 HELP: uint
  89 { $description "This C type represents a four-byte unsigned integer type. Input values will be converted to " { $link math:integer } "s and truncated to 32 bits; output values will be returned as " { $link math:integer } "s." } ;
  90 HELP: long
  91 { $description "This C type represents a four- or eight-byte signed integer type. On Windows and on 32-bit Unix platforms, it will be four bytes. On 64-bit Unix platforms, it will be eight bytes. Input values will be converted to " { $link math:integer } "s and truncated to 32 or 64 bits; output values will be returned as " { $link math:integer } "s." } ;
  92 HELP: intptr_t
  93 { $description "This C type represents a signed integer type large enough to hold any pointer value; that is, on 32-bit platforms, it will be four bytes, and on 64-bit platforms, it will be eight bytes. Input values will be converted to " { $link math:integer } "s and truncated to 32 or 64 bits; output values will be returned as " { $link math:integer } "s." } ;
  94 HELP: ulong
  95 { $description "This C type represents a four- or eight-byte unsigned integer type. On Windows and on 32-bit Unix platforms, it will be four bytes. On 64-bit Unix platforms, it will be eight bytes. Input values will be converted to " { $link math:integer } "s and truncated to 32 or 64 bits; output values will be returned as " { $link math:integer } "s." } ;
  96 HELP: uintptr_t
  97 { $description "This C type represents an unsigned integer type large enough to hold any pointer value; that is, on 32-bit platforms, it will be four bytes, and on 64-bit platforms, it will be eight bytes. Input values will be converted to " { $link math:integer } "s and truncated to 32 or 64 bits; output values will be returned as " { $link math:integer } "s." } ;
  98 HELP: ptrdiff_t
  99 { $description "This C type represents a signed integer type large enough to hold the distance between two pointer values; that is, on 32-bit platforms, it will be four bytes, and on 64-bit platforms, it will be eight bytes. Input values will be converted to " { $link math:integer } "s and truncated to 32 or 64 bits; output values will be returned as " { $link math:integer } "s." } ;
 100 HELP: size_t
 101 { $description "This C type represents unsigned size values of the size expected by the platform's standard C library (usually four bytes on a 32-bit platform, and eight on a 64-bit platform). Input values will be converted to " { $link math:integer } "s and truncated to the appropriate size; output values will be returned as " { $link math:integer } "s." } ;
 102 HELP: longlong
 103 { $description "This C type represents an eight-byte signed integer type. Input values will be converted to " { $link math:integer } "s and truncated to 64 bits; output values will be returned as " { $link math:integer } "s." } ;
 104 HELP: ulonglong
 105 { $description "This C type represents an eight-byte unsigned integer type. Input values will be converted to " { $link math:integer } "s and truncated to 64 bits; output values will be returned as " { $link math:integer } "s." } ;
 106 HELP: void
 107 { $description "This symbol is not a valid C type, but it can be used as the return type for a " { $link POSTPONE: FUNCTION: } " or " { $link POSTPONE: CALLBACK: } " definition or for an " { $link alien-invoke } " or " { $link alien-callback } " call." } ;
 108 HELP: void*
 109 { $description "This C type represents a pointer to C memory. " { $link byte-array } " and " { $link alien } " values can be passed as " { $snippet "void*" } " function inputs, but see " { $link "byte-arrays-gc" } " for notes about passing byte arrays into C functions. " { $snippet "void*" } " output values are returned as " { $link alien } "s." } ;
 110 HELP: char*
 111 { $description "This C type represents a pointer to a C string. See " { $link "c-strings" } " for details about using strings with the FFI." } ;
 112 HELP: float
 113 { $description "This C type represents a single-precision IEEE 754 floating-point type. Input values will be converted to Factor " { $link math:float } "s and demoted to single-precision; output values will be returned as Factor " { $link math:float } "s." } ;
 114 HELP: double
 115 { $description "This C type represents a double-precision IEEE 754 floating-point type. Input values will be converted to Factor " { $link math:float } "s; output values will be returned as Factor " { $link math:float } "s." } ;
 116 HELP: complex-float
 117 { $description "This C type represents a single-precision IEEE 754 floating-point complex type. Input values will be converted from Factor " { $link math:complex } " objects into a single-precision complex float type; output values will be returned as Factor " { $link math:complex } " objects." } ;
 118 HELP: complex-double
 119 { $description "This C type represents a double-precision IEEE 754 floating-point complex type. Input values will be converted from Factor " { $link math:complex } " objects into a double-precision complex float type; output values will be returned as Factor " { $link math:complex } " objects." } ;
 120
 121
 122 ARTICLE: "byte-arrays-gc" "Byte arrays and the garbage collector"
 123 "The Factor garbage collector can move byte arrays around, and it is only safe to pass byte arrays to C functions if the garbage collector will not run while C code still has a reference to the data."
 124 $nl
 125 "In particular, a byte array can only be passed as a parameter if the the C function does not use the parameter after one of the following occurs:"
 126 { $list
 127     "the C function returns"
 128     "the C function calls Factor code via a callback"
 129 }
 130 "Returning from C to Factor, as well as invoking Factor code via a callback, may trigger garbage collection, and if the function had stored a pointer to the byte array somewhere, this pointer may cease to be valid."
 131 $nl
 132 "If this condition is not satisfied, " { $link "malloc" } " must be used instead."
 133 { $warning "Failure to comply with these requirements can lead to crashes, data corruption, and security exploits." } ;
 134
 135 ARTICLE: "c-out-params" "Output parameters in C"
 136 "A frequently-occurring idiom in C code is the \"out parameter\". If a C function returns more than one value, the caller passes pointers of the correct type, and the C function writes its return values to those locations."
 137 $nl
 138 "Each numerical C type, together with " { $snippet "void*" } ", has an associated " { $emphasis "out parameter constructor" } " word which takes a Factor object as input, constructs a byte array of the correct size, and converts the Factor object to a C value stored into the byte array:"
 139 { $subsections
 140     <char>
 141     <uchar>
 142     <short>
 143     <ushort>
 144     <int>
 145     <uint>
 146     <long>
 147     <ulong>
 148     <longlong>
 149     <ulonglong>
 150     <float>
 151     <double>
 152     <void*>
 153 }
 154 "You call the out parameter constructor with the required initial value, then pass the byte array to the C function, which receives a pointer to the start of the byte array's data area. The C function then returns, leaving the result in the byte array; you read it back using the next set of words:"
 155 { $subsections
 156     *char
 157     *uchar
 158     *short
 159     *ushort
 160     *int
 161     *uint
 162     *long
 163     *ulong
 164     *longlong
 165     *ulonglong
 166     *float
 167     *double
 168     *void*
 169 }
 170 "Note that while structure and union types do not get these words defined for them, there is no loss of generality since " { $link <void*> } " and " { $link *void* } " may be used." ;
 171
 172 ARTICLE: "c-types.primitives" "Primitive C types"
 173 "The following numerical types are defined in the " { $vocab-link "alien.c-types" } " vocabulary; a " { $snippet "u" } " prefix denotes an unsigned type:"
 174 { $table
 175     { "C type" "Notes" }
 176     { { $link char } "always 1 byte" }
 177     { { $link uchar } { } }
 178     { { $link short } "always 2 bytes" }
 179     { { $link ushort } { } }
 180     { { $link int } "always 4 bytes" }
 181     { { $link uint } { } }
 182     { { $link long } { "same size as CPU word size and " { $link void* } ", except on 64-bit Windows, where it is 4 bytes" } }
 183     { { $link ulong } { } }
 184     { { $link longlong } "always 8 bytes" }
 185     { { $link ulonglong } { } }
 186     { { $link float } { "single-precision float (not the same as Factor's " { $link math:float } " class!)" } }
 187     { { $link double } { "double-precision float (the same format as Factor's " { $link math:float } " objects)" } }
 188 }
 189 "The following C99 complex number types are defined in the " { $vocab-link "alien.complex" } " vocabulary:"
 190 { $table
 191     { { $link complex-float } { "C99 or Fortran " { $snippet "complex float" } " type, converted to and from Factor " { $link math:complex } " values" } }
 192     { { $link complex-double } { "C99 or Fortran " { $snippet "complex double" } " type, converted to and from Factor " { $link math:complex } " values" } }
 193 }
 194 "When making alien calls, Factor numbers are converted to and from the above types in a canonical way. Converting a Factor number to a C value may result in a loss of precision." ;
 195
 196 ARTICLE: "c-types.pointers" "Pointer and array types"
 197 "Pointer types are specified by suffixing a C type with " { $snippet "*" } ", for example " { $snippet "float*" } ". One special case is " { $link void* } ", which denotes a generic pointer; " { $link void } " by itself is not a valid C type specifier. With the exception of strings (see " { $link "c-strings" } "), all pointer types are identical to " { $snippet "void*" } " as far as the C library interface is concerned."
 198 $nl
 199 "Fixed-size array types are supported; the syntax consists of a C type name followed by dimension sizes in brackets; the following denotes a 3 by 4 array of integers:"
 200 { $code "int[3][4]" }
 201 "Fixed-size arrays differ from pointers in that they are allocated inside structures and unions; however when used as function parameters they behave exactly like pointers and thus the dimensions only serve as documentation." ;
 202
 203 ARTICLE: "c-types.ambiguity" "Word name clashes with C types"
 204 "Note that some of the C type word names clash with commonly-used Factor words:"
 205 { $list
 206   { { $link short } " clashes with the " { $link sequences:short } " word in the " { $vocab-link "sequences" } " vocabulary" }
 207   { { $link float } " clashes with the " { $link math:float } " word in the " { $vocab-link "math" } " vocabulary" }
 208 }
 209 "If you use the wrong vocabulary, you will see a " { $link no-c-type } " error. For example, the following is " { $strong "not" } " valid, and will raise an error because the " { $link math:float } " word from the " { $vocab-link "math" } " vocabulary is not a C type:"
 210 { $code
 211   "USING: alien.syntax math prettyprint ;"
 212   "FUNCTION: float magic_number ( ) ;"
 213   "magic_number 3.0 + ."
 214 }
 215 "The following won't work either; now the problem is that there are two vocabularies in the search path that define a word named " { $snippet "float" } ":"
 216 { $code
 217   "USING: alien.c-types alien.syntax math prettyprint ;"
 218   "FUNCTION: float magic_number ( ) ;"
 219   "magic_number 3.0 + ."
 220 }
 221 "The correct solution is to use one of " { $link POSTPONE: FROM: } ", " { $link POSTPONE: QUALIFIED: } " or " { $link POSTPONE: QUALIFIED-WITH: } " to disambiguate word lookup:"
 222 { $code
 223   "USING: alien.syntax math prettyprint ;"
 224   "QUALIFIED-WITH: alien.c-types c"
 225   "FUNCTION: c:float magic_number ( ) ;"
 226   "magic_number 3.0 + ."
 227 }
 228 "See " { $link "word-search-semantics" } " for details." ;
 229
 230 ARTICLE: "c-types.structs" "Struct and union types"
 231 "Struct and union types are identified by their class word. See " { $link "classes.struct" } "." ;
 232
 233 ARTICLE: "c-types-specs" "C type specifiers"
 234 "C types are identified by special words, and type names occur as parameters to the " { $link alien-invoke } ", " { $link alien-indirect } " and " { $link alien-callback } " words."
 235 $nl
 236 "Defining new C types:"
 237 { $subsections
 238     POSTPONE: STRUCT:
 239     POSTPONE: UNION-STRUCT:
 240     POSTPONE: CALLBACK:
 241     POSTPONE: TYPEDEF:
 242 }
 243 { $heading "Related articles" }
 244 { $subsections
 245     "c-types.primitives"
 246     "c-types.pointers"
 247     "c-types.ambiguity"
 248     "c-types.structs"
 249 }
 250 ;
 251
 252 ABOUT: "c-types-specs"