basis/alien/c-types/c-types-docs.factor

   1 USING: alien alien.complex help.syntax help.markup libc kernel.private
   2 byte-arrays strings hashtables alien.syntax alien.strings sequences
   3 io.encodings.string debugger destructors vocabs.loader
   4 classes.struct ;
   5 QUALIFIED: math
   6 QUALIFIED: sequences
   7 IN: alien.c-types
   8
   9 HELP: heap-size
  10 { $values { "name" "a C type name" } { "size" math:integer } }
  11 { $description "Outputs the number of bytes needed for a heap-allocated value of this C type." }
  12 { $examples
  13     { $example "USING: alien alien.c-types prettyprint ;\nint heap-size ." "4" }
  14 }
  15 { $errors "Throws a " { $link no-c-type } " error if the type does not exist." } ;
  16
  17 HELP: stack-size
  18 { $values { "name" "a C type name" } { "size" math:integer } }
  19 { $description "Outputs the number of bytes to reserve on the C stack by a value of this C type. In most cases this is equal to " { $link heap-size } ", except on some platforms where C structs are passed by invisible reference, in which case a C struct type only uses as much space as a pointer on the C stack." }
  20 { $errors "Throws a " { $link no-c-type } " error if the type does not exist." } ;
  21
  22 HELP: <c-type>
  23 { $values { "c-type" c-type } }
  24 { $description "Creates a prototypical C type. User code should use higher-level facilities to define C types; see " { $link "c-data" } "." } ;
  25
  26 HELP: no-c-type
  27 { $values { "name" "a C type name" } }
  28 { $description "Throws a " { $link no-c-type } " error." }
  29 { $error-description "Thrown by " { $link c-type } " if a given string does not name a C type. When thrown during compile time, indicates a typo in an " { $link alien-invoke } " or " { $link alien-callback } " form." } ;
  30
  31 HELP: c-type
  32 { $values { "name" "a C type" } { "c-type" c-type } }
  33 { $description "Looks up a C type by name." }
  34 { $errors "Throws a " { $link no-c-type } " error if the type does not exist, or the word is not a C type." } ;
  35
  36 HELP: c-getter
  37 { $values { "name" "a C type" } { "quot" { $quotation "( c-ptr n -- obj )" } } }
  38 { $description "Outputs a quotation which reads values of this C type from a C structure." }
  39 { $errors "Throws a " { $link no-c-type } " error if the type does not exist." } ;
  40
  41 HELP: c-setter
  42 { $values { "name" "a C type" } { "quot" { $quotation "( obj c-ptr n -- )" } } }
  43 { $description "Outputs a quotation which writes values of this C type to a C structure." }
  44 { $errors "Throws an error if the type does not exist." } ;
  45
  46 HELP: define-deref
  47 { $values { "c-type" "a C type" } }
  48 { $description "Defines a word " { $snippet "*name" } " with stack effect " { $snippet "( c-ptr -- value )" } " for reading a value with C type " { $snippet "name" } " stored at an alien pointer." }
  49 { $notes "This is an internal word called when defining C types, there is no need to call it on your own." } ;
  50
  51 HELP: define-out
  52 { $values { "c-type" "a C type" } }
  53 { $description "Defines a word " { $snippet "<" { $emphasis "name" } ">" } " with stack effect " { $snippet "( value -- array )" } ". This word allocates a byte array large enough to hold a value with C type " { $snippet "name" } ", and writes the value at the top of the stack to the array." }
  54 { $notes "This is an internal word called when defining C types, there is no need to call it on your own." } ;
  55
  56 HELP: char
  57 { $description "This C type represents a one-byte signed integer type. Input values will be converted to " { $link math:integer } "s and truncated to eight bits; output values will be returned as " { $link math:fixnum } "s." } ;
  58 HELP: uchar
  59 { $description "This C type represents a one-byte unsigned integer type. Input values will be converted to " { $link math:integer } "s and truncated to eight bits; output values will be returned as " { $link math:fixnum } "s." } ;
  60 HELP: short
  61 { $description "This C type represents a two-byte signed integer type. Input values will be converted to " { $link math:integer } "s and truncated to sixteen bits; output values will be returned as " { $link math:fixnum } "s." } ;
  62 HELP: ushort
  63 { $description "This C type represents a two-byte unsigned integer type. Input values will be converted to " { $link math:integer } "s and truncated to sixteen bits; output values will be returned as " { $link math:fixnum } "s." } ;
  64 HELP: int
  65 { $description "This C type represents a four-byte signed integer type. Input values will be converted to " { $link math:integer } "s and truncated to 32 bits; output values will be returned as " { $link math:integer } "s." } ;
  66 HELP: uint
  67 { $description "This C type represents a four-byte unsigned integer type. Input values will be converted to " { $link math:integer } "s and truncated to 32 bits; output values will be returned as " { $link math:integer } "s." } ;
  68 HELP: long
  69 { $description "This C type represents a four- or eight-byte signed integer type. On Windows and on 32-bit Unix platforms, it will be four bytes. On 64-bit Unix platforms, it will be eight bytes. Input values will be converted to " { $link math:integer } "s and truncated to 32 or 64 bits; output values will be returned as " { $link math:integer } "s." } ;
  70 HELP: intptr_t
  71 { $description "This C type represents a signed integer type large enough to hold any pointer value; that is, on 32-bit platforms, it will be four bytes, and on 64-bit platforms, it will be eight bytes. Input values will be converted to " { $link math:integer } "s and truncated to 32 or 64 bits; output values will be returned as " { $link math:integer } "s." } ;
  72 HELP: ulong
  73 { $description "This C type represents a four- or eight-byte unsigned integer type. On Windows and on 32-bit Unix platforms, it will be four bytes. On 64-bit Unix platforms, it will be eight bytes. Input values will be converted to " { $link math:integer } "s and truncated to 32 or 64 bits; output values will be returned as " { $link math:integer } "s." } ;
  74 HELP: uintptr_t
  75 { $description "This C type represents an unsigned integer type large enough to hold any pointer value; that is, on 32-bit platforms, it will be four bytes, and on 64-bit platforms, it will be eight bytes. Input values will be converted to " { $link math:integer } "s and truncated to 32 or 64 bits; output values will be returned as " { $link math:integer } "s." } ;
  76 HELP: ptrdiff_t
  77 { $description "This C type represents a signed integer type large enough to hold the distance between two pointer values; that is, on 32-bit platforms, it will be four bytes, and on 64-bit platforms, it will be eight bytes. Input values will be converted to " { $link math:integer } "s and truncated to 32 or 64 bits; output values will be returned as " { $link math:integer } "s." } ;
  78 HELP: size_t
  79 { $description "This C type represents unsigned size values of the size expected by the platform's standard C library (usually four bytes on a 32-bit platform, and eight on a 64-bit platform). Input values will be converted to " { $link math:integer } "s and truncated to the appropriate size; output values will be returned as " { $link math:integer } "s." } ;
  80 HELP: longlong
  81 { $description "This C type represents an eight-byte signed integer type. Input values will be converted to " { $link math:integer } "s and truncated to 64 bits; output values will be returned as " { $link math:integer } "s." } ;
  82 HELP: ulonglong
  83 { $description "This C type represents an eight-byte unsigned integer type. Input values will be converted to " { $link math:integer } "s and truncated to 64 bits; output values will be returned as " { $link math:integer } "s." } ;
  84 HELP: void
  85 { $description "This symbol is not a valid C type, but it can be used as the return type for a " { $link POSTPONE: FUNCTION: } " or " { $link POSTPONE: CALLBACK: } " definition or for an " { $link alien-invoke } " or " { $link alien-callback } " call." } ;
  86 HELP: void*
  87 { $description "This C type represents a generic pointer to C memory. See " { $link pointer } " for information on pointer C types." } ;
  88 HELP: c-string
  89 { $description "This C type represents a pointer to a C string. See " { $link "c-strings" } " for details about using strings with the FFI." } ;
  90 HELP: float
  91 { $description "This C type represents a single-precision IEEE 754 floating-point type. Input values will be converted to Factor " { $link math:float } "s and demoted to single-precision; output values will be returned as Factor " { $link math:float } "s." } ;
  92 HELP: double
  93 { $description "This C type represents a double-precision IEEE 754 floating-point type. Input values will be converted to Factor " { $link math:float } "s; output values will be returned as Factor " { $link math:float } "s." } ;
  94 HELP: complex-float
  95 { $description "This C type represents a single-precision IEEE 754 floating-point complex type. Input values will be converted from Factor " { $link math:complex } " objects into a single-precision complex float type; output values will be returned as Factor " { $link math:complex } " objects." } ;
  96 HELP: complex-double
  97 { $description "This C type represents a double-precision IEEE 754 floating-point complex type. Input values will be converted from Factor " { $link math:complex } " objects into a double-precision complex float type; output values will be returned as Factor " { $link math:complex } " objects." } ;
  98
  99 HELP: pointer:
 100 { $syntax "pointer: c-type" }
 101 { $description "Constructs a " { $link pointer } " C type." } ;
 102
 103 HELP: pointer
 104 { $class-description "Represents a pointer C type. The " { $snippet "to" } " slot contains the C type being pointed to." { $link byte-array } " and " { $link alien } " values can be provided as pointer function inputs, but see " { $link "byte-arrays-gc" } " for notes about passing byte arrays into C functions. Objects with methods on " { $link >c-ptr } ", such as structs and specialized arrays, may also be used as pointer inputs."
 105 $nl
 106 "Pointer output values are represented in Factor as " { $link alien } "s. If the pointed-to type is a struct, the alien will automatically be wrapped in a struct object if it is not null."
 107 $nl
 108 "In " { $link POSTPONE: TYPEDEF: } ", " { $link POSTPONE: FUNCTION: } ", " { $link POSTPONE: CALLBACK: } ", and " { $link POSTPONE: STRUCT: } " definitions, pointer types can be created by suffixing " { $snippet "*" } " to a C type name. Outside of FFI definitions, a pointer C type can be created using the " { $link POSTPONE: pointer: } " syntax word:"
 109 { $unchecked-example "FUNCTION: int* foo ( char* bar ) ;" }
 110 { $unchecked-example """: foo ( bar -- int* )
 111     pointer: int f \"foo\" { pointer: char } alien-invoke ;""" } } ;
 112
 113 ARTICLE: "byte-arrays-gc" "Byte arrays and the garbage collector"
 114 "The Factor garbage collector can move byte arrays around, and it is only safe to pass byte arrays to C functions if the garbage collector will not run while C code still has a reference to the data."
 115 $nl
 116 "In particular, a byte array can only be passed as a parameter if the the C function does not use the parameter after one of the following occurs:"
 117 { $list
 118     "the C function returns"
 119     "the C function calls Factor code via a callback"
 120 }
 121 "Returning from C to Factor, as well as invoking Factor code via a callback, may trigger garbage collection, and if the function had stored a pointer to the byte array somewhere, this pointer may cease to be valid."
 122 $nl
 123 "If this condition is not satisfied, " { $link "malloc" } " must be used instead."
 124 { $warning "Failure to comply with these requirements can lead to crashes, data corruption, and security exploits." } ;
 125
 126 ARTICLE: "c-out-params" "Output parameters in C"
 127 "A frequently-occurring idiom in C code is the \"out parameter\". If a C function returns more than one value, the caller passes pointers of the correct type, and the C function writes its return values to those locations."
 128 $nl
 129 "Each numerical C type, together with " { $snippet "void*" } ", has an associated " { $emphasis "out parameter constructor" } " word which takes a Factor object as input, constructs a byte array of the correct size, and converts the Factor object to a C value stored into the byte array:"
 130 { $subsections
 131     <char>
 132     <uchar>
 133     <short>
 134     <ushort>
 135     <int>
 136     <uint>
 137     <long>
 138     <ulong>
 139     <longlong>
 140     <ulonglong>
 141     <float>
 142     <double>
 143     <void*>
 144 }
 145 "You call the out parameter constructor with the required initial value, then pass the byte array to the C function, which receives a pointer to the start of the byte array's data area. The C function then returns, leaving the result in the byte array; you read it back using the next set of words:"
 146 { $subsections
 147     *char
 148     *uchar
 149     *short
 150     *ushort
 151     *int
 152     *uint
 153     *long
 154     *ulong
 155     *longlong
 156     *ulonglong
 157     *float
 158     *double
 159     *void*
 160 }
 161 "Note that while structure and union types do not get these words defined for them, there is no loss of generality since " { $link <void*> } " and " { $link *void* } " may be used." ;
 162
 163 ARTICLE: "c-types.primitives" "Primitive C types"
 164 "The following numerical types are defined in the " { $vocab-link "alien.c-types" } " vocabulary; a " { $snippet "u" } " prefix denotes an unsigned type:"
 165 { $table
 166     { "C type" "Notes" }
 167     { { $link char } "always 1 byte" }
 168     { { $link uchar } { } }
 169     { { $link short } "always 2 bytes" }
 170     { { $link ushort } { } }
 171     { { $link int } "always 4 bytes" }
 172     { { $link uint } { } }
 173     { { $link long } { "same size as CPU word size and " { $link void* } ", except on 64-bit Windows, where it is 4 bytes" } }
 174     { { $link ulong } { } }
 175     { { $link longlong } "always 8 bytes" }
 176     { { $link ulonglong } { } }
 177     { { $link float } { "single-precision float (not the same as Factor's " { $link math:float } " class!)" } }
 178     { { $link double } { "double-precision float (the same format as Factor's " { $link math:float } " objects)" } }
 179 }
 180 "The following C99 complex number types are defined in the " { $vocab-link "alien.complex" } " vocabulary:"
 181 { $table
 182     { { $link complex-float } { "C99 or Fortran " { $snippet "complex float" } " type, converted to and from Factor " { $link math:complex } " values" } }
 183     { { $link complex-double } { "C99 or Fortran " { $snippet "complex double" } " type, converted to and from Factor " { $link math:complex } " values" } }
 184 }
 185 "When making alien calls, Factor numbers are converted to and from the above types in a canonical way. Converting a Factor number to a C value may result in a loss of precision." ;
 186
 187 ARTICLE: "c-types.pointers" "Pointer and array types"
 188 "Pointer types are specified by suffixing a C type with " { $snippet "*" } ", for example " { $snippet "float*" } ". One special case is " { $link void* } ", which denotes a generic pointer; " { $link void } " by itself is not a valid C type specifier. This syntax constructs a " { $link pointer } " object to represent the C type."
 189 $nl
 190 "Fixed-size array types are supported; the syntax consists of a C type name followed by dimension sizes in brackets; the following denotes a 3 by 4 array of integers:"
 191 { $code "int[3][4]" }
 192 "Fixed-size arrays differ from pointers in that they are allocated inside structures and unions; however, when used as function parameters, they behave exactly like pointers with the dimensions only serving as documentation." ;
 193
 194 ARTICLE: "c-types.ambiguity" "Word name clashes with C types"
 195 "Note that some of the C type word names clash with commonly-used Factor words:"
 196 { $list
 197   { { $link short } " clashes with the " { $link sequences:short } " word in the " { $vocab-link "sequences" } " vocabulary" }
 198   { { $link float } " clashes with the " { $link math:float } " word in the " { $vocab-link "math" } " vocabulary" }
 199 }
 200 "If you use the wrong vocabulary, you will see a " { $link no-c-type } " error. For example, the following is " { $strong "not" } " valid, and will raise an error because the " { $link math:float } " word from the " { $vocab-link "math" } " vocabulary is not a C type:"
 201 { $code
 202   "USING: alien.syntax math prettyprint ;"
 203   "FUNCTION: float magic_number ( ) ;"
 204   "magic_number 3.0 + ."
 205 }
 206 "The following won't work either; now the problem is that there are two vocabularies in the search path that define a word named " { $snippet "float" } ":"
 207 { $code
 208   "USING: alien.c-types alien.syntax math prettyprint ;"
 209   "FUNCTION: float magic_number ( ) ;"
 210   "magic_number 3.0 + ."
 211 }
 212 "The correct solution is to use one of " { $link POSTPONE: FROM: } ", " { $link POSTPONE: QUALIFIED: } " or " { $link POSTPONE: QUALIFIED-WITH: } " to disambiguate word lookup:"
 213 { $code
 214   "USING: alien.syntax math prettyprint ;"
 215   "QUALIFIED-WITH: alien.c-types c"
 216   "FUNCTION: c:float magic_number ( ) ;"
 217   "magic_number 3.0 + ."
 218 }
 219 "See " { $link "word-search-semantics" } " for details." ;
 220
 221 ARTICLE: "c-types.structs" "Struct and union types"
 222 "Struct and union types are identified by their class word. See " { $link "classes.struct" } "." ;
 223
 224 ARTICLE: "c-types-specs" "C type specifiers"
 225 "C types are identified by special words. Type names occur as parameters to the " { $link alien-invoke } ", " { $link alien-indirect } " and " { $link alien-callback } " words."
 226 $nl
 227 "Defining new C types:"
 228 { $subsections
 229     POSTPONE: STRUCT:
 230     POSTPONE: UNION-STRUCT:
 231     POSTPONE: CALLBACK:
 232     POSTPONE: TYPEDEF:
 233 }
 234 { $heading "Related articles" }
 235 { $subsections
 236     "c-types.primitives"
 237     "c-types.pointers"
 238     "c-types.ambiguity"
 239     "c-types.structs"
 240 }
 241 ;
 242
 243 ABOUT: "c-types-specs"