basis/alien/c-types/c-types.factor

   1 ! Copyright (C) 2004, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: byte-arrays arrays assocs delegate kernel kernel.private math
   4 math.order math.parser namespaces make parser sequences strings
   5 words splitting cpu.architecture alien alien.accessors
   6 alien.strings quotations layouts system compiler.units io
   7 io.files io.encodings.binary io.streams.memory accessors
   8 combinators effects continuations fry classes vocabs
   9 vocabs.loader words.symbol macros ;
  10 QUALIFIED: math
  11 IN: alien.c-types
  12
  13 SYMBOLS:
  14     char uchar
  15     short ushort
  16     int uint
  17     long ulong
  18     longlong ulonglong
  19     float double
  20     void* bool ;
  21
  22 SINGLETON: void
  23
  24 DEFER: <int>
  25 DEFER: *char
  26
  27 TUPLE: abstract-c-type
  28 { class class initial: object }
  29 { boxed-class class initial: object }
  30 { boxer-quot callable }
  31 { unboxer-quot callable }
  32 { getter callable }
  33 { setter callable }
  34 { size integer }
  35 { align integer }
  36 { align-first integer } ;
  37
  38 TUPLE: c-type < abstract-c-type
  39 boxer
  40 unboxer
  41 { rep initial: int-rep } ;
  42
  43 : <c-type> ( -- c-type )
  44     \ c-type new ; inline
  45
  46 ERROR: no-c-type name ;
  47
  48 ! C type protocol
  49 GENERIC: c-type ( name -- c-type ) foldable
  50
  51 PREDICATE: c-type-word < word
  52     "c-type" word-prop ;
  53
  54 TUPLE: pointer { to initial: void read-only } ;
  55 C: <pointer> pointer
  56
  57 UNION: c-type-name
  58     c-type-word pointer ;
  59
  60 : resolve-typedef ( name -- c-type )
  61     dup void? [ no-c-type ] when
  62     dup c-type-name? [ c-type ] when ;
  63
  64 M: word c-type
  65     dup "c-type" word-prop resolve-typedef
  66     [ ] [ no-c-type ] ?if ;
  67
  68 GENERIC: c-type-class ( name -- class )
  69
  70 M: abstract-c-type c-type-class class>> ;
  71
  72 GENERIC: c-type-boxed-class ( name -- class )
  73
  74 M: abstract-c-type c-type-boxed-class boxed-class>> ;
  75
  76 GENERIC: c-type-boxer-quot ( name -- quot )
  77
  78 M: abstract-c-type c-type-boxer-quot boxer-quot>> ;
  79
  80 GENERIC: c-type-unboxer-quot ( name -- quot )
  81
  82 M: abstract-c-type c-type-unboxer-quot unboxer-quot>> ;
  83
  84 GENERIC: c-type-rep ( name -- rep )
  85
  86 M: c-type c-type-rep rep>> ;
  87
  88 GENERIC: c-type-getter ( name -- quot )
  89
  90 M: c-type c-type-getter getter>> ;
  91
  92 GENERIC: c-type-setter ( name -- quot )
  93
  94 M: c-type c-type-setter setter>> ;
  95
  96 GENERIC: c-type-align ( name -- n ) foldable
  97
  98 M: abstract-c-type c-type-align align>> ;
  99
 100 GENERIC: c-type-align-first ( name -- n )
 101
 102 M: abstract-c-type c-type-align-first align-first>> ;
 103
 104 GENERIC: base-type ( c-type -- c-type )
 105
 106 M: c-type-name base-type c-type ;
 107
 108 M: c-type base-type ;
 109
 110 : little-endian? ( -- ? ) 1 <int> *char 1 = ; foldable
 111
 112 GENERIC: heap-size ( name -- size )
 113
 114 M: abstract-c-type heap-size size>> ;
 115
 116 MIXIN: value-type
 117
 118 MACRO: alien-value ( c-type -- quot: ( c-ptr offset -- value ) )
 119     [ c-type-getter ] [ c-type-boxer-quot ] bi append ;
 120
 121 MACRO: set-alien-value ( c-type -- quot: ( value c-ptr offset -- ) )
 122     [ c-type-unboxer-quot [ [ ] ] [ '[ _ 2dip ] ] if-empty ]
 123     [ c-type-setter ]
 124     bi append ;
 125
 126 : array-accessor ( n c-ptr c-type -- c-ptr offset c-type )
 127     [ swapd heap-size * >fixnum ] keep ; inline
 128
 129 : alien-element ( n c-ptr c-type -- value )
 130     array-accessor alien-value ; inline
 131
 132 : set-alien-element ( value n c-ptr c-type -- )
 133     array-accessor set-alien-value ; inline
 134
 135 PROTOCOL: c-type-protocol
 136     c-type-class
 137     c-type-boxed-class
 138     c-type-boxer-quot
 139     c-type-unboxer-quot
 140     c-type-rep
 141     c-type-getter
 142     c-type-setter
 143     c-type-align
 144     c-type-align-first
 145     base-type
 146     heap-size ;
 147
 148 CONSULT: c-type-protocol c-type-name
 149     c-type ;
 150
 151 PREDICATE: typedef-word < c-type-word
 152     "c-type" word-prop c-type-name? ;
 153
 154 : typedef ( old new -- )
 155     {
 156         [ nip define-symbol ]
 157         [ swap "c-type" set-word-prop ]
 158     } 2cleave ;
 159
 160 TUPLE: long-long-type < c-type ;
 161
 162 : <long-long-type> ( -- c-type )
 163     long-long-type new ;
 164
 165 : define-deref ( c-type -- )
 166     [ name>> CHAR: * prefix "alien.c-types" create ]
 167     [ '[ 0 _ alien-value ] ]
 168     bi (( c-ptr -- value )) define-inline ;
 169
 170 : define-out ( c-type -- )
 171     [ name>> "alien.c-types" constructor-word ]
 172     [ dup '[ _ heap-size (byte-array) [ 0 _ set-alien-value ] keep ] ] bi
 173     (( value -- c-ptr )) define-inline ;
 174
 175 : define-primitive-type ( c-type name -- )
 176     [ typedef ] [ define-deref ] [ define-out ] tri ;
 177
 178 : if-void ( c-type true false -- )
 179     pick void? [ drop nip call ] [ nip call ] if ; inline
 180
 181 SYMBOLS:
 182     ptrdiff_t intptr_t uintptr_t size_t
 183     c-string ;
 184
 185 CONSTANT: primitive-types
 186     {
 187         char uchar
 188         short ushort
 189         int uint
 190         long ulong
 191         longlong ulonglong
 192         float double
 193         void* bool
 194         c-string
 195     }
 196
 197 : >c-bool ( ? -- int ) 1 0 ? ; inline
 198
 199 : c-bool> ( int -- ? ) 0 = not ; inline
 200
 201 <PRIVATE
 202
 203 : 8-byte-alignment ( c-type -- c-type )
 204     {
 205         { [ cpu ppc? os macosx? and ] [ 4 >>align 8 >>align-first ] }
 206         { [ cpu x86.32? os windows? not and ] [ 4 >>align 4 >>align-first ] }
 207         [ 8 >>align 8 >>align-first ]
 208     } cond ;
 209
 210 : resolve-pointer-typedef ( type -- base-type )
 211     dup "c-type" word-prop dup word?
 212     [ nip resolve-pointer-typedef ] [
 213         pointer? [ drop void* ] when
 214     ] if ;
 215
 216 : primitive-pointer-type? ( type -- ? )
 217     dup c-type-word? [
 218         resolve-pointer-typedef [ void? ] [ primitive-types member? ] bi or
 219     ] [ drop t ] if ;
 220
 221 : (pointer-c-type) ( void* type -- void*' )
 222     [ clone ] dip c-type-boxer-quot '[ _ [ f ] if* ] >>boxer-quot ;
 223
 224 PRIVATE>
 225
 226 M: pointer c-type
 227     [ \ void* c-type ] dip
 228     to>> dup primitive-pointer-type? [ drop ] [ (pointer-c-type) ] if ;
 229
 230 [
 231     <c-type>
 232         c-ptr >>class
 233         c-ptr >>boxed-class
 234         [ alien-cell ] >>getter
 235         [ set-alien-cell ] >>setter
 236         bootstrap-cell >>size
 237         bootstrap-cell >>align
 238         bootstrap-cell >>align-first
 239         [ >c-ptr ] >>unboxer-quot
 240         "allot_alien" >>boxer
 241         "alien_offset" >>unboxer
 242     \ void* define-primitive-type
 243
 244     <c-type>
 245         fixnum >>class
 246         fixnum >>boxed-class
 247         [ alien-signed-2 ] >>getter
 248         [ set-alien-signed-2 ] >>setter
 249         2 >>size
 250         2 >>align
 251         2 >>align-first
 252         "from_signed_2" >>boxer
 253         "to_fixnum" >>unboxer
 254         [ >fixnum ] >>unboxer-quot
 255     \ short define-primitive-type
 256
 257     <c-type>
 258         fixnum >>class
 259         fixnum >>boxed-class
 260         [ alien-unsigned-2 ] >>getter
 261         [ set-alien-unsigned-2 ] >>setter
 262         2 >>size
 263         2 >>align
 264         2 >>align-first
 265         "from_unsigned_2" >>boxer
 266         "to_cell" >>unboxer
 267         [ >fixnum ] >>unboxer-quot
 268     \ ushort define-primitive-type
 269
 270     <c-type>
 271         fixnum >>class
 272         fixnum >>boxed-class
 273         [ alien-signed-1 ] >>getter
 274         [ set-alien-signed-1 ] >>setter
 275         1 >>size
 276         1 >>align
 277         1 >>align-first
 278         "from_signed_1" >>boxer
 279         "to_fixnum" >>unboxer
 280         [ >fixnum ] >>unboxer-quot
 281     \ char define-primitive-type
 282
 283     <c-type>
 284         fixnum >>class
 285         fixnum >>boxed-class
 286         [ alien-unsigned-1 ] >>getter
 287         [ set-alien-unsigned-1 ] >>setter
 288         1 >>size
 289         1 >>align
 290         1 >>align-first
 291         "from_unsigned_1" >>boxer
 292         "to_cell" >>unboxer
 293         [ >fixnum ] >>unboxer-quot
 294     \ uchar define-primitive-type
 295
 296     <c-type>
 297         math:float >>class
 298         math:float >>boxed-class
 299         [ alien-float ] >>getter
 300         [ set-alien-float ] >>setter
 301         4 >>size
 302         4 >>align
 303         4 >>align-first
 304         "from_float" >>boxer
 305         "to_float" >>unboxer
 306         float-rep >>rep
 307         [ >float ] >>unboxer-quot
 308     \ float define-primitive-type
 309
 310     <c-type>
 311         math:float >>class
 312         math:float >>boxed-class
 313         [ alien-double ] >>getter
 314         [ set-alien-double ] >>setter
 315         8 >>size
 316         8-byte-alignment
 317         "from_double" >>boxer
 318         "to_double" >>unboxer
 319         double-rep >>rep
 320         [ >float ] >>unboxer-quot
 321     \ double define-primitive-type
 322
 323     cell 8 = [
 324         <c-type>
 325             fixnum >>class
 326             fixnum >>boxed-class
 327             [ alien-signed-4 ] >>getter
 328             [ set-alien-signed-4 ] >>setter
 329             4 >>size
 330             4 >>align
 331             4 >>align-first
 332             "from_signed_4" >>boxer
 333             "to_fixnum" >>unboxer
 334             [ >fixnum ] >>unboxer-quot
 335         \ int define-primitive-type
 336
 337         <c-type>
 338             fixnum >>class
 339             fixnum >>boxed-class
 340             [ alien-unsigned-4 ] >>getter
 341             [ set-alien-unsigned-4 ] >>setter
 342             4 >>size
 343             4 >>align
 344             4 >>align-first
 345             "from_unsigned_4" >>boxer
 346             "to_cell" >>unboxer
 347             [ >fixnum ] >>unboxer-quot
 348         \ uint define-primitive-type
 349
 350         <c-type>
 351             integer >>class
 352             integer >>boxed-class
 353             [ alien-signed-cell ] >>getter
 354             [ set-alien-signed-cell ] >>setter
 355             8 >>size
 356             8 >>align
 357             8 >>align-first
 358             "from_signed_cell" >>boxer
 359             "to_fixnum" >>unboxer
 360         \ longlong define-primitive-type
 361
 362         <c-type>
 363             integer >>class
 364             integer >>boxed-class
 365             [ alien-unsigned-cell ] >>getter
 366             [ set-alien-unsigned-cell ] >>setter
 367             8 >>size
 368             8 >>align
 369             8 >>align-first
 370             "from_unsigned_cell" >>boxer
 371             "to_cell" >>unboxer
 372         \ ulonglong define-primitive-type
 373
 374         os windows? [
 375             \ int c-type \ long define-primitive-type
 376             \ uint c-type \ ulong define-primitive-type
 377         ] [
 378             \ longlong c-type \ long define-primitive-type
 379             \ ulonglong c-type \ ulong define-primitive-type
 380         ] if
 381
 382         \ longlong c-type \ ptrdiff_t typedef
 383         \ longlong c-type \ intptr_t typedef
 384
 385         \ ulonglong c-type \ uintptr_t typedef
 386         \ ulonglong c-type \ size_t typedef
 387     ] [
 388         <c-type>
 389             integer >>class
 390             integer >>boxed-class
 391             [ alien-signed-cell ] >>getter
 392             [ set-alien-signed-cell ] >>setter
 393             4 >>size
 394             4 >>align
 395             4 >>align-first
 396             "from_signed_cell" >>boxer
 397             "to_fixnum" >>unboxer
 398         \ int define-primitive-type
 399
 400         <c-type>
 401             integer >>class
 402             integer >>boxed-class
 403             [ alien-unsigned-cell ] >>getter
 404             [ set-alien-unsigned-cell ] >>setter
 405             4 >>size
 406             4 >>align
 407             4 >>align-first
 408             "from_unsigned_cell" >>boxer
 409             "to_cell" >>unboxer
 410         \ uint define-primitive-type
 411
 412         <long-long-type>
 413             integer >>class
 414             integer >>boxed-class
 415             [ alien-signed-8 ] >>getter
 416             [ set-alien-signed-8 ] >>setter
 417             8 >>size
 418             8-byte-alignment
 419             "from_signed_8" >>boxer
 420             "to_signed_8" >>unboxer
 421         \ longlong define-primitive-type
 422
 423         <long-long-type>
 424             integer >>class
 425             integer >>boxed-class
 426             [ alien-unsigned-8 ] >>getter
 427             [ set-alien-unsigned-8 ] >>setter
 428             8 >>size
 429             8-byte-alignment
 430             "from_unsigned_8" >>boxer
 431             "to_unsigned_8" >>unboxer
 432         \ ulonglong define-primitive-type
 433
 434         \ int c-type \ long define-primitive-type
 435         \ uint c-type \ ulong define-primitive-type
 436
 437         \ int c-type \ ptrdiff_t typedef
 438         \ int c-type \ intptr_t typedef
 439
 440         \ uint c-type \ uintptr_t typedef
 441         \ uint c-type \ size_t typedef
 442     ] if
 443
 444     cpu ppc? \ uint \ uchar ? c-type clone
 445         [ >c-bool ] >>unboxer-quot
 446         [ c-bool> ] >>boxer-quot
 447         object >>boxed-class
 448     \ bool define-primitive-type
 449
 450 ] with-compilation-unit
 451
 452 M: char-16-rep rep-component-type drop char ;
 453 M: uchar-16-rep rep-component-type drop uchar ;
 454 M: short-8-rep rep-component-type drop short ;
 455 M: ushort-8-rep rep-component-type drop ushort ;
 456 M: int-4-rep rep-component-type drop int ;
 457 M: uint-4-rep rep-component-type drop uint ;
 458 M: longlong-2-rep rep-component-type drop longlong ;
 459 M: ulonglong-2-rep rep-component-type drop ulonglong ;
 460 M: float-4-rep rep-component-type drop float ;
 461 M: double-2-rep rep-component-type drop double ;
 462
 463 : (unsigned-interval) ( bytes -- from to ) [ 0 ] dip 8 * 2^ 1 - ; foldable
 464 : unsigned-interval ( c-type -- from to ) heap-size (unsigned-interval) ; foldable
 465 : (signed-interval) ( bytes -- from to ) 8 * 1 - 2^ [ neg ] [ 1 - ] bi ; foldable
 466 : signed-interval ( c-type -- from to ) heap-size (signed-interval) ; foldable
 467
 468 : c-type-interval ( c-type -- from to )
 469     {
 470         { [ dup { float double } member-eq? ] [ drop -1/0. 1/0. ] }
 471         { [ dup { char short int long longlong } member-eq? ] [ signed-interval ] }
 472         { [ dup { uchar ushort uint ulong ulonglong } member-eq? ] [ unsigned-interval ] }
 473     } cond ; foldable
 474
 475 : c-type-clamp ( value c-type -- value' )
 476     dup { float double } member-eq?
 477     [ drop ] [ c-type-interval clamp ] if ; inline