basis/alien/c-types/c-types.factor

   1 ! Copyright (C) 2004, 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: byte-arrays arrays assocs kernel kernel.private libc math
   4 namespaces make parser sequences strings words assocs splitting
   5 math.parser cpu.architecture alien alien.accessors quotations
   6 layouts system compiler.units io.files io.encodings.binary
   7 accessors combinators effects continuations fry ;
   8 IN: alien.c-types
   9
  10 DEFER: <int>
  11 DEFER: *char
  12
  13 : little-endian? ( -- ? ) 1 <int> *char 1 = ; foldable
  14
  15 TUPLE: c-type
  16 class
  17 boxer boxer-quot unboxer unboxer-quot
  18 getter setter
  19 reg-class size align stack-align? ;
  20
  21 : new-c-type ( class -- type )
  22     new
  23         int-regs >>reg-class
  24         object >>class ; inline
  25
  26 : <c-type> ( -- type )
  27     \ c-type new-c-type ;
  28
  29 SYMBOL: c-types
  30
  31 global [
  32     c-types [ H{ } assoc-like ] change
  33 ] bind
  34
  35 ERROR: no-c-type name ;
  36
  37 : (c-type) ( name -- type/f )
  38     c-types get-global at dup [
  39         dup string? [ (c-type) ] when
  40     ] when ;
  41
  42 ! C type protocol
  43 GENERIC: c-type ( name -- type ) foldable
  44
  45 : resolve-pointer-type ( name -- name )
  46     c-types get at dup string?
  47     [ "*" append ] [ drop "void*" ] if
  48     c-type ;
  49
  50 : resolve-typedef ( name -- type )
  51     dup string? [ c-type ] when ;
  52
  53 : parse-array-type ( name -- array )
  54     "[" split unclip
  55     [ [ "]" ?tail drop string>number ] map ] dip prefix ;
  56
  57 M: string c-type ( name -- type )
  58     CHAR: ] over member? [
  59         parse-array-type
  60     ] [
  61         dup c-types get at [
  62             resolve-typedef
  63         ] [
  64             "*" ?tail [ resolve-pointer-type ] [ no-c-type ] if
  65         ] ?if
  66     ] if ;
  67
  68 GENERIC: c-type-class ( name -- class )
  69
  70 M: c-type c-type-class class>> ;
  71
  72 M: string c-type-class c-type c-type-class ;
  73
  74 GENERIC: c-type-boxer ( name -- boxer )
  75
  76 M: c-type c-type-boxer boxer>> ;
  77
  78 M: string c-type-boxer c-type c-type-boxer ;
  79
  80 GENERIC: c-type-boxer-quot ( name -- quot )
  81
  82 M: c-type c-type-boxer-quot boxer-quot>> ;
  83
  84 M: string c-type-boxer-quot c-type c-type-boxer-quot ;
  85
  86 GENERIC: c-type-unboxer ( name -- boxer )
  87
  88 M: c-type c-type-unboxer unboxer>> ;
  89
  90 M: string c-type-unboxer c-type c-type-unboxer ;
  91
  92 GENERIC: c-type-unboxer-quot ( name -- quot )
  93
  94 M: c-type c-type-unboxer-quot unboxer-quot>> ;
  95
  96 M: string c-type-unboxer-quot c-type c-type-unboxer-quot ;
  97
  98 GENERIC: c-type-reg-class ( name -- reg-class )
  99
 100 M: c-type c-type-reg-class reg-class>> ;
 101
 102 M: string c-type-reg-class c-type c-type-reg-class ;
 103
 104 GENERIC: c-type-getter ( name -- quot )
 105
 106 M: c-type c-type-getter getter>> ;
 107
 108 M: string c-type-getter c-type c-type-getter ;
 109
 110 GENERIC: c-type-setter ( name -- quot )
 111
 112 M: c-type c-type-setter setter>> ;
 113
 114 M: string c-type-setter c-type c-type-setter ;
 115
 116 GENERIC: c-type-align ( name -- n )
 117
 118 M: c-type c-type-align align>> ;
 119
 120 M: string c-type-align c-type c-type-align ;
 121
 122 GENERIC: c-type-stack-align? ( name -- ? )
 123
 124 M: c-type c-type-stack-align? stack-align?>> ;
 125
 126 M: string c-type-stack-align? c-type c-type-stack-align? ;
 127
 128 : c-type-box ( n type -- )
 129     dup c-type-reg-class
 130     swap c-type-boxer [ "No boxer" throw ] unless*
 131     %box ;
 132
 133 : c-type-unbox ( n ctype -- )
 134     dup c-type-reg-class
 135     swap c-type-unboxer [ "No unboxer" throw ] unless*
 136     %unbox ;
 137
 138 GENERIC: box-parameter ( n ctype -- )
 139
 140 M: c-type box-parameter c-type-box ;
 141
 142 M: string box-parameter c-type box-parameter ;
 143
 144 GENERIC: box-return ( ctype -- )
 145
 146 M: c-type box-return f swap c-type-box ;
 147
 148 M: string box-return c-type box-return ;
 149
 150 GENERIC: unbox-parameter ( n ctype -- )
 151
 152 M: c-type unbox-parameter c-type-unbox ;
 153
 154 M: string unbox-parameter c-type unbox-parameter ;
 155
 156 GENERIC: unbox-return ( ctype -- )
 157
 158 M: c-type unbox-return f swap c-type-unbox ;
 159
 160 M: string unbox-return c-type unbox-return ;
 161
 162 ! These words being foldable means that words need to be
 163 ! recompiled if a C type is redefined. Even so, folding the
 164 ! size facilitates some optimizations.
 165 GENERIC: heap-size ( type -- size ) foldable
 166
 167 M: string heap-size c-type heap-size ;
 168
 169 M: c-type heap-size size>> ;
 170
 171 GENERIC: stack-size ( type -- size ) foldable
 172
 173 M: string stack-size c-type stack-size ;
 174
 175 M: c-type stack-size size>> cell align ;
 176
 177 GENERIC: byte-length ( seq -- n ) flushable
 178
 179 M: byte-array byte-length length ;
 180
 181 : c-getter ( name -- quot )
 182     c-type-getter [
 183         [ "Cannot read struct fields with this type" throw ]
 184     ] unless* ;
 185
 186 : c-setter ( name -- quot )
 187     c-type-setter [
 188         [ "Cannot write struct fields with this type" throw ]
 189     ] unless* ;
 190
 191 : <c-array> ( n type -- array )
 192     heap-size * <byte-array> ; inline
 193
 194 : <c-object> ( type -- array )
 195     1 swap <c-array> ; inline
 196
 197 : malloc-array ( n type -- alien )
 198     heap-size calloc ; inline
 199
 200 : malloc-object ( type -- alien )
 201     1 swap malloc-array ; inline
 202
 203 : malloc-byte-array ( byte-array -- alien )
 204     dup length [ nip malloc dup ] 2keep memcpy ;
 205
 206 : memory>byte-array ( alien len -- byte-array )
 207     [ nip (byte-array) dup ] 2keep memcpy ;
 208
 209 : byte-array>memory ( byte-array base -- )
 210     swap dup length memcpy ;
 211
 212 : array-accessor ( type quot -- def )
 213     [
 214         \ swap , [ heap-size , [ * >fixnum ] % ] [ % ] bi*
 215     ] [ ] make ;
 216
 217 : typedef ( old new -- ) c-types get set-at ;
 218
 219 TUPLE: long-long-type < c-type ;
 220
 221 : <long-long-type> ( -- type )
 222     long-long-type new-c-type ;
 223
 224 M: long-long-type unbox-parameter ( n type -- )
 225     c-type-unboxer %unbox-long-long ;
 226
 227 M: long-long-type unbox-return ( type -- )
 228     f swap unbox-parameter ;
 229
 230 M: long-long-type box-parameter ( n type -- )
 231     c-type-boxer %box-long-long ;
 232
 233 M: long-long-type box-return ( type -- )
 234     f swap box-parameter ;
 235
 236 : define-deref ( name -- )
 237     [ CHAR: * prefix "alien.c-types" create ]
 238     [ c-getter 0 prefix ] bi
 239     define-inline ;
 240
 241 : define-out ( name -- )
 242     [ "alien.c-types" constructor-word ]
 243     [ dup c-setter '[ _ <c-object> [ 0 @ ] keep ] ]
 244     bi define-inline ;
 245
 246 : c-bool> ( int -- ? )
 247     zero? not ;
 248
 249 : define-primitive-type ( type name -- )
 250     [ typedef ]
 251     [ define-deref ]
 252     [ define-out ]
 253     tri ;
 254
 255 : expand-constants ( c-type -- c-type' )
 256     dup array? [
 257         unclip [
 258             [
 259                 dup word? [
 260                     def>> { } swap with-datastack first
 261                 ] when
 262             ] map
 263         ] dip prefix
 264     ] when ;
 265
 266 : malloc-file-contents ( path -- alien len )
 267     binary file-contents dup malloc-byte-array swap length ;
 268
 269 : if-void ( type true false -- )
 270     pick "void" = [ drop nip call ] [ nip call ] if ; inline
 271
 272 : primitive-types
 273     {
 274         "char" "uchar"
 275         "short" "ushort"
 276         "int" "uint"
 277         "long" "ulong"
 278         "longlong" "ulonglong"
 279         "float" "double"
 280         "void*" "bool"
 281     } ;
 282
 283 [
 284     <c-type>
 285         c-ptr >>class
 286         [ alien-cell ] >>getter
 287         [ set-alien-cell ] >>setter
 288         bootstrap-cell >>size
 289         bootstrap-cell >>align
 290         "box_alien" >>boxer
 291         "alien_offset" >>unboxer
 292     "void*" define-primitive-type
 293
 294     <long-long-type>
 295         integer >>class
 296         [ alien-signed-8 ] >>getter
 297         [ set-alien-signed-8 ] >>setter
 298         8 >>size
 299         8 >>align
 300         "box_signed_8" >>boxer
 301         "to_signed_8" >>unboxer
 302     "longlong" define-primitive-type
 303
 304     <long-long-type>
 305         integer >>class
 306         [ alien-unsigned-8 ] >>getter
 307         [ set-alien-unsigned-8 ] >>setter
 308         8 >>size
 309         8 >>align
 310         "box_unsigned_8" >>boxer
 311         "to_unsigned_8" >>unboxer
 312     "ulonglong" define-primitive-type
 313
 314     <c-type>
 315         integer >>class
 316         [ alien-signed-cell ] >>getter
 317         [ set-alien-signed-cell ] >>setter
 318         bootstrap-cell >>size
 319         bootstrap-cell >>align
 320         "box_signed_cell" >>boxer
 321         "to_fixnum" >>unboxer
 322     "long" define-primitive-type
 323
 324     <c-type>
 325         integer >>class
 326         [ alien-unsigned-cell ] >>getter
 327         [ set-alien-unsigned-cell ] >>setter
 328         bootstrap-cell >>size
 329         bootstrap-cell >>align
 330         "box_unsigned_cell" >>boxer
 331         "to_cell" >>unboxer
 332     "ulong" define-primitive-type
 333
 334     <c-type>
 335         integer >>class
 336         [ alien-signed-4 ] >>getter
 337         [ set-alien-signed-4 ] >>setter
 338         4 >>size
 339         4 >>align
 340         "box_signed_4" >>boxer
 341         "to_fixnum" >>unboxer
 342     "int" define-primitive-type
 343
 344     <c-type>
 345         integer >>class
 346         [ alien-unsigned-4 ] >>getter
 347         [ set-alien-unsigned-4 ] >>setter
 348         4 >>size
 349         4 >>align
 350         "box_unsigned_4" >>boxer
 351         "to_cell" >>unboxer
 352     "uint" define-primitive-type
 353
 354     <c-type>
 355         fixnum >>class
 356         [ alien-signed-2 ] >>getter
 357         [ set-alien-signed-2 ] >>setter
 358         2 >>size
 359         2 >>align
 360         "box_signed_2" >>boxer
 361         "to_fixnum" >>unboxer
 362     "short" define-primitive-type
 363
 364     <c-type>
 365         fixnum >>class
 366         [ alien-unsigned-2 ] >>getter
 367         [ set-alien-unsigned-2 ] >>setter
 368         2 >>size
 369         2 >>align
 370         "box_unsigned_2" >>boxer
 371         "to_cell" >>unboxer
 372     "ushort" define-primitive-type
 373
 374     <c-type>
 375         fixnum >>class
 376         [ alien-signed-1 ] >>getter
 377         [ set-alien-signed-1 ] >>setter
 378         1 >>size
 379         1 >>align
 380         "box_signed_1" >>boxer
 381         "to_fixnum" >>unboxer
 382     "char" define-primitive-type
 383
 384     <c-type>
 385         fixnum >>class
 386         [ alien-unsigned-1 ] >>getter
 387         [ set-alien-unsigned-1 ] >>setter
 388         1 >>size
 389         1 >>align
 390         "box_unsigned_1" >>boxer
 391         "to_cell" >>unboxer
 392     "uchar" define-primitive-type
 393
 394     <c-type>
 395         [ alien-unsigned-4 zero? not ] >>getter
 396         [ [ 1 0 ? ] 2dip set-alien-unsigned-4 ] >>setter
 397         4 >>size
 398         4 >>align
 399         "box_boolean" >>boxer
 400         "to_boolean" >>unboxer
 401     "bool" define-primitive-type
 402
 403     <c-type>
 404         float >>class
 405         [ alien-float ] >>getter
 406         [ [ >float ] 2dip set-alien-float ] >>setter
 407         4 >>size
 408         4 >>align
 409         "box_float" >>boxer
 410         "to_float" >>unboxer
 411         single-float-regs >>reg-class
 412         [ >float ] >>unboxer-quot
 413     "float" define-primitive-type
 414
 415     <c-type>
 416         float >>class
 417         [ alien-double ] >>getter
 418         [ [ >float ] 2dip set-alien-double ] >>setter
 419         8 >>size
 420         8 >>align
 421         "box_double" >>boxer
 422         "to_double" >>unboxer
 423         double-float-regs >>reg-class
 424         [ >float ] >>unboxer-quot
 425     "double" define-primitive-type
 426
 427     "long" "ptrdiff_t" typedef
 428     "long" "intptr_t" typedef
 429     "ulong" "size_t" typedef
 430 ] with-compilation-unit