basis/alien/c-types/c-types.factor

   1 ! Copyright (C) 2004, 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: byte-arrays arrays assocs kernel kernel.private libc math
   4 namespaces parser sequences strings words assocs splitting
   5 math.parser cpu.architecture alien alien.accessors quotations
   6 layouts system compiler.units io.files io.encodings.binary
   7 accessors combinators effects ;
   8 IN: alien.c-types
   9
  10 DEFER: <int>
  11 DEFER: *char
  12
  13 : little-endian? ( -- ? ) 1 <int> *char 1 = ; foldable
  14
  15 TUPLE: c-type
  16 boxer boxer-quot unboxer unboxer-quot
  17 getter setter
  18 reg-class size align stack-align? ;
  19
  20 : new-c-type ( class -- type )
  21     new
  22         int-regs >>reg-class ;
  23
  24 : <c-type> ( -- type )
  25     \ c-type new-c-type ;
  26
  27 SYMBOL: c-types
  28
  29 global [
  30     c-types [ H{ } assoc-like ] change
  31 ] bind
  32
  33 ERROR: no-c-type name ;
  34
  35 : (c-type) ( name -- type/f )
  36     c-types get-global at dup [
  37         dup string? [ (c-type) ] when
  38     ] when ;
  39
  40 GENERIC: c-type ( name -- type ) foldable
  41
  42 : resolve-pointer-type ( name -- name )
  43     c-types get at dup string?
  44     [ "*" append ] [ drop "void*" ] if
  45     c-type ;
  46
  47 : resolve-typedef ( name -- type )
  48     dup string? [ c-type ] when ;
  49
  50 : parse-array-type ( name -- array )
  51     "[" split unclip
  52     >r [ "]" ?tail drop string>number ] map r> prefix ;
  53
  54 M: string c-type ( name -- type )
  55     CHAR: ] over member? [
  56         parse-array-type
  57     ] [
  58         dup c-types get at [
  59             resolve-typedef
  60         ] [
  61             "*" ?tail [ resolve-pointer-type ] [ no-c-type ] if
  62         ] ?if
  63     ] if ;
  64
  65 : c-type-box ( n type -- )
  66     dup c-type-reg-class
  67     swap c-type-boxer [ "No boxer" throw ] unless*
  68     %box ;
  69
  70 : c-type-unbox ( n ctype -- )
  71     dup c-type-reg-class
  72     swap c-type-unboxer [ "No unboxer" throw ] unless*
  73     %unbox ;
  74
  75 M: string c-type-align c-type c-type-align ;
  76
  77 M: string c-type-stack-align? c-type c-type-stack-align? ;
  78
  79 GENERIC: box-parameter ( n ctype -- )
  80
  81 M: c-type box-parameter c-type-box ;
  82
  83 M: string box-parameter c-type box-parameter ;
  84
  85 GENERIC: box-return ( ctype -- )
  86
  87 M: c-type box-return f swap c-type-box ;
  88
  89 M: string box-return c-type box-return ;
  90
  91 GENERIC: unbox-parameter ( n ctype -- )
  92
  93 M: c-type unbox-parameter c-type-unbox ;
  94
  95 M: string unbox-parameter c-type unbox-parameter ;
  96
  97 GENERIC: unbox-return ( ctype -- )
  98
  99 M: c-type unbox-return f swap c-type-unbox ;
 100
 101 M: string unbox-return c-type unbox-return ;
 102
 103 ! These words being foldable means that words need to be
 104 ! recompiled if a C type is redefined. Even so, folding the
 105 ! size facilitates some optimizations.
 106 GENERIC: heap-size ( type -- size ) foldable
 107
 108 M: string heap-size c-type heap-size ;
 109
 110 M: c-type heap-size c-type-size ;
 111
 112 GENERIC: stack-size ( type -- size ) foldable
 113
 114 M: string stack-size c-type stack-size ;
 115
 116 M: c-type stack-size c-type-size ;
 117
 118 GENERIC: byte-length ( seq -- n ) flushable
 119
 120 M: byte-array byte-length length ;
 121
 122 : c-getter ( name -- quot )
 123     c-type c-type-getter [
 124         [ "Cannot read struct fields with type" throw ]
 125     ] unless* ;
 126
 127 : c-setter ( name -- quot )
 128     c-type c-type-setter [
 129         [ "Cannot write struct fields with type" throw ]
 130     ] unless* ;
 131
 132 : <c-array> ( n type -- array )
 133     heap-size * <byte-array> ; inline
 134
 135 : <c-object> ( type -- array )
 136     1 swap <c-array> ; inline
 137
 138 : malloc-array ( n type -- alien )
 139     heap-size calloc ; inline
 140
 141 : malloc-object ( type -- alien )
 142     1 swap malloc-array ; inline
 143
 144 : malloc-byte-array ( byte-array -- alien )
 145     dup length dup malloc [ -rot memcpy ] keep ;
 146
 147 : memory>byte-array ( alien len -- byte-array )
 148     dup <byte-array> [ -rot memcpy ] keep ;
 149
 150 : byte-array>memory ( byte-array base -- )
 151     swap dup length memcpy ;
 152
 153 : (define-nth) ( word type quot -- )
 154     [
 155         \ swap , [ heap-size , [ * >fixnum ] % ] [ % ] bi*
 156     ] [ ] make define-inline ;
 157
 158 : nth-word ( name vocab -- word )
 159     >r "-nth" append r> create ;
 160
 161 : define-nth ( name vocab -- )
 162     dupd nth-word swap dup c-getter (define-nth) ;
 163
 164 : set-nth-word ( name vocab -- word )
 165     >r "set-" swap "-nth" 3append r> create ;
 166
 167 : define-set-nth ( name vocab -- )
 168     dupd set-nth-word swap dup c-setter (define-nth) ;
 169
 170 : typedef ( old new -- ) c-types get set-at ;
 171
 172 : define-c-type ( type name vocab -- )
 173     >r tuck typedef r> [ define-nth ] 2keep define-set-nth ;
 174
 175 TUPLE: long-long-type < c-type ;
 176
 177 : <long-long-type> ( -- type )
 178     long-long-type new-c-type ;
 179
 180 M: long-long-type unbox-parameter ( n type -- )
 181     c-type-unboxer %unbox-long-long ;
 182
 183 M: long-long-type unbox-return ( type -- )
 184     f swap unbox-parameter ;
 185
 186 M: long-long-type box-parameter ( n type -- )
 187     c-type-boxer %box-long-long ;
 188
 189 M: long-long-type box-return ( type -- )
 190     f swap box-parameter ;
 191
 192 : define-deref ( name vocab -- )
 193     >r dup CHAR: * prefix r> create
 194     swap c-getter 0 prefix define-inline ;
 195
 196 : define-out ( name vocab -- )
 197     over [ <c-object> tuck 0 ] over c-setter append swap
 198     >r >r constructor-word r> r> prefix define-inline ;
 199
 200 : c-bool> ( int -- ? )
 201     zero? not ;
 202
 203 : >c-array ( seq type word -- byte-array )
 204     [ [ dup length ] dip <c-array> ] dip
 205     [ [ execute ] 2curry each-index ] 2keep drop ; inline
 206
 207 : >c-array-quot ( type vocab -- quot )
 208     dupd set-nth-word [ >c-array ] 2curry ;
 209
 210 : to-array-word ( name vocab -- word )
 211     >r ">c-" swap "-array" 3append r> create ;
 212
 213 : define-to-array ( type vocab -- )
 214     [ to-array-word ] 2keep >c-array-quot
 215     (( array -- byte-array )) define-declared ;
 216
 217 : c-array>quot ( type vocab -- quot )
 218     [
 219         \ swap ,
 220         nth-word 1quotation ,
 221         [ curry map ] %
 222     ] [ ] make ;
 223
 224 : from-array-word ( name vocab -- word )
 225     >r "c-" swap "-array>" 3append r> create ;
 226
 227 : define-from-array ( type vocab -- )
 228     [ from-array-word ] 2keep c-array>quot
 229     (( c-ptr n -- array )) define-declared ;
 230
 231 : define-primitive-type ( type name -- )
 232     "alien.c-types"
 233     {
 234         [ define-c-type ]
 235         [ define-deref ]
 236         [ define-to-array ]
 237         [ define-from-array ]
 238         [ define-out ]
 239     } 2cleave ;
 240
 241 : expand-constants ( c-type -- c-type' )
 242     #! We use def>> call instead of execute to get around
 243     #! staging violations
 244     dup array? [
 245         unclip >r [ dup word? [ def>> call ] when ] map r> prefix
 246     ] when ;
 247
 248 : malloc-file-contents ( path -- alien len )
 249     binary file-contents dup malloc-byte-array swap length ;
 250
 251 [
 252     <c-type>
 253         [ alien-cell ] >>getter
 254         [ set-alien-cell ] >>setter
 255         bootstrap-cell >>size
 256         bootstrap-cell >>align
 257         "box_alien" >>boxer
 258         "alien_offset" >>unboxer
 259     "void*" define-primitive-type
 260
 261     <long-long-type>
 262         [ alien-signed-8 ] >>getter
 263         [ set-alien-signed-8 ] >>setter
 264         8 >>size
 265         8 >>align
 266         "box_signed_8" >>boxer
 267         "to_signed_8" >>unboxer
 268     "longlong" define-primitive-type
 269
 270     <long-long-type>
 271         [ alien-unsigned-8 ] >>getter
 272         [ set-alien-unsigned-8 ] >>setter
 273         8 >>size
 274         8 >>align
 275         "box_unsigned_8" >>boxer
 276         "to_unsigned_8" >>unboxer
 277     "ulonglong" define-primitive-type
 278
 279     <c-type>
 280         [ alien-signed-cell ] >>getter
 281         [ set-alien-signed-cell ] >>setter
 282         bootstrap-cell >>size
 283         bootstrap-cell >>align
 284         "box_signed_cell" >>boxer
 285         "to_fixnum" >>unboxer
 286     "long" define-primitive-type
 287
 288     <c-type>
 289         [ alien-unsigned-cell ] >>getter
 290         [ set-alien-unsigned-cell ] >>setter
 291         bootstrap-cell >>size
 292         bootstrap-cell >>align
 293         "box_unsigned_cell" >>boxer
 294         "to_cell" >>unboxer
 295     "ulong" define-primitive-type
 296
 297     <c-type>
 298         [ alien-signed-4 ] >>getter
 299         [ set-alien-signed-4 ] >>setter
 300         4 >>size
 301         4 >>align
 302         "box_signed_4" >>boxer
 303         "to_fixnum" >>unboxer
 304     "int" define-primitive-type
 305
 306     <c-type>
 307         [ alien-unsigned-4 ] >>getter
 308         [ set-alien-unsigned-4 ] >>setter
 309         4 >>size
 310         4 >>align
 311         "box_unsigned_4" >>boxer
 312         "to_cell" >>unboxer
 313     "uint" define-primitive-type
 314
 315     <c-type>
 316         [ alien-signed-2 ] >>getter
 317         [ set-alien-signed-2 ] >>setter
 318         2 >>size
 319         2 >>align
 320         "box_signed_2" >>boxer
 321         "to_fixnum" >>unboxer
 322     "short" define-primitive-type
 323
 324     <c-type>
 325         [ alien-unsigned-2 ] >>getter
 326         [ set-alien-unsigned-2 ] >>setter
 327         2 >>size
 328         2 >>align
 329         "box_unsigned_2" >>boxer
 330         "to_cell" >>unboxer
 331     "ushort" define-primitive-type
 332
 333     <c-type>
 334         [ alien-signed-1 ] >>getter
 335         [ set-alien-signed-1 ] >>setter
 336         1 >>size
 337         1 >>align
 338         "box_signed_1" >>boxer
 339         "to_fixnum" >>unboxer
 340     "char" define-primitive-type
 341
 342     <c-type>
 343         [ alien-unsigned-1 ] >>getter
 344         [ set-alien-unsigned-1 ] >>setter
 345         1 >>size
 346         1 >>align
 347         "box_unsigned_1" >>boxer
 348         "to_cell" >>unboxer
 349     "uchar" define-primitive-type
 350
 351     <c-type>
 352         [ alien-unsigned-4 zero? not ] >>getter
 353         [ [ 1 0 ? ] 2dip set-alien-unsigned-4 ] >>setter
 354         4 >>size
 355         4 >>align
 356         "box_boolean" >>boxer
 357         "to_boolean" >>unboxer
 358     "bool" define-primitive-type
 359
 360     <c-type>
 361         [ alien-float ] >>getter
 362         [ [ >float ] 2dip set-alien-float ] >>setter
 363         4 >>size
 364         4 >>align
 365         "box_float" >>boxer
 366         "to_float" >>unboxer
 367         single-float-regs >>reg-class
 368         [ >float ] >>unboxer-quot
 369     "float" define-primitive-type
 370
 371     <c-type>
 372         [ alien-double ] >>getter
 373         [ [ >float ] 2dip set-alien-double ] >>setter
 374         8 >>size
 375         8 >>align
 376         "box_double" >>boxer
 377         "to_double" >>unboxer
 378         double-float-regs >>reg-class
 379         [ >float ] >>unboxer-quot
 380     "double" define-primitive-type
 381
 382     os winnt? cpu x86.64? and "longlong" "long" ? "ptrdiff_t" typedef
 383
 384     "ulong" "size_t" typedef
 385 ] with-compilation-unit