basis/alien/c-types/c-types.factor

   1 ! Copyright (C) 2004, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: byte-arrays arrays assocs kernel kernel.private math
   4 math.order math.parser namespaces make parser sequences strings
   5 words splitting cpu.architecture alien alien.accessors
   6 alien.strings quotations layouts system compiler.units io
   7 io.files io.encodings.binary io.streams.memory accessors
   8 combinators effects continuations fry classes vocabs
   9 vocabs.loader words.symbol ;
  10 QUALIFIED: math
  11 IN: alien.c-types
  12
  13 SYMBOLS:
  14     char uchar
  15     short ushort
  16     int uint
  17     long ulong
  18     longlong ulonglong
  19     float double
  20     void* bool
  21     void ;
  22
  23 DEFER: <int>
  24 DEFER: *char
  25
  26 TUPLE: abstract-c-type
  27 { class class initial: object }
  28 { boxed-class class initial: object }
  29 { boxer-quot callable }
  30 { unboxer-quot callable }
  31 { getter callable }
  32 { setter callable }
  33 size
  34 align ;
  35
  36 TUPLE: c-type < abstract-c-type
  37 boxer
  38 unboxer
  39 { rep initial: int-rep }
  40 stack-align? ;
  41
  42 : <c-type> ( -- c-type )
  43     \ c-type new ; inline
  44
  45 SYMBOL: c-types
  46
  47 global [
  48     c-types [ H{ } assoc-like ] change
  49 ] bind
  50
  51 ERROR: no-c-type name ;
  52
  53 PREDICATE: c-type-word < word
  54     "c-type" word-prop ;
  55
  56 UNION: c-type-name string c-type-word ;
  57
  58 ! C type protocol
  59 GENERIC: c-type ( name -- c-type ) foldable
  60
  61 GENERIC: resolve-pointer-type ( name -- c-type )
  62
  63 << \ void \ void* "pointer-c-type" set-word-prop >>
  64
  65 : void? ( c-type -- ? )
  66     { void "void" } member? ;
  67
  68 M: word resolve-pointer-type
  69     dup "pointer-c-type" word-prop
  70     [ ] [ drop void* ] ?if ;
  71
  72 M: string resolve-pointer-type
  73     dup "*" append dup c-types get at
  74     [ nip ] [
  75         drop
  76         c-types get at dup c-type-name?
  77         [ resolve-pointer-type ] [ drop void* ] if
  78     ] if ;
  79
  80 : resolve-typedef ( name -- c-type )
  81     dup void? [ no-c-type ] when
  82     dup c-type-name? [ c-type ] when ;
  83
  84 : parse-array-type ( name -- dims c-type )
  85     "[" split unclip
  86     [ [ "]" ?tail drop string>number ] map ] dip ;
  87
  88 M: string c-type ( name -- c-type )
  89     CHAR: ] over member? [
  90         parse-array-type prefix
  91     ] [
  92         dup c-types get at [ ] [
  93             "*" ?tail [ resolve-pointer-type ] [ no-c-type ] if
  94         ] ?if resolve-typedef
  95     ] if ;
  96
  97 M: word c-type
  98     dup "c-type" word-prop resolve-typedef
  99     [ ] [ no-c-type ] ?if ;
 100
 101 GENERIC: c-struct? ( c-type -- ? )
 102
 103 M: object c-struct?
 104     drop f ;
 105 M: c-type-name c-struct?
 106     dup void? [ drop f ] [ c-type c-struct? ] if ;
 107
 108 ! These words being foldable means that words need to be
 109 ! recompiled if a C type is redefined. Even so, folding the
 110 ! size facilitates some optimizations.
 111 GENERIC: c-type-class ( name -- class )
 112
 113 M: abstract-c-type c-type-class class>> ;
 114
 115 M: c-type-name c-type-class c-type c-type-class ;
 116
 117 GENERIC: c-type-boxed-class ( name -- class )
 118
 119 M: abstract-c-type c-type-boxed-class boxed-class>> ;
 120
 121 M: c-type-name c-type-boxed-class c-type c-type-boxed-class ;
 122
 123 GENERIC: c-type-boxer ( name -- boxer )
 124
 125 M: c-type c-type-boxer boxer>> ;
 126
 127 M: c-type-name c-type-boxer c-type c-type-boxer ;
 128
 129 GENERIC: c-type-boxer-quot ( name -- quot )
 130
 131 M: abstract-c-type c-type-boxer-quot boxer-quot>> ;
 132
 133 M: c-type-name c-type-boxer-quot c-type c-type-boxer-quot ;
 134
 135 GENERIC: c-type-unboxer ( name -- boxer )
 136
 137 M: c-type c-type-unboxer unboxer>> ;
 138
 139 M: c-type-name c-type-unboxer c-type c-type-unboxer ;
 140
 141 GENERIC: c-type-unboxer-quot ( name -- quot )
 142
 143 M: abstract-c-type c-type-unboxer-quot unboxer-quot>> ;
 144
 145 M: c-type-name c-type-unboxer-quot c-type c-type-unboxer-quot ;
 146
 147 GENERIC: c-type-rep ( name -- rep )
 148
 149 M: c-type c-type-rep rep>> ;
 150
 151 M: c-type-name c-type-rep c-type c-type-rep ;
 152
 153 GENERIC: c-type-getter ( name -- quot )
 154
 155 M: c-type c-type-getter getter>> ;
 156
 157 M: c-type-name c-type-getter c-type c-type-getter ;
 158
 159 GENERIC: c-type-setter ( name -- quot )
 160
 161 M: c-type c-type-setter setter>> ;
 162
 163 M: c-type-name c-type-setter c-type c-type-setter ;
 164
 165 GENERIC: c-type-align ( name -- n )
 166
 167 M: abstract-c-type c-type-align align>> ;
 168
 169 M: c-type-name c-type-align c-type c-type-align ;
 170
 171 GENERIC: c-type-stack-align? ( name -- ? )
 172
 173 M: c-type c-type-stack-align? stack-align?>> ;
 174
 175 M: c-type-name c-type-stack-align? c-type c-type-stack-align? ;
 176
 177 : c-type-box ( n c-type -- )
 178     [ c-type-rep ] [ c-type-boxer [ "No boxer" throw ] unless* ] bi
 179     %box ;
 180
 181 : c-type-unbox ( n c-type -- )
 182     [ c-type-rep ] [ c-type-unboxer [ "No unboxer" throw ] unless* ] bi
 183     %unbox ;
 184
 185 GENERIC: box-parameter ( n c-type -- )
 186
 187 M: c-type box-parameter c-type-box ;
 188
 189 M: c-type-name box-parameter c-type box-parameter ;
 190
 191 GENERIC: box-return ( c-type -- )
 192
 193 M: c-type box-return f swap c-type-box ;
 194
 195 M: c-type-name box-return c-type box-return ;
 196
 197 GENERIC: unbox-parameter ( n c-type -- )
 198
 199 M: c-type unbox-parameter c-type-unbox ;
 200
 201 M: c-type-name unbox-parameter c-type unbox-parameter ;
 202
 203 GENERIC: unbox-return ( c-type -- )
 204
 205 M: c-type unbox-return f swap c-type-unbox ;
 206
 207 M: c-type-name unbox-return c-type unbox-return ;
 208
 209 : little-endian? ( -- ? ) 1 <int> *char 1 = ; foldable
 210
 211 GENERIC: heap-size ( name -- size ) foldable
 212
 213 M: c-type-name heap-size c-type heap-size ;
 214
 215 M: abstract-c-type heap-size size>> ;
 216
 217 GENERIC: stack-size ( name -- size ) foldable
 218
 219 M: c-type-name stack-size c-type stack-size ;
 220
 221 M: c-type stack-size size>> cell align ;
 222
 223 GENERIC: byte-length ( seq -- n ) flushable
 224
 225 M: byte-array byte-length length ; inline
 226
 227 M: f byte-length drop 0 ; inline
 228
 229 MIXIN: value-type
 230
 231 : c-getter ( name -- quot )
 232     c-type-getter [
 233         [ "Cannot read struct fields with this type" throw ]
 234     ] unless* ;
 235
 236 : c-type-getter-boxer ( name -- quot )
 237     [ c-getter ] [ c-type-boxer-quot ] bi append ;
 238
 239 : c-setter ( name -- quot )
 240     c-type-setter [
 241         [ "Cannot write struct fields with this type" throw ]
 242     ] unless* ;
 243
 244 : array-accessor ( c-type quot -- def )
 245     [
 246         \ swap , [ heap-size , [ * >fixnum ] % ] [ % ] bi*
 247     ] [ ] make ;
 248
 249 GENERIC: typedef ( old new -- )
 250
 251 PREDICATE: typedef-word < c-type-word
 252     "c-type" word-prop c-type-name? ;
 253
 254 M: string typedef ( old new -- ) c-types get set-at ;
 255 M: word typedef ( old new -- )
 256     {
 257         [ nip define-symbol ]
 258         [ name>> typedef ]
 259         [ swap "c-type" set-word-prop ]
 260         [
 261             swap dup c-type-name? [
 262                 resolve-pointer-type
 263                 "pointer-c-type" set-word-prop
 264             ] [ 2drop ] if
 265         ]
 266     } 2cleave ;
 267
 268 TUPLE: long-long-type < c-type ;
 269
 270 : <long-long-type> ( -- c-type )
 271     long-long-type new ;
 272
 273 M: long-long-type unbox-parameter ( n c-type -- )
 274     c-type-unboxer %unbox-long-long ;
 275
 276 M: long-long-type unbox-return ( c-type -- )
 277     f swap unbox-parameter ;
 278
 279 M: long-long-type box-parameter ( n c-type -- )
 280     c-type-boxer %box-long-long ;
 281
 282 M: long-long-type box-return ( c-type -- )
 283     f swap box-parameter ;
 284
 285 : define-deref ( name -- )
 286     [ CHAR: * prefix "alien.c-types" create ] [ c-getter 0 prefix ] bi
 287     (( c-ptr -- value )) define-inline ;
 288
 289 : define-out ( name -- )
 290     [ "alien.c-types" constructor-word ]
 291     [ dup c-setter '[ _ heap-size <byte-array> [ 0 @ ] keep ] ] bi
 292     (( value -- c-ptr )) define-inline ;
 293
 294 : define-primitive-type ( c-type name -- )
 295     [ typedef ]
 296     [ name>> define-deref ]
 297     [ name>> define-out ]
 298     tri ;
 299
 300 : if-void ( c-type true false -- )
 301     pick void? [ drop nip call ] [ nip call ] if ; inline
 302
 303 CONSTANT: primitive-types
 304     {
 305         char uchar
 306         short ushort
 307         int uint
 308         long ulong
 309         longlong ulonglong
 310         float double
 311         void* bool
 312     }
 313
 314 SYMBOLS:
 315     ptrdiff_t intptr_t uintptr_t size_t
 316     char* uchar* ;
 317
 318 [
 319     <c-type>
 320         c-ptr >>class
 321         c-ptr >>boxed-class
 322         [ alien-cell ] >>getter
 323         [ [ >c-ptr ] 2dip set-alien-cell ] >>setter
 324         bootstrap-cell >>size
 325         bootstrap-cell >>align
 326         [ >c-ptr ] >>unboxer-quot
 327         "box_alien" >>boxer
 328         "alien_offset" >>unboxer
 329     \ void* define-primitive-type
 330
 331     <long-long-type>
 332         integer >>class
 333         integer >>boxed-class
 334         [ alien-signed-8 ] >>getter
 335         [ set-alien-signed-8 ] >>setter
 336         8 >>size
 337         8 >>align
 338         "box_signed_8" >>boxer
 339         "to_signed_8" >>unboxer
 340     \ longlong define-primitive-type
 341
 342     <long-long-type>
 343         integer >>class
 344         integer >>boxed-class
 345         [ alien-unsigned-8 ] >>getter
 346         [ set-alien-unsigned-8 ] >>setter
 347         8 >>size
 348         8 >>align
 349         "box_unsigned_8" >>boxer
 350         "to_unsigned_8" >>unboxer
 351     \ ulonglong define-primitive-type
 352
 353     <c-type>
 354         integer >>class
 355         integer >>boxed-class
 356         [ alien-signed-cell ] >>getter
 357         [ set-alien-signed-cell ] >>setter
 358         bootstrap-cell >>size
 359         bootstrap-cell >>align
 360         "box_signed_cell" >>boxer
 361         "to_fixnum" >>unboxer
 362     \ long define-primitive-type
 363
 364     <c-type>
 365         integer >>class
 366         integer >>boxed-class
 367         [ alien-unsigned-cell ] >>getter
 368         [ set-alien-unsigned-cell ] >>setter
 369         bootstrap-cell >>size
 370         bootstrap-cell >>align
 371         "box_unsigned_cell" >>boxer
 372         "to_cell" >>unboxer
 373     \ ulong define-primitive-type
 374
 375     <c-type>
 376         integer >>class
 377         integer >>boxed-class
 378         [ alien-signed-4 ] >>getter
 379         [ set-alien-signed-4 ] >>setter
 380         4 >>size
 381         4 >>align
 382         "box_signed_4" >>boxer
 383         "to_fixnum" >>unboxer
 384     \ int define-primitive-type
 385
 386     <c-type>
 387         integer >>class
 388         integer >>boxed-class
 389         [ alien-unsigned-4 ] >>getter
 390         [ set-alien-unsigned-4 ] >>setter
 391         4 >>size
 392         4 >>align
 393         "box_unsigned_4" >>boxer
 394         "to_cell" >>unboxer
 395     \ uint define-primitive-type
 396
 397     <c-type>
 398         fixnum >>class
 399         fixnum >>boxed-class
 400         [ alien-signed-2 ] >>getter
 401         [ set-alien-signed-2 ] >>setter
 402         2 >>size
 403         2 >>align
 404         "box_signed_2" >>boxer
 405         "to_fixnum" >>unboxer
 406     \ short define-primitive-type
 407
 408     <c-type>
 409         fixnum >>class
 410         fixnum >>boxed-class
 411         [ alien-unsigned-2 ] >>getter
 412         [ set-alien-unsigned-2 ] >>setter
 413         2 >>size
 414         2 >>align
 415         "box_unsigned_2" >>boxer
 416         "to_cell" >>unboxer
 417     \ ushort define-primitive-type
 418
 419     <c-type>
 420         fixnum >>class
 421         fixnum >>boxed-class
 422         [ alien-signed-1 ] >>getter
 423         [ set-alien-signed-1 ] >>setter
 424         1 >>size
 425         1 >>align
 426         "box_signed_1" >>boxer
 427         "to_fixnum" >>unboxer
 428     \ char define-primitive-type
 429
 430     <c-type>
 431         fixnum >>class
 432         fixnum >>boxed-class
 433         [ alien-unsigned-1 ] >>getter
 434         [ set-alien-unsigned-1 ] >>setter
 435         1 >>size
 436         1 >>align
 437         "box_unsigned_1" >>boxer
 438         "to_cell" >>unboxer
 439     \ uchar define-primitive-type
 440
 441     <c-type>
 442         [ alien-unsigned-1 0 = not ] >>getter
 443         [ [ 1 0 ? ] 2dip set-alien-unsigned-1 ] >>setter
 444         1 >>size
 445         1 >>align
 446         "box_boolean" >>boxer
 447         "to_boolean" >>unboxer
 448     \ bool define-primitive-type
 449
 450     <c-type>
 451         math:float >>class
 452         math:float >>boxed-class
 453         [ alien-float ] >>getter
 454         [ [ >float ] 2dip set-alien-float ] >>setter
 455         4 >>size
 456         4 >>align
 457         "box_float" >>boxer
 458         "to_float" >>unboxer
 459         float-rep >>rep
 460         [ >float ] >>unboxer-quot
 461     \ float define-primitive-type
 462
 463     <c-type>
 464         math:float >>class
 465         math:float >>boxed-class
 466         [ alien-double ] >>getter
 467         [ [ >float ] 2dip set-alien-double ] >>setter
 468         8 >>size
 469         8 >>align
 470         "box_double" >>boxer
 471         "to_double" >>unboxer
 472         double-rep >>rep
 473         [ >float ] >>unboxer-quot
 474     \ double define-primitive-type
 475
 476     \ long c-type \ ptrdiff_t typedef
 477     \ long c-type \ intptr_t typedef
 478     \ ulong c-type \ uintptr_t typedef
 479     \ ulong c-type \ size_t typedef
 480 ] with-compilation-unit
 481
 482 M: char-16-rep rep-component-type drop char ;
 483 M: uchar-16-rep rep-component-type drop uchar ;
 484 M: short-8-rep rep-component-type drop short ;
 485 M: ushort-8-rep rep-component-type drop ushort ;
 486 M: int-4-rep rep-component-type drop int ;
 487 M: uint-4-rep rep-component-type drop uint ;
 488 M: longlong-2-rep rep-component-type drop longlong ;
 489 M: ulonglong-2-rep rep-component-type drop ulonglong ;
 490 M: float-4-rep rep-component-type drop float ;
 491 M: double-2-rep rep-component-type drop double ;
 492
 493 : (unsigned-interval) ( bytes -- from to ) [ 0 ] dip 8 * 2^ 1 - ; foldable
 494 : unsigned-interval ( c-type -- from to ) heap-size (unsigned-interval) ; foldable
 495 : (signed-interval) ( bytes -- from to ) 8 * 1 - 2^ [ neg ] [ 1 - ] bi ; foldable
 496 : signed-interval ( c-type -- from to ) heap-size (signed-interval) ; foldable
 497
 498 : c-type-interval ( c-type -- from to )
 499     {
 500         { [ dup { float double } memq? ] [ drop -1/0. 1/0. ] }
 501         { [ dup { char short int long longlong } memq? ] [ signed-interval ] }
 502         { [ dup { uchar ushort uint ulong ulonglong } memq? ] [ unsigned-interval ] }
 503     } cond ; foldable
 504
 505 : c-type-clamp ( value c-type -- value' ) c-type-interval clamp ; inline