basis/alien/c-types/c-types.factor

   1 ! Copyright (C) 2004, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: byte-arrays arrays assocs kernel kernel.private libc math
   4 namespaces make parser sequences strings words splitting math.parser
   5 cpu.architecture alien alien.accessors alien.strings quotations
   6 layouts system compiler.units io io.files io.encodings.binary
   7 io.streams.memory accessors combinators effects continuations fry
   8 classes vocabs vocabs.loader ;
   9 IN: alien.c-types
  10
  11 DEFER: <int>
  12 DEFER: *char
  13
  14 : little-endian? ( -- ? ) 1 <int> *char 1 = ; foldable
  15
  16 TUPLE: abstract-c-type
  17 { class class initial: object }
  18 { boxed-class class initial: object }
  19 { boxer-quot callable }
  20 { unboxer-quot callable }
  21 { getter callable }
  22 { setter callable }
  23 size
  24 align
  25 array-class
  26 array-constructor
  27 direct-array-class
  28 direct-array-constructor
  29 sequence-mixin-class ;
  30
  31 TUPLE: c-type < abstract-c-type
  32 boxer
  33 unboxer
  34 { rep initial: int-rep }
  35 stack-align? ;
  36
  37 : <c-type> ( -- type )
  38     \ c-type new ;
  39
  40 SYMBOL: c-types
  41
  42 global [
  43     c-types [ H{ } assoc-like ] change
  44 ] bind
  45
  46 ERROR: no-c-type name ;
  47
  48 : (c-type) ( name -- type/f )
  49     c-types get-global at dup [
  50         dup string? [ (c-type) ] when
  51     ] when ;
  52
  53 ! C type protocol
  54 GENERIC: c-type ( name -- type ) foldable
  55
  56 : resolve-pointer-type ( name -- name )
  57     c-types get at dup string?
  58     [ "*" append ] [ drop "void*" ] if
  59     c-type ;
  60
  61 : resolve-typedef ( name -- type )
  62     dup string? [ c-type ] when ;
  63
  64 : parse-array-type ( name -- array )
  65     "[" split unclip
  66     [ [ "]" ?tail drop string>number ] map ] dip prefix ;
  67
  68 M: string c-type ( name -- type )
  69     CHAR: ] over member? [
  70         parse-array-type
  71     ] [
  72         dup c-types get at [
  73             resolve-typedef
  74         ] [
  75             "*" ?tail [ resolve-pointer-type ] [ no-c-type ] if
  76         ] ?if
  77     ] if ;
  78
  79 : ?require-word ( word/pair -- )
  80     dup word? [ drop ] [ first require ] ?if ;
  81
  82 GENERIC: require-c-type-arrays ( c-type -- )
  83
  84 M: object require-c-type-arrays
  85     drop ;
  86
  87 M: c-type require-c-type-arrays
  88     [ array-class>> ?require-word ]
  89     [ sequence-mixin-class>> ?require-word ]
  90     [ direct-array-class>> ?require-word ] tri ;
  91
  92 M: string require-c-type-arrays
  93     c-type require-c-type-arrays ;
  94
  95 M: array require-c-type-arrays
  96     first c-type require-c-type-arrays ;
  97
  98 ERROR: specialized-array-vocab-not-loaded vocab word ;
  99
 100 : c-type-array-constructor ( c-type -- word )
 101     array-constructor>> dup array?
 102     [ first2 specialized-array-vocab-not-loaded ] when ; foldable
 103
 104 : c-type-direct-array-constructor ( c-type -- word )
 105     direct-array-constructor>> dup array?
 106     [ first2 specialized-array-vocab-not-loaded ] when ; foldable
 107
 108 GENERIC: <c-type-array> ( len c-type -- array )
 109 M: object <c-type-array>
 110     c-type-array-constructor execute( len -- array ) ; inline
 111 M: string <c-type-array>
 112     c-type <c-type-array> ; inline
 113 M: array <c-type-array>
 114     first c-type <c-type-array> ; inline
 115
 116 GENERIC: <c-type-direct-array> ( alien len c-type -- array )
 117 M: object <c-type-direct-array>
 118     c-type-direct-array-constructor execute( alien len -- array ) ; inline
 119 M: string <c-type-direct-array>
 120     c-type <c-type-direct-array> ; inline
 121 M: array <c-type-direct-array>
 122     first c-type <c-type-direct-array> ; inline
 123
 124 GENERIC: c-type-class ( name -- class )
 125
 126 M: abstract-c-type c-type-class class>> ;
 127
 128 M: string c-type-class c-type c-type-class ;
 129
 130 GENERIC: c-type-boxed-class ( name -- class )
 131
 132 M: abstract-c-type c-type-boxed-class boxed-class>> ;
 133
 134 M: string c-type-boxed-class c-type c-type-boxed-class ;
 135
 136 GENERIC: c-type-boxer ( name -- boxer )
 137
 138 M: c-type c-type-boxer boxer>> ;
 139
 140 M: string c-type-boxer c-type c-type-boxer ;
 141
 142 GENERIC: c-type-boxer-quot ( name -- quot )
 143
 144 M: abstract-c-type c-type-boxer-quot boxer-quot>> ;
 145
 146 M: string c-type-boxer-quot c-type c-type-boxer-quot ;
 147
 148 GENERIC: c-type-unboxer ( name -- boxer )
 149
 150 M: c-type c-type-unboxer unboxer>> ;
 151
 152 M: string c-type-unboxer c-type c-type-unboxer ;
 153
 154 GENERIC: c-type-unboxer-quot ( name -- quot )
 155
 156 M: abstract-c-type c-type-unboxer-quot unboxer-quot>> ;
 157
 158 M: string c-type-unboxer-quot c-type c-type-unboxer-quot ;
 159
 160 GENERIC: c-type-rep ( name -- rep )
 161
 162 M: c-type c-type-rep rep>> ;
 163
 164 M: string c-type-rep c-type c-type-rep ;
 165
 166 GENERIC: c-type-getter ( name -- quot )
 167
 168 M: c-type c-type-getter getter>> ;
 169
 170 M: string c-type-getter c-type c-type-getter ;
 171
 172 GENERIC: c-type-setter ( name -- quot )
 173
 174 M: c-type c-type-setter setter>> ;
 175
 176 M: string c-type-setter c-type c-type-setter ;
 177
 178 GENERIC: c-type-align ( name -- n )
 179
 180 M: abstract-c-type c-type-align align>> ;
 181
 182 M: string c-type-align c-type c-type-align ;
 183
 184 GENERIC: c-type-stack-align? ( name -- ? )
 185
 186 M: c-type c-type-stack-align? stack-align?>> ;
 187
 188 M: string c-type-stack-align? c-type c-type-stack-align? ;
 189
 190 : c-type-box ( n type -- )
 191     [ c-type-rep ] [ c-type-boxer [ "No boxer" throw ] unless* ] bi
 192     %box ;
 193
 194 : c-type-unbox ( n ctype -- )
 195     [ c-type-rep ] [ c-type-unboxer [ "No unboxer" throw ] unless* ] bi
 196     %unbox ;
 197
 198 GENERIC: box-parameter ( n ctype -- )
 199
 200 M: c-type box-parameter c-type-box ;
 201
 202 M: string box-parameter c-type box-parameter ;
 203
 204 GENERIC: box-return ( ctype -- )
 205
 206 M: c-type box-return f swap c-type-box ;
 207
 208 M: string box-return c-type box-return ;
 209
 210 GENERIC: unbox-parameter ( n ctype -- )
 211
 212 M: c-type unbox-parameter c-type-unbox ;
 213
 214 M: string unbox-parameter c-type unbox-parameter ;
 215
 216 GENERIC: unbox-return ( ctype -- )
 217
 218 M: c-type unbox-return f swap c-type-unbox ;
 219
 220 M: string unbox-return c-type unbox-return ;
 221
 222 ! These words being foldable means that words need to be
 223 ! recompiled if a C type is redefined. Even so, folding the
 224 ! size facilitates some optimizations.
 225 GENERIC: heap-size ( type -- size ) foldable
 226
 227 M: string heap-size c-type heap-size ;
 228
 229 M: abstract-c-type heap-size size>> ;
 230
 231 GENERIC: stack-size ( type -- size ) foldable
 232
 233 M: string stack-size c-type stack-size ;
 234
 235 M: c-type stack-size size>> cell align ;
 236
 237 GENERIC: byte-length ( seq -- n ) flushable
 238
 239 M: byte-array byte-length length ; inline
 240
 241 M: f byte-length drop 0 ; inline
 242
 243 : c-getter ( name -- quot )
 244     c-type-getter [
 245         [ "Cannot read struct fields with this type" throw ]
 246     ] unless* ;
 247
 248 : c-type-getter-boxer ( name -- quot )
 249     [ c-getter ] [ c-type-boxer-quot ] bi append ;
 250
 251 : c-setter ( name -- quot )
 252     c-type-setter [
 253         [ "Cannot write struct fields with this type" throw ]
 254     ] unless* ;
 255
 256 : <c-array> ( n type -- array )
 257     heap-size * <byte-array> ; inline deprecated
 258
 259 : <c-object> ( type -- array )
 260     heap-size <byte-array> ; inline
 261
 262 : (c-object) ( type -- array )
 263     heap-size (byte-array) ; inline
 264
 265 : malloc-array ( n type -- alien )
 266     [ heap-size calloc ] [ <c-type-direct-array> ] 2bi ; inline
 267
 268 : malloc-object ( type -- alien )
 269    heap-size malloc ; inline
 270
 271 : malloc-byte-array ( byte-array -- alien )
 272     dup byte-length [ nip malloc dup ] 2keep memcpy ;
 273
 274 : memory>byte-array ( alien len -- byte-array )
 275     [ nip (byte-array) dup ] 2keep memcpy ;
 276
 277 : malloc-string ( string encoding -- alien )
 278     string>alien malloc-byte-array ;
 279
 280 M: memory-stream stream-read
 281     [
 282         [ index>> ] [ alien>> ] bi <displaced-alien>
 283         swap memory>byte-array
 284     ] [ [ + ] change-index drop ] 2bi ;
 285
 286 : byte-array>memory ( byte-array base -- )
 287     swap dup byte-length memcpy ; inline
 288
 289 : array-accessor ( type quot -- def )
 290     [
 291         \ swap , [ heap-size , [ * >fixnum ] % ] [ % ] bi*
 292     ] [ ] make ;
 293
 294 : typedef ( old new -- ) c-types get set-at ;
 295
 296 TUPLE: long-long-type < c-type ;
 297
 298 : <long-long-type> ( -- type )
 299     long-long-type new ;
 300
 301 M: long-long-type unbox-parameter ( n type -- )
 302     c-type-unboxer %unbox-long-long ;
 303
 304 M: long-long-type unbox-return ( type -- )
 305     f swap unbox-parameter ;
 306
 307 M: long-long-type box-parameter ( n type -- )
 308     c-type-boxer %box-long-long ;
 309
 310 M: long-long-type box-return ( type -- )
 311     f swap box-parameter ;
 312
 313 : define-deref ( name -- )
 314     [ CHAR: * prefix "alien.c-types" create ] [ c-getter 0 prefix ] bi
 315     (( c-ptr -- value )) define-inline ;
 316
 317 : define-out ( name -- )
 318     [ "alien.c-types" constructor-word ]
 319     [ dup c-setter '[ _ <c-object> [ 0 @ ] keep ] ] bi
 320     (( value -- c-ptr )) define-inline ;
 321
 322 : >c-bool ( ? -- int ) 1 0 ? ; inline
 323
 324 : c-bool> ( int -- ? ) 0 = not ; inline
 325
 326 : define-primitive-type ( type name -- )
 327     [ typedef ]
 328     [ define-deref ]
 329     [ define-out ]
 330     tri ;
 331
 332 : malloc-file-contents ( path -- alien len )
 333     binary file-contents [ malloc-byte-array ] [ length ] bi ;
 334
 335 : if-void ( type true false -- )
 336     pick "void" = [ drop nip call ] [ nip call ] if ; inline
 337
 338 : ?lookup ( vocab word -- word/pair )
 339     over vocab [ swap lookup ] [ 2array ] if ;
 340
 341 : set-array-class* ( c-type vocab-stem type-stem -- c-type )
 342     {
 343         [
 344             [ "specialized-arrays." prepend ]
 345             [ "-array" append ] bi* ?lookup >>array-class
 346         ]
 347         [
 348             [ "specialized-arrays." prepend ]
 349             [ "<" "-array>" surround ] bi* ?lookup >>array-constructor
 350         ]
 351         [
 352             [ "specialized-arrays." prepend ]
 353             [ "-sequence" append ] bi* ?lookup >>sequence-mixin-class
 354         ]
 355         [
 356             [ "specialized-arrays.direct." prepend ]
 357             [ "direct-" "-array" surround ] bi* ?lookup >>direct-array-class
 358         ]
 359         [
 360             [ "specialized-arrays.direct." prepend ]
 361             [ "<direct-" "-array>" surround ] bi* ?lookup >>direct-array-constructor
 362         ]
 363     } 2cleave ;
 364
 365 : set-array-class ( c-type stem -- c-type )
 366     dup set-array-class* ;
 367
 368 CONSTANT: primitive-types
 369     {
 370         "char" "uchar"
 371         "short" "ushort"
 372         "int" "uint"
 373         "long" "ulong"
 374         "longlong" "ulonglong"
 375         "float" "double"
 376         "void*" "bool"
 377     }
 378
 379 [
 380     <c-type>
 381         c-ptr >>class
 382         c-ptr >>boxed-class
 383         [ alien-cell ] >>getter
 384         [ [ >c-ptr ] 2dip set-alien-cell ] >>setter
 385         bootstrap-cell >>size
 386         bootstrap-cell >>align
 387         [ >c-ptr ] >>unboxer-quot
 388         "box_alien" >>boxer
 389         "alien_offset" >>unboxer
 390         "alien" "void*" set-array-class*
 391     "void*" define-primitive-type
 392
 393     <long-long-type>
 394         integer >>class
 395         integer >>boxed-class
 396         [ alien-signed-8 ] >>getter
 397         [ set-alien-signed-8 ] >>setter
 398         8 >>size
 399         8 >>align
 400         "box_signed_8" >>boxer
 401         "to_signed_8" >>unboxer
 402         "longlong" set-array-class
 403     "longlong" define-primitive-type
 404
 405     <long-long-type>
 406         integer >>class
 407         integer >>boxed-class
 408         [ alien-unsigned-8 ] >>getter
 409         [ set-alien-unsigned-8 ] >>setter
 410         8 >>size
 411         8 >>align
 412         "box_unsigned_8" >>boxer
 413         "to_unsigned_8" >>unboxer
 414         "ulonglong" set-array-class
 415     "ulonglong" define-primitive-type
 416
 417     <c-type>
 418         integer >>class
 419         integer >>boxed-class
 420         [ alien-signed-cell ] >>getter
 421         [ set-alien-signed-cell ] >>setter
 422         bootstrap-cell >>size
 423         bootstrap-cell >>align
 424         "box_signed_cell" >>boxer
 425         "to_fixnum" >>unboxer
 426         "long" set-array-class
 427     "long" define-primitive-type
 428
 429     <c-type>
 430         integer >>class
 431         integer >>boxed-class
 432         [ alien-unsigned-cell ] >>getter
 433         [ set-alien-unsigned-cell ] >>setter
 434         bootstrap-cell >>size
 435         bootstrap-cell >>align
 436         "box_unsigned_cell" >>boxer
 437         "to_cell" >>unboxer
 438         "ulong" set-array-class
 439     "ulong" define-primitive-type
 440
 441     <c-type>
 442         integer >>class
 443         integer >>boxed-class
 444         [ alien-signed-4 ] >>getter
 445         [ set-alien-signed-4 ] >>setter
 446         4 >>size
 447         4 >>align
 448         "box_signed_4" >>boxer
 449         "to_fixnum" >>unboxer
 450         "int" set-array-class
 451     "int" define-primitive-type
 452
 453     <c-type>
 454         integer >>class
 455         integer >>boxed-class
 456         [ alien-unsigned-4 ] >>getter
 457         [ set-alien-unsigned-4 ] >>setter
 458         4 >>size
 459         4 >>align
 460         "box_unsigned_4" >>boxer
 461         "to_cell" >>unboxer
 462         "uint" set-array-class
 463     "uint" define-primitive-type
 464
 465     <c-type>
 466         fixnum >>class
 467         fixnum >>boxed-class
 468         [ alien-signed-2 ] >>getter
 469         [ set-alien-signed-2 ] >>setter
 470         2 >>size
 471         2 >>align
 472         "box_signed_2" >>boxer
 473         "to_fixnum" >>unboxer
 474         "short" set-array-class
 475     "short" define-primitive-type
 476
 477     <c-type>
 478         fixnum >>class
 479         fixnum >>boxed-class
 480         [ alien-unsigned-2 ] >>getter
 481         [ set-alien-unsigned-2 ] >>setter
 482         2 >>size
 483         2 >>align
 484         "box_unsigned_2" >>boxer
 485         "to_cell" >>unboxer
 486         "ushort" set-array-class
 487     "ushort" define-primitive-type
 488
 489     <c-type>
 490         fixnum >>class
 491         fixnum >>boxed-class
 492         [ alien-signed-1 ] >>getter
 493         [ set-alien-signed-1 ] >>setter
 494         1 >>size
 495         1 >>align
 496         "box_signed_1" >>boxer
 497         "to_fixnum" >>unboxer
 498         "char" set-array-class
 499     "char" define-primitive-type
 500
 501     <c-type>
 502         fixnum >>class
 503         fixnum >>boxed-class
 504         [ alien-unsigned-1 ] >>getter
 505         [ set-alien-unsigned-1 ] >>setter
 506         1 >>size
 507         1 >>align
 508         "box_unsigned_1" >>boxer
 509         "to_cell" >>unboxer
 510         "uchar" set-array-class
 511     "uchar" define-primitive-type
 512
 513     <c-type>
 514         [ alien-unsigned-1 c-bool> ] >>getter
 515         [ [ >c-bool ] 2dip set-alien-unsigned-1 ] >>setter
 516         1 >>size
 517         1 >>align
 518         "box_boolean" >>boxer
 519         "to_boolean" >>unboxer
 520         "bool" set-array-class
 521     "bool" define-primitive-type
 522
 523     <c-type>
 524         float >>class
 525         float >>boxed-class
 526         [ alien-float ] >>getter
 527         [ [ >float ] 2dip set-alien-float ] >>setter
 528         4 >>size
 529         4 >>align
 530         "box_float" >>boxer
 531         "to_float" >>unboxer
 532         single-float-rep >>rep
 533         [ >float ] >>unboxer-quot
 534         "float" set-array-class
 535     "float" define-primitive-type
 536
 537     <c-type>
 538         float >>class
 539         float >>boxed-class
 540         [ alien-double ] >>getter
 541         [ [ >float ] 2dip set-alien-double ] >>setter
 542         8 >>size
 543         8 >>align
 544         "box_double" >>boxer
 545         "to_double" >>unboxer
 546         double-float-rep >>rep
 547         [ >float ] >>unboxer-quot
 548         "double" set-array-class
 549     "double" define-primitive-type
 550
 551     "long" "ptrdiff_t" typedef
 552     "long" "intptr_t" typedef
 553     "ulong" "size_t" typedef
 554 ] with-compilation-unit
 555