basis/alien/c-types/c-types.factor

   1 ! Copyright (C) 2004, 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: byte-arrays arrays assocs kernel kernel.private libc math
   4 namespaces make parser sequences strings words assocs splitting
   5 math.parser cpu.architecture alien alien.accessors quotations
   6 layouts system compiler.units io.files io.encodings.binary
   7 accessors combinators effects continuations ;
   8 IN: alien.c-types
   9
  10 DEFER: <int>
  11 DEFER: *char
  12
  13 : little-endian? ( -- ? ) 1 <int> *char 1 = ; foldable
  14
  15 TUPLE: c-type
  16 boxer boxer-quot unboxer unboxer-quot
  17 getter setter
  18 reg-class size align stack-align? ;
  19
  20 : new-c-type ( class -- type )
  21     new
  22         int-regs >>reg-class ;
  23
  24 : <c-type> ( -- type )
  25     \ c-type new-c-type ;
  26
  27 SYMBOL: c-types
  28
  29 global [
  30     c-types [ H{ } assoc-like ] change
  31 ] bind
  32
  33 ERROR: no-c-type name ;
  34
  35 : (c-type) ( name -- type/f )
  36     c-types get-global at dup [
  37         dup string? [ (c-type) ] when
  38     ] when ;
  39
  40 ! C type protocol
  41 GENERIC: c-type ( name -- type ) foldable
  42
  43 : resolve-pointer-type ( name -- name )
  44     c-types get at dup string?
  45     [ "*" append ] [ drop "void*" ] if
  46     c-type ;
  47
  48 : resolve-typedef ( name -- type )
  49     dup string? [ c-type ] when ;
  50
  51 : parse-array-type ( name -- array )
  52     "[" split unclip
  53     >r [ "]" ?tail drop string>number ] map r> prefix ;
  54
  55 M: string c-type ( name -- type )
  56     CHAR: ] over member? [
  57         parse-array-type
  58     ] [
  59         dup c-types get at [
  60             resolve-typedef
  61         ] [
  62             "*" ?tail [ resolve-pointer-type ] [ no-c-type ] if
  63         ] ?if
  64     ] if ;
  65
  66 GENERIC: c-type-boxer ( name -- boxer )
  67
  68 M: c-type c-type-boxer boxer>> ;
  69
  70 M: string c-type-boxer c-type c-type-boxer ;
  71
  72 GENERIC: c-type-boxer-quot ( name -- quot )
  73
  74 M: c-type c-type-boxer-quot boxer-quot>> ;
  75
  76 M: string c-type-boxer-quot c-type c-type-boxer-quot ;
  77
  78 GENERIC: c-type-unboxer ( name -- boxer )
  79
  80 M: c-type c-type-unboxer unboxer>> ;
  81
  82 M: string c-type-unboxer c-type c-type-unboxer ;
  83
  84 GENERIC: c-type-unboxer-quot ( name -- quot )
  85
  86 M: c-type c-type-unboxer-quot unboxer-quot>> ;
  87
  88 M: string c-type-unboxer-quot c-type c-type-unboxer-quot ;
  89
  90 GENERIC: c-type-reg-class ( name -- reg-class )
  91
  92 M: c-type c-type-reg-class reg-class>> ;
  93
  94 M: string c-type-reg-class c-type c-type-reg-class ;
  95
  96 GENERIC: c-type-getter ( name -- quot )
  97
  98 M: c-type c-type-getter getter>> ;
  99
 100 M: string c-type-getter c-type c-type-getter ;
 101
 102 GENERIC: c-type-setter ( name -- quot )
 103
 104 M: c-type c-type-setter setter>> ;
 105
 106 M: string c-type-setter c-type c-type-setter ;
 107
 108 GENERIC: c-type-align ( name -- n )
 109
 110 M: c-type c-type-align align>> ;
 111
 112 M: string c-type-align c-type c-type-align ;
 113
 114 GENERIC: c-type-stack-align? ( name -- ? )
 115
 116 M: c-type c-type-stack-align? stack-align?>> ;
 117
 118 M: string c-type-stack-align? c-type c-type-stack-align? ;
 119
 120 : c-type-box ( n type -- )
 121     dup c-type-reg-class
 122     swap c-type-boxer [ "No boxer" throw ] unless*
 123     %box ;
 124
 125 : c-type-unbox ( n ctype -- )
 126     dup c-type-reg-class
 127     swap c-type-unboxer [ "No unboxer" throw ] unless*
 128     %unbox ;
 129
 130 GENERIC: box-parameter ( n ctype -- )
 131
 132 M: c-type box-parameter c-type-box ;
 133
 134 M: string box-parameter c-type box-parameter ;
 135
 136 GENERIC: box-return ( ctype -- )
 137
 138 M: c-type box-return f swap c-type-box ;
 139
 140 M: string box-return c-type box-return ;
 141
 142 GENERIC: unbox-parameter ( n ctype -- )
 143
 144 M: c-type unbox-parameter c-type-unbox ;
 145
 146 M: string unbox-parameter c-type unbox-parameter ;
 147
 148 GENERIC: unbox-return ( ctype -- )
 149
 150 M: c-type unbox-return f swap c-type-unbox ;
 151
 152 M: string unbox-return c-type unbox-return ;
 153
 154 ! These words being foldable means that words need to be
 155 ! recompiled if a C type is redefined. Even so, folding the
 156 ! size facilitates some optimizations.
 157 GENERIC: heap-size ( type -- size ) foldable
 158
 159 M: string heap-size c-type heap-size ;
 160
 161 M: c-type heap-size size>> ;
 162
 163 GENERIC: stack-size ( type -- size ) foldable
 164
 165 M: string stack-size c-type stack-size ;
 166
 167 M: c-type stack-size size>> ;
 168
 169 GENERIC: byte-length ( seq -- n ) flushable
 170
 171 M: byte-array byte-length length ;
 172
 173 : c-getter ( name -- quot )
 174     c-type-getter [
 175         [ "Cannot read struct fields with type" throw ]
 176     ] unless* ;
 177
 178 : c-setter ( name -- quot )
 179     c-type-setter [
 180         [ "Cannot write struct fields with type" throw ]
 181     ] unless* ;
 182
 183 : <c-array> ( n type -- array )
 184     heap-size * <byte-array> ; inline
 185
 186 : <c-object> ( type -- array )
 187     1 swap <c-array> ; inline
 188
 189 : malloc-array ( n type -- alien )
 190     heap-size calloc ; inline
 191
 192 : malloc-object ( type -- alien )
 193     1 swap malloc-array ; inline
 194
 195 : malloc-byte-array ( byte-array -- alien )
 196     dup length dup malloc [ -rot memcpy ] keep ;
 197
 198 : memory>byte-array ( alien len -- byte-array )
 199     dup <byte-array> [ -rot memcpy ] keep ;
 200
 201 : byte-array>memory ( byte-array base -- )
 202     swap dup length memcpy ;
 203
 204 : (define-nth) ( word type quot -- )
 205     [
 206         \ swap , [ heap-size , [ * >fixnum ] % ] [ % ] bi*
 207     ] [ ] make define-inline ;
 208
 209 : nth-word ( name vocab -- word )
 210     >r "-nth" append r> create ;
 211
 212 : define-nth ( name vocab -- )
 213     dupd nth-word swap dup c-getter (define-nth) ;
 214
 215 : set-nth-word ( name vocab -- word )
 216     >r "set-" swap "-nth" 3append r> create ;
 217
 218 : define-set-nth ( name vocab -- )
 219     dupd set-nth-word swap dup c-setter (define-nth) ;
 220
 221 : typedef ( old new -- ) c-types get set-at ;
 222
 223 : define-c-type ( type name vocab -- )
 224     >r tuck typedef r> [ define-nth ] 2keep define-set-nth ;
 225
 226 TUPLE: long-long-type < c-type ;
 227
 228 : <long-long-type> ( -- type )
 229     long-long-type new-c-type ;
 230
 231 M: long-long-type unbox-parameter ( n type -- )
 232     c-type-unboxer %unbox-long-long ;
 233
 234 M: long-long-type unbox-return ( type -- )
 235     f swap unbox-parameter ;
 236
 237 M: long-long-type box-parameter ( n type -- )
 238     c-type-boxer %box-long-long ;
 239
 240 M: long-long-type box-return ( type -- )
 241     f swap box-parameter ;
 242
 243 : define-deref ( name vocab -- )
 244     >r dup CHAR: * prefix r> create
 245     swap c-getter 0 prefix define-inline ;
 246
 247 : define-out ( name vocab -- )
 248     over [ <c-object> tuck 0 ] over c-setter append swap
 249     >r >r constructor-word r> r> prefix define-inline ;
 250
 251 : c-bool> ( int -- ? )
 252     zero? not ;
 253
 254 : >c-array ( seq type word -- byte-array )
 255     [ [ dup length ] dip <c-array> ] dip
 256     [ [ execute ] 2curry each-index ] 2keep drop ; inline
 257
 258 : >c-array-quot ( type vocab -- quot )
 259     dupd set-nth-word [ >c-array ] 2curry ;
 260
 261 : to-array-word ( name vocab -- word )
 262     >r ">c-" swap "-array" 3append r> create ;
 263
 264 : define-to-array ( type vocab -- )
 265     [ to-array-word ] 2keep >c-array-quot
 266     (( array -- byte-array )) define-declared ;
 267
 268 : c-array>quot ( type vocab -- quot )
 269     [
 270         \ swap ,
 271         nth-word 1quotation ,
 272         [ curry map ] %
 273     ] [ ] make ;
 274
 275 : from-array-word ( name vocab -- word )
 276     >r "c-" swap "-array>" 3append r> create ;
 277
 278 : define-from-array ( type vocab -- )
 279     [ from-array-word ] 2keep c-array>quot
 280     (( c-ptr n -- array )) define-declared ;
 281
 282 : define-primitive-type ( type name -- )
 283     "alien.c-types"
 284     {
 285         [ define-c-type ]
 286         [ define-deref ]
 287         [ define-to-array ]
 288         [ define-from-array ]
 289         [ define-out ]
 290     } 2cleave ;
 291
 292 : expand-constants ( c-type -- c-type' )
 293     dup array? [
 294         unclip >r [
 295             dup word? [
 296                 def>> { } swap with-datastack first
 297             ] when
 298         ] map r> prefix
 299     ] when ;
 300
 301 : malloc-file-contents ( path -- alien len )
 302     binary file-contents dup malloc-byte-array swap length ;
 303
 304 : if-void ( type true false -- )
 305     pick "void" = [ drop nip call ] [ nip call ] if ; inline
 306
 307 [
 308     <c-type>
 309         [ alien-cell ] >>getter
 310         [ set-alien-cell ] >>setter
 311         bootstrap-cell >>size
 312         bootstrap-cell >>align
 313         "box_alien" >>boxer
 314         "alien_offset" >>unboxer
 315     "void*" define-primitive-type
 316
 317     <long-long-type>
 318         [ alien-signed-8 ] >>getter
 319         [ set-alien-signed-8 ] >>setter
 320         8 >>size
 321         8 >>align
 322         "box_signed_8" >>boxer
 323         "to_signed_8" >>unboxer
 324     "longlong" define-primitive-type
 325
 326     <long-long-type>
 327         [ alien-unsigned-8 ] >>getter
 328         [ set-alien-unsigned-8 ] >>setter
 329         8 >>size
 330         8 >>align
 331         "box_unsigned_8" >>boxer
 332         "to_unsigned_8" >>unboxer
 333     "ulonglong" define-primitive-type
 334
 335     <c-type>
 336         [ alien-signed-cell ] >>getter
 337         [ set-alien-signed-cell ] >>setter
 338         bootstrap-cell >>size
 339         bootstrap-cell >>align
 340         "box_signed_cell" >>boxer
 341         "to_fixnum" >>unboxer
 342     "long" define-primitive-type
 343
 344     <c-type>
 345         [ alien-unsigned-cell ] >>getter
 346         [ set-alien-unsigned-cell ] >>setter
 347         bootstrap-cell >>size
 348         bootstrap-cell >>align
 349         "box_unsigned_cell" >>boxer
 350         "to_cell" >>unboxer
 351     "ulong" define-primitive-type
 352
 353     <c-type>
 354         [ alien-signed-4 ] >>getter
 355         [ set-alien-signed-4 ] >>setter
 356         4 >>size
 357         4 >>align
 358         "box_signed_4" >>boxer
 359         "to_fixnum" >>unboxer
 360     "int" define-primitive-type
 361
 362     <c-type>
 363         [ alien-unsigned-4 ] >>getter
 364         [ set-alien-unsigned-4 ] >>setter
 365         4 >>size
 366         4 >>align
 367         "box_unsigned_4" >>boxer
 368         "to_cell" >>unboxer
 369     "uint" define-primitive-type
 370
 371     <c-type>
 372         [ alien-signed-2 ] >>getter
 373         [ set-alien-signed-2 ] >>setter
 374         2 >>size
 375         2 >>align
 376         "box_signed_2" >>boxer
 377         "to_fixnum" >>unboxer
 378     "short" define-primitive-type
 379
 380     <c-type>
 381         [ alien-unsigned-2 ] >>getter
 382         [ set-alien-unsigned-2 ] >>setter
 383         2 >>size
 384         2 >>align
 385         "box_unsigned_2" >>boxer
 386         "to_cell" >>unboxer
 387     "ushort" define-primitive-type
 388
 389     <c-type>
 390         [ alien-signed-1 ] >>getter
 391         [ set-alien-signed-1 ] >>setter
 392         1 >>size
 393         1 >>align
 394         "box_signed_1" >>boxer
 395         "to_fixnum" >>unboxer
 396     "char" define-primitive-type
 397
 398     <c-type>
 399         [ alien-unsigned-1 ] >>getter
 400         [ set-alien-unsigned-1 ] >>setter
 401         1 >>size
 402         1 >>align
 403         "box_unsigned_1" >>boxer
 404         "to_cell" >>unboxer
 405     "uchar" define-primitive-type
 406
 407     <c-type>
 408         [ alien-unsigned-4 zero? not ] >>getter
 409         [ [ 1 0 ? ] 2dip set-alien-unsigned-4 ] >>setter
 410         4 >>size
 411         4 >>align
 412         "box_boolean" >>boxer
 413         "to_boolean" >>unboxer
 414     "bool" define-primitive-type
 415
 416     <c-type>
 417         [ alien-float ] >>getter
 418         [ [ >float ] 2dip set-alien-float ] >>setter
 419         4 >>size
 420         4 >>align
 421         "box_float" >>boxer
 422         "to_float" >>unboxer
 423         single-float-regs >>reg-class
 424         [ >float ] >>unboxer-quot
 425     "float" define-primitive-type
 426
 427     <c-type>
 428         [ alien-double ] >>getter
 429         [ [ >float ] 2dip set-alien-double ] >>setter
 430         8 >>size
 431         8 >>align
 432         "box_double" >>boxer
 433         "to_double" >>unboxer
 434         double-float-regs >>reg-class
 435         [ >float ] >>unboxer-quot
 436     "double" define-primitive-type
 437
 438     os winnt? cpu x86.64? and "longlong" "long" ? "ptrdiff_t" typedef
 439
 440     "ulong" "size_t" typedef
 441 ] with-compilation-unit