basis/alien/c-types/c-types.factor

   1 ! Copyright (C) 2004, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: byte-arrays arrays assocs kernel kernel.private libc math
   4 namespaces make parser sequences strings words splitting math.parser
   5 cpu.architecture alien alien.accessors alien.strings quotations
   6 layouts system compiler.units io io.files io.encodings.binary
   7 io.streams.memory accessors combinators effects continuations fry
   8 classes ;
   9 IN: alien.c-types
  10
  11 DEFER: <int>
  12 DEFER: *char
  13
  14 : little-endian? ( -- ? ) 1 <int> *char 1 = ; foldable
  15
  16 TUPLE: c-type
  17 { class class initial: object }
  18 boxer
  19 { boxer-quot callable }
  20 unboxer
  21 { unboxer-quot callable }
  22 { getter callable }
  23 { setter callable }
  24 { rep initial: int-rep }
  25 size
  26 align
  27 stack-align? ;
  28
  29 : <c-type> ( -- type )
  30     \ c-type new ;
  31
  32 SYMBOL: c-types
  33
  34 global [
  35     c-types [ H{ } assoc-like ] change
  36 ] bind
  37
  38 ERROR: no-c-type name ;
  39
  40 : (c-type) ( name -- type/f )
  41     c-types get-global at dup [
  42         dup string? [ (c-type) ] when
  43     ] when ;
  44
  45 ! C type protocol
  46 GENERIC: c-type ( name -- type ) foldable
  47
  48 : resolve-pointer-type ( name -- name )
  49     c-types get at dup string?
  50     [ "*" append ] [ drop "void*" ] if
  51     c-type ;
  52
  53 : resolve-typedef ( name -- type )
  54     dup string? [ c-type ] when ;
  55
  56 : parse-array-type ( name -- array )
  57     "[" split unclip
  58     [ [ "]" ?tail drop string>number ] map ] dip prefix ;
  59
  60 M: string c-type ( name -- type )
  61     CHAR: ] over member? [
  62         parse-array-type
  63     ] [
  64         dup c-types get at [
  65             resolve-typedef
  66         ] [
  67             "*" ?tail [ resolve-pointer-type ] [ no-c-type ] if
  68         ] ?if
  69     ] if ;
  70
  71 GENERIC: c-type-class ( name -- class )
  72
  73 M: c-type c-type-class class>> ;
  74
  75 M: string c-type-class c-type c-type-class ;
  76
  77 GENERIC: c-type-boxer ( name -- boxer )
  78
  79 M: c-type c-type-boxer boxer>> ;
  80
  81 M: string c-type-boxer c-type c-type-boxer ;
  82
  83 GENERIC: c-type-boxer-quot ( name -- quot )
  84
  85 M: c-type c-type-boxer-quot boxer-quot>> ;
  86
  87 M: string c-type-boxer-quot c-type c-type-boxer-quot ;
  88
  89 GENERIC: c-type-unboxer ( name -- boxer )
  90
  91 M: c-type c-type-unboxer unboxer>> ;
  92
  93 M: string c-type-unboxer c-type c-type-unboxer ;
  94
  95 GENERIC: c-type-unboxer-quot ( name -- quot )
  96
  97 M: c-type c-type-unboxer-quot unboxer-quot>> ;
  98
  99 M: string c-type-unboxer-quot c-type c-type-unboxer-quot ;
 100
 101 GENERIC: c-type-rep ( name -- rep )
 102
 103 M: c-type c-type-rep rep>> ;
 104
 105 M: string c-type-rep c-type c-type-rep ;
 106
 107 GENERIC: c-type-getter ( name -- quot )
 108
 109 M: c-type c-type-getter getter>> ;
 110
 111 M: string c-type-getter c-type c-type-getter ;
 112
 113 GENERIC: c-type-setter ( name -- quot )
 114
 115 M: c-type c-type-setter setter>> ;
 116
 117 M: string c-type-setter c-type c-type-setter ;
 118
 119 GENERIC: c-type-align ( name -- n )
 120
 121 M: c-type c-type-align align>> ;
 122
 123 M: string c-type-align c-type c-type-align ;
 124
 125 GENERIC: c-type-stack-align? ( name -- ? )
 126
 127 M: c-type c-type-stack-align? stack-align?>> ;
 128
 129 M: string c-type-stack-align? c-type c-type-stack-align? ;
 130
 131 : c-type-box ( n type -- )
 132     [ c-type-rep ] [ c-type-boxer [ "No boxer" throw ] unless* ] bi
 133     %box ;
 134
 135 : c-type-unbox ( n ctype -- )
 136     [ c-type-rep ] [ c-type-unboxer [ "No unboxer" throw ] unless* ] bi
 137     %unbox ;
 138
 139 GENERIC: box-parameter ( n ctype -- )
 140
 141 M: c-type box-parameter c-type-box ;
 142
 143 M: string box-parameter c-type box-parameter ;
 144
 145 GENERIC: box-return ( ctype -- )
 146
 147 M: c-type box-return f swap c-type-box ;
 148
 149 M: string box-return c-type box-return ;
 150
 151 GENERIC: unbox-parameter ( n ctype -- )
 152
 153 M: c-type unbox-parameter c-type-unbox ;
 154
 155 M: string unbox-parameter c-type unbox-parameter ;
 156
 157 GENERIC: unbox-return ( ctype -- )
 158
 159 M: c-type unbox-return f swap c-type-unbox ;
 160
 161 M: string unbox-return c-type unbox-return ;
 162
 163 ! These words being foldable means that words need to be
 164 ! recompiled if a C type is redefined. Even so, folding the
 165 ! size facilitates some optimizations.
 166 GENERIC: heap-size ( type -- size ) foldable
 167
 168 M: string heap-size c-type heap-size ;
 169
 170 M: c-type heap-size size>> ;
 171
 172 GENERIC: stack-size ( type -- size ) foldable
 173
 174 M: string stack-size c-type stack-size ;
 175
 176 M: c-type stack-size size>> cell align ;
 177
 178 GENERIC: byte-length ( seq -- n ) flushable
 179
 180 M: byte-array byte-length length ;
 181
 182 M: f byte-length drop 0 ;
 183
 184 : c-getter ( name -- quot )
 185     c-type-getter [
 186         [ "Cannot read struct fields with this type" throw ]
 187     ] unless* ;
 188
 189 : c-type-getter-boxer ( name -- quot )
 190     [ c-getter ] [ c-type-boxer-quot ] bi append ;
 191
 192 : c-setter ( name -- quot )
 193     c-type-setter [
 194         [ "Cannot write struct fields with this type" throw ]
 195     ] unless* ;
 196
 197 : <c-array> ( n type -- array )
 198     heap-size * <byte-array> ; inline
 199
 200 : <c-object> ( type -- array )
 201     1 swap <c-array> ; inline
 202
 203 : malloc-array ( n type -- alien )
 204     heap-size calloc ; inline
 205
 206 : malloc-object ( type -- alien )
 207     1 swap malloc-array ; inline
 208
 209 : malloc-byte-array ( byte-array -- alien )
 210     dup byte-length [ nip malloc dup ] 2keep memcpy ;
 211
 212 : memory>byte-array ( alien len -- byte-array )
 213     [ nip (byte-array) dup ] 2keep memcpy ;
 214
 215 : malloc-string ( string encoding -- alien )
 216     string>alien malloc-byte-array ;
 217
 218 M: memory-stream stream-read
 219     [
 220         [ index>> ] [ alien>> ] bi <displaced-alien>
 221         swap memory>byte-array
 222     ] [ [ + ] change-index drop ] 2bi ;
 223
 224 : byte-array>memory ( byte-array base -- )
 225     swap dup byte-length memcpy ;
 226
 227 : array-accessor ( type quot -- def )
 228     [
 229         \ swap , [ heap-size , [ * >fixnum ] % ] [ % ] bi*
 230     ] [ ] make ;
 231
 232 : typedef ( old new -- ) c-types get set-at ;
 233
 234 TUPLE: long-long-type < c-type ;
 235
 236 : <long-long-type> ( -- type )
 237     long-long-type new ;
 238
 239 M: long-long-type unbox-parameter ( n type -- )
 240     c-type-unboxer %unbox-long-long ;
 241
 242 M: long-long-type unbox-return ( type -- )
 243     f swap unbox-parameter ;
 244
 245 M: long-long-type box-parameter ( n type -- )
 246     c-type-boxer %box-long-long ;
 247
 248 M: long-long-type box-return ( type -- )
 249     f swap box-parameter ;
 250
 251 : define-deref ( name -- )
 252     [ CHAR: * prefix "alien.c-types" create ] [ c-getter 0 prefix ] bi
 253     (( c-ptr -- value )) define-inline ;
 254
 255 : define-out ( name -- )
 256     [ "alien.c-types" constructor-word ]
 257     [ dup c-setter '[ _ <c-object> [ 0 @ ] keep ] ] bi
 258     (( value -- c-ptr )) define-inline ;
 259
 260 : >c-bool ( ? -- int ) 1 0 ? ; inline
 261
 262 : c-bool> ( int -- ? ) 0 = not ; inline
 263
 264 : define-primitive-type ( type name -- )
 265     [ typedef ]
 266     [ define-deref ]
 267     [ define-out ]
 268     tri ;
 269
 270 : expand-constants ( c-type -- c-type' )
 271     dup array? [
 272         unclip [
 273             [
 274                 dup word? [
 275                     def>> call( -- object )
 276                 ] when
 277             ] map
 278         ] dip prefix
 279     ] when ;
 280
 281 : malloc-file-contents ( path -- alien len )
 282     binary file-contents [ malloc-byte-array ] [ length ] bi ;
 283
 284 : if-void ( type true false -- )
 285     pick "void" = [ drop nip call ] [ nip call ] if ; inline
 286
 287 CONSTANT: primitive-types
 288     {
 289         "char" "uchar"
 290         "short" "ushort"
 291         "int" "uint"
 292         "long" "ulong"
 293         "longlong" "ulonglong"
 294         "float" "double"
 295         "void*" "bool"
 296     }
 297
 298 [
 299     <c-type>
 300         c-ptr >>class
 301         [ alien-cell ] >>getter
 302         [ [ >c-ptr ] 2dip set-alien-cell ] >>setter
 303         bootstrap-cell >>size
 304         bootstrap-cell >>align
 305         [ >c-ptr ] >>unboxer-quot
 306         "box_alien" >>boxer
 307         "alien_offset" >>unboxer
 308     "void*" define-primitive-type
 309
 310     <long-long-type>
 311         integer >>class
 312         [ alien-signed-8 ] >>getter
 313         [ set-alien-signed-8 ] >>setter
 314         8 >>size
 315         8 >>align
 316         "box_signed_8" >>boxer
 317         "to_signed_8" >>unboxer
 318     "longlong" define-primitive-type
 319
 320     <long-long-type>
 321         integer >>class
 322         [ alien-unsigned-8 ] >>getter
 323         [ set-alien-unsigned-8 ] >>setter
 324         8 >>size
 325         8 >>align
 326         "box_unsigned_8" >>boxer
 327         "to_unsigned_8" >>unboxer
 328     "ulonglong" define-primitive-type
 329
 330     <c-type>
 331         integer >>class
 332         [ alien-signed-cell ] >>getter
 333         [ set-alien-signed-cell ] >>setter
 334         bootstrap-cell >>size
 335         bootstrap-cell >>align
 336         "box_signed_cell" >>boxer
 337         "to_fixnum" >>unboxer
 338     "long" define-primitive-type
 339
 340     <c-type>
 341         integer >>class
 342         [ alien-unsigned-cell ] >>getter
 343         [ set-alien-unsigned-cell ] >>setter
 344         bootstrap-cell >>size
 345         bootstrap-cell >>align
 346         "box_unsigned_cell" >>boxer
 347         "to_cell" >>unboxer
 348     "ulong" define-primitive-type
 349
 350     <c-type>
 351         integer >>class
 352         [ alien-signed-4 ] >>getter
 353         [ set-alien-signed-4 ] >>setter
 354         4 >>size
 355         4 >>align
 356         "box_signed_4" >>boxer
 357         "to_fixnum" >>unboxer
 358     "int" define-primitive-type
 359
 360     <c-type>
 361         integer >>class
 362         [ alien-unsigned-4 ] >>getter
 363         [ set-alien-unsigned-4 ] >>setter
 364         4 >>size
 365         4 >>align
 366         "box_unsigned_4" >>boxer
 367         "to_cell" >>unboxer
 368     "uint" define-primitive-type
 369
 370     <c-type>
 371         fixnum >>class
 372         [ alien-signed-2 ] >>getter
 373         [ set-alien-signed-2 ] >>setter
 374         2 >>size
 375         2 >>align
 376         "box_signed_2" >>boxer
 377         "to_fixnum" >>unboxer
 378     "short" define-primitive-type
 379
 380     <c-type>
 381         fixnum >>class
 382         [ alien-unsigned-2 ] >>getter
 383         [ set-alien-unsigned-2 ] >>setter
 384         2 >>size
 385         2 >>align
 386         "box_unsigned_2" >>boxer
 387         "to_cell" >>unboxer
 388     "ushort" define-primitive-type
 389
 390     <c-type>
 391         fixnum >>class
 392         [ alien-signed-1 ] >>getter
 393         [ set-alien-signed-1 ] >>setter
 394         1 >>size
 395         1 >>align
 396         "box_signed_1" >>boxer
 397         "to_fixnum" >>unboxer
 398     "char" define-primitive-type
 399
 400     <c-type>
 401         fixnum >>class
 402         [ alien-unsigned-1 ] >>getter
 403         [ set-alien-unsigned-1 ] >>setter
 404         1 >>size
 405         1 >>align
 406         "box_unsigned_1" >>boxer
 407         "to_cell" >>unboxer
 408     "uchar" define-primitive-type
 409
 410     <c-type>
 411         [ alien-unsigned-1 c-bool> ] >>getter
 412         [ [ >c-bool ] 2dip set-alien-unsigned-1 ] >>setter
 413         1 >>size
 414         1 >>align
 415         "box_boolean" >>boxer
 416         "to_boolean" >>unboxer
 417     "bool" define-primitive-type
 418
 419     <c-type>
 420         float >>class
 421         [ alien-float ] >>getter
 422         [ [ >float ] 2dip set-alien-float ] >>setter
 423         4 >>size
 424         4 >>align
 425         "box_float" >>boxer
 426         "to_float" >>unboxer
 427         single-float-rep >>rep
 428         [ >float ] >>unboxer-quot
 429     "float" define-primitive-type
 430
 431     <c-type>
 432         float >>class
 433         [ alien-double ] >>getter
 434         [ [ >float ] 2dip set-alien-double ] >>setter
 435         8 >>size
 436         8 >>align
 437         "box_double" >>boxer
 438         "to_double" >>unboxer
 439         double-float-rep >>rep
 440         [ >float ] >>unboxer-quot
 441     "double" define-primitive-type
 442
 443     "long" "ptrdiff_t" typedef
 444     "long" "intptr_t" typedef
 445     "ulong" "size_t" typedef
 446 ] with-compilation-unit