basis/alien/c-types/c-types.factor

   1 ! Copyright (C) 2004, 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: byte-arrays arrays assocs kernel kernel.private libc math
   4 namespaces make parser sequences strings words assocs splitting
   5 math.parser cpu.architecture alien alien.accessors quotations
   6 layouts system compiler.units io.files io.encodings.binary
   7 accessors combinators effects continuations ;
   8 IN: alien.c-types
   9
  10 DEFER: <int>
  11 DEFER: *char
  12
  13 : little-endian? ( -- ? ) 1 <int> *char 1 = ; foldable
  14
  15 TUPLE: c-type
  16 boxer boxer-quot unboxer unboxer-quot
  17 getter setter
  18 reg-class size align stack-align? ;
  19
  20 : new-c-type ( class -- type )
  21     new
  22         int-regs >>reg-class ; inline
  23
  24 : <c-type> ( -- type )
  25     \ c-type new-c-type ;
  26
  27 SYMBOL: c-types
  28
  29 global [
  30     c-types [ H{ } assoc-like ] change
  31 ] bind
  32
  33 ERROR: no-c-type name ;
  34
  35 : (c-type) ( name -- type/f )
  36     c-types get-global at dup [
  37         dup string? [ (c-type) ] when
  38     ] when ;
  39
  40 ! C type protocol
  41 GENERIC: c-type ( name -- type ) foldable
  42
  43 : resolve-pointer-type ( name -- name )
  44     c-types get at dup string?
  45     [ "*" append ] [ drop "void*" ] if
  46     c-type ;
  47
  48 : resolve-typedef ( name -- type )
  49     dup string? [ c-type ] when ;
  50
  51 : parse-array-type ( name -- array )
  52     "[" split unclip
  53     >r [ "]" ?tail drop string>number ] map r> prefix ;
  54
  55 M: string c-type ( name -- type )
  56     CHAR: ] over member? [
  57         parse-array-type
  58     ] [
  59         dup c-types get at [
  60             resolve-typedef
  61         ] [
  62             "*" ?tail [ resolve-pointer-type ] [ no-c-type ] if
  63         ] ?if
  64     ] if ;
  65
  66 GENERIC: c-type-boxer ( name -- boxer )
  67
  68 M: c-type c-type-boxer boxer>> ;
  69
  70 M: string c-type-boxer c-type c-type-boxer ;
  71
  72 GENERIC: c-type-boxer-quot ( name -- quot )
  73
  74 M: c-type c-type-boxer-quot boxer-quot>> ;
  75
  76 M: string c-type-boxer-quot c-type c-type-boxer-quot ;
  77
  78 GENERIC: c-type-unboxer ( name -- boxer )
  79
  80 M: c-type c-type-unboxer unboxer>> ;
  81
  82 M: string c-type-unboxer c-type c-type-unboxer ;
  83
  84 GENERIC: c-type-unboxer-quot ( name -- quot )
  85
  86 M: c-type c-type-unboxer-quot unboxer-quot>> ;
  87
  88 M: string c-type-unboxer-quot c-type c-type-unboxer-quot ;
  89
  90 GENERIC: c-type-reg-class ( name -- reg-class )
  91
  92 M: c-type c-type-reg-class reg-class>> ;
  93
  94 M: string c-type-reg-class c-type c-type-reg-class ;
  95
  96 GENERIC: c-type-getter ( name -- quot )
  97
  98 M: c-type c-type-getter getter>> ;
  99
 100 M: string c-type-getter c-type c-type-getter ;
 101
 102 GENERIC: c-type-setter ( name -- quot )
 103
 104 M: c-type c-type-setter setter>> ;
 105
 106 M: string c-type-setter c-type c-type-setter ;
 107
 108 GENERIC: c-type-align ( name -- n )
 109
 110 M: c-type c-type-align align>> ;
 111
 112 M: string c-type-align c-type c-type-align ;
 113
 114 GENERIC: c-type-stack-align? ( name -- ? )
 115
 116 M: c-type c-type-stack-align? stack-align?>> ;
 117
 118 M: string c-type-stack-align? c-type c-type-stack-align? ;
 119
 120 : c-type-box ( n type -- )
 121     dup c-type-reg-class
 122     swap c-type-boxer [ "No boxer" throw ] unless*
 123     %box ;
 124
 125 : c-type-unbox ( n ctype -- )
 126     dup c-type-reg-class
 127     swap c-type-unboxer [ "No unboxer" throw ] unless*
 128     %unbox ;
 129
 130 GENERIC: box-parameter ( n ctype -- )
 131
 132 M: c-type box-parameter c-type-box ;
 133
 134 M: string box-parameter c-type box-parameter ;
 135
 136 GENERIC: box-return ( ctype -- )
 137
 138 M: c-type box-return f swap c-type-box ;
 139
 140 M: string box-return c-type box-return ;
 141
 142 GENERIC: unbox-parameter ( n ctype -- )
 143
 144 M: c-type unbox-parameter c-type-unbox ;
 145
 146 M: string unbox-parameter c-type unbox-parameter ;
 147
 148 GENERIC: unbox-return ( ctype -- )
 149
 150 M: c-type unbox-return f swap c-type-unbox ;
 151
 152 M: string unbox-return c-type unbox-return ;
 153
 154 ! These words being foldable means that words need to be
 155 ! recompiled if a C type is redefined. Even so, folding the
 156 ! size facilitates some optimizations.
 157 GENERIC: heap-size ( type -- size ) foldable
 158
 159 M: string heap-size c-type heap-size ;
 160
 161 M: c-type heap-size size>> ;
 162
 163 GENERIC: stack-size ( type -- size ) foldable
 164
 165 M: string stack-size c-type stack-size ;
 166
 167 M: c-type stack-size size>> cell align ;
 168
 169 GENERIC: byte-length ( seq -- n ) flushable
 170
 171 M: byte-array byte-length length ;
 172
 173 : c-getter ( name -- quot )
 174     c-type-getter [
 175         [ "Cannot read struct fields with this type" throw ]
 176     ] unless* ;
 177
 178 : c-setter ( name -- quot )
 179     c-type-setter [
 180         [ "Cannot write struct fields with this type" throw ]
 181     ] unless* ;
 182
 183 : <c-array> ( n type -- array )
 184     heap-size * <byte-array> ; inline
 185
 186 : <c-object> ( type -- array )
 187     1 swap <c-array> ; inline
 188
 189 : malloc-array ( n type -- alien )
 190     heap-size calloc ; inline
 191
 192 : malloc-object ( type -- alien )
 193     1 swap malloc-array ; inline
 194
 195 : malloc-byte-array ( byte-array -- alien )
 196     dup length dup malloc [ -rot memcpy ] keep ;
 197
 198 : memory>byte-array ( alien len -- byte-array )
 199     dup <byte-array> [ -rot memcpy ] keep ;
 200
 201 : byte-array>memory ( byte-array base -- )
 202     swap dup length memcpy ;
 203
 204 : array-accessor ( type quot -- def )
 205     [
 206         \ swap , [ heap-size , [ * >fixnum ] % ] [ % ] bi*
 207     ] [ ] make ;
 208
 209 : typedef ( old new -- ) c-types get set-at ;
 210
 211 TUPLE: long-long-type < c-type ;
 212
 213 : <long-long-type> ( -- type )
 214     long-long-type new-c-type ;
 215
 216 M: long-long-type unbox-parameter ( n type -- )
 217     c-type-unboxer %unbox-long-long ;
 218
 219 M: long-long-type unbox-return ( type -- )
 220     f swap unbox-parameter ;
 221
 222 M: long-long-type box-parameter ( n type -- )
 223     c-type-boxer %box-long-long ;
 224
 225 M: long-long-type box-return ( type -- )
 226     f swap box-parameter ;
 227
 228 : define-deref ( name -- )
 229     [ CHAR: * prefix "alien.c-types" create ]
 230     [ c-getter 0 prefix ] bi
 231     define-inline ;
 232
 233 : define-out ( name -- )
 234     [ "alien.c-types" constructor-word ]
 235     [ [ [ <c-object> ] curry ] [ c-setter ] bi append ] bi
 236     define-inline ;
 237
 238 : c-bool> ( int -- ? )
 239     zero? not ;
 240
 241 : define-primitive-type ( type name -- )
 242     [ typedef ]
 243     [ define-deref ]
 244     [ define-out ]
 245     tri ;
 246
 247 : expand-constants ( c-type -- c-type' )
 248     dup array? [
 249         unclip [
 250             [
 251                 dup word? [
 252                     def>> { } swap with-datastack first
 253                 ] when
 254             ] map
 255         ] dip prefix
 256     ] when ;
 257
 258 : malloc-file-contents ( path -- alien len )
 259     binary file-contents dup malloc-byte-array swap length ;
 260
 261 : if-void ( type true false -- )
 262     pick "void" = [ drop nip call ] [ nip call ] if ; inline
 263
 264 : primitive-types
 265     {
 266         "char" "uchar"
 267         "short" "ushort"
 268         "int" "uint"
 269         "long" "ulong"
 270         "longlong" "ulonglong"
 271         "float" "double"
 272         "void*" "bool"
 273     } ;
 274
 275 [
 276     <c-type>
 277         [ alien-cell ] >>getter
 278         [ set-alien-cell ] >>setter
 279         bootstrap-cell >>size
 280         bootstrap-cell >>align
 281         "box_alien" >>boxer
 282         "alien_offset" >>unboxer
 283     "void*" define-primitive-type
 284
 285     <long-long-type>
 286         [ alien-signed-8 ] >>getter
 287         [ set-alien-signed-8 ] >>setter
 288         8 >>size
 289         8 >>align
 290         "box_signed_8" >>boxer
 291         "to_signed_8" >>unboxer
 292     "longlong" define-primitive-type
 293
 294     <long-long-type>
 295         [ alien-unsigned-8 ] >>getter
 296         [ set-alien-unsigned-8 ] >>setter
 297         8 >>size
 298         8 >>align
 299         "box_unsigned_8" >>boxer
 300         "to_unsigned_8" >>unboxer
 301     "ulonglong" define-primitive-type
 302
 303     <c-type>
 304         [ alien-signed-cell ] >>getter
 305         [ set-alien-signed-cell ] >>setter
 306         bootstrap-cell >>size
 307         bootstrap-cell >>align
 308         "box_signed_cell" >>boxer
 309         "to_fixnum" >>unboxer
 310     "long" define-primitive-type
 311
 312     <c-type>
 313         [ alien-unsigned-cell ] >>getter
 314         [ set-alien-unsigned-cell ] >>setter
 315         bootstrap-cell >>size
 316         bootstrap-cell >>align
 317         "box_unsigned_cell" >>boxer
 318         "to_cell" >>unboxer
 319     "ulong" define-primitive-type
 320
 321     <c-type>
 322         [ alien-signed-4 ] >>getter
 323         [ set-alien-signed-4 ] >>setter
 324         4 >>size
 325         4 >>align
 326         "box_signed_4" >>boxer
 327         "to_fixnum" >>unboxer
 328     "int" define-primitive-type
 329
 330     <c-type>
 331         [ alien-unsigned-4 ] >>getter
 332         [ set-alien-unsigned-4 ] >>setter
 333         4 >>size
 334         4 >>align
 335         "box_unsigned_4" >>boxer
 336         "to_cell" >>unboxer
 337     "uint" define-primitive-type
 338
 339     <c-type>
 340         [ alien-signed-2 ] >>getter
 341         [ set-alien-signed-2 ] >>setter
 342         2 >>size
 343         2 >>align
 344         "box_signed_2" >>boxer
 345         "to_fixnum" >>unboxer
 346     "short" define-primitive-type
 347
 348     <c-type>
 349         [ alien-unsigned-2 ] >>getter
 350         [ set-alien-unsigned-2 ] >>setter
 351         2 >>size
 352         2 >>align
 353         "box_unsigned_2" >>boxer
 354         "to_cell" >>unboxer
 355     "ushort" define-primitive-type
 356
 357     <c-type>
 358         [ alien-signed-1 ] >>getter
 359         [ set-alien-signed-1 ] >>setter
 360         1 >>size
 361         1 >>align
 362         "box_signed_1" >>boxer
 363         "to_fixnum" >>unboxer
 364     "char" define-primitive-type
 365
 366     <c-type>
 367         [ alien-unsigned-1 ] >>getter
 368         [ set-alien-unsigned-1 ] >>setter
 369         1 >>size
 370         1 >>align
 371         "box_unsigned_1" >>boxer
 372         "to_cell" >>unboxer
 373     "uchar" define-primitive-type
 374
 375     <c-type>
 376         [ alien-unsigned-4 zero? not ] >>getter
 377         [ [ 1 0 ? ] 2dip set-alien-unsigned-4 ] >>setter
 378         4 >>size
 379         4 >>align
 380         "box_boolean" >>boxer
 381         "to_boolean" >>unboxer
 382     "bool" define-primitive-type
 383
 384     <c-type>
 385         [ alien-float ] >>getter
 386         [ [ >float ] 2dip set-alien-float ] >>setter
 387         4 >>size
 388         4 >>align
 389         "box_float" >>boxer
 390         "to_float" >>unboxer
 391         single-float-regs >>reg-class
 392         [ >float ] >>unboxer-quot
 393     "float" define-primitive-type
 394
 395     <c-type>
 396         [ alien-double ] >>getter
 397         [ [ >float ] 2dip set-alien-double ] >>setter
 398         8 >>size
 399         8 >>align
 400         "box_double" >>boxer
 401         "to_double" >>unboxer
 402         double-float-regs >>reg-class
 403         [ >float ] >>unboxer-quot
 404     "double" define-primitive-type
 405
 406     "long" "ptrdiff_t" typedef
 407     "long" "intptr_t" typedef
 408     "ulong" "size_t" typedef
 409 ] with-compilation-unit