basis/alien/c-types/c-types.factor

   1 ! Copyright (C) 2004, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: byte-arrays arrays assocs kernel kernel.private libc math
   4 namespaces make parser sequences strings words splitting math.parser
   5 cpu.architecture alien alien.accessors alien.strings quotations
   6 layouts system compiler.units io io.files io.encodings.binary
   7 io.streams.memory accessors combinators effects continuations fry
   8 classes vocabs vocabs.loader ;
   9 IN: alien.c-types
  10
  11 DEFER: <int>
  12 DEFER: *char
  13
  14 : little-endian? ( -- ? ) 1 <int> *char 1 = ; foldable
  15
  16 TUPLE: abstract-c-type
  17 { class class initial: object }
  18 { boxed-class class initial: object }
  19 { boxer-quot callable }
  20 { unboxer-quot callable }
  21 { getter callable }
  22 { setter callable }
  23 size
  24 align
  25 array-class
  26 array-constructor
  27 direct-array-class
  28 direct-array-constructor
  29 sequence-mixin-class ;
  30
  31 TUPLE: c-type < abstract-c-type
  32 boxer
  33 unboxer
  34 { rep initial: int-rep }
  35 stack-align? ;
  36
  37 : <c-type> ( -- type )
  38     \ c-type new ;
  39
  40 SYMBOL: c-types
  41
  42 global [
  43     c-types [ H{ } assoc-like ] change
  44 ] bind
  45
  46 ERROR: no-c-type name ;
  47
  48 : (c-type) ( name -- type/f )
  49     c-types get-global at dup [
  50         dup string? [ (c-type) ] when
  51     ] when ;
  52
  53 ! C type protocol
  54 GENERIC: c-type ( name -- type ) foldable
  55
  56 : resolve-pointer-type ( name -- name )
  57     c-types get at dup string?
  58     [ "*" append ] [ drop "void*" ] if
  59     c-type ;
  60
  61 : resolve-typedef ( name -- type )
  62     dup string? [ c-type ] when ;
  63
  64 : parse-array-type ( name -- array )
  65     "[" split unclip
  66     [ [ "]" ?tail drop string>number ] map ] dip prefix ;
  67
  68 M: string c-type ( name -- type )
  69     CHAR: ] over member? [
  70         parse-array-type
  71     ] [
  72         dup c-types get at [
  73             resolve-typedef
  74         ] [
  75             "*" ?tail [ resolve-pointer-type ] [ no-c-type ] if
  76         ] ?if
  77     ] if ;
  78
  79 : ?require-word ( word/pair -- )
  80     dup word? [ drop ] [ first require ] ?if ;
  81
  82 GENERIC: require-c-type-arrays ( c-type -- )
  83
  84 M: object require-c-type-arrays
  85     drop ;
  86
  87 M: c-type require-c-type-arrays
  88     [ array-class>> ?require-word ]
  89     [ sequence-mixin-class>> ?require-word ]
  90     [ direct-array-class>> ?require-word ] tri ;
  91
  92 M: string require-c-type-arrays
  93     c-type require-c-type-arrays ;
  94
  95 M: array require-c-type-arrays
  96     first c-type require-c-type-arrays ;
  97
  98 ERROR: specialized-array-vocab-not-loaded vocab word ;
  99
 100 : c-type-array-constructor ( c-type -- word )
 101     array-constructor>> dup array?
 102     [ first2 specialized-array-vocab-not-loaded ] when ; foldable
 103
 104 : c-type-direct-array-constructor ( c-type -- word )
 105     direct-array-constructor>> dup array?
 106     [ first2 specialized-array-vocab-not-loaded ] when ; foldable
 107
 108 GENERIC: <c-type-array> ( len c-type -- array )
 109 M: object <c-type-array>
 110     c-type-array-constructor execute( len -- array ) ; inline
 111 M: string <c-type-array>
 112     c-type <c-type-array> ; inline
 113 M: array <c-type-array>
 114     first c-type <c-type-array> ; inline
 115
 116 GENERIC: <c-type-direct-array> ( alien len c-type -- array )
 117 M: object <c-type-direct-array>
 118     c-type-direct-array-constructor execute( alien len -- array ) ; inline
 119 M: string <c-type-direct-array>
 120     c-type <c-type-direct-array> ; inline
 121 M: array <c-type-direct-array>
 122     first c-type <c-type-direct-array> ; inline
 123
 124 GENERIC: c-type-class ( name -- class )
 125
 126 M: abstract-c-type c-type-class class>> ;
 127
 128 M: string c-type-class c-type c-type-class ;
 129
 130 GENERIC: c-type-boxed-class ( name -- class )
 131
 132 M: abstract-c-type c-type-boxed-class boxed-class>> ;
 133
 134 M: string c-type-boxed-class c-type c-type-boxed-class ;
 135
 136 GENERIC: c-type-boxer ( name -- boxer )
 137
 138 M: c-type c-type-boxer boxer>> ;
 139
 140 M: string c-type-boxer c-type c-type-boxer ;
 141
 142 GENERIC: c-type-boxer-quot ( name -- quot )
 143
 144 M: abstract-c-type c-type-boxer-quot boxer-quot>> ;
 145
 146 M: string c-type-boxer-quot c-type c-type-boxer-quot ;
 147
 148 GENERIC: c-type-unboxer ( name -- boxer )
 149
 150 M: c-type c-type-unboxer unboxer>> ;
 151
 152 M: string c-type-unboxer c-type c-type-unboxer ;
 153
 154 GENERIC: c-type-unboxer-quot ( name -- quot )
 155
 156 M: abstract-c-type c-type-unboxer-quot unboxer-quot>> ;
 157
 158 M: string c-type-unboxer-quot c-type c-type-unboxer-quot ;
 159
 160 GENERIC: c-type-rep ( name -- rep )
 161
 162 M: c-type c-type-rep rep>> ;
 163
 164 M: string c-type-rep c-type c-type-rep ;
 165
 166 GENERIC: c-type-getter ( name -- quot )
 167
 168 M: c-type c-type-getter getter>> ;
 169
 170 M: string c-type-getter c-type c-type-getter ;
 171
 172 GENERIC: c-type-setter ( name -- quot )
 173
 174 M: c-type c-type-setter setter>> ;
 175
 176 M: string c-type-setter c-type c-type-setter ;
 177
 178 GENERIC: c-type-align ( name -- n )
 179
 180 M: abstract-c-type c-type-align align>> ;
 181
 182 M: string c-type-align c-type c-type-align ;
 183
 184 GENERIC: c-type-stack-align? ( name -- ? )
 185
 186 M: c-type c-type-stack-align? stack-align?>> ;
 187
 188 M: string c-type-stack-align? c-type c-type-stack-align? ;
 189
 190 : c-type-box ( n type -- )
 191     [ c-type-rep ] [ c-type-boxer [ "No boxer" throw ] unless* ] bi
 192     %box ;
 193
 194 : c-type-unbox ( n ctype -- )
 195     [ c-type-rep ] [ c-type-unboxer [ "No unboxer" throw ] unless* ] bi
 196     %unbox ;
 197
 198 GENERIC: box-parameter ( n ctype -- )
 199
 200 M: c-type box-parameter c-type-box ;
 201
 202 M: string box-parameter c-type box-parameter ;
 203
 204 GENERIC: box-return ( ctype -- )
 205
 206 M: c-type box-return f swap c-type-box ;
 207
 208 M: string box-return c-type box-return ;
 209
 210 GENERIC: unbox-parameter ( n ctype -- )
 211
 212 M: c-type unbox-parameter c-type-unbox ;
 213
 214 M: string unbox-parameter c-type unbox-parameter ;
 215
 216 GENERIC: unbox-return ( ctype -- )
 217
 218 M: c-type unbox-return f swap c-type-unbox ;
 219
 220 M: string unbox-return c-type unbox-return ;
 221
 222 ! These words being foldable means that words need to be
 223 ! recompiled if a C type is redefined. Even so, folding the
 224 ! size facilitates some optimizations.
 225 GENERIC: heap-size ( type -- size ) foldable
 226
 227 M: string heap-size c-type heap-size ;
 228
 229 M: abstract-c-type heap-size size>> ;
 230
 231 GENERIC: stack-size ( type -- size ) foldable
 232
 233 M: string stack-size c-type stack-size ;
 234
 235 M: c-type stack-size size>> cell align ;
 236
 237 GENERIC: byte-length ( seq -- n ) flushable
 238
 239 M: byte-array byte-length length ;
 240
 241 M: f byte-length drop 0 ;
 242
 243 : c-getter ( name -- quot )
 244     c-type-getter [
 245         [ "Cannot read struct fields with this type" throw ]
 246     ] unless* ;
 247
 248 : c-type-getter-boxer ( name -- quot )
 249     [ c-getter ] [ c-type-boxer-quot ] bi append ;
 250
 251 : c-setter ( name -- quot )
 252     c-type-setter [
 253         [ "Cannot write struct fields with this type" throw ]
 254     ] unless* ;
 255
 256 : <c-array> ( n type -- array )
 257     heap-size * <byte-array> ; inline
 258
 259 : <c-object> ( type -- array )
 260     1 swap <c-array> ; inline
 261
 262 : malloc-array ( n type -- alien )
 263     heap-size calloc ; inline
 264
 265 : malloc-object ( type -- alien )
 266     1 swap malloc-array ; inline
 267
 268 : malloc-byte-array ( byte-array -- alien )
 269     dup byte-length [ nip malloc dup ] 2keep memcpy ;
 270
 271 : memory>byte-array ( alien len -- byte-array )
 272     [ nip (byte-array) dup ] 2keep memcpy ;
 273
 274 : malloc-string ( string encoding -- alien )
 275     string>alien malloc-byte-array ;
 276
 277 M: memory-stream stream-read
 278     [
 279         [ index>> ] [ alien>> ] bi <displaced-alien>
 280         swap memory>byte-array
 281     ] [ [ + ] change-index drop ] 2bi ;
 282
 283 : byte-array>memory ( byte-array base -- )
 284     swap dup byte-length memcpy ;
 285
 286 : array-accessor ( type quot -- def )
 287     [
 288         \ swap , [ heap-size , [ * >fixnum ] % ] [ % ] bi*
 289     ] [ ] make ;
 290
 291 : typedef ( old new -- ) c-types get set-at ;
 292
 293 TUPLE: long-long-type < c-type ;
 294
 295 : <long-long-type> ( -- type )
 296     long-long-type new ;
 297
 298 M: long-long-type unbox-parameter ( n type -- )
 299     c-type-unboxer %unbox-long-long ;
 300
 301 M: long-long-type unbox-return ( type -- )
 302     f swap unbox-parameter ;
 303
 304 M: long-long-type box-parameter ( n type -- )
 305     c-type-boxer %box-long-long ;
 306
 307 M: long-long-type box-return ( type -- )
 308     f swap box-parameter ;
 309
 310 : define-deref ( name -- )
 311     [ CHAR: * prefix "alien.c-types" create ] [ c-getter 0 prefix ] bi
 312     (( c-ptr -- value )) define-inline ;
 313
 314 : define-out ( name -- )
 315     [ "alien.c-types" constructor-word ]
 316     [ dup c-setter '[ _ <c-object> [ 0 @ ] keep ] ] bi
 317     (( value -- c-ptr )) define-inline ;
 318
 319 : >c-bool ( ? -- int ) 1 0 ? ; inline
 320
 321 : c-bool> ( int -- ? ) 0 = not ; inline
 322
 323 : define-primitive-type ( type name -- )
 324     [ typedef ]
 325     [ define-deref ]
 326     [ define-out ]
 327     tri ;
 328
 329 : expand-constants ( c-type -- c-type' )
 330     dup array? [
 331         unclip [
 332             [
 333                 dup word? [
 334                     def>> call( -- object )
 335                 ] when
 336             ] map
 337         ] dip prefix
 338     ] when ;
 339
 340 : malloc-file-contents ( path -- alien len )
 341     binary file-contents [ malloc-byte-array ] [ length ] bi ;
 342
 343 : if-void ( type true false -- )
 344     pick "void" = [ drop nip call ] [ nip call ] if ; inline
 345
 346 : ?lookup ( vocab word -- word/pair )
 347     over vocab [ swap lookup ] [ 2array ] if ;
 348
 349 : set-array-class* ( c-type vocab-stem type-stem -- c-type )
 350     {
 351         [
 352             [ "specialized-arrays." prepend ]
 353             [ "-array" append ] bi* ?lookup >>array-class
 354         ]
 355         [
 356             [ "specialized-arrays." prepend ]
 357             [ "<" "-array>" surround ] bi* ?lookup >>array-constructor
 358         ]
 359         [
 360             [ "specialized-arrays." prepend ]
 361             [ "-sequence" append ] bi* ?lookup >>sequence-mixin-class
 362         ]
 363         [
 364             [ "specialized-arrays.direct." prepend ]
 365             [ "direct-" "-array" surround ] bi* ?lookup >>direct-array-class
 366         ]
 367         [
 368             [ "specialized-arrays.direct." prepend ]
 369             [ "<direct-" "-array>" surround ] bi* ?lookup >>direct-array-constructor
 370         ]
 371     } 2cleave ;
 372
 373 : set-array-class ( c-type stem -- c-type )
 374     dup set-array-class* ;
 375
 376 CONSTANT: primitive-types
 377     {
 378         "char" "uchar"
 379         "short" "ushort"
 380         "int" "uint"
 381         "long" "ulong"
 382         "longlong" "ulonglong"
 383         "float" "double"
 384         "void*" "bool"
 385     }
 386
 387 [
 388     <c-type>
 389         c-ptr >>class
 390         c-ptr >>boxed-class
 391         [ alien-cell ] >>getter
 392         [ [ >c-ptr ] 2dip set-alien-cell ] >>setter
 393         bootstrap-cell >>size
 394         bootstrap-cell >>align
 395         [ >c-ptr ] >>unboxer-quot
 396         "box_alien" >>boxer
 397         "alien_offset" >>unboxer
 398         "alien" "void*" set-array-class*
 399     "void*" define-primitive-type
 400
 401     <long-long-type>
 402         integer >>class
 403         integer >>boxed-class
 404         [ alien-signed-8 ] >>getter
 405         [ set-alien-signed-8 ] >>setter
 406         8 >>size
 407         8 >>align
 408         "box_signed_8" >>boxer
 409         "to_signed_8" >>unboxer
 410         "longlong" set-array-class
 411     "longlong" define-primitive-type
 412
 413     <long-long-type>
 414         integer >>class
 415         integer >>boxed-class
 416         [ alien-unsigned-8 ] >>getter
 417         [ set-alien-unsigned-8 ] >>setter
 418         8 >>size
 419         8 >>align
 420         "box_unsigned_8" >>boxer
 421         "to_unsigned_8" >>unboxer
 422         "ulonglong" set-array-class
 423     "ulonglong" define-primitive-type
 424
 425     <c-type>
 426         integer >>class
 427         integer >>boxed-class
 428         [ alien-signed-cell ] >>getter
 429         [ set-alien-signed-cell ] >>setter
 430         bootstrap-cell >>size
 431         bootstrap-cell >>align
 432         "box_signed_cell" >>boxer
 433         "to_fixnum" >>unboxer
 434         "long" set-array-class
 435     "long" define-primitive-type
 436
 437     <c-type>
 438         integer >>class
 439         integer >>boxed-class
 440         [ alien-unsigned-cell ] >>getter
 441         [ set-alien-unsigned-cell ] >>setter
 442         bootstrap-cell >>size
 443         bootstrap-cell >>align
 444         "box_unsigned_cell" >>boxer
 445         "to_cell" >>unboxer
 446         "ulong" set-array-class
 447     "ulong" define-primitive-type
 448
 449     <c-type>
 450         integer >>class
 451         integer >>boxed-class
 452         [ alien-signed-4 ] >>getter
 453         [ set-alien-signed-4 ] >>setter
 454         4 >>size
 455         4 >>align
 456         "box_signed_4" >>boxer
 457         "to_fixnum" >>unboxer
 458         "int" set-array-class
 459     "int" define-primitive-type
 460
 461     <c-type>
 462         integer >>class
 463         integer >>boxed-class
 464         [ alien-unsigned-4 ] >>getter
 465         [ set-alien-unsigned-4 ] >>setter
 466         4 >>size
 467         4 >>align
 468         "box_unsigned_4" >>boxer
 469         "to_cell" >>unboxer
 470         "uint" set-array-class
 471     "uint" define-primitive-type
 472
 473     <c-type>
 474         fixnum >>class
 475         fixnum >>boxed-class
 476         [ alien-signed-2 ] >>getter
 477         [ set-alien-signed-2 ] >>setter
 478         2 >>size
 479         2 >>align
 480         "box_signed_2" >>boxer
 481         "to_fixnum" >>unboxer
 482         "short" set-array-class
 483     "short" define-primitive-type
 484
 485     <c-type>
 486         fixnum >>class
 487         fixnum >>boxed-class
 488         [ alien-unsigned-2 ] >>getter
 489         [ set-alien-unsigned-2 ] >>setter
 490         2 >>size
 491         2 >>align
 492         "box_unsigned_2" >>boxer
 493         "to_cell" >>unboxer
 494         "ushort" set-array-class
 495     "ushort" define-primitive-type
 496
 497     <c-type>
 498         fixnum >>class
 499         fixnum >>boxed-class
 500         [ alien-signed-1 ] >>getter
 501         [ set-alien-signed-1 ] >>setter
 502         1 >>size
 503         1 >>align
 504         "box_signed_1" >>boxer
 505         "to_fixnum" >>unboxer
 506         "char" set-array-class
 507     "char" define-primitive-type
 508
 509     <c-type>
 510         fixnum >>class
 511         fixnum >>boxed-class
 512         [ alien-unsigned-1 ] >>getter
 513         [ set-alien-unsigned-1 ] >>setter
 514         1 >>size
 515         1 >>align
 516         "box_unsigned_1" >>boxer
 517         "to_cell" >>unboxer
 518         "uchar" set-array-class
 519     "uchar" define-primitive-type
 520
 521     <c-type>
 522         [ alien-unsigned-1 c-bool> ] >>getter
 523         [ [ >c-bool ] 2dip set-alien-unsigned-1 ] >>setter
 524         1 >>size
 525         1 >>align
 526         "box_boolean" >>boxer
 527         "to_boolean" >>unboxer
 528         "bool" set-array-class
 529     "bool" define-primitive-type
 530
 531     <c-type>
 532         float >>class
 533         float >>boxed-class
 534         [ alien-float ] >>getter
 535         [ [ >float ] 2dip set-alien-float ] >>setter
 536         4 >>size
 537         4 >>align
 538         "box_float" >>boxer
 539         "to_float" >>unboxer
 540         single-float-rep >>rep
 541         [ >float ] >>unboxer-quot
 542         "float" set-array-class
 543     "float" define-primitive-type
 544
 545     <c-type>
 546         float >>class
 547         float >>boxed-class
 548         [ alien-double ] >>getter
 549         [ [ >float ] 2dip set-alien-double ] >>setter
 550         8 >>size
 551         8 >>align
 552         "box_double" >>boxer
 553         "to_double" >>unboxer
 554         double-float-rep >>rep
 555         [ >float ] >>unboxer-quot
 556         "double" set-array-class
 557     "double" define-primitive-type
 558
 559     "long" "ptrdiff_t" typedef
 560     "long" "intptr_t" typedef
 561     "ulong" "size_t" typedef
 562 ] with-compilation-unit
 563