basis/alien/c-types/c-types.factor

   1 ! Copyright (C) 2004, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: byte-arrays arrays assocs kernel kernel.private math
   4 math.order math.parser namespaces make parser sequences strings
   5 words splitting cpu.architecture alien alien.accessors
   6 alien.strings quotations layouts system compiler.units io
   7 io.files io.encodings.binary io.streams.memory accessors
   8 combinators effects continuations fry classes vocabs
   9 vocabs.loader words.symbol ;
  10 QUALIFIED: math
  11 IN: alien.c-types
  12
  13 SYMBOLS:
  14     char uchar
  15     short ushort
  16     int uint
  17     long ulong
  18     longlong ulonglong
  19     float double
  20     bool void*
  21     void ;
  22
  23 DEFER: <int>
  24 DEFER: *char
  25
  26 TUPLE: abstract-c-type
  27 { class class initial: object }
  28 { boxed-class class initial: object }
  29 { boxer-quot callable }
  30 { unboxer-quot callable }
  31 { getter callable }
  32 { setter callable }
  33 { size integer }
  34 { align integer }
  35 { align-first integer } ;
  36
  37 TUPLE: c-type < abstract-c-type
  38 boxer
  39 unboxer
  40 { rep initial: int-rep }
  41 stack-align? ;
  42
  43 : <c-type> ( -- c-type )
  44     \ c-type new ; inline
  45
  46 ERROR: no-c-type name ;
  47
  48 ! C type protocol
  49 GENERIC: c-type ( name -- c-type ) foldable
  50
  51 : void? ( c-type -- ? )
  52     void = ; inline
  53
  54 PREDICATE: c-type-word < word
  55     "c-type" word-prop ;
  56
  57 TUPLE: pointer { to initial: void read-only } ;
  58 C: <pointer> pointer
  59
  60 UNION: c-type-name
  61     c-type-word pointer ;
  62
  63 : resolve-typedef ( name -- c-type )
  64     dup void? [ no-c-type ] when
  65     dup c-type-name? [ c-type ] when ;
  66
  67 <PRIVATE
  68
  69 : parse-array-type ( name -- dims c-type )
  70     "[" split unclip
  71     [ [ "]" ?tail drop string>number ] map ] dip ;
  72
  73 PRIVATE>
  74
  75 M: word c-type
  76     dup "c-type" word-prop resolve-typedef
  77     [ ] [ no-c-type ] ?if ;
  78
  79 GENERIC: c-struct? ( c-type -- ? )
  80
  81 M: object c-struct? drop f ;
  82
  83 M: c-type-name c-struct? dup void? [ drop f ] [ c-type c-struct? ] if ;
  84
  85 ! These words being foldable means that words need to be
  86 ! recompiled if a C type is redefined. Even so, folding the
  87 ! size facilitates some optimizations.
  88 GENERIC: c-type-class ( name -- class )
  89
  90 M: abstract-c-type c-type-class class>> ;
  91
  92 M: c-type-name c-type-class c-type c-type-class ;
  93
  94 GENERIC: c-type-boxed-class ( name -- class )
  95
  96 M: abstract-c-type c-type-boxed-class boxed-class>> ;
  97
  98 M: c-type-name c-type-boxed-class c-type c-type-boxed-class ;
  99
 100 GENERIC: c-type-boxer ( name -- boxer )
 101
 102 M: c-type c-type-boxer boxer>> ;
 103
 104 M: c-type-name c-type-boxer c-type c-type-boxer ;
 105
 106 GENERIC: c-type-boxer-quot ( name -- quot )
 107
 108 M: abstract-c-type c-type-boxer-quot boxer-quot>> ;
 109
 110 M: c-type-name c-type-boxer-quot c-type c-type-boxer-quot ;
 111
 112 GENERIC: c-type-unboxer ( name -- boxer )
 113
 114 M: c-type c-type-unboxer unboxer>> ;
 115
 116 M: c-type-name c-type-unboxer c-type c-type-unboxer ;
 117
 118 GENERIC: c-type-unboxer-quot ( name -- quot )
 119
 120 M: abstract-c-type c-type-unboxer-quot unboxer-quot>> ;
 121
 122 M: c-type-name c-type-unboxer-quot c-type c-type-unboxer-quot ;
 123
 124 GENERIC: c-type-rep ( name -- rep )
 125
 126 M: c-type c-type-rep rep>> ;
 127
 128 M: c-type-name c-type-rep c-type c-type-rep ;
 129
 130 GENERIC: c-type-getter ( name -- quot )
 131
 132 M: c-type c-type-getter getter>> ;
 133
 134 M: c-type-name c-type-getter c-type c-type-getter ;
 135
 136 GENERIC: c-type-setter ( name -- quot )
 137
 138 M: c-type c-type-setter setter>> ;
 139
 140 M: c-type-name c-type-setter c-type c-type-setter ;
 141
 142 GENERIC: c-type-align ( name -- n )
 143
 144 M: abstract-c-type c-type-align align>> ;
 145
 146 M: c-type-name c-type-align c-type c-type-align ;
 147
 148 GENERIC: c-type-align-first ( name -- n )
 149
 150 M: c-type-name c-type-align-first c-type c-type-align-first ;
 151
 152 M: abstract-c-type c-type-align-first align-first>> ;
 153
 154 GENERIC: c-type-stack-align? ( name -- ? )
 155
 156 M: c-type c-type-stack-align? stack-align?>> ;
 157
 158 M: c-type-name c-type-stack-align? c-type c-type-stack-align? ;
 159
 160 : c-type-box ( n c-type -- )
 161     [ c-type-rep ] [ c-type-boxer [ "No boxer" throw ] unless* ] bi
 162     %box ;
 163
 164 : c-type-unbox ( n c-type -- )
 165     [ c-type-rep ] [ c-type-unboxer [ "No unboxer" throw ] unless* ] bi
 166     %unbox ;
 167
 168 GENERIC: box-parameter ( n c-type -- )
 169
 170 M: c-type box-parameter c-type-box ;
 171
 172 M: c-type-name box-parameter c-type box-parameter ;
 173
 174 GENERIC: box-return ( c-type -- )
 175
 176 M: c-type box-return f swap c-type-box ;
 177
 178 M: c-type-name box-return c-type box-return ;
 179
 180 GENERIC: unbox-parameter ( n c-type -- )
 181
 182 M: c-type unbox-parameter c-type-unbox ;
 183
 184 M: c-type-name unbox-parameter c-type unbox-parameter ;
 185
 186 GENERIC: unbox-return ( c-type -- )
 187
 188 M: c-type unbox-return f swap c-type-unbox ;
 189
 190 M: c-type-name unbox-return c-type unbox-return ;
 191
 192 : little-endian? ( -- ? ) 1 <int> *char 1 = ; foldable
 193
 194 GENERIC: heap-size ( name -- size )
 195
 196 M: c-type-name heap-size c-type heap-size ;
 197
 198 M: abstract-c-type heap-size size>> ;
 199
 200 GENERIC: stack-size ( name -- size )
 201
 202 M: c-type-name stack-size c-type stack-size ;
 203
 204 M: c-type stack-size size>> cell align ;
 205
 206 GENERIC: byte-length ( seq -- n ) flushable
 207
 208 M: byte-array byte-length length ; inline
 209
 210 M: f byte-length drop 0 ; inline
 211
 212 : >c-bool ( ? -- int ) 1 0 ? ; inline
 213
 214 : c-bool> ( int -- ? ) 0 = not ; inline
 215
 216 MIXIN: value-type
 217
 218 : c-getter ( name -- quot )
 219     c-type-getter [
 220         [ "Cannot read struct fields with this type" throw ]
 221     ] unless* ;
 222
 223 : c-type-getter-boxer ( name -- quot )
 224     [ c-getter ] [ c-type-boxer-quot ] bi append ;
 225
 226 : c-setter ( name -- quot )
 227     c-type-setter [
 228         [ "Cannot write struct fields with this type" throw ]
 229     ] unless* ;
 230
 231 : array-accessor ( c-type quot -- def )
 232     [
 233         \ swap , [ heap-size , [ * >fixnum ] % ] [ % ] bi*
 234     ] [ ] make ;
 235
 236 GENERIC: typedef ( old new -- )
 237
 238 PREDICATE: typedef-word < c-type-word
 239     "c-type" word-prop c-type-name? ;
 240
 241 M: word typedef ( old new -- )
 242     {
 243         [ nip define-symbol ]
 244         [ swap "c-type" set-word-prop ]
 245     } 2cleave ;
 246
 247 M: pointer typedef ( old new -- )
 248     to>> dup c-type-word?
 249     [ swap "pointer-c-type" set-word-prop ]
 250     [ 2drop ] if ;
 251
 252 TUPLE: long-long-type < c-type ;
 253
 254 : <long-long-type> ( -- c-type )
 255     long-long-type new ;
 256
 257 M: long-long-type unbox-parameter ( n c-type -- )
 258     c-type-unboxer %unbox-long-long ;
 259
 260 M: long-long-type unbox-return ( c-type -- )
 261     f swap unbox-parameter ;
 262
 263 M: long-long-type box-parameter ( n c-type -- )
 264     c-type-boxer %box-long-long ;
 265
 266 M: long-long-type box-return ( c-type -- )
 267     f swap box-parameter ;
 268
 269 : define-deref ( c-type -- )
 270     [ name>> CHAR: * prefix "alien.c-types" create ] [ c-getter 0 prefix ] bi
 271     (( c-ptr -- value )) define-inline ;
 272
 273 : define-out ( c-type -- )
 274     [ name>> "alien.c-types" constructor-word ]
 275     [ dup c-setter '[ _ heap-size (byte-array) [ 0 @ ] keep ] ] bi
 276     (( value -- c-ptr )) define-inline ;
 277
 278 : define-primitive-type ( c-type name -- )
 279     [ typedef ] [ define-deref ] [ define-out ] tri ;
 280
 281 : if-void ( c-type true false -- )
 282     pick void? [ drop nip call ] [ nip call ] if ; inline
 283
 284 SYMBOLS:
 285     ptrdiff_t intptr_t uintptr_t size_t
 286     byte ubyte char* ;
 287
 288 CONSTANT: primitive-types
 289     {
 290         char uchar
 291         short ushort
 292         int uint
 293         long ulong
 294         longlong ulonglong
 295         float double
 296         void* bool
 297         char*
 298     }
 299
 300 : (pointer-c-type) ( void* type -- void*' )
 301     [ clone ] dip c-type-boxer-quot >>boxer-quot ;
 302
 303 <PRIVATE
 304
 305 : resolve-pointer-typedef ( type -- base-type )
 306     dup "c-type" word-prop dup word?
 307     [ nip resolve-pointer-typedef ] [
 308         pointer? [ drop void* ] when
 309     ] if ;
 310
 311 : special-pointer-type ( type -- special-type )
 312     dup c-type-word? [
 313         dup "pointer-c-type" word-prop
 314         [ ] [ resolve-pointer-typedef "pointer-c-type" word-prop ] ?if
 315     ] [ drop f ] if ;
 316
 317 : primitive-pointer-type? ( type -- ? )
 318     dup c-type-word? [
 319         resolve-pointer-typedef [ void? ] [ primitive-types member? ] bi or
 320     ] [ drop t ] if ;
 321
 322 PRIVATE>
 323
 324 M: pointer c-type
 325     [ \ void* c-type ] dip
 326     to>> dup special-pointer-type
 327     [ nip ] [
 328         dup primitive-pointer-type? [ drop ] [ (pointer-c-type) ] if
 329     ] ?if ;
 330
 331 : 8-byte-alignment ( c-type -- c-type )
 332     {
 333         { [ cpu ppc? os macosx? and ] [ 4 >>align 8 >>align-first ] }
 334         { [ cpu x86.32? os windows? not and ] [ 4 >>align 4 >>align-first ] }
 335         [ 8 >>align 8 >>align-first ]
 336     } cond ;
 337
 338 [
 339     <c-type>
 340         c-ptr >>class
 341         c-ptr >>boxed-class
 342         [ alien-cell ] >>getter
 343         [ [ >c-ptr ] 2dip set-alien-cell ] >>setter
 344         bootstrap-cell >>size
 345         bootstrap-cell >>align
 346         bootstrap-cell >>align-first
 347         [ >c-ptr ] >>unboxer-quot
 348         "allot_alien" >>boxer
 349         "alien_offset" >>unboxer
 350     \ void* define-primitive-type
 351
 352     <c-type>
 353         integer >>class
 354         integer >>boxed-class
 355         [ alien-signed-4 ] >>getter
 356         [ set-alien-signed-4 ] >>setter
 357         4 >>size
 358         4 >>align
 359         4 >>align-first
 360         "from_signed_4" >>boxer
 361         "to_fixnum" >>unboxer
 362     \ int define-primitive-type
 363
 364     <c-type>
 365         integer >>class
 366         integer >>boxed-class
 367         [ alien-unsigned-4 ] >>getter
 368         [ set-alien-unsigned-4 ] >>setter
 369         4 >>size
 370         4 >>align
 371         4 >>align-first
 372         "from_unsigned_4" >>boxer
 373         "to_cell" >>unboxer
 374     \ uint define-primitive-type
 375
 376     <c-type>
 377         fixnum >>class
 378         fixnum >>boxed-class
 379         [ alien-signed-2 ] >>getter
 380         [ set-alien-signed-2 ] >>setter
 381         2 >>size
 382         2 >>align
 383         2 >>align-first
 384         "from_signed_2" >>boxer
 385         "to_fixnum" >>unboxer
 386     \ short define-primitive-type
 387
 388     <c-type>
 389         fixnum >>class
 390         fixnum >>boxed-class
 391         [ alien-unsigned-2 ] >>getter
 392         [ set-alien-unsigned-2 ] >>setter
 393         2 >>size
 394         2 >>align
 395         2 >>align-first
 396         "from_unsigned_2" >>boxer
 397         "to_cell" >>unboxer
 398     \ ushort define-primitive-type
 399
 400     <c-type>
 401         fixnum >>class
 402         fixnum >>boxed-class
 403         [ alien-signed-1 ] >>getter
 404         [ set-alien-signed-1 ] >>setter
 405         1 >>size
 406         1 >>align
 407         1 >>align-first
 408         "from_signed_1" >>boxer
 409         "to_fixnum" >>unboxer
 410     \ char define-primitive-type
 411
 412     <c-type>
 413         fixnum >>class
 414         fixnum >>boxed-class
 415         [ alien-unsigned-1 ] >>getter
 416         [ set-alien-unsigned-1 ] >>setter
 417         1 >>size
 418         1 >>align
 419         1 >>align-first
 420         "from_unsigned_1" >>boxer
 421         "to_cell" >>unboxer
 422     \ uchar define-primitive-type
 423
 424     cpu ppc? [
 425         <c-type>
 426             [ alien-unsigned-4 c-bool> ] >>getter
 427             [ [ >c-bool ] 2dip set-alien-unsigned-4 ] >>setter
 428             4 >>size
 429             4 >>align
 430             4 >>align-first
 431             "from_boolean" >>boxer
 432             "to_boolean" >>unboxer
 433     ] [
 434         <c-type>
 435             [ alien-unsigned-1 c-bool> ] >>getter
 436             [ [ >c-bool ] 2dip set-alien-unsigned-1 ] >>setter
 437             1 >>size
 438             1 >>align
 439             1 >>align-first
 440             "from_boolean" >>boxer
 441             "to_boolean" >>unboxer
 442     ] if
 443     \ bool define-primitive-type
 444
 445     <c-type>
 446         math:float >>class
 447         math:float >>boxed-class
 448         [ alien-float ] >>getter
 449         [ [ >float ] 2dip set-alien-float ] >>setter
 450         4 >>size
 451         4 >>align
 452         4 >>align-first
 453         "from_float" >>boxer
 454         "to_float" >>unboxer
 455         float-rep >>rep
 456         [ >float ] >>unboxer-quot
 457     \ float define-primitive-type
 458
 459     <c-type>
 460         math:float >>class
 461         math:float >>boxed-class
 462         [ alien-double ] >>getter
 463         [ [ >float ] 2dip set-alien-double ] >>setter
 464         8 >>size
 465         8-byte-alignment
 466         "from_double" >>boxer
 467         "to_double" >>unboxer
 468         double-rep >>rep
 469         [ >float ] >>unboxer-quot
 470     \ double define-primitive-type
 471
 472     cell 8 = [
 473         <c-type>
 474             integer >>class
 475             integer >>boxed-class
 476             [ alien-signed-cell ] >>getter
 477             [ set-alien-signed-cell ] >>setter
 478             bootstrap-cell >>size
 479             bootstrap-cell >>align
 480             bootstrap-cell >>align-first
 481             "from_signed_cell" >>boxer
 482             "to_fixnum" >>unboxer
 483         \ longlong define-primitive-type
 484
 485         <c-type>
 486             integer >>class
 487             integer >>boxed-class
 488             [ alien-unsigned-cell ] >>getter
 489             [ set-alien-unsigned-cell ] >>setter
 490             bootstrap-cell >>size
 491             bootstrap-cell >>align
 492             bootstrap-cell >>align-first
 493             "from_unsigned_cell" >>boxer
 494             "to_cell" >>unboxer
 495         \ ulonglong define-primitive-type
 496
 497         os windows? [
 498             \ int c-type \ long define-primitive-type
 499             \ uint c-type \ ulong define-primitive-type
 500         ] [
 501             \ longlong c-type \ long define-primitive-type
 502             \ ulonglong c-type \ ulong define-primitive-type
 503         ] if
 504
 505         \ longlong c-type \ ptrdiff_t typedef
 506         \ longlong c-type \ intptr_t typedef
 507
 508         \ ulonglong c-type \ uintptr_t typedef
 509         \ ulonglong c-type \ size_t typedef
 510     ] [
 511         <long-long-type>
 512             integer >>class
 513             integer >>boxed-class
 514             [ alien-signed-8 ] >>getter
 515             [ set-alien-signed-8 ] >>setter
 516             8 >>size
 517             8-byte-alignment
 518             "from_signed_8" >>boxer
 519             "to_signed_8" >>unboxer
 520         \ longlong define-primitive-type
 521
 522         <long-long-type>
 523             integer >>class
 524             integer >>boxed-class
 525             [ alien-unsigned-8 ] >>getter
 526             [ set-alien-unsigned-8 ] >>setter
 527             8 >>size
 528             8-byte-alignment
 529             "from_unsigned_8" >>boxer
 530             "to_unsigned_8" >>unboxer
 531         \ ulonglong define-primitive-type
 532
 533         \ int c-type \ long define-primitive-type
 534         \ uint c-type \ ulong define-primitive-type
 535
 536         \ int c-type \ ptrdiff_t typedef
 537         \ int c-type \ intptr_t typedef
 538
 539         \ uint c-type \ uintptr_t typedef
 540         \ uint c-type \ size_t typedef
 541     ] if
 542
 543     \ char \ byte typedef
 544     \ uchar \ ubyte typedef
 545 ] with-compilation-unit
 546
 547 M: char-16-rep rep-component-type drop char ;
 548 M: uchar-16-rep rep-component-type drop uchar ;
 549 M: short-8-rep rep-component-type drop short ;
 550 M: ushort-8-rep rep-component-type drop ushort ;
 551 M: int-4-rep rep-component-type drop int ;
 552 M: uint-4-rep rep-component-type drop uint ;
 553 M: longlong-2-rep rep-component-type drop longlong ;
 554 M: ulonglong-2-rep rep-component-type drop ulonglong ;
 555 M: float-4-rep rep-component-type drop float ;
 556 M: double-2-rep rep-component-type drop double ;
 557
 558 : (unsigned-interval) ( bytes -- from to ) [ 0 ] dip 8 * 2^ 1 - ; foldable
 559 : unsigned-interval ( c-type -- from to ) heap-size (unsigned-interval) ; foldable
 560 : (signed-interval) ( bytes -- from to ) 8 * 1 - 2^ [ neg ] [ 1 - ] bi ; foldable
 561 : signed-interval ( c-type -- from to ) heap-size (signed-interval) ; foldable
 562
 563 : c-type-interval ( c-type -- from to )
 564     {
 565         { [ dup { float double } member-eq? ] [ drop -1/0. 1/0. ] }
 566         { [ dup { char short int long longlong } member-eq? ] [ signed-interval ] }
 567         { [ dup { uchar ushort uint ulong ulonglong } member-eq? ] [ unsigned-interval ] }
 568     } cond ; foldable
 569
 570 : c-type-clamp ( value c-type -- value' )
 571     dup { float double } member-eq?
 572     [ drop ] [ c-type-interval clamp ] if ; inline