basis/alien/c-types/c-types.factor

   1 ! Copyright (C) 2004, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: byte-arrays arrays assocs kernel kernel.private libc math
   4 namespaces make parser sequences strings words assocs splitting
   5 math.parser cpu.architecture alien alien.accessors quotations
   6 layouts system compiler.units io.files io.encodings.binary
   7 accessors combinators effects continuations fry call classes ;
   8 IN: alien.c-types
   9
  10 DEFER: <int>
  11 DEFER: *char
  12
  13 : little-endian? ( -- ? ) 1 <int> *char 1 = ; foldable
  14
  15 TUPLE: c-type
  16 { class class initial: object }
  17 boxer
  18 { boxer-quot callable }
  19 unboxer
  20 { unboxer-quot callable }
  21 { getter callable }
  22 { setter callable }
  23 { reg-class initial: int-regs }
  24 size
  25 align
  26 stack-align? ;
  27
  28 : <c-type> ( -- type )
  29     \ c-type new ;
  30
  31 SYMBOL: c-types
  32
  33 global [
  34     c-types [ H{ } assoc-like ] change
  35 ] bind
  36
  37 ERROR: no-c-type name ;
  38
  39 : (c-type) ( name -- type/f )
  40     c-types get-global at dup [
  41         dup string? [ (c-type) ] when
  42     ] when ;
  43
  44 ! C type protocol
  45 GENERIC: c-type ( name -- type ) foldable
  46
  47 : resolve-pointer-type ( name -- name )
  48     c-types get at dup string?
  49     [ "*" append ] [ drop "void*" ] if
  50     c-type ;
  51
  52 : resolve-typedef ( name -- type )
  53     dup string? [ c-type ] when ;
  54
  55 : parse-array-type ( name -- array )
  56     "[" split unclip
  57     [ [ "]" ?tail drop string>number ] map ] dip prefix ;
  58
  59 M: string c-type ( name -- type )
  60     CHAR: ] over member? [
  61         parse-array-type
  62     ] [
  63         dup c-types get at [
  64             resolve-typedef
  65         ] [
  66             "*" ?tail [ resolve-pointer-type ] [ no-c-type ] if
  67         ] ?if
  68     ] if ;
  69
  70 GENERIC: c-type-class ( name -- class )
  71
  72 M: c-type c-type-class class>> ;
  73
  74 M: string c-type-class c-type c-type-class ;
  75
  76 GENERIC: c-type-boxer ( name -- boxer )
  77
  78 M: c-type c-type-boxer boxer>> ;
  79
  80 M: string c-type-boxer c-type c-type-boxer ;
  81
  82 GENERIC: c-type-boxer-quot ( name -- quot )
  83
  84 M: c-type c-type-boxer-quot boxer-quot>> ;
  85
  86 M: string c-type-boxer-quot c-type c-type-boxer-quot ;
  87
  88 GENERIC: c-type-unboxer ( name -- boxer )
  89
  90 M: c-type c-type-unboxer unboxer>> ;
  91
  92 M: string c-type-unboxer c-type c-type-unboxer ;
  93
  94 GENERIC: c-type-unboxer-quot ( name -- quot )
  95
  96 M: c-type c-type-unboxer-quot unboxer-quot>> ;
  97
  98 M: string c-type-unboxer-quot c-type c-type-unboxer-quot ;
  99
 100 GENERIC: c-type-reg-class ( name -- reg-class )
 101
 102 M: c-type c-type-reg-class reg-class>> ;
 103
 104 M: string c-type-reg-class c-type c-type-reg-class ;
 105
 106 GENERIC: c-type-getter ( name -- quot )
 107
 108 M: c-type c-type-getter getter>> ;
 109
 110 M: string c-type-getter c-type c-type-getter ;
 111
 112 GENERIC: c-type-setter ( name -- quot )
 113
 114 M: c-type c-type-setter setter>> ;
 115
 116 M: string c-type-setter c-type c-type-setter ;
 117
 118 GENERIC: c-type-align ( name -- n )
 119
 120 M: c-type c-type-align align>> ;
 121
 122 M: string c-type-align c-type c-type-align ;
 123
 124 GENERIC: c-type-stack-align? ( name -- ? )
 125
 126 M: c-type c-type-stack-align? stack-align?>> ;
 127
 128 M: string c-type-stack-align? c-type c-type-stack-align? ;
 129
 130 : c-type-box ( n type -- )
 131     dup c-type-reg-class
 132     swap c-type-boxer [ "No boxer" throw ] unless*
 133     %box ;
 134
 135 : c-type-unbox ( n ctype -- )
 136     dup c-type-reg-class
 137     swap c-type-unboxer [ "No unboxer" throw ] unless*
 138     %unbox ;
 139
 140 GENERIC: box-parameter ( n ctype -- )
 141
 142 M: c-type box-parameter c-type-box ;
 143
 144 M: string box-parameter c-type box-parameter ;
 145
 146 GENERIC: box-return ( ctype -- )
 147
 148 M: c-type box-return f swap c-type-box ;
 149
 150 M: string box-return c-type box-return ;
 151
 152 GENERIC: unbox-parameter ( n ctype -- )
 153
 154 M: c-type unbox-parameter c-type-unbox ;
 155
 156 M: string unbox-parameter c-type unbox-parameter ;
 157
 158 GENERIC: unbox-return ( ctype -- )
 159
 160 M: c-type unbox-return f swap c-type-unbox ;
 161
 162 M: string unbox-return c-type unbox-return ;
 163
 164 ! These words being foldable means that words need to be
 165 ! recompiled if a C type is redefined. Even so, folding the
 166 ! size facilitates some optimizations.
 167 GENERIC: heap-size ( type -- size ) foldable
 168
 169 M: string heap-size c-type heap-size ;
 170
 171 M: c-type heap-size size>> ;
 172
 173 GENERIC: stack-size ( type -- size ) foldable
 174
 175 M: string stack-size c-type stack-size ;
 176
 177 M: c-type stack-size size>> cell align ;
 178
 179 GENERIC: byte-length ( seq -- n ) flushable
 180
 181 M: byte-array byte-length length ;
 182
 183 M: f byte-length drop 0 ;
 184
 185 : c-getter ( name -- quot )
 186     c-type-getter [
 187         [ "Cannot read struct fields with this type" throw ]
 188     ] unless* ;
 189
 190 : c-type-getter-boxer ( name -- quot )
 191     [ c-getter ] [ c-type-boxer-quot ] bi append ;
 192
 193 : c-setter ( name -- quot )
 194     c-type-setter [
 195         [ "Cannot write struct fields with this type" throw ]
 196     ] unless* ;
 197
 198 : <c-array> ( n type -- array )
 199     heap-size * <byte-array> ; inline
 200
 201 : <c-object> ( type -- array )
 202     1 swap <c-array> ; inline
 203
 204 : malloc-array ( n type -- alien )
 205     heap-size calloc ; inline
 206
 207 : malloc-object ( type -- alien )
 208     1 swap malloc-array ; inline
 209
 210 : malloc-byte-array ( byte-array -- alien )
 211     dup byte-length [ nip malloc dup ] 2keep memcpy ;
 212
 213 : memory>byte-array ( alien len -- byte-array )
 214     [ nip (byte-array) dup ] 2keep memcpy ;
 215
 216 : byte-array>memory ( byte-array base -- )
 217     swap dup byte-length memcpy ;
 218
 219 : array-accessor ( type quot -- def )
 220     [
 221         \ swap , [ heap-size , [ * >fixnum ] % ] [ % ] bi*
 222     ] [ ] make ;
 223
 224 : typedef ( old new -- ) c-types get set-at ;
 225
 226 TUPLE: long-long-type < c-type ;
 227
 228 : <long-long-type> ( -- type )
 229     long-long-type new ;
 230
 231 M: long-long-type unbox-parameter ( n type -- )
 232     c-type-unboxer %unbox-long-long ;
 233
 234 M: long-long-type unbox-return ( type -- )
 235     f swap unbox-parameter ;
 236
 237 M: long-long-type box-parameter ( n type -- )
 238     c-type-boxer %box-long-long ;
 239
 240 M: long-long-type box-return ( type -- )
 241     f swap box-parameter ;
 242
 243 : define-deref ( name -- )
 244     [ CHAR: * prefix "alien.c-types" create ] [ c-getter 0 prefix ] bi
 245     (( c-ptr -- value )) define-inline ;
 246
 247 : define-out ( name -- )
 248     [ "alien.c-types" constructor-word ]
 249     [ dup c-setter '[ _ <c-object> [ 0 @ ] keep ] ] bi
 250     (( value -- c-ptr )) define-inline ;
 251
 252 : c-bool> ( int -- ? )
 253     0 = not ; inline
 254
 255 : define-primitive-type ( type name -- )
 256     [ typedef ]
 257     [ define-deref ]
 258     [ define-out ]
 259     tri ;
 260
 261 : expand-constants ( c-type -- c-type' )
 262     dup array? [
 263         unclip [
 264             [
 265                 dup word? [
 266                     def>> call( -- object )
 267                 ] when
 268             ] map
 269         ] dip prefix
 270     ] when ;
 271
 272 : malloc-file-contents ( path -- alien len )
 273     binary file-contents [ malloc-byte-array ] [ length ] bi ;
 274
 275 : if-void ( type true false -- )
 276     pick "void" = [ drop nip call ] [ nip call ] if ; inline
 277
 278 CONSTANT: primitive-types
 279     {
 280         "char" "uchar"
 281         "short" "ushort"
 282         "int" "uint"
 283         "long" "ulong"
 284         "longlong" "ulonglong"
 285         "float" "double"
 286         "void*" "bool"
 287     }
 288
 289 [
 290     <c-type>
 291         c-ptr >>class
 292         [ alien-cell ] >>getter
 293         [ [ >c-ptr ] 2dip set-alien-cell ] >>setter
 294         bootstrap-cell >>size
 295         bootstrap-cell >>align
 296         [ >c-ptr ] >>unboxer-quot
 297         "box_alien" >>boxer
 298         "alien_offset" >>unboxer
 299     "void*" define-primitive-type
 300
 301     <long-long-type>
 302         integer >>class
 303         [ alien-signed-8 ] >>getter
 304         [ set-alien-signed-8 ] >>setter
 305         8 >>size
 306         8 >>align
 307         "box_signed_8" >>boxer
 308         "to_signed_8" >>unboxer
 309     "longlong" define-primitive-type
 310
 311     <long-long-type>
 312         integer >>class
 313         [ alien-unsigned-8 ] >>getter
 314         [ set-alien-unsigned-8 ] >>setter
 315         8 >>size
 316         8 >>align
 317         "box_unsigned_8" >>boxer
 318         "to_unsigned_8" >>unboxer
 319     "ulonglong" define-primitive-type
 320
 321     <c-type>
 322         integer >>class
 323         [ alien-signed-cell ] >>getter
 324         [ set-alien-signed-cell ] >>setter
 325         bootstrap-cell >>size
 326         bootstrap-cell >>align
 327         "box_signed_cell" >>boxer
 328         "to_fixnum" >>unboxer
 329     "long" define-primitive-type
 330
 331     <c-type>
 332         integer >>class
 333         [ alien-unsigned-cell ] >>getter
 334         [ set-alien-unsigned-cell ] >>setter
 335         bootstrap-cell >>size
 336         bootstrap-cell >>align
 337         "box_unsigned_cell" >>boxer
 338         "to_cell" >>unboxer
 339     "ulong" define-primitive-type
 340
 341     <c-type>
 342         integer >>class
 343         [ alien-signed-4 ] >>getter
 344         [ set-alien-signed-4 ] >>setter
 345         4 >>size
 346         4 >>align
 347         "box_signed_4" >>boxer
 348         "to_fixnum" >>unboxer
 349     "int" define-primitive-type
 350
 351     <c-type>
 352         integer >>class
 353         [ alien-unsigned-4 ] >>getter
 354         [ set-alien-unsigned-4 ] >>setter
 355         4 >>size
 356         4 >>align
 357         "box_unsigned_4" >>boxer
 358         "to_cell" >>unboxer
 359     "uint" define-primitive-type
 360
 361     <c-type>
 362         fixnum >>class
 363         [ alien-signed-2 ] >>getter
 364         [ set-alien-signed-2 ] >>setter
 365         2 >>size
 366         2 >>align
 367         "box_signed_2" >>boxer
 368         "to_fixnum" >>unboxer
 369     "short" define-primitive-type
 370
 371     <c-type>
 372         fixnum >>class
 373         [ alien-unsigned-2 ] >>getter
 374         [ set-alien-unsigned-2 ] >>setter
 375         2 >>size
 376         2 >>align
 377         "box_unsigned_2" >>boxer
 378         "to_cell" >>unboxer
 379     "ushort" define-primitive-type
 380
 381     <c-type>
 382         fixnum >>class
 383         [ alien-signed-1 ] >>getter
 384         [ set-alien-signed-1 ] >>setter
 385         1 >>size
 386         1 >>align
 387         "box_signed_1" >>boxer
 388         "to_fixnum" >>unboxer
 389     "char" define-primitive-type
 390
 391     <c-type>
 392         fixnum >>class
 393         [ alien-unsigned-1 ] >>getter
 394         [ set-alien-unsigned-1 ] >>setter
 395         1 >>size
 396         1 >>align
 397         "box_unsigned_1" >>boxer
 398         "to_cell" >>unboxer
 399     "uchar" define-primitive-type
 400
 401     <c-type>
 402         [ alien-unsigned-4 zero? not ] >>getter
 403         [ [ 1 0 ? ] 2dip set-alien-unsigned-4 ] >>setter
 404         4 >>size
 405         4 >>align
 406         "box_boolean" >>boxer
 407         "to_boolean" >>unboxer
 408     "bool" define-primitive-type
 409
 410     <c-type>
 411         float >>class
 412         [ alien-float ] >>getter
 413         [ [ >float ] 2dip set-alien-float ] >>setter
 414         4 >>size
 415         4 >>align
 416         "box_float" >>boxer
 417         "to_float" >>unboxer
 418         single-float-regs >>reg-class
 419         [ >float ] >>unboxer-quot
 420     "float" define-primitive-type
 421
 422     <c-type>
 423         float >>class
 424         [ alien-double ] >>getter
 425         [ [ >float ] 2dip set-alien-double ] >>setter
 426         8 >>size
 427         8 >>align
 428         "box_double" >>boxer
 429         "to_double" >>unboxer
 430         double-float-regs >>reg-class
 431         [ >float ] >>unboxer-quot
 432     "double" define-primitive-type
 433
 434     "long" "ptrdiff_t" typedef
 435     "long" "intptr_t" typedef
 436     "ulong" "size_t" typedef
 437 ] with-compilation-unit