basis/alien/c-types/c-types.factor

   1 ! Copyright (C) 2004, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: byte-arrays arrays assocs kernel kernel.private libc math
   4 namespaces make parser sequences strings words splitting math.parser
   5 cpu.architecture alien alien.accessors alien.strings quotations
   6 layouts system compiler.units io io.files io.encodings.binary
   7 io.streams.memory accessors combinators effects continuations fry
   8 classes vocabs vocabs.loader ;
   9 IN: alien.c-types
  10
  11 DEFER: <int>
  12 DEFER: *char
  13
  14 : little-endian? ( -- ? ) 1 <int> *char 1 = ; foldable
  15
  16 TUPLE: abstract-c-type
  17 { class class initial: object }
  18 { boxed-class class initial: object }
  19 { boxer-quot callable }
  20 { unboxer-quot callable }
  21 { getter callable }
  22 { setter callable }
  23 size
  24 align
  25 array-class
  26 array-constructor
  27 direct-array-class
  28 direct-array-constructor
  29 sequence-mixin-class ;
  30
  31 TUPLE: c-type < abstract-c-type
  32 boxer
  33 unboxer
  34 { rep initial: int-rep }
  35 stack-align? ;
  36
  37 : <c-type> ( -- type )
  38     \ c-type new ;
  39
  40 SYMBOL: c-types
  41
  42 global [
  43     c-types [ H{ } assoc-like ] change
  44 ] bind
  45
  46 ERROR: no-c-type name ;
  47
  48 : (c-type) ( name -- type/f )
  49     c-types get-global at dup [
  50         dup string? [ (c-type) ] when
  51     ] when ;
  52
  53 ! C type protocol
  54 GENERIC: c-type ( name -- type ) foldable
  55
  56 : resolve-pointer-type ( name -- name )
  57     c-types get at dup string?
  58     [ "*" append ] [ drop "void*" ] if
  59     c-type ;
  60
  61 : resolve-typedef ( name -- type )
  62     dup string? [ c-type ] when ;
  63
  64 : parse-array-type ( name -- array )
  65     "[" split unclip
  66     [ [ "]" ?tail drop string>number ] map ] dip prefix ;
  67
  68 M: string c-type ( name -- type )
  69     CHAR: ] over member? [
  70         parse-array-type
  71     ] [
  72         dup c-types get at [
  73             resolve-typedef
  74         ] [
  75             "*" ?tail [ resolve-pointer-type ] [ no-c-type ] if
  76         ] ?if
  77     ] if ;
  78
  79 : ?require-word ( word/pair -- )
  80     dup word? [ drop ] [ first require ] ?if ;
  81
  82 GENERIC: require-c-type-arrays ( c-type -- )
  83
  84 M: object require-c-type-arrays
  85     drop ;
  86
  87 M: c-type require-c-type-arrays
  88     [ array-class>> ?require-word ]
  89     [ sequence-mixin-class>> ?require-word ]
  90     [ direct-array-class>> ?require-word ] tri ;
  91
  92 M: string require-c-type-arrays
  93     c-type require-c-type-arrays ;
  94
  95 M: array require-c-type-arrays
  96     first c-type require-c-type-arrays ;
  97
  98 ERROR: specialized-array-vocab-not-loaded vocab word ;
  99
 100 : c-type-array-constructor ( c-type -- word )
 101     array-constructor>> dup array?
 102     [ first2 specialized-array-vocab-not-loaded ] when ; foldable
 103
 104 : c-type-direct-array-constructor ( c-type -- word )
 105     direct-array-constructor>> dup array?
 106     [ first2 specialized-array-vocab-not-loaded ] when ; foldable
 107
 108 GENERIC: <c-type-array> ( len c-type -- array )
 109 M: object <c-type-array>
 110     c-type-array-constructor execute( len -- array ) ; inline
 111 M: string <c-type-array>
 112     c-type <c-type-array> ; inline
 113 M: array <c-type-array>
 114     first c-type <c-type-array> ; inline
 115
 116 GENERIC: <c-type-direct-array> ( alien len c-type -- array )
 117 M: object <c-type-direct-array>
 118     c-type-direct-array-constructor execute( alien len -- array ) ; inline
 119 M: string <c-type-direct-array>
 120     c-type <c-type-direct-array> ; inline
 121 M: array <c-type-direct-array>
 122     first c-type <c-type-direct-array> ; inline
 123
 124 GENERIC: c-type-class ( name -- class )
 125
 126 M: abstract-c-type c-type-class class>> ;
 127
 128 M: string c-type-class c-type c-type-class ;
 129
 130 GENERIC: c-type-boxed-class ( name -- class )
 131
 132 M: abstract-c-type c-type-boxed-class boxed-class>> ;
 133
 134 M: string c-type-boxed-class c-type c-type-boxed-class ;
 135
 136 GENERIC: c-type-boxer ( name -- boxer )
 137
 138 M: c-type c-type-boxer boxer>> ;
 139
 140 M: string c-type-boxer c-type c-type-boxer ;
 141
 142 GENERIC: c-type-boxer-quot ( name -- quot )
 143
 144 M: abstract-c-type c-type-boxer-quot boxer-quot>> ;
 145
 146 M: string c-type-boxer-quot c-type c-type-boxer-quot ;
 147
 148 GENERIC: c-type-unboxer ( name -- boxer )
 149
 150 M: c-type c-type-unboxer unboxer>> ;
 151
 152 M: string c-type-unboxer c-type c-type-unboxer ;
 153
 154 GENERIC: c-type-unboxer-quot ( name -- quot )
 155
 156 M: abstract-c-type c-type-unboxer-quot unboxer-quot>> ;
 157
 158 M: string c-type-unboxer-quot c-type c-type-unboxer-quot ;
 159
 160 GENERIC: c-type-rep ( name -- rep )
 161
 162 M: c-type c-type-rep rep>> ;
 163
 164 M: string c-type-rep c-type c-type-rep ;
 165
 166 GENERIC: c-type-getter ( name -- quot )
 167
 168 M: c-type c-type-getter getter>> ;
 169
 170 M: string c-type-getter c-type c-type-getter ;
 171
 172 GENERIC: c-type-setter ( name -- quot )
 173
 174 M: c-type c-type-setter setter>> ;
 175
 176 M: string c-type-setter c-type c-type-setter ;
 177
 178 GENERIC: c-type-align ( name -- n )
 179
 180 M: abstract-c-type c-type-align align>> ;
 181
 182 M: string c-type-align c-type c-type-align ;
 183
 184 GENERIC: c-type-stack-align? ( name -- ? )
 185
 186 M: c-type c-type-stack-align? stack-align?>> ;
 187
 188 M: string c-type-stack-align? c-type c-type-stack-align? ;
 189
 190 : c-type-box ( n type -- )
 191     [ c-type-rep ] [ c-type-boxer [ "No boxer" throw ] unless* ] bi
 192     %box ;
 193
 194 : c-type-unbox ( n ctype -- )
 195     [ c-type-rep ] [ c-type-unboxer [ "No unboxer" throw ] unless* ] bi
 196     %unbox ;
 197
 198 GENERIC: box-parameter ( n ctype -- )
 199
 200 M: c-type box-parameter c-type-box ;
 201
 202 M: string box-parameter c-type box-parameter ;
 203
 204 GENERIC: box-return ( ctype -- )
 205
 206 M: c-type box-return f swap c-type-box ;
 207
 208 M: string box-return c-type box-return ;
 209
 210 GENERIC: unbox-parameter ( n ctype -- )
 211
 212 M: c-type unbox-parameter c-type-unbox ;
 213
 214 M: string unbox-parameter c-type unbox-parameter ;
 215
 216 GENERIC: unbox-return ( ctype -- )
 217
 218 M: c-type unbox-return f swap c-type-unbox ;
 219
 220 M: string unbox-return c-type unbox-return ;
 221
 222 ! These words being foldable means that words need to be
 223 ! recompiled if a C type is redefined. Even so, folding the
 224 ! size facilitates some optimizations.
 225 GENERIC: heap-size ( type -- size ) foldable
 226
 227 M: string heap-size c-type heap-size ;
 228
 229 M: abstract-c-type heap-size size>> ;
 230
 231 GENERIC: stack-size ( type -- size ) foldable
 232
 233 M: string stack-size c-type stack-size ;
 234
 235 M: c-type stack-size size>> cell align ;
 236
 237 GENERIC: byte-length ( seq -- n ) flushable
 238
 239 M: byte-array byte-length length ; inline
 240
 241 M: f byte-length drop 0 ; inline
 242
 243 : c-getter ( name -- quot )
 244     c-type-getter [
 245         [ "Cannot read struct fields with this type" throw ]
 246     ] unless* ;
 247
 248 : c-type-getter-boxer ( name -- quot )
 249     [ c-getter ] [ c-type-boxer-quot ] bi append ;
 250
 251 : c-setter ( name -- quot )
 252     c-type-setter [
 253         [ "Cannot write struct fields with this type" throw ]
 254     ] unless* ;
 255
 256 : <c-array> ( n type -- array )
 257     heap-size * <byte-array> ; inline deprecated
 258
 259 : <c-object> ( type -- array )
 260     1 swap <c-array> ; inline
 261
 262 : malloc-array ( n type -- alien )
 263     [ heap-size calloc ] [ <c-type-direct-array> ] 2bi ; inline
 264
 265 : malloc-object ( type -- alien )
 266     1 swap malloc-array ; inline
 267
 268 : malloc-byte-array ( byte-array -- alien )
 269     dup byte-length [ nip malloc dup ] 2keep memcpy ;
 270
 271 : memory>byte-array ( alien len -- byte-array )
 272     [ nip (byte-array) dup ] 2keep memcpy ;
 273
 274 : malloc-string ( string encoding -- alien )
 275     string>alien malloc-byte-array ;
 276
 277 M: memory-stream stream-read
 278     [
 279         [ index>> ] [ alien>> ] bi <displaced-alien>
 280         swap memory>byte-array
 281     ] [ [ + ] change-index drop ] 2bi ;
 282
 283 : byte-array>memory ( byte-array base -- )
 284     swap dup byte-length memcpy ; inline
 285
 286 : array-accessor ( type quot -- def )
 287     [
 288         \ swap , [ heap-size , [ * >fixnum ] % ] [ % ] bi*
 289     ] [ ] make ;
 290
 291 : typedef ( old new -- ) c-types get set-at ;
 292
 293 TUPLE: long-long-type < c-type ;
 294
 295 : <long-long-type> ( -- type )
 296     long-long-type new ;
 297
 298 M: long-long-type unbox-parameter ( n type -- )
 299     c-type-unboxer %unbox-long-long ;
 300
 301 M: long-long-type unbox-return ( type -- )
 302     f swap unbox-parameter ;
 303
 304 M: long-long-type box-parameter ( n type -- )
 305     c-type-boxer %box-long-long ;
 306
 307 M: long-long-type box-return ( type -- )
 308     f swap box-parameter ;
 309
 310 : define-deref ( name -- )
 311     [ CHAR: * prefix "alien.c-types" create ] [ c-getter 0 prefix ] bi
 312     (( c-ptr -- value )) define-inline ;
 313
 314 : define-out ( name -- )
 315     [ "alien.c-types" constructor-word ]
 316     [ dup c-setter '[ _ <c-object> [ 0 @ ] keep ] ] bi
 317     (( value -- c-ptr )) define-inline ;
 318
 319 : >c-bool ( ? -- int ) 1 0 ? ; inline
 320
 321 : c-bool> ( int -- ? ) 0 = not ; inline
 322
 323 : define-primitive-type ( type name -- )
 324     [ typedef ]
 325     [ define-deref ]
 326     [ define-out ]
 327     tri ;
 328
 329 : malloc-file-contents ( path -- alien len )
 330     binary file-contents [ malloc-byte-array ] [ length ] bi ;
 331
 332 : if-void ( type true false -- )
 333     pick "void" = [ drop nip call ] [ nip call ] if ; inline
 334
 335 : ?lookup ( vocab word -- word/pair )
 336     over vocab [ swap lookup ] [ 2array ] if ;
 337
 338 : set-array-class* ( c-type vocab-stem type-stem -- c-type )
 339     {
 340         [
 341             [ "specialized-arrays." prepend ]
 342             [ "-array" append ] bi* ?lookup >>array-class
 343         ]
 344         [
 345             [ "specialized-arrays." prepend ]
 346             [ "<" "-array>" surround ] bi* ?lookup >>array-constructor
 347         ]
 348         [
 349             [ "specialized-arrays." prepend ]
 350             [ "-sequence" append ] bi* ?lookup >>sequence-mixin-class
 351         ]
 352         [
 353             [ "specialized-arrays.direct." prepend ]
 354             [ "direct-" "-array" surround ] bi* ?lookup >>direct-array-class
 355         ]
 356         [
 357             [ "specialized-arrays.direct." prepend ]
 358             [ "<direct-" "-array>" surround ] bi* ?lookup >>direct-array-constructor
 359         ]
 360     } 2cleave ;
 361
 362 : set-array-class ( c-type stem -- c-type )
 363     dup set-array-class* ;
 364
 365 CONSTANT: primitive-types
 366     {
 367         "char" "uchar"
 368         "short" "ushort"
 369         "int" "uint"
 370         "long" "ulong"
 371         "longlong" "ulonglong"
 372         "float" "double"
 373         "void*" "bool"
 374     }
 375
 376 [
 377     <c-type>
 378         c-ptr >>class
 379         c-ptr >>boxed-class
 380         [ alien-cell ] >>getter
 381         [ [ >c-ptr ] 2dip set-alien-cell ] >>setter
 382         bootstrap-cell >>size
 383         bootstrap-cell >>align
 384         [ >c-ptr ] >>unboxer-quot
 385         "box_alien" >>boxer
 386         "alien_offset" >>unboxer
 387         "alien" "void*" set-array-class*
 388     "void*" define-primitive-type
 389
 390     <long-long-type>
 391         integer >>class
 392         integer >>boxed-class
 393         [ alien-signed-8 ] >>getter
 394         [ set-alien-signed-8 ] >>setter
 395         8 >>size
 396         8 >>align
 397         "box_signed_8" >>boxer
 398         "to_signed_8" >>unboxer
 399         "longlong" set-array-class
 400     "longlong" define-primitive-type
 401
 402     <long-long-type>
 403         integer >>class
 404         integer >>boxed-class
 405         [ alien-unsigned-8 ] >>getter
 406         [ set-alien-unsigned-8 ] >>setter
 407         8 >>size
 408         8 >>align
 409         "box_unsigned_8" >>boxer
 410         "to_unsigned_8" >>unboxer
 411         "ulonglong" set-array-class
 412     "ulonglong" define-primitive-type
 413
 414     <c-type>
 415         integer >>class
 416         integer >>boxed-class
 417         [ alien-signed-cell ] >>getter
 418         [ set-alien-signed-cell ] >>setter
 419         bootstrap-cell >>size
 420         bootstrap-cell >>align
 421         "box_signed_cell" >>boxer
 422         "to_fixnum" >>unboxer
 423         "long" set-array-class
 424     "long" define-primitive-type
 425
 426     <c-type>
 427         integer >>class
 428         integer >>boxed-class
 429         [ alien-unsigned-cell ] >>getter
 430         [ set-alien-unsigned-cell ] >>setter
 431         bootstrap-cell >>size
 432         bootstrap-cell >>align
 433         "box_unsigned_cell" >>boxer
 434         "to_cell" >>unboxer
 435         "ulong" set-array-class
 436     "ulong" define-primitive-type
 437
 438     <c-type>
 439         integer >>class
 440         integer >>boxed-class
 441         [ alien-signed-4 ] >>getter
 442         [ set-alien-signed-4 ] >>setter
 443         4 >>size
 444         4 >>align
 445         "box_signed_4" >>boxer
 446         "to_fixnum" >>unboxer
 447         "int" set-array-class
 448     "int" define-primitive-type
 449
 450     <c-type>
 451         integer >>class
 452         integer >>boxed-class
 453         [ alien-unsigned-4 ] >>getter
 454         [ set-alien-unsigned-4 ] >>setter
 455         4 >>size
 456         4 >>align
 457         "box_unsigned_4" >>boxer
 458         "to_cell" >>unboxer
 459         "uint" set-array-class
 460     "uint" define-primitive-type
 461
 462     <c-type>
 463         fixnum >>class
 464         fixnum >>boxed-class
 465         [ alien-signed-2 ] >>getter
 466         [ set-alien-signed-2 ] >>setter
 467         2 >>size
 468         2 >>align
 469         "box_signed_2" >>boxer
 470         "to_fixnum" >>unboxer
 471         "short" set-array-class
 472     "short" define-primitive-type
 473
 474     <c-type>
 475         fixnum >>class
 476         fixnum >>boxed-class
 477         [ alien-unsigned-2 ] >>getter
 478         [ set-alien-unsigned-2 ] >>setter
 479         2 >>size
 480         2 >>align
 481         "box_unsigned_2" >>boxer
 482         "to_cell" >>unboxer
 483         "ushort" set-array-class
 484     "ushort" define-primitive-type
 485
 486     <c-type>
 487         fixnum >>class
 488         fixnum >>boxed-class
 489         [ alien-signed-1 ] >>getter
 490         [ set-alien-signed-1 ] >>setter
 491         1 >>size
 492         1 >>align
 493         "box_signed_1" >>boxer
 494         "to_fixnum" >>unboxer
 495         "char" set-array-class
 496     "char" define-primitive-type
 497
 498     <c-type>
 499         fixnum >>class
 500         fixnum >>boxed-class
 501         [ alien-unsigned-1 ] >>getter
 502         [ set-alien-unsigned-1 ] >>setter
 503         1 >>size
 504         1 >>align
 505         "box_unsigned_1" >>boxer
 506         "to_cell" >>unboxer
 507         "uchar" set-array-class
 508     "uchar" define-primitive-type
 509
 510     <c-type>
 511         [ alien-unsigned-1 c-bool> ] >>getter
 512         [ [ >c-bool ] 2dip set-alien-unsigned-1 ] >>setter
 513         1 >>size
 514         1 >>align
 515         "box_boolean" >>boxer
 516         "to_boolean" >>unboxer
 517         "bool" set-array-class
 518     "bool" define-primitive-type
 519
 520     <c-type>
 521         float >>class
 522         float >>boxed-class
 523         [ alien-float ] >>getter
 524         [ [ >float ] 2dip set-alien-float ] >>setter
 525         4 >>size
 526         4 >>align
 527         "box_float" >>boxer
 528         "to_float" >>unboxer
 529         single-float-rep >>rep
 530         [ >float ] >>unboxer-quot
 531         "float" set-array-class
 532     "float" define-primitive-type
 533
 534     <c-type>
 535         float >>class
 536         float >>boxed-class
 537         [ alien-double ] >>getter
 538         [ [ >float ] 2dip set-alien-double ] >>setter
 539         8 >>size
 540         8 >>align
 541         "box_double" >>boxer
 542         "to_double" >>unboxer
 543         double-float-rep >>rep
 544         [ >float ] >>unboxer-quot
 545         "double" set-array-class
 546     "double" define-primitive-type
 547
 548     "long" "ptrdiff_t" typedef
 549     "long" "intptr_t" typedef
 550     "ulong" "size_t" typedef
 551 ] with-compilation-unit
 552