basis/alien/c-types/c-types.factor

   1 ! Copyright (C) 2004, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: byte-arrays arrays assocs kernel kernel.private math
   4 namespaces make parser sequences strings words splitting math.parser
   5 cpu.architecture alien alien.accessors alien.strings quotations
   6 layouts system compiler.units io io.files io.encodings.binary
   7 io.streams.memory accessors combinators effects continuations fry
   8 classes vocabs vocabs.loader words.symbol ;
   9 QUALIFIED: math
  10 IN: alien.c-types
  11
  12 SYMBOLS:
  13     char uchar
  14     short ushort
  15     int uint
  16     long ulong
  17     longlong ulonglong
  18     float double
  19     void* bool
  20     void ;
  21
  22 DEFER: <int>
  23 DEFER: *char
  24
  25 TUPLE: abstract-c-type
  26 { class class initial: object }
  27 { boxed-class class initial: object }
  28 { boxer-quot callable }
  29 { unboxer-quot callable }
  30 { getter callable }
  31 { setter callable }
  32 size
  33 align ;
  34
  35 TUPLE: c-type < abstract-c-type
  36 boxer
  37 unboxer
  38 { rep initial: int-rep }
  39 stack-align? ;
  40
  41 : <c-type> ( -- type )
  42     \ c-type new ;
  43
  44 SYMBOL: c-types
  45
  46 global [
  47     c-types [ H{ } assoc-like ] change
  48 ] bind
  49
  50 ERROR: no-c-type name ;
  51
  52 PREDICATE: c-type-word < word
  53     "c-type" word-prop ;
  54
  55 UNION: c-type-name string c-type-word ;
  56
  57 ! C type protocol
  58 GENERIC: c-type ( name -- type ) foldable
  59
  60 GENERIC: resolve-pointer-type ( name -- c-type )
  61
  62 M: word resolve-pointer-type
  63     dup "pointer-c-type" word-prop
  64     [ ] [ drop void* ] ?if ;
  65 M: string resolve-pointer-type
  66     dup "*" append dup c-types get at
  67     [ nip ] [
  68         drop
  69         c-types get at dup c-type-name?
  70         [ resolve-pointer-type ] [ drop void* ] if
  71     ] if ;
  72
  73 : resolve-typedef ( name -- type )
  74     dup c-type-name? [ c-type ] when ;
  75
  76 : parse-array-type ( name -- dims type )
  77     "[" split unclip
  78     [ [ "]" ?tail drop string>number ] map ] dip ;
  79
  80 M: string c-type ( name -- type )
  81     CHAR: ] over member? [
  82         parse-array-type prefix
  83     ] [
  84         dup c-types get at [ ] [
  85             "*" ?tail [ resolve-pointer-type ] [ no-c-type ] if
  86         ] ?if resolve-typedef
  87     ] if ;
  88
  89 M: word c-type
  90     "c-type" word-prop resolve-typedef ;
  91
  92 : void? ( c-type -- ? )
  93     { void "void" } member? ;
  94
  95 GENERIC: c-struct? ( type -- ? )
  96
  97 M: object c-struct?
  98     drop f ;
  99 M: c-type-name c-struct?
 100     dup void? [ drop f ] [ c-type c-struct? ] if ;
 101
 102 ! These words being foldable means that words need to be
 103 ! recompiled if a C type is redefined. Even so, folding the
 104 ! size facilitates some optimizations.
 105 GENERIC: c-type-class ( name -- class )
 106
 107 M: abstract-c-type c-type-class class>> ;
 108
 109 M: c-type-name c-type-class c-type c-type-class ;
 110
 111 GENERIC: c-type-boxed-class ( name -- class )
 112
 113 M: abstract-c-type c-type-boxed-class boxed-class>> ;
 114
 115 M: c-type-name c-type-boxed-class c-type c-type-boxed-class ;
 116
 117 GENERIC: c-type-boxer ( name -- boxer )
 118
 119 M: c-type c-type-boxer boxer>> ;
 120
 121 M: c-type-name c-type-boxer c-type c-type-boxer ;
 122
 123 GENERIC: c-type-boxer-quot ( name -- quot )
 124
 125 M: abstract-c-type c-type-boxer-quot boxer-quot>> ;
 126
 127 M: c-type-name c-type-boxer-quot c-type c-type-boxer-quot ;
 128
 129 GENERIC: c-type-unboxer ( name -- boxer )
 130
 131 M: c-type c-type-unboxer unboxer>> ;
 132
 133 M: c-type-name c-type-unboxer c-type c-type-unboxer ;
 134
 135 GENERIC: c-type-unboxer-quot ( name -- quot )
 136
 137 M: abstract-c-type c-type-unboxer-quot unboxer-quot>> ;
 138
 139 M: c-type-name c-type-unboxer-quot c-type c-type-unboxer-quot ;
 140
 141 GENERIC: c-type-rep ( name -- rep )
 142
 143 M: c-type c-type-rep rep>> ;
 144
 145 M: c-type-name c-type-rep c-type c-type-rep ;
 146
 147 GENERIC: c-type-getter ( name -- quot )
 148
 149 M: c-type c-type-getter getter>> ;
 150
 151 M: c-type-name c-type-getter c-type c-type-getter ;
 152
 153 GENERIC: c-type-setter ( name -- quot )
 154
 155 M: c-type c-type-setter setter>> ;
 156
 157 M: c-type-name c-type-setter c-type c-type-setter ;
 158
 159 GENERIC: c-type-align ( name -- n )
 160
 161 M: abstract-c-type c-type-align align>> ;
 162
 163 M: c-type-name c-type-align c-type c-type-align ;
 164
 165 GENERIC: c-type-stack-align? ( name -- ? )
 166
 167 M: c-type c-type-stack-align? stack-align?>> ;
 168
 169 M: c-type-name c-type-stack-align? c-type c-type-stack-align? ;
 170
 171 : c-type-box ( n type -- )
 172     [ c-type-rep ] [ c-type-boxer [ "No boxer" throw ] unless* ] bi
 173     %box ;
 174
 175 : c-type-unbox ( n ctype -- )
 176     [ c-type-rep ] [ c-type-unboxer [ "No unboxer" throw ] unless* ] bi
 177     %unbox ;
 178
 179 GENERIC: box-parameter ( n ctype -- )
 180
 181 M: c-type box-parameter c-type-box ;
 182
 183 M: c-type-name box-parameter c-type box-parameter ;
 184
 185 GENERIC: box-return ( ctype -- )
 186
 187 M: c-type box-return f swap c-type-box ;
 188
 189 M: c-type-name box-return c-type box-return ;
 190
 191 GENERIC: unbox-parameter ( n ctype -- )
 192
 193 M: c-type unbox-parameter c-type-unbox ;
 194
 195 M: c-type-name unbox-parameter c-type unbox-parameter ;
 196
 197 GENERIC: unbox-return ( ctype -- )
 198
 199 M: c-type unbox-return f swap c-type-unbox ;
 200
 201 M: c-type-name unbox-return c-type unbox-return ;
 202
 203 : little-endian? ( -- ? ) 1 <int> *char 1 = ; foldable
 204
 205 GENERIC: heap-size ( type -- size ) foldable
 206
 207 M: c-type-name heap-size c-type heap-size ;
 208
 209 M: abstract-c-type heap-size size>> ;
 210
 211 GENERIC: stack-size ( type -- size ) foldable
 212
 213 M: c-type-name stack-size c-type stack-size ;
 214
 215 M: c-type stack-size size>> cell align ;
 216
 217 GENERIC: byte-length ( seq -- n ) flushable
 218
 219 M: byte-array byte-length length ; inline
 220
 221 M: f byte-length drop 0 ; inline
 222
 223 MIXIN: value-type
 224
 225 : c-getter ( name -- quot )
 226     c-type-getter [
 227         [ "Cannot read struct fields with this type" throw ]
 228     ] unless* ;
 229
 230 : c-type-getter-boxer ( name -- quot )
 231     [ c-getter ] [ c-type-boxer-quot ] bi append ;
 232
 233 : c-setter ( name -- quot )
 234     c-type-setter [
 235         [ "Cannot write struct fields with this type" throw ]
 236     ] unless* ;
 237
 238 : array-accessor ( type quot -- def )
 239     [
 240         \ swap , [ heap-size , [ * >fixnum ] % ] [ % ] bi*
 241     ] [ ] make ;
 242
 243 GENERIC: typedef ( old new -- )
 244
 245 PREDICATE: typedef-word < c-type-word
 246     "c-type" word-prop c-type-name? ;
 247
 248 M: string typedef ( old new -- ) c-types get set-at ;
 249 M: word typedef ( old new -- )
 250     {
 251         [ nip define-symbol ]
 252         [ name>> typedef ]
 253         [ swap "c-type" set-word-prop ]
 254         [
 255             swap dup c-type-name? [
 256                 resolve-pointer-type
 257                 "pointer-c-type" set-word-prop
 258             ] [ 2drop ] if
 259         ]
 260     } 2cleave ;
 261
 262 TUPLE: long-long-type < c-type ;
 263
 264 : <long-long-type> ( -- type )
 265     long-long-type new ;
 266
 267 M: long-long-type unbox-parameter ( n type -- )
 268     c-type-unboxer %unbox-long-long ;
 269
 270 M: long-long-type unbox-return ( type -- )
 271     f swap unbox-parameter ;
 272
 273 M: long-long-type box-parameter ( n type -- )
 274     c-type-boxer %box-long-long ;
 275
 276 M: long-long-type box-return ( type -- )
 277     f swap box-parameter ;
 278
 279 : define-deref ( name -- )
 280     [ CHAR: * prefix "alien.c-types" create ] [ c-getter 0 prefix ] bi
 281     (( c-ptr -- value )) define-inline ;
 282
 283 : define-out ( name -- )
 284     [ "alien.c-types" constructor-word ]
 285     [ dup c-setter '[ _ heap-size <byte-array> [ 0 @ ] keep ] ] bi
 286     (( value -- c-ptr )) define-inline ;
 287
 288 : define-primitive-type ( type name -- )
 289     [ typedef ]
 290     [ name>> define-deref ]
 291     [ name>> define-out ]
 292     tri ;
 293
 294 : if-void ( type true false -- )
 295     pick void? [ drop nip call ] [ nip call ] if ; inline
 296
 297 CONSTANT: primitive-types
 298     {
 299         char uchar
 300         short ushort
 301         int uint
 302         long ulong
 303         longlong ulonglong
 304         float double
 305         void* bool
 306     }
 307
 308 SYMBOLS:
 309     ptrdiff_t intptr_t size_t
 310     char* uchar* ;
 311
 312 [
 313     <c-type>
 314         c-ptr >>class
 315         c-ptr >>boxed-class
 316         [ alien-cell ] >>getter
 317         [ [ >c-ptr ] 2dip set-alien-cell ] >>setter
 318         bootstrap-cell >>size
 319         bootstrap-cell >>align
 320         [ >c-ptr ] >>unboxer-quot
 321         "box_alien" >>boxer
 322         "alien_offset" >>unboxer
 323     \ void* define-primitive-type
 324
 325     <long-long-type>
 326         integer >>class
 327         integer >>boxed-class
 328         [ alien-signed-8 ] >>getter
 329         [ set-alien-signed-8 ] >>setter
 330         8 >>size
 331         8 >>align
 332         "box_signed_8" >>boxer
 333         "to_signed_8" >>unboxer
 334     \ longlong define-primitive-type
 335
 336     <long-long-type>
 337         integer >>class
 338         integer >>boxed-class
 339         [ alien-unsigned-8 ] >>getter
 340         [ set-alien-unsigned-8 ] >>setter
 341         8 >>size
 342         8 >>align
 343         "box_unsigned_8" >>boxer
 344         "to_unsigned_8" >>unboxer
 345     \ ulonglong define-primitive-type
 346
 347     <c-type>
 348         integer >>class
 349         integer >>boxed-class
 350         [ alien-signed-cell ] >>getter
 351         [ set-alien-signed-cell ] >>setter
 352         bootstrap-cell >>size
 353         bootstrap-cell >>align
 354         "box_signed_cell" >>boxer
 355         "to_fixnum" >>unboxer
 356     \ long define-primitive-type
 357
 358     <c-type>
 359         integer >>class
 360         integer >>boxed-class
 361         [ alien-unsigned-cell ] >>getter
 362         [ set-alien-unsigned-cell ] >>setter
 363         bootstrap-cell >>size
 364         bootstrap-cell >>align
 365         "box_unsigned_cell" >>boxer
 366         "to_cell" >>unboxer
 367     \ ulong define-primitive-type
 368
 369     <c-type>
 370         integer >>class
 371         integer >>boxed-class
 372         [ alien-signed-4 ] >>getter
 373         [ set-alien-signed-4 ] >>setter
 374         4 >>size
 375         4 >>align
 376         "box_signed_4" >>boxer
 377         "to_fixnum" >>unboxer
 378     \ int define-primitive-type
 379
 380     <c-type>
 381         integer >>class
 382         integer >>boxed-class
 383         [ alien-unsigned-4 ] >>getter
 384         [ set-alien-unsigned-4 ] >>setter
 385         4 >>size
 386         4 >>align
 387         "box_unsigned_4" >>boxer
 388         "to_cell" >>unboxer
 389     \ uint define-primitive-type
 390
 391     <c-type>
 392         fixnum >>class
 393         fixnum >>boxed-class
 394         [ alien-signed-2 ] >>getter
 395         [ set-alien-signed-2 ] >>setter
 396         2 >>size
 397         2 >>align
 398         "box_signed_2" >>boxer
 399         "to_fixnum" >>unboxer
 400     \ short define-primitive-type
 401
 402     <c-type>
 403         fixnum >>class
 404         fixnum >>boxed-class
 405         [ alien-unsigned-2 ] >>getter
 406         [ set-alien-unsigned-2 ] >>setter
 407         2 >>size
 408         2 >>align
 409         "box_unsigned_2" >>boxer
 410         "to_cell" >>unboxer
 411     \ ushort define-primitive-type
 412
 413     <c-type>
 414         fixnum >>class
 415         fixnum >>boxed-class
 416         [ alien-signed-1 ] >>getter
 417         [ set-alien-signed-1 ] >>setter
 418         1 >>size
 419         1 >>align
 420         "box_signed_1" >>boxer
 421         "to_fixnum" >>unboxer
 422     \ char define-primitive-type
 423
 424     <c-type>
 425         fixnum >>class
 426         fixnum >>boxed-class
 427         [ alien-unsigned-1 ] >>getter
 428         [ set-alien-unsigned-1 ] >>setter
 429         1 >>size
 430         1 >>align
 431         "box_unsigned_1" >>boxer
 432         "to_cell" >>unboxer
 433     \ uchar define-primitive-type
 434
 435     <c-type>
 436         [ alien-unsigned-1 0 = not ] >>getter
 437         [ [ 1 0 ? ] 2dip set-alien-unsigned-1 ] >>setter
 438         1 >>size
 439         1 >>align
 440         "box_boolean" >>boxer
 441         "to_boolean" >>unboxer
 442     \ bool define-primitive-type
 443
 444     <c-type>
 445         math:float >>class
 446         math:float >>boxed-class
 447         [ alien-float ] >>getter
 448         [ [ >float ] 2dip set-alien-float ] >>setter
 449         4 >>size
 450         4 >>align
 451         "box_float" >>boxer
 452         "to_float" >>unboxer
 453         float-rep >>rep
 454         [ >float ] >>unboxer-quot
 455     \ float define-primitive-type
 456
 457     <c-type>
 458         math:float >>class
 459         math:float >>boxed-class
 460         [ alien-double ] >>getter
 461         [ [ >float ] 2dip set-alien-double ] >>setter
 462         8 >>size
 463         8 >>align
 464         "box_double" >>boxer
 465         "to_double" >>unboxer
 466         double-rep >>rep
 467         [ >float ] >>unboxer-quot
 468     \ double define-primitive-type
 469
 470     \ long \ ptrdiff_t typedef
 471     \ long \ intptr_t typedef
 472     \ ulong \ size_t typedef
 473 ] with-compilation-unit
 474