basis/alien/c-types/c-types-docs.factor

   1 USING: alien alien.complex help.syntax help.markup libc kernel.private
   2 byte-arrays strings hashtables alien.syntax alien.strings sequences
   3 io.encodings.string debugger destructors vocabs.loader
   4 classes.struct math kernel ;
   5 QUALIFIED: math
   6 QUALIFIED: sequences
   7 IN: alien.c-types
   8
   9 HELP: heap-size
  10 { $values { "name" c-type-name } { "size" math:integer } }
  11 { $description "Outputs the number of bytes needed for a heap-allocated value of this C type." }
  12 { $examples
  13     { $example "USING: alien alien.c-types prettyprint ;\nint heap-size ." "4" }
  14 }
  15 { $errors "Throws a " { $link no-c-type } " error if the type does not exist." } ;
  16
  17 HELP: <c-type>
  18 { $values { "c-type" c-type } }
  19 { $description "Creates a prototypical C type. User code should use higher-level facilities to define C types; see " { $link "c-data" } "." } ;
  20
  21 HELP: no-c-type
  22 { $values { "name" c-type-name } }
  23 { $description "Throws a " { $link no-c-type } " error." }
  24 { $error-description "Thrown by " { $link c-type } " if a given word is not a C type." } ;
  25
  26 HELP: c-type
  27 { $values { "name" c-type-name } { "c-type" c-type } }
  28 { $description "Looks up a C type by name." }
  29 { $errors "Throws a " { $link no-c-type } " error if the type does not exist, or the word is not a C type." } ;
  30
  31 HELP: alien-value
  32 { $values { "c-ptr" c-ptr } { "offset" integer } { "c-type" c-type-name } { "value" object } }
  33 { $description "Loads a value at a byte offset from a base C pointer." }
  34 { $errors "Throws a " { $link no-c-type } " error if the type does not exist." } ;
  35
  36 HELP: set-alien-value
  37 { $values { "value" object } { "c-ptr" c-ptr } { "offset" integer } { "c-type" c-type-name } }
  38 { $description "Stores a value at a byte offset from a base C pointer." }
  39 { $errors "Throws a " { $link no-c-type } " error if the type does not exist." } ;
  40
  41 HELP: char
  42 { $description "This C type represents a one-byte signed integer type. Input values will be converted to " { $link math:integer } "s and truncated to eight bits; output values will be returned as " { $link math:fixnum } "s." } ;
  43 HELP: uchar
  44 { $description "This C type represents a one-byte unsigned integer type. Input values will be converted to " { $link math:integer } "s and truncated to eight bits; output values will be returned as " { $link math:fixnum } "s." } ;
  45 HELP: short
  46 { $description "This C type represents a two-byte signed integer type. Input values will be converted to " { $link math:integer } "s and truncated to sixteen bits; output values will be returned as " { $link math:fixnum } "s." } ;
  47 HELP: ushort
  48 { $description "This C type represents a two-byte unsigned integer type. Input values will be converted to " { $link math:integer } "s and truncated to sixteen bits; output values will be returned as " { $link math:fixnum } "s." } ;
  49 HELP: int
  50 { $description "This C type represents a four-byte signed integer type. Input values will be converted to " { $link math:integer } "s and truncated to 32 bits; output values will be returned as " { $link math:integer } "s." } ;
  51 HELP: uint
  52 { $description "This C type represents a four-byte unsigned integer type. Input values will be converted to " { $link math:integer } "s and truncated to 32 bits; output values will be returned as " { $link math:integer } "s." } ;
  53 HELP: long
  54 { $description "This C type represents a four- or eight-byte signed integer type. On Windows and on 32-bit Unix platforms, it will be four bytes. On 64-bit Unix platforms, it will be eight bytes. Input values will be converted to " { $link math:integer } "s and truncated to 32 or 64 bits; output values will be returned as " { $link math:integer } "s." } ;
  55 HELP: intptr_t
  56 { $description "This C type represents a signed integer type large enough to hold any pointer value; that is, on 32-bit platforms, it will be four bytes, and on 64-bit platforms, it will be eight bytes. Input values will be converted to " { $link math:integer } "s and truncated to 32 or 64 bits; output values will be returned as " { $link math:integer } "s." } ;
  57 HELP: ulong
  58 { $description "This C type represents a four- or eight-byte unsigned integer type. On Windows and on 32-bit Unix platforms, it will be four bytes. On 64-bit Unix platforms, it will be eight bytes. Input values will be converted to " { $link math:integer } "s and truncated to 32 or 64 bits; output values will be returned as " { $link math:integer } "s." } ;
  59 HELP: uintptr_t
  60 { $description "This C type represents an unsigned integer type large enough to hold any pointer value; that is, on 32-bit platforms, it will be four bytes, and on 64-bit platforms, it will be eight bytes. Input values will be converted to " { $link math:integer } "s and truncated to 32 or 64 bits; output values will be returned as " { $link math:integer } "s." } ;
  61 HELP: ptrdiff_t
  62 { $description "This C type represents a signed integer type large enough to hold the distance between two pointer values; that is, on 32-bit platforms, it will be four bytes, and on 64-bit platforms, it will be eight bytes. Input values will be converted to " { $link math:integer } "s and truncated to 32 or 64 bits; output values will be returned as " { $link math:integer } "s." } ;
  63 HELP: size_t
  64 { $description "This C type represents unsigned size values of the size expected by the platform's standard C library (usually four bytes on a 32-bit platform, and eight on a 64-bit platform). Input values will be converted to " { $link math:integer } "s and truncated to the appropriate size; output values will be returned as " { $link math:integer } "s." } ;
  65 HELP: longlong
  66 { $description "This C type represents an eight-byte signed integer type. Input values will be converted to " { $link math:integer } "s and truncated to 64 bits; output values will be returned as " { $link math:integer } "s." } ;
  67 HELP: ulonglong
  68 { $description "This C type represents an eight-byte unsigned integer type. Input values will be converted to " { $link math:integer } "s and truncated to 64 bits; output values will be returned as " { $link math:integer } "s." } ;
  69 HELP: void
  70 { $description "This symbol is not a valid C type, but it can be used as the return type for a " { $link POSTPONE: FUNCTION: } " or " { $link POSTPONE: CALLBACK: } " definition or for an " { $link alien-invoke } " or " { $link alien-callback } " call." } ;
  71 HELP: void*
  72 { $description "This C type represents a generic pointer to C memory. See " { $link pointer } " for information on pointer C types." } ;
  73 HELP: c-string
  74 { $description "This C type represents a pointer to a C string. See " { $link "c-strings" } " for details about using strings with the FFI." } ;
  75 HELP: float
  76 { $description "This C type represents a single-precision IEEE 754 floating-point type. Input values will be converted to Factor " { $link math:float } "s and demoted to single-precision; output values will be returned as Factor " { $link math:float } "s." } ;
  77 HELP: double
  78 { $description "This C type represents a double-precision IEEE 754 floating-point type. Input values will be converted to Factor " { $link math:float } "s; output values will be returned as Factor " { $link math:float } "s." } ;
  79 HELP: complex-float
  80 { $description "This C type represents a single-precision IEEE 754 floating-point complex type. Input values will be converted from Factor " { $link math:complex } " objects into a single-precision complex float type; output values will be returned as Factor " { $link math:complex } " objects." } ;
  81 HELP: complex-double
  82 { $description "This C type represents a double-precision IEEE 754 floating-point complex type. Input values will be converted from Factor " { $link math:complex } " objects into a double-precision complex float type; output values will be returned as Factor " { $link math:complex } " objects." } ;
  83
  84 HELP: pointer:
  85 { $syntax "pointer: c-type" }
  86 { $description "Constructs a " { $link pointer } " C type." } ;
  87
  88 HELP: pointer
  89 { $class-description "Represents a pointer C type. The " { $snippet "to" } " slot contains the C type being pointed to." { $link byte-array } " and " { $link alien } " values can be provided as pointer function inputs, but see " { $link "byte-arrays-gc" } " for notes about passing byte arrays into C functions. Objects with methods on " { $link >c-ptr } ", such as structs and specialized arrays, may also be used as pointer inputs."
  90 $nl
  91 "Pointer output values are represented in Factor as " { $link alien } "s. If the pointed-to type is a struct, the alien will automatically be wrapped in a struct object if it is not null."
  92 $nl
  93 "In " { $link POSTPONE: TYPEDEF: } ", " { $link POSTPONE: FUNCTION: } ", " { $link POSTPONE: CALLBACK: } ", and " { $link POSTPONE: STRUCT: } " definitions, pointer types can be created by suffixing " { $snippet "*" } " to a C type name. Outside of FFI definitions, a pointer C type can be created using the " { $link POSTPONE: pointer: } " syntax word:"
  94 { $unchecked-example "FUNCTION: int* foo ( char* bar ) ;" }
  95 { $unchecked-example """: foo ( bar -- int* )
  96     pointer: int f \"foo\" { pointer: char } alien-invoke ;""" } } ;
  97
  98 ARTICLE: "byte-arrays-gc" "Byte arrays and the garbage collector"
  99 "The Factor garbage collector can move byte arrays around, and it is only safe to pass byte arrays to C functions if the garbage collector will not run while C code still has a reference to the data."
 100 $nl
 101 "In particular, a byte array can only be passed as a parameter if the the C function does not use the parameter after one of the following occurs:"
 102 { $list
 103     "the C function returns"
 104     "the C function calls Factor code via a callback"
 105 }
 106 "Returning from C to Factor, as well as invoking Factor code via a callback, may trigger garbage collection, and if the function had stored a pointer to the byte array somewhere, this pointer may cease to be valid."
 107 $nl
 108 "If this condition is not satisfied, " { $link "malloc" } " must be used instead."
 109 { $warning "Failure to comply with these requirements can lead to crashes, data corruption, and security exploits." } ;
 110
 111 ARTICLE: "c-types.primitives" "Primitive C types"
 112 "The following numerical types are defined in the " { $vocab-link "alien.c-types" } " vocabulary; a " { $snippet "u" } " prefix denotes an unsigned type:"
 113 { $table
 114     { "C type" "Notes" }
 115     { { $link char } "always 1 byte" }
 116     { { $link uchar } { } }
 117     { { $link short } "always 2 bytes" }
 118     { { $link ushort } { } }
 119     { { $link int } "always 4 bytes" }
 120     { { $link uint } { } }
 121     { { $link long } { "same size as CPU word size and " { $link void* } ", except on 64-bit Windows, where it is 4 bytes" } }
 122     { { $link ulong } { } }
 123     { { $link longlong } "always 8 bytes" }
 124     { { $link ulonglong } { } }
 125     { { $link float } { "single-precision float (not the same as Factor's " { $link math:float } " class!)" } }
 126     { { $link double } { "double-precision float (the same format as Factor's " { $link math:float } " objects)" } }
 127 }
 128 "The following C99 complex number types are defined in the " { $vocab-link "alien.complex" } " vocabulary:"
 129 { $table
 130     { { $link complex-float } { "C99 or Fortran " { $snippet "complex float" } " type, converted to and from Factor " { $link math:complex } " values" } }
 131     { { $link complex-double } { "C99 or Fortran " { $snippet "complex double" } " type, converted to and from Factor " { $link math:complex } " values" } }
 132 }
 133 "When making alien calls, Factor numbers are converted to and from the above types in a canonical way. Converting a Factor number to a C value may result in a loss of precision." ;
 134
 135 ARTICLE: "c-types.pointers" "Pointer and array types"
 136 "Pointer types are specified by suffixing a C type with " { $snippet "*" } ", for example " { $snippet "float*" } ". One special case is " { $link void* } ", which denotes a generic pointer; " { $link void } " by itself is not a valid C type specifier. This syntax constructs a " { $link pointer } " object to represent the C type."
 137 $nl
 138 "Fixed-size array types are supported; the syntax consists of a C type name followed by dimension sizes in brackets; the following denotes a 3 by 4 array of integers:"
 139 { $code "int[3][4]" }
 140 "Fixed-size arrays differ from pointers in that they are allocated inside structures and unions; however, when used as function parameters, they behave exactly like pointers with the dimensions only serving as documentation." ;
 141
 142 ARTICLE: "c-types.ambiguity" "Word name clashes with C types"
 143 "Note that some of the C type word names clash with commonly-used Factor words:"
 144 { $list
 145   { { $link short } " clashes with the " { $link sequences:short } " word in the " { $vocab-link "sequences" } " vocabulary" }
 146   { { $link float } " clashes with the " { $link math:float } " word in the " { $vocab-link "math" } " vocabulary" }
 147 }
 148 "If you use the wrong vocabulary, you will see a " { $link no-c-type } " error. For example, the following is " { $strong "not" } " valid, and will raise an error because the " { $link math:float } " word from the " { $vocab-link "math" } " vocabulary is not a C type:"
 149 { $code
 150   "USING: alien.syntax math prettyprint ;"
 151   "FUNCTION: float magic_number ( ) ;"
 152   "magic_number 3.0 + ."
 153 }
 154 "The following won't work either; now the problem is that there are two vocabularies in the search path that define a word named " { $snippet "float" } ":"
 155 { $code
 156   "USING: alien.c-types alien.syntax math prettyprint ;"
 157   "FUNCTION: float magic_number ( ) ;"
 158   "magic_number 3.0 + ."
 159 }
 160 "The correct solution is to use one of " { $link POSTPONE: FROM: } ", " { $link POSTPONE: QUALIFIED: } " or " { $link POSTPONE: QUALIFIED-WITH: } " to disambiguate word lookup:"
 161 { $code
 162   "USING: alien.syntax math prettyprint ;"
 163   "QUALIFIED-WITH: alien.c-types c"
 164   "FUNCTION: c:float magic_number ( ) ;"
 165   "magic_number 3.0 + ."
 166 }
 167 "See " { $link "word-search-semantics" } " for details." ;
 168
 169 ARTICLE: "c-types.structs" "Struct and union types"
 170 "Struct and union types are identified by their class word. See " { $link "classes.struct" } "." ;
 171
 172 ARTICLE: "c-types-specs" "C type specifiers"
 173 "C types are identified by special words. Type names occur as parameters to the " { $link alien-invoke } ", " { $link alien-indirect } " and " { $link alien-callback } " words."
 174 $nl
 175 "Defining new C types:"
 176 { $subsections
 177     POSTPONE: STRUCT:
 178     POSTPONE: UNION-STRUCT:
 179     POSTPONE: CALLBACK:
 180     POSTPONE: TYPEDEF:
 181 }
 182 { $heading "Related articles" }
 183 { $subsections
 184     "c-types.primitives"
 185     "c-types.pointers"
 186     "c-types.ambiguity"
 187     "c-types.structs"
 188 }
 189 ;
 190
 191 ABOUT: "c-types-specs"