basis/alien/c-types/c-types.factor

   1 ! Copyright (C) 2004, 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: byte-arrays arrays assocs kernel kernel.private libc math
   4 namespaces make parser sequences strings words assocs splitting
   5 math.parser cpu.architecture alien alien.accessors quotations
   6 layouts system compiler.units io.files io.encodings.binary
   7 accessors combinators effects continuations fry ;
   8 IN: alien.c-types
   9
  10 DEFER: <int>
  11 DEFER: *char
  12
  13 : little-endian? ( -- ? ) 1 <int> *char 1 = ; foldable
  14
  15 TUPLE: c-type
  16 class
  17 boxer boxer-quot unboxer unboxer-quot
  18 getter setter
  19 reg-class size align stack-align? ;
  20
  21 : new-c-type ( class -- type )
  22     new
  23         int-regs >>reg-class
  24         object >>class ; inline
  25
  26 : <c-type> ( -- type )
  27     \ c-type new-c-type ;
  28
  29 SYMBOL: c-types
  30
  31 global [
  32     c-types [ H{ } assoc-like ] change
  33 ] bind
  34
  35 ERROR: no-c-type name ;
  36
  37 : (c-type) ( name -- type/f )
  38     c-types get-global at dup [
  39         dup string? [ (c-type) ] when
  40     ] when ;
  41
  42 ! C type protocol
  43 GENERIC: c-type ( name -- type ) foldable
  44
  45 : resolve-pointer-type ( name -- name )
  46     c-types get at dup string?
  47     [ "*" append ] [ drop "void*" ] if
  48     c-type ;
  49
  50 : resolve-typedef ( name -- type )
  51     dup string? [ c-type ] when ;
  52
  53 : parse-array-type ( name -- array )
  54     "[" split unclip
  55     [ [ "]" ?tail drop string>number ] map ] dip prefix ;
  56
  57 M: string c-type ( name -- type )
  58     CHAR: ] over member? [
  59         parse-array-type
  60     ] [
  61         dup c-types get at [
  62             resolve-typedef
  63         ] [
  64             "*" ?tail [ resolve-pointer-type ] [ no-c-type ] if
  65         ] ?if
  66     ] if ;
  67
  68 GENERIC: c-type-class ( name -- class )
  69
  70 M: c-type c-type-class class>> ;
  71
  72 M: string c-type-class c-type c-type-class ;
  73
  74 GENERIC: c-type-boxer ( name -- boxer )
  75
  76 M: c-type c-type-boxer boxer>> ;
  77
  78 M: string c-type-boxer c-type c-type-boxer ;
  79
  80 GENERIC: c-type-boxer-quot ( name -- quot )
  81
  82 M: c-type c-type-boxer-quot boxer-quot>> ;
  83
  84 M: string c-type-boxer-quot c-type c-type-boxer-quot ;
  85
  86 GENERIC: c-type-unboxer ( name -- boxer )
  87
  88 M: c-type c-type-unboxer unboxer>> ;
  89
  90 M: string c-type-unboxer c-type c-type-unboxer ;
  91
  92 GENERIC: c-type-unboxer-quot ( name -- quot )
  93
  94 M: c-type c-type-unboxer-quot unboxer-quot>> ;
  95
  96 M: string c-type-unboxer-quot c-type c-type-unboxer-quot ;
  97
  98 GENERIC: c-type-reg-class ( name -- reg-class )
  99
 100 M: c-type c-type-reg-class reg-class>> ;
 101
 102 M: string c-type-reg-class c-type c-type-reg-class ;
 103
 104 GENERIC: c-type-getter ( name -- quot )
 105
 106 M: c-type c-type-getter getter>> ;
 107
 108 M: string c-type-getter c-type c-type-getter ;
 109
 110 GENERIC: c-type-setter ( name -- quot )
 111
 112 M: c-type c-type-setter setter>> ;
 113
 114 M: string c-type-setter c-type c-type-setter ;
 115
 116 GENERIC: c-type-align ( name -- n )
 117
 118 M: c-type c-type-align align>> ;
 119
 120 M: string c-type-align c-type c-type-align ;
 121
 122 GENERIC: c-type-stack-align? ( name -- ? )
 123
 124 M: c-type c-type-stack-align? stack-align?>> ;
 125
 126 M: string c-type-stack-align? c-type c-type-stack-align? ;
 127
 128 : c-type-box ( n type -- )
 129     dup c-type-reg-class
 130     swap c-type-boxer [ "No boxer" throw ] unless*
 131     %box ;
 132
 133 : c-type-unbox ( n ctype -- )
 134     dup c-type-reg-class
 135     swap c-type-unboxer [ "No unboxer" throw ] unless*
 136     %unbox ;
 137
 138 GENERIC: box-parameter ( n ctype -- )
 139
 140 M: c-type box-parameter c-type-box ;
 141
 142 M: string box-parameter c-type box-parameter ;
 143
 144 GENERIC: box-return ( ctype -- )
 145
 146 M: c-type box-return f swap c-type-box ;
 147
 148 M: string box-return c-type box-return ;
 149
 150 GENERIC: unbox-parameter ( n ctype -- )
 151
 152 M: c-type unbox-parameter c-type-unbox ;
 153
 154 M: string unbox-parameter c-type unbox-parameter ;
 155
 156 GENERIC: unbox-return ( ctype -- )
 157
 158 M: c-type unbox-return f swap c-type-unbox ;
 159
 160 M: string unbox-return c-type unbox-return ;
 161
 162 ! These words being foldable means that words need to be
 163 ! recompiled if a C type is redefined. Even so, folding the
 164 ! size facilitates some optimizations.
 165 GENERIC: heap-size ( type -- size ) foldable
 166
 167 M: string heap-size c-type heap-size ;
 168
 169 M: c-type heap-size size>> ;
 170
 171 GENERIC: stack-size ( type -- size ) foldable
 172
 173 M: string stack-size c-type stack-size ;
 174
 175 M: c-type stack-size size>> cell align ;
 176
 177 GENERIC: byte-length ( seq -- n ) flushable
 178
 179 M: byte-array byte-length length ;
 180
 181 : c-getter ( name -- quot )
 182     c-type-getter [
 183         [ "Cannot read struct fields with this type" throw ]
 184     ] unless* ;
 185
 186 : c-setter ( name -- quot )
 187     c-type-setter [
 188         [ "Cannot write struct fields with this type" throw ]
 189     ] unless* ;
 190
 191 : <c-array> ( n type -- array )
 192     heap-size * <byte-array> ; inline
 193
 194 : <c-object> ( type -- array )
 195     1 swap <c-array> ; inline
 196
 197 : malloc-array ( n type -- alien )
 198     heap-size calloc ; inline
 199
 200 : malloc-object ( type -- alien )
 201     1 swap malloc-array ; inline
 202
 203 : malloc-byte-array ( byte-array -- alien )
 204     dup length [ nip malloc dup ] 2keep memcpy ;
 205
 206 : memory>byte-array ( alien len -- byte-array )
 207     [ nip (byte-array) dup ] 2keep memcpy ;
 208
 209 : byte-array>memory ( byte-array base -- )
 210     swap dup length memcpy ;
 211
 212 : array-accessor ( type quot -- def )
 213     [
 214         \ swap , [ heap-size , [ * >fixnum ] % ] [ % ] bi*
 215     ] [ ] make ;
 216
 217 : typedef ( old new -- ) c-types get set-at ;
 218
 219 TUPLE: long-long-type < c-type ;
 220
 221 : <long-long-type> ( -- type )
 222     long-long-type new-c-type ;
 223
 224 M: long-long-type unbox-parameter ( n type -- )
 225     c-type-unboxer %unbox-long-long ;
 226
 227 M: long-long-type unbox-return ( type -- )
 228     f swap unbox-parameter ;
 229
 230 M: long-long-type box-parameter ( n type -- )
 231     c-type-boxer %box-long-long ;
 232
 233 M: long-long-type box-return ( type -- )
 234     f swap box-parameter ;
 235
 236 : define-deref ( name -- )
 237     [ CHAR: * prefix "alien.c-types" create ] [ c-getter 0 prefix ] bi
 238     (( c-ptr -- value )) define-inline ;
 239
 240 : define-out ( name -- )
 241     [ "alien.c-types" constructor-word ]
 242     [ dup c-setter '[ _ <c-object> [ 0 @ ] keep ] ] bi
 243     (( value -- c-ptr )) define-inline ;
 244
 245 : c-bool> ( int -- ? )
 246     0 = not ; inline
 247
 248 : define-primitive-type ( type name -- )
 249     [ typedef ]
 250     [ define-deref ]
 251     [ define-out ]
 252     tri ;
 253
 254 : expand-constants ( c-type -- c-type' )
 255     dup array? [
 256         unclip [
 257             [
 258                 dup word? [
 259                     def>> { } swap with-datastack first
 260                 ] when
 261             ] map
 262         ] dip prefix
 263     ] when ;
 264
 265 : malloc-file-contents ( path -- alien len )
 266     binary file-contents dup malloc-byte-array swap length ;
 267
 268 : if-void ( type true false -- )
 269     pick "void" = [ drop nip call ] [ nip call ] if ; inline
 270
 271 : primitive-types
 272     {
 273         "char" "uchar"
 274         "short" "ushort"
 275         "int" "uint"
 276         "long" "ulong"
 277         "longlong" "ulonglong"
 278         "float" "double"
 279         "void*" "bool"
 280     } ;
 281
 282 [
 283     <c-type>
 284         c-ptr >>class
 285         [ alien-cell ] >>getter
 286         [ set-alien-cell ] >>setter
 287         bootstrap-cell >>size
 288         bootstrap-cell >>align
 289         "box_alien" >>boxer
 290         "alien_offset" >>unboxer
 291     "void*" define-primitive-type
 292
 293     <long-long-type>
 294         integer >>class
 295         [ alien-signed-8 ] >>getter
 296         [ set-alien-signed-8 ] >>setter
 297         8 >>size
 298         8 >>align
 299         "box_signed_8" >>boxer
 300         "to_signed_8" >>unboxer
 301     "longlong" define-primitive-type
 302
 303     <long-long-type>
 304         integer >>class
 305         [ alien-unsigned-8 ] >>getter
 306         [ set-alien-unsigned-8 ] >>setter
 307         8 >>size
 308         8 >>align
 309         "box_unsigned_8" >>boxer
 310         "to_unsigned_8" >>unboxer
 311     "ulonglong" define-primitive-type
 312
 313     <c-type>
 314         integer >>class
 315         [ alien-signed-cell ] >>getter
 316         [ set-alien-signed-cell ] >>setter
 317         bootstrap-cell >>size
 318         bootstrap-cell >>align
 319         "box_signed_cell" >>boxer
 320         "to_fixnum" >>unboxer
 321     "long" define-primitive-type
 322
 323     <c-type>
 324         integer >>class
 325         [ alien-unsigned-cell ] >>getter
 326         [ set-alien-unsigned-cell ] >>setter
 327         bootstrap-cell >>size
 328         bootstrap-cell >>align
 329         "box_unsigned_cell" >>boxer
 330         "to_cell" >>unboxer
 331     "ulong" define-primitive-type
 332
 333     <c-type>
 334         integer >>class
 335         [ alien-signed-4 ] >>getter
 336         [ set-alien-signed-4 ] >>setter
 337         4 >>size
 338         4 >>align
 339         "box_signed_4" >>boxer
 340         "to_fixnum" >>unboxer
 341     "int" define-primitive-type
 342
 343     <c-type>
 344         integer >>class
 345         [ alien-unsigned-4 ] >>getter
 346         [ set-alien-unsigned-4 ] >>setter
 347         4 >>size
 348         4 >>align
 349         "box_unsigned_4" >>boxer
 350         "to_cell" >>unboxer
 351     "uint" define-primitive-type
 352
 353     <c-type>
 354         fixnum >>class
 355         [ alien-signed-2 ] >>getter
 356         [ set-alien-signed-2 ] >>setter
 357         2 >>size
 358         2 >>align
 359         "box_signed_2" >>boxer
 360         "to_fixnum" >>unboxer
 361     "short" define-primitive-type
 362
 363     <c-type>
 364         fixnum >>class
 365         [ alien-unsigned-2 ] >>getter
 366         [ set-alien-unsigned-2 ] >>setter
 367         2 >>size
 368         2 >>align
 369         "box_unsigned_2" >>boxer
 370         "to_cell" >>unboxer
 371     "ushort" define-primitive-type
 372
 373     <c-type>
 374         fixnum >>class
 375         [ alien-signed-1 ] >>getter
 376         [ set-alien-signed-1 ] >>setter
 377         1 >>size
 378         1 >>align
 379         "box_signed_1" >>boxer
 380         "to_fixnum" >>unboxer
 381     "char" define-primitive-type
 382
 383     <c-type>
 384         fixnum >>class
 385         [ alien-unsigned-1 ] >>getter
 386         [ set-alien-unsigned-1 ] >>setter
 387         1 >>size
 388         1 >>align
 389         "box_unsigned_1" >>boxer
 390         "to_cell" >>unboxer
 391     "uchar" define-primitive-type
 392
 393     <c-type>
 394         [ alien-unsigned-4 zero? not ] >>getter
 395         [ [ 1 0 ? ] 2dip set-alien-unsigned-4 ] >>setter
 396         4 >>size
 397         4 >>align
 398         "box_boolean" >>boxer
 399         "to_boolean" >>unboxer
 400     "bool" define-primitive-type
 401
 402     <c-type>
 403         float >>class
 404         [ alien-float ] >>getter
 405         [ [ >float ] 2dip set-alien-float ] >>setter
 406         4 >>size
 407         4 >>align
 408         "box_float" >>boxer
 409         "to_float" >>unboxer
 410         single-float-regs >>reg-class
 411         [ >float ] >>unboxer-quot
 412     "float" define-primitive-type
 413
 414     <c-type>
 415         float >>class
 416         [ alien-double ] >>getter
 417         [ [ >float ] 2dip set-alien-double ] >>setter
 418         8 >>size
 419         8 >>align
 420         "box_double" >>boxer
 421         "to_double" >>unboxer
 422         double-float-regs >>reg-class
 423         [ >float ] >>unboxer-quot
 424     "double" define-primitive-type
 425
 426     "long" "ptrdiff_t" typedef
 427     "long" "intptr_t" typedef
 428     "ulong" "size_t" typedef
 429 ] with-compilation-unit