basis/alien/c-types/c-types.factor

   1 ! Copyright (C) 2004, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: byte-arrays arrays assocs kernel kernel.private math
   4 math.order math.parser namespaces make parser sequences strings
   5 words splitting cpu.architecture alien alien.accessors
   6 alien.strings quotations layouts system compiler.units io
   7 io.files io.encodings.binary io.streams.memory accessors
   8 combinators effects continuations fry classes vocabs
   9 vocabs.loader words.symbol ;
  10 QUALIFIED: math
  11 IN: alien.c-types
  12
  13 SYMBOLS:
  14     char uchar
  15     short ushort
  16     int uint
  17     long ulong
  18     longlong ulonglong
  19     float double
  20     void* bool
  21     void ;
  22
  23 DEFER: <int>
  24 DEFER: *char
  25
  26 TUPLE: abstract-c-type
  27 { class class initial: object }
  28 { boxed-class class initial: object }
  29 { boxer-quot callable }
  30 { unboxer-quot callable }
  31 { getter callable }
  32 { setter callable }
  33 size
  34 align ;
  35
  36 TUPLE: c-type < abstract-c-type
  37 boxer
  38 unboxer
  39 { rep initial: int-rep }
  40 stack-align? ;
  41
  42 : <c-type> ( -- c-type )
  43     \ c-type new ; inline
  44
  45 SYMBOL: c-types
  46
  47 global [
  48     c-types [ H{ } assoc-like ] change
  49 ] bind
  50
  51 ERROR: no-c-type name ;
  52
  53 PREDICATE: c-type-word < word
  54     "c-type" word-prop ;
  55
  56 UNION: c-type-name string word ;
  57
  58 ! C type protocol
  59 GENERIC: c-type ( name -- c-type ) foldable
  60
  61 GENERIC: resolve-pointer-type ( name -- c-type )
  62
  63 << \ void \ void* "pointer-c-type" set-word-prop >>
  64
  65 M: word resolve-pointer-type
  66     dup "pointer-c-type" word-prop
  67     [ ] [ drop void* ] ?if ;
  68
  69 M: string resolve-pointer-type
  70     dup "*" append dup c-types get at
  71     [ nip ] [
  72         drop
  73         c-types get at dup c-type-name?
  74         [ resolve-pointer-type ] [ drop void* ] if
  75     ] if ;
  76
  77 : resolve-typedef ( name -- c-type )
  78     dup c-type-name? [ c-type ] when ;
  79
  80 : parse-array-type ( name -- dims c-type )
  81     "[" split unclip
  82     [ [ "]" ?tail drop string>number ] map ] dip ;
  83
  84 M: string c-type ( name -- c-type )
  85     CHAR: ] over member? [
  86         parse-array-type prefix
  87     ] [
  88         dup c-types get at [ ] [
  89             "*" ?tail [ resolve-pointer-type ] [ no-c-type ] if
  90         ] ?if resolve-typedef
  91     ] if ;
  92
  93 M: word c-type
  94     "c-type" word-prop resolve-typedef ;
  95
  96 : void? ( c-type -- ? )
  97     { void "void" } member? ;
  98
  99 GENERIC: c-struct? ( c-type -- ? )
 100
 101 M: object c-struct?
 102     drop f ;
 103 M: c-type-name c-struct?
 104     dup void? [ drop f ] [ c-type c-struct? ] if ;
 105
 106 ! These words being foldable means that words need to be
 107 ! recompiled if a C type is redefined. Even so, folding the
 108 ! size facilitates some optimizations.
 109 GENERIC: c-type-class ( name -- class )
 110
 111 M: abstract-c-type c-type-class class>> ;
 112
 113 M: c-type-name c-type-class c-type c-type-class ;
 114
 115 GENERIC: c-type-boxed-class ( name -- class )
 116
 117 M: abstract-c-type c-type-boxed-class boxed-class>> ;
 118
 119 M: c-type-name c-type-boxed-class c-type c-type-boxed-class ;
 120
 121 GENERIC: c-type-boxer ( name -- boxer )
 122
 123 M: c-type c-type-boxer boxer>> ;
 124
 125 M: c-type-name c-type-boxer c-type c-type-boxer ;
 126
 127 GENERIC: c-type-boxer-quot ( name -- quot )
 128
 129 M: abstract-c-type c-type-boxer-quot boxer-quot>> ;
 130
 131 M: c-type-name c-type-boxer-quot c-type c-type-boxer-quot ;
 132
 133 GENERIC: c-type-unboxer ( name -- boxer )
 134
 135 M: c-type c-type-unboxer unboxer>> ;
 136
 137 M: c-type-name c-type-unboxer c-type c-type-unboxer ;
 138
 139 GENERIC: c-type-unboxer-quot ( name -- quot )
 140
 141 M: abstract-c-type c-type-unboxer-quot unboxer-quot>> ;
 142
 143 M: c-type-name c-type-unboxer-quot c-type c-type-unboxer-quot ;
 144
 145 GENERIC: c-type-rep ( name -- rep )
 146
 147 M: c-type c-type-rep rep>> ;
 148
 149 M: c-type-name c-type-rep c-type c-type-rep ;
 150
 151 GENERIC: c-type-getter ( name -- quot )
 152
 153 M: c-type c-type-getter getter>> ;
 154
 155 M: c-type-name c-type-getter c-type c-type-getter ;
 156
 157 GENERIC: c-type-setter ( name -- quot )
 158
 159 M: c-type c-type-setter setter>> ;
 160
 161 M: c-type-name c-type-setter c-type c-type-setter ;
 162
 163 GENERIC: c-type-align ( name -- n )
 164
 165 M: abstract-c-type c-type-align align>> ;
 166
 167 M: c-type-name c-type-align c-type c-type-align ;
 168
 169 GENERIC: c-type-stack-align? ( name -- ? )
 170
 171 M: c-type c-type-stack-align? stack-align?>> ;
 172
 173 M: c-type-name c-type-stack-align? c-type c-type-stack-align? ;
 174
 175 : c-type-box ( n c-type -- )
 176     [ c-type-rep ] [ c-type-boxer [ "No boxer" throw ] unless* ] bi
 177     %box ;
 178
 179 : c-type-unbox ( n c-type -- )
 180     [ c-type-rep ] [ c-type-unboxer [ "No unboxer" throw ] unless* ] bi
 181     %unbox ;
 182
 183 GENERIC: box-parameter ( n c-type -- )
 184
 185 M: c-type box-parameter c-type-box ;
 186
 187 M: c-type-name box-parameter c-type box-parameter ;
 188
 189 GENERIC: box-return ( c-type -- )
 190
 191 M: c-type box-return f swap c-type-box ;
 192
 193 M: c-type-name box-return c-type box-return ;
 194
 195 GENERIC: unbox-parameter ( n c-type -- )
 196
 197 M: c-type unbox-parameter c-type-unbox ;
 198
 199 M: c-type-name unbox-parameter c-type unbox-parameter ;
 200
 201 GENERIC: unbox-return ( c-type -- )
 202
 203 M: c-type unbox-return f swap c-type-unbox ;
 204
 205 M: c-type-name unbox-return c-type unbox-return ;
 206
 207 : little-endian? ( -- ? ) 1 <int> *char 1 = ; foldable
 208
 209 GENERIC: heap-size ( name -- size ) foldable
 210
 211 M: c-type-name heap-size c-type heap-size ;
 212
 213 M: abstract-c-type heap-size size>> ;
 214
 215 GENERIC: stack-size ( name -- size ) foldable
 216
 217 M: c-type-name stack-size c-type stack-size ;
 218
 219 M: c-type stack-size size>> cell align ;
 220
 221 GENERIC: byte-length ( seq -- n ) flushable
 222
 223 M: byte-array byte-length length ; inline
 224
 225 M: f byte-length drop 0 ; inline
 226
 227 MIXIN: value-type
 228
 229 : c-getter ( name -- quot )
 230     c-type-getter [
 231         [ "Cannot read struct fields with this type" throw ]
 232     ] unless* ;
 233
 234 : c-type-getter-boxer ( name -- quot )
 235     [ c-getter ] [ c-type-boxer-quot ] bi append ;
 236
 237 : c-setter ( name -- quot )
 238     c-type-setter [
 239         [ "Cannot write struct fields with this type" throw ]
 240     ] unless* ;
 241
 242 : array-accessor ( c-type quot -- def )
 243     [
 244         \ swap , [ heap-size , [ * >fixnum ] % ] [ % ] bi*
 245     ] [ ] make ;
 246
 247 GENERIC: typedef ( old new -- )
 248
 249 PREDICATE: typedef-word < c-type-word
 250     "c-type" word-prop c-type-name? ;
 251
 252 M: string typedef ( old new -- ) c-types get set-at ;
 253 M: word typedef ( old new -- )
 254     {
 255         [ nip define-symbol ]
 256         [ name>> typedef ]
 257         [ swap "c-type" set-word-prop ]
 258         [
 259             swap dup c-type-name? [
 260                 resolve-pointer-type
 261                 "pointer-c-type" set-word-prop
 262             ] [ 2drop ] if
 263         ]
 264     } 2cleave ;
 265
 266 TUPLE: long-long-type < c-type ;
 267
 268 : <long-long-type> ( -- c-type )
 269     long-long-type new ;
 270
 271 M: long-long-type unbox-parameter ( n c-type -- )
 272     c-type-unboxer %unbox-long-long ;
 273
 274 M: long-long-type unbox-return ( c-type -- )
 275     f swap unbox-parameter ;
 276
 277 M: long-long-type box-parameter ( n c-type -- )
 278     c-type-boxer %box-long-long ;
 279
 280 M: long-long-type box-return ( c-type -- )
 281     f swap box-parameter ;
 282
 283 : define-deref ( name -- )
 284     [ CHAR: * prefix "alien.c-types" create ] [ c-getter 0 prefix ] bi
 285     (( c-ptr -- value )) define-inline ;
 286
 287 : define-out ( name -- )
 288     [ "alien.c-types" constructor-word ]
 289     [ dup c-setter '[ _ heap-size <byte-array> [ 0 @ ] keep ] ] bi
 290     (( value -- c-ptr )) define-inline ;
 291
 292 : define-primitive-type ( c-type name -- )
 293     [ typedef ]
 294     [ name>> define-deref ]
 295     [ name>> define-out ]
 296     tri ;
 297
 298 : if-void ( c-type true false -- )
 299     pick void? [ drop nip call ] [ nip call ] if ; inline
 300
 301 CONSTANT: primitive-types
 302     {
 303         char uchar
 304         short ushort
 305         int uint
 306         long ulong
 307         longlong ulonglong
 308         float double
 309         void* bool
 310     }
 311
 312 SYMBOLS:
 313     ptrdiff_t intptr_t size_t
 314     char* uchar* ;
 315
 316 [
 317     <c-type>
 318         c-ptr >>class
 319         c-ptr >>boxed-class
 320         [ alien-cell ] >>getter
 321         [ [ >c-ptr ] 2dip set-alien-cell ] >>setter
 322         bootstrap-cell >>size
 323         bootstrap-cell >>align
 324         [ >c-ptr ] >>unboxer-quot
 325         "box_alien" >>boxer
 326         "alien_offset" >>unboxer
 327     \ void* define-primitive-type
 328
 329     <long-long-type>
 330         integer >>class
 331         integer >>boxed-class
 332         [ alien-signed-8 ] >>getter
 333         [ set-alien-signed-8 ] >>setter
 334         8 >>size
 335         8 >>align
 336         "box_signed_8" >>boxer
 337         "to_signed_8" >>unboxer
 338     \ longlong define-primitive-type
 339
 340     <long-long-type>
 341         integer >>class
 342         integer >>boxed-class
 343         [ alien-unsigned-8 ] >>getter
 344         [ set-alien-unsigned-8 ] >>setter
 345         8 >>size
 346         8 >>align
 347         "box_unsigned_8" >>boxer
 348         "to_unsigned_8" >>unboxer
 349     \ ulonglong define-primitive-type
 350
 351     <c-type>
 352         integer >>class
 353         integer >>boxed-class
 354         [ alien-signed-cell ] >>getter
 355         [ set-alien-signed-cell ] >>setter
 356         bootstrap-cell >>size
 357         bootstrap-cell >>align
 358         "box_signed_cell" >>boxer
 359         "to_fixnum" >>unboxer
 360     \ long define-primitive-type
 361
 362     <c-type>
 363         integer >>class
 364         integer >>boxed-class
 365         [ alien-unsigned-cell ] >>getter
 366         [ set-alien-unsigned-cell ] >>setter
 367         bootstrap-cell >>size
 368         bootstrap-cell >>align
 369         "box_unsigned_cell" >>boxer
 370         "to_cell" >>unboxer
 371     \ ulong define-primitive-type
 372
 373     <c-type>
 374         integer >>class
 375         integer >>boxed-class
 376         [ alien-signed-4 ] >>getter
 377         [ set-alien-signed-4 ] >>setter
 378         4 >>size
 379         4 >>align
 380         "box_signed_4" >>boxer
 381         "to_fixnum" >>unboxer
 382     \ int define-primitive-type
 383
 384     <c-type>
 385         integer >>class
 386         integer >>boxed-class
 387         [ alien-unsigned-4 ] >>getter
 388         [ set-alien-unsigned-4 ] >>setter
 389         4 >>size
 390         4 >>align
 391         "box_unsigned_4" >>boxer
 392         "to_cell" >>unboxer
 393     \ uint define-primitive-type
 394
 395     <c-type>
 396         fixnum >>class
 397         fixnum >>boxed-class
 398         [ alien-signed-2 ] >>getter
 399         [ set-alien-signed-2 ] >>setter
 400         2 >>size
 401         2 >>align
 402         "box_signed_2" >>boxer
 403         "to_fixnum" >>unboxer
 404     \ short define-primitive-type
 405
 406     <c-type>
 407         fixnum >>class
 408         fixnum >>boxed-class
 409         [ alien-unsigned-2 ] >>getter
 410         [ set-alien-unsigned-2 ] >>setter
 411         2 >>size
 412         2 >>align
 413         "box_unsigned_2" >>boxer
 414         "to_cell" >>unboxer
 415     \ ushort define-primitive-type
 416
 417     <c-type>
 418         fixnum >>class
 419         fixnum >>boxed-class
 420         [ alien-signed-1 ] >>getter
 421         [ set-alien-signed-1 ] >>setter
 422         1 >>size
 423         1 >>align
 424         "box_signed_1" >>boxer
 425         "to_fixnum" >>unboxer
 426     \ char define-primitive-type
 427
 428     <c-type>
 429         fixnum >>class
 430         fixnum >>boxed-class
 431         [ alien-unsigned-1 ] >>getter
 432         [ set-alien-unsigned-1 ] >>setter
 433         1 >>size
 434         1 >>align
 435         "box_unsigned_1" >>boxer
 436         "to_cell" >>unboxer
 437     \ uchar define-primitive-type
 438
 439     <c-type>
 440         [ alien-unsigned-1 0 = not ] >>getter
 441         [ [ 1 0 ? ] 2dip set-alien-unsigned-1 ] >>setter
 442         1 >>size
 443         1 >>align
 444         "box_boolean" >>boxer
 445         "to_boolean" >>unboxer
 446     \ bool define-primitive-type
 447
 448     <c-type>
 449         math:float >>class
 450         math:float >>boxed-class
 451         [ alien-float ] >>getter
 452         [ [ >float ] 2dip set-alien-float ] >>setter
 453         4 >>size
 454         4 >>align
 455         "box_float" >>boxer
 456         "to_float" >>unboxer
 457         float-rep >>rep
 458         [ >float ] >>unboxer-quot
 459     \ float define-primitive-type
 460
 461     <c-type>
 462         math:float >>class
 463         math:float >>boxed-class
 464         [ alien-double ] >>getter
 465         [ [ >float ] 2dip set-alien-double ] >>setter
 466         8 >>size
 467         8 >>align
 468         "box_double" >>boxer
 469         "to_double" >>unboxer
 470         double-rep >>rep
 471         [ >float ] >>unboxer-quot
 472     \ double define-primitive-type
 473
 474     \ long \ ptrdiff_t typedef
 475     \ long \ intptr_t typedef
 476     \ ulong \ size_t typedef
 477 ] with-compilation-unit
 478
 479 M: char-16-rep rep-component-type drop char ;
 480 M: uchar-16-rep rep-component-type drop uchar ;
 481 M: short-8-rep rep-component-type drop short ;
 482 M: ushort-8-rep rep-component-type drop ushort ;
 483 M: int-4-rep rep-component-type drop int ;
 484 M: uint-4-rep rep-component-type drop uint ;
 485 M: longlong-2-rep rep-component-type drop longlong ;
 486 M: ulonglong-2-rep rep-component-type drop ulonglong ;
 487 M: float-4-rep rep-component-type drop float ;
 488 M: double-2-rep rep-component-type drop double ;
 489
 490 : (unsigned-interval) ( bytes -- from to ) [ 0 ] dip 8 * 2^ 1 - ; foldable
 491 : unsigned-interval ( c-type -- from to ) heap-size (unsigned-interval) ; foldable
 492 : (signed-interval) ( bytes -- from to ) 8 * 1 - 2^ [ neg ] [ 1 - ] bi ; foldable
 493 : signed-interval ( c-type -- from to ) heap-size (signed-interval) ; foldable
 494
 495 : c-type-interval ( c-type -- from to )
 496     {
 497         { [ dup { float double } memq? ] [ drop -1/0. 1/0. ] }
 498         { [ dup { char short int long longlong } memq? ] [ signed-interval ] }
 499         { [ dup { uchar ushort uint ulong ulonglong } memq? ] [ unsigned-interval ] }
 500     } cond ; foldable
 501
 502 : c-type-clamp ( value c-type -- value' ) c-type-interval clamp ; inline