basis/alien/c-types/c-types.factor

   1 ! Copyright (C) 2004, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: byte-arrays arrays assocs kernel kernel.private libc math
   4 namespaces make parser sequences strings words splitting math.parser
   5 cpu.architecture alien alien.accessors alien.strings quotations
   6 layouts system compiler.units io io.files io.encodings.binary
   7 io.streams.memory accessors combinators effects continuations fry
   8 classes vocabs vocabs.loader ;
   9 IN: alien.c-types
  10
  11 DEFER: <int>
  12 DEFER: *char
  13
  14 : little-endian? ( -- ? ) 1 <int> *char 1 = ; foldable
  15
  16 TUPLE: abstract-c-type
  17 { class class initial: object }
  18 { boxed-class class initial: object }
  19 { boxer-quot callable }
  20 { unboxer-quot callable }
  21 { getter callable }
  22 { setter callable }
  23 size
  24 align
  25 array-class
  26 array-constructor
  27 (array)-constructor
  28 direct-array-constructor ;
  29
  30 TUPLE: c-type < abstract-c-type
  31 boxer
  32 unboxer
  33 { rep initial: int-rep }
  34 stack-align? ;
  35
  36 : <c-type> ( -- type )
  37     \ c-type new ;
  38
  39 SYMBOL: c-types
  40
  41 global [
  42     c-types [ H{ } assoc-like ] change
  43 ] bind
  44
  45 ERROR: no-c-type name ;
  46
  47 : (c-type) ( name -- type/f )
  48     c-types get-global at dup [
  49         dup string? [ (c-type) ] when
  50     ] when ;
  51
  52 ! C type protocol
  53 GENERIC: c-type ( name -- type ) foldable
  54
  55 : resolve-pointer-type ( name -- name )
  56     c-types get at dup string?
  57     [ "*" append ] [ drop "void*" ] if
  58     c-type ;
  59
  60 : resolve-typedef ( name -- type )
  61     dup string? [ c-type ] when ;
  62
  63 : parse-array-type ( name -- array )
  64     "[" split unclip
  65     [ [ "]" ?tail drop string>number ] map ] dip prefix ;
  66
  67 M: string c-type ( name -- type )
  68     CHAR: ] over member? [
  69         parse-array-type
  70     ] [
  71         dup c-types get at [
  72             resolve-typedef
  73         ] [
  74             "*" ?tail [ resolve-pointer-type ] [ no-c-type ] if
  75         ] ?if
  76     ] if ;
  77
  78 : ?require-word ( word/pair -- )
  79     dup word? [ drop ] [ first require ] ?if ;
  80
  81 ! These words being foldable means that words need to be
  82 ! recompiled if a C type is redefined. Even so, folding the
  83 ! size facilitates some optimizations.
  84 GENERIC: heap-size ( type -- size ) foldable
  85
  86 M: string heap-size c-type heap-size ;
  87
  88 M: abstract-c-type heap-size size>> ;
  89
  90 GENERIC: require-c-array ( c-type -- )
  91
  92 M: object require-c-array
  93     drop ;
  94
  95 M: c-type require-c-array
  96     array-class>> ?require-word ;
  97
  98 M: string require-c-array
  99     c-type require-c-array ;
 100
 101 M: array require-c-array
 102     first c-type require-c-array ;
 103
 104 ERROR: specialized-array-vocab-not-loaded vocab word ;
 105
 106 : c-array-constructor ( c-type -- word )
 107     array-constructor>> dup array?
 108     [ first2 specialized-array-vocab-not-loaded ] when ; foldable
 109
 110 : c-(array)-constructor ( c-type -- word )
 111     (array)-constructor>> dup array?
 112     [ first2 specialized-array-vocab-not-loaded ] when ; foldable
 113
 114 : c-direct-array-constructor ( c-type -- word )
 115     direct-array-constructor>> dup array?
 116     [ first2 specialized-array-vocab-not-loaded ] when ; foldable
 117
 118 GENERIC: <c-array> ( len c-type -- array )
 119 M: object <c-array>
 120     c-array-constructor execute( len -- array ) ; inline
 121 M: string <c-array>
 122     c-type <c-array> ; inline
 123 M: array <c-array>
 124     first c-type <c-array> ; inline
 125
 126 GENERIC: (c-array) ( len c-type -- array )
 127 M: object (c-array)
 128     c-(array)-constructor execute( len -- array ) ; inline
 129 M: string (c-array)
 130     c-type (c-array) ; inline
 131 M: array (c-array)
 132     first c-type (c-array) ; inline
 133
 134 GENERIC: <c-direct-array> ( alien len c-type -- array )
 135 M: object <c-direct-array>
 136     c-direct-array-constructor execute( alien len -- array ) ; inline
 137 M: string <c-direct-array>
 138     c-type <c-direct-array> ; inline
 139 M: array <c-direct-array>
 140     first c-type <c-direct-array> ; inline
 141
 142 : malloc-array ( n type -- alien )
 143     [ heap-size calloc ] [ <c-direct-array> ] 2bi ; inline
 144
 145 : (malloc-array) ( n type -- alien )
 146     [ heap-size * malloc ] [ <c-direct-array> ] 2bi ; inline
 147
 148 GENERIC: c-type-class ( name -- class )
 149
 150 M: abstract-c-type c-type-class class>> ;
 151
 152 M: string c-type-class c-type c-type-class ;
 153
 154 GENERIC: c-type-boxed-class ( name -- class )
 155
 156 M: abstract-c-type c-type-boxed-class boxed-class>> ;
 157
 158 M: string c-type-boxed-class c-type c-type-boxed-class ;
 159
 160 GENERIC: c-type-boxer ( name -- boxer )
 161
 162 M: c-type c-type-boxer boxer>> ;
 163
 164 M: string c-type-boxer c-type c-type-boxer ;
 165
 166 GENERIC: c-type-boxer-quot ( name -- quot )
 167
 168 M: abstract-c-type c-type-boxer-quot boxer-quot>> ;
 169
 170 M: string c-type-boxer-quot c-type c-type-boxer-quot ;
 171
 172 GENERIC: c-type-unboxer ( name -- boxer )
 173
 174 M: c-type c-type-unboxer unboxer>> ;
 175
 176 M: string c-type-unboxer c-type c-type-unboxer ;
 177
 178 GENERIC: c-type-unboxer-quot ( name -- quot )
 179
 180 M: abstract-c-type c-type-unboxer-quot unboxer-quot>> ;
 181
 182 M: string c-type-unboxer-quot c-type c-type-unboxer-quot ;
 183
 184 GENERIC: c-type-rep ( name -- rep )
 185
 186 M: c-type c-type-rep rep>> ;
 187
 188 M: string c-type-rep c-type c-type-rep ;
 189
 190 GENERIC: c-type-getter ( name -- quot )
 191
 192 M: c-type c-type-getter getter>> ;
 193
 194 M: string c-type-getter c-type c-type-getter ;
 195
 196 GENERIC: c-type-setter ( name -- quot )
 197
 198 M: c-type c-type-setter setter>> ;
 199
 200 M: string c-type-setter c-type c-type-setter ;
 201
 202 GENERIC: c-type-align ( name -- n )
 203
 204 M: abstract-c-type c-type-align align>> ;
 205
 206 M: string c-type-align c-type c-type-align ;
 207
 208 GENERIC: c-type-stack-align? ( name -- ? )
 209
 210 M: c-type c-type-stack-align? stack-align?>> ;
 211
 212 M: string c-type-stack-align? c-type c-type-stack-align? ;
 213
 214 : c-type-box ( n type -- )
 215     [ c-type-rep ] [ c-type-boxer [ "No boxer" throw ] unless* ] bi
 216     %box ;
 217
 218 : c-type-unbox ( n ctype -- )
 219     [ c-type-rep ] [ c-type-unboxer [ "No unboxer" throw ] unless* ] bi
 220     %unbox ;
 221
 222 GENERIC: box-parameter ( n ctype -- )
 223
 224 M: c-type box-parameter c-type-box ;
 225
 226 M: string box-parameter c-type box-parameter ;
 227
 228 GENERIC: box-return ( ctype -- )
 229
 230 M: c-type box-return f swap c-type-box ;
 231
 232 M: string box-return c-type box-return ;
 233
 234 GENERIC: unbox-parameter ( n ctype -- )
 235
 236 M: c-type unbox-parameter c-type-unbox ;
 237
 238 M: string unbox-parameter c-type unbox-parameter ;
 239
 240 GENERIC: unbox-return ( ctype -- )
 241
 242 M: c-type unbox-return f swap c-type-unbox ;
 243
 244 M: string unbox-return c-type unbox-return ;
 245
 246 GENERIC: stack-size ( type -- size ) foldable
 247
 248 M: string stack-size c-type stack-size ;
 249
 250 M: c-type stack-size size>> cell align ;
 251
 252 GENERIC: byte-length ( seq -- n ) flushable
 253
 254 M: byte-array byte-length length ; inline
 255
 256 M: f byte-length drop 0 ; inline
 257
 258 : c-getter ( name -- quot )
 259     c-type-getter [
 260         [ "Cannot read struct fields with this type" throw ]
 261     ] unless* ;
 262
 263 : c-type-getter-boxer ( name -- quot )
 264     [ c-getter ] [ c-type-boxer-quot ] bi append ;
 265
 266 : c-setter ( name -- quot )
 267     c-type-setter [
 268         [ "Cannot write struct fields with this type" throw ]
 269     ] unless* ;
 270
 271 : <c-object> ( type -- array )
 272     heap-size <byte-array> ; inline
 273
 274 : (c-object) ( type -- array )
 275     heap-size (byte-array) ; inline
 276
 277 : malloc-object ( type -- alien )
 278     1 swap heap-size calloc ; inline
 279
 280 : (malloc-object) ( type -- alien )
 281     heap-size malloc ; inline
 282
 283 : malloc-byte-array ( byte-array -- alien )
 284     dup byte-length [ nip malloc dup ] 2keep memcpy ;
 285
 286 : memory>byte-array ( alien len -- byte-array )
 287     [ nip (byte-array) dup ] 2keep memcpy ;
 288
 289 : malloc-string ( string encoding -- alien )
 290     string>alien malloc-byte-array ;
 291
 292 M: memory-stream stream-read
 293     [
 294         [ index>> ] [ alien>> ] bi <displaced-alien>
 295         swap memory>byte-array
 296     ] [ [ + ] change-index drop ] 2bi ;
 297
 298 : byte-array>memory ( byte-array base -- )
 299     swap dup byte-length memcpy ; inline
 300
 301 : array-accessor ( type quot -- def )
 302     [
 303         \ swap , [ heap-size , [ * >fixnum ] % ] [ % ] bi*
 304     ] [ ] make ;
 305
 306 : typedef ( old new -- ) c-types get set-at ;
 307
 308 TUPLE: long-long-type < c-type ;
 309
 310 : <long-long-type> ( -- type )
 311     long-long-type new ;
 312
 313 M: long-long-type unbox-parameter ( n type -- )
 314     c-type-unboxer %unbox-long-long ;
 315
 316 M: long-long-type unbox-return ( type -- )
 317     f swap unbox-parameter ;
 318
 319 M: long-long-type box-parameter ( n type -- )
 320     c-type-boxer %box-long-long ;
 321
 322 M: long-long-type box-return ( type -- )
 323     f swap box-parameter ;
 324
 325 : define-deref ( name -- )
 326     [ CHAR: * prefix "alien.c-types" create ] [ c-getter 0 prefix ] bi
 327     (( c-ptr -- value )) define-inline ;
 328
 329 : define-out ( name -- )
 330     [ "alien.c-types" constructor-word ]
 331     [ dup c-setter '[ _ <c-object> [ 0 @ ] keep ] ] bi
 332     (( value -- c-ptr )) define-inline ;
 333
 334 : >c-bool ( ? -- int ) 1 0 ? ; inline
 335
 336 : c-bool> ( int -- ? ) 0 = not ; inline
 337
 338 : define-primitive-type ( type name -- )
 339     [ typedef ]
 340     [ define-deref ]
 341     [ define-out ]
 342     tri ;
 343
 344 : malloc-file-contents ( path -- alien len )
 345     binary file-contents [ malloc-byte-array ] [ length ] bi ;
 346
 347 : if-void ( type true false -- )
 348     pick "void" = [ drop nip call ] [ nip call ] if ; inline
 349
 350 : ?lookup ( vocab word -- word/pair )
 351     over vocab [ swap lookup ] [ 2array ] if ;
 352
 353 : set-array-class* ( c-type vocab-stem type-stem -- c-type )
 354     {
 355         [
 356             [ "specialized-arrays." prepend ]
 357             [ "-array" append ] bi* ?lookup >>array-class
 358         ]
 359         [
 360             [ "specialized-arrays." prepend ]
 361             [ "<" "-array>" surround ] bi* ?lookup >>array-constructor
 362         ]
 363         [
 364             [ "specialized-arrays." prepend ]
 365             [ "(" "-array)" surround ] bi* ?lookup >>(array)-constructor
 366         ]
 367         [
 368             [ "specialized-arrays." prepend ]
 369             [ "<direct-" "-array>" surround ] bi* ?lookup >>direct-array-constructor
 370         ]
 371     } 2cleave ;
 372
 373 : set-array-class ( c-type stem -- c-type )
 374     dup set-array-class* ;
 375
 376 CONSTANT: primitive-types
 377     {
 378         "char" "uchar"
 379         "short" "ushort"
 380         "int" "uint"
 381         "long" "ulong"
 382         "longlong" "ulonglong"
 383         "float" "double"
 384         "void*" "bool"
 385     }
 386
 387 [
 388     <c-type>
 389         c-ptr >>class
 390         c-ptr >>boxed-class
 391         [ alien-cell ] >>getter
 392         [ [ >c-ptr ] 2dip set-alien-cell ] >>setter
 393         bootstrap-cell >>size
 394         bootstrap-cell >>align
 395         [ >c-ptr ] >>unboxer-quot
 396         "box_alien" >>boxer
 397         "alien_offset" >>unboxer
 398         "alien" "void*" set-array-class*
 399     "void*" define-primitive-type
 400
 401     <long-long-type>
 402         integer >>class
 403         integer >>boxed-class
 404         [ alien-signed-8 ] >>getter
 405         [ set-alien-signed-8 ] >>setter
 406         8 >>size
 407         8 >>align
 408         "box_signed_8" >>boxer
 409         "to_signed_8" >>unboxer
 410         "longlong" set-array-class
 411     "longlong" define-primitive-type
 412
 413     <long-long-type>
 414         integer >>class
 415         integer >>boxed-class
 416         [ alien-unsigned-8 ] >>getter
 417         [ set-alien-unsigned-8 ] >>setter
 418         8 >>size
 419         8 >>align
 420         "box_unsigned_8" >>boxer
 421         "to_unsigned_8" >>unboxer
 422         "ulonglong" set-array-class
 423     "ulonglong" define-primitive-type
 424
 425     <c-type>
 426         integer >>class
 427         integer >>boxed-class
 428         [ alien-signed-cell ] >>getter
 429         [ set-alien-signed-cell ] >>setter
 430         bootstrap-cell >>size
 431         bootstrap-cell >>align
 432         "box_signed_cell" >>boxer
 433         "to_fixnum" >>unboxer
 434         "long" set-array-class
 435     "long" define-primitive-type
 436
 437     <c-type>
 438         integer >>class
 439         integer >>boxed-class
 440         [ alien-unsigned-cell ] >>getter
 441         [ set-alien-unsigned-cell ] >>setter
 442         bootstrap-cell >>size
 443         bootstrap-cell >>align
 444         "box_unsigned_cell" >>boxer
 445         "to_cell" >>unboxer
 446         "ulong" set-array-class
 447     "ulong" define-primitive-type
 448
 449     <c-type>
 450         integer >>class
 451         integer >>boxed-class
 452         [ alien-signed-4 ] >>getter
 453         [ set-alien-signed-4 ] >>setter
 454         4 >>size
 455         4 >>align
 456         "box_signed_4" >>boxer
 457         "to_fixnum" >>unboxer
 458         "int" set-array-class
 459     "int" define-primitive-type
 460
 461     <c-type>
 462         integer >>class
 463         integer >>boxed-class
 464         [ alien-unsigned-4 ] >>getter
 465         [ set-alien-unsigned-4 ] >>setter
 466         4 >>size
 467         4 >>align
 468         "box_unsigned_4" >>boxer
 469         "to_cell" >>unboxer
 470         "uint" set-array-class
 471     "uint" define-primitive-type
 472
 473     <c-type>
 474         fixnum >>class
 475         fixnum >>boxed-class
 476         [ alien-signed-2 ] >>getter
 477         [ set-alien-signed-2 ] >>setter
 478         2 >>size
 479         2 >>align
 480         "box_signed_2" >>boxer
 481         "to_fixnum" >>unboxer
 482         "short" set-array-class
 483     "short" define-primitive-type
 484
 485     <c-type>
 486         fixnum >>class
 487         fixnum >>boxed-class
 488         [ alien-unsigned-2 ] >>getter
 489         [ set-alien-unsigned-2 ] >>setter
 490         2 >>size
 491         2 >>align
 492         "box_unsigned_2" >>boxer
 493         "to_cell" >>unboxer
 494         "ushort" set-array-class
 495     "ushort" define-primitive-type
 496
 497     <c-type>
 498         fixnum >>class
 499         fixnum >>boxed-class
 500         [ alien-signed-1 ] >>getter
 501         [ set-alien-signed-1 ] >>setter
 502         1 >>size
 503         1 >>align
 504         "box_signed_1" >>boxer
 505         "to_fixnum" >>unboxer
 506         "char" set-array-class
 507     "char" define-primitive-type
 508
 509     <c-type>
 510         fixnum >>class
 511         fixnum >>boxed-class
 512         [ alien-unsigned-1 ] >>getter
 513         [ set-alien-unsigned-1 ] >>setter
 514         1 >>size
 515         1 >>align
 516         "box_unsigned_1" >>boxer
 517         "to_cell" >>unboxer
 518         "uchar" set-array-class
 519     "uchar" define-primitive-type
 520
 521     <c-type>
 522         [ alien-unsigned-1 c-bool> ] >>getter
 523         [ [ >c-bool ] 2dip set-alien-unsigned-1 ] >>setter
 524         1 >>size
 525         1 >>align
 526         "box_boolean" >>boxer
 527         "to_boolean" >>unboxer
 528         "bool" set-array-class
 529     "bool" define-primitive-type
 530
 531     <c-type>
 532         float >>class
 533         float >>boxed-class
 534         [ alien-float ] >>getter
 535         [ [ >float ] 2dip set-alien-float ] >>setter
 536         4 >>size
 537         4 >>align
 538         "box_float" >>boxer
 539         "to_float" >>unboxer
 540         float-rep >>rep
 541         [ >float ] >>unboxer-quot
 542         "float" set-array-class
 543     "float" define-primitive-type
 544
 545     <c-type>
 546         float >>class
 547         float >>boxed-class
 548         [ alien-double ] >>getter
 549         [ [ >float ] 2dip set-alien-double ] >>setter
 550         8 >>size
 551         8 >>align
 552         "box_double" >>boxer
 553         "to_double" >>unboxer
 554         double-rep >>rep
 555         [ >float ] >>unboxer-quot
 556         "double" set-array-class
 557     "double" define-primitive-type
 558
 559     "long" "ptrdiff_t" typedef
 560     "long" "intptr_t" typedef
 561     "ulong" "size_t" typedef
 562 ] with-compilation-unit
 563