basis/alien/c-types/c-types.factor

   1 ! Copyright (C) 2004, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: byte-arrays arrays assocs kernel kernel.private libc math
   4 namespaces make parser sequences strings words splitting math.parser
   5 cpu.architecture alien alien.accessors alien.strings quotations
   6 layouts system compiler.units io io.files io.encodings.binary
   7 io.streams.memory accessors combinators effects continuations fry
   8 classes ;
   9 IN: alien.c-types
  10
  11 DEFER: <int>
  12 DEFER: *char
  13
  14 : little-endian? ( -- ? ) 1 <int> *char 1 = ; foldable
  15
  16 TUPLE: c-type
  17 { class class initial: object }
  18 boxer
  19 { boxer-quot callable }
  20 unboxer
  21 { unboxer-quot callable }
  22 { getter callable }
  23 { setter callable }
  24 { reg-class initial: int-regs }
  25 size
  26 align
  27 stack-align? ;
  28
  29 : <c-type> ( -- type )
  30     \ c-type new ;
  31
  32 SYMBOL: c-types
  33
  34 global [
  35     c-types [ H{ } assoc-like ] change
  36 ] bind
  37
  38 ERROR: no-c-type name ;
  39
  40 : (c-type) ( name -- type/f )
  41     c-types get-global at dup [
  42         dup string? [ (c-type) ] when
  43     ] when ;
  44
  45 ! C type protocol
  46 GENERIC: c-type ( name -- type ) foldable
  47
  48 : resolve-pointer-type ( name -- name )
  49     c-types get at dup string?
  50     [ "*" append ] [ drop "void*" ] if
  51     c-type ;
  52
  53 : resolve-typedef ( name -- type )
  54     dup string? [ c-type ] when ;
  55
  56 : parse-array-type ( name -- array )
  57     "[" split unclip
  58     [ [ "]" ?tail drop string>number ] map ] dip prefix ;
  59
  60 M: string c-type ( name -- type )
  61     CHAR: ] over member? [
  62         parse-array-type
  63     ] [
  64         dup c-types get at [
  65             resolve-typedef
  66         ] [
  67             "*" ?tail [ resolve-pointer-type ] [ no-c-type ] if
  68         ] ?if
  69     ] if ;
  70
  71 GENERIC: c-type-class ( name -- class )
  72
  73 M: c-type c-type-class class>> ;
  74
  75 M: string c-type-class c-type c-type-class ;
  76
  77 GENERIC: c-type-boxer ( name -- boxer )
  78
  79 M: c-type c-type-boxer boxer>> ;
  80
  81 M: string c-type-boxer c-type c-type-boxer ;
  82
  83 GENERIC: c-type-boxer-quot ( name -- quot )
  84
  85 M: c-type c-type-boxer-quot boxer-quot>> ;
  86
  87 M: string c-type-boxer-quot c-type c-type-boxer-quot ;
  88
  89 GENERIC: c-type-unboxer ( name -- boxer )
  90
  91 M: c-type c-type-unboxer unboxer>> ;
  92
  93 M: string c-type-unboxer c-type c-type-unboxer ;
  94
  95 GENERIC: c-type-unboxer-quot ( name -- quot )
  96
  97 M: c-type c-type-unboxer-quot unboxer-quot>> ;
  98
  99 M: string c-type-unboxer-quot c-type c-type-unboxer-quot ;
 100
 101 GENERIC: c-type-reg-class ( name -- reg-class )
 102
 103 M: c-type c-type-reg-class reg-class>> ;
 104
 105 M: string c-type-reg-class c-type c-type-reg-class ;
 106
 107 GENERIC: c-type-getter ( name -- quot )
 108
 109 M: c-type c-type-getter getter>> ;
 110
 111 M: string c-type-getter c-type c-type-getter ;
 112
 113 GENERIC: c-type-setter ( name -- quot )
 114
 115 M: c-type c-type-setter setter>> ;
 116
 117 M: string c-type-setter c-type c-type-setter ;
 118
 119 GENERIC: c-type-align ( name -- n )
 120
 121 M: c-type c-type-align align>> ;
 122
 123 M: string c-type-align c-type c-type-align ;
 124
 125 GENERIC: c-type-stack-align? ( name -- ? )
 126
 127 M: c-type c-type-stack-align? stack-align?>> ;
 128
 129 M: string c-type-stack-align? c-type c-type-stack-align? ;
 130
 131 : c-type-box ( n type -- )
 132     dup c-type-reg-class
 133     swap c-type-boxer [ "No boxer" throw ] unless*
 134     %box ;
 135
 136 : c-type-unbox ( n ctype -- )
 137     dup c-type-reg-class
 138     swap c-type-unboxer [ "No unboxer" throw ] unless*
 139     %unbox ;
 140
 141 GENERIC: box-parameter ( n ctype -- )
 142
 143 M: c-type box-parameter c-type-box ;
 144
 145 M: string box-parameter c-type box-parameter ;
 146
 147 GENERIC: box-return ( ctype -- )
 148
 149 M: c-type box-return f swap c-type-box ;
 150
 151 M: string box-return c-type box-return ;
 152
 153 GENERIC: unbox-parameter ( n ctype -- )
 154
 155 M: c-type unbox-parameter c-type-unbox ;
 156
 157 M: string unbox-parameter c-type unbox-parameter ;
 158
 159 GENERIC: unbox-return ( ctype -- )
 160
 161 M: c-type unbox-return f swap c-type-unbox ;
 162
 163 M: string unbox-return c-type unbox-return ;
 164
 165 ! These words being foldable means that words need to be
 166 ! recompiled if a C type is redefined. Even so, folding the
 167 ! size facilitates some optimizations.
 168 GENERIC: heap-size ( type -- size ) foldable
 169
 170 M: string heap-size c-type heap-size ;
 171
 172 M: c-type heap-size size>> ;
 173
 174 GENERIC: stack-size ( type -- size ) foldable
 175
 176 M: string stack-size c-type stack-size ;
 177
 178 M: c-type stack-size size>> cell align ;
 179
 180 GENERIC: byte-length ( seq -- n ) flushable
 181
 182 M: byte-array byte-length length ;
 183
 184 M: f byte-length drop 0 ;
 185
 186 : c-getter ( name -- quot )
 187     c-type-getter [
 188         [ "Cannot read struct fields with this type" throw ]
 189     ] unless* ;
 190
 191 : c-type-getter-boxer ( name -- quot )
 192     [ c-getter ] [ c-type-boxer-quot ] bi append ;
 193
 194 : c-setter ( name -- quot )
 195     c-type-setter [
 196         [ "Cannot write struct fields with this type" throw ]
 197     ] unless* ;
 198
 199 : <c-array> ( n type -- array )
 200     heap-size * <byte-array> ; inline
 201
 202 : <c-object> ( type -- array )
 203     1 swap <c-array> ; inline
 204
 205 : malloc-array ( n type -- alien )
 206     heap-size calloc ; inline
 207
 208 : malloc-object ( type -- alien )
 209     1 swap malloc-array ; inline
 210
 211 : malloc-byte-array ( byte-array -- alien )
 212     dup byte-length [ nip malloc dup ] 2keep memcpy ;
 213
 214 : memory>byte-array ( alien len -- byte-array )
 215     [ nip (byte-array) dup ] 2keep memcpy ;
 216
 217 : malloc-string ( string encoding -- alien )
 218     string>alien malloc-byte-array ;
 219
 220 M: memory-stream stream-read
 221     [
 222         [ index>> ] [ alien>> ] bi <displaced-alien>
 223         swap memory>byte-array
 224     ] [ [ + ] change-index drop ] 2bi ;
 225
 226 : byte-array>memory ( byte-array base -- )
 227     swap dup byte-length memcpy ;
 228
 229 : array-accessor ( type quot -- def )
 230     [
 231         \ swap , [ heap-size , [ * >fixnum ] % ] [ % ] bi*
 232     ] [ ] make ;
 233
 234 : typedef ( old new -- ) c-types get set-at ;
 235
 236 TUPLE: long-long-type < c-type ;
 237
 238 : <long-long-type> ( -- type )
 239     long-long-type new ;
 240
 241 M: long-long-type unbox-parameter ( n type -- )
 242     c-type-unboxer %unbox-long-long ;
 243
 244 M: long-long-type unbox-return ( type -- )
 245     f swap unbox-parameter ;
 246
 247 M: long-long-type box-parameter ( n type -- )
 248     c-type-boxer %box-long-long ;
 249
 250 M: long-long-type box-return ( type -- )
 251     f swap box-parameter ;
 252
 253 : define-deref ( name -- )
 254     [ CHAR: * prefix "alien.c-types" create ] [ c-getter 0 prefix ] bi
 255     (( c-ptr -- value )) define-inline ;
 256
 257 : define-out ( name -- )
 258     [ "alien.c-types" constructor-word ]
 259     [ dup c-setter '[ _ <c-object> [ 0 @ ] keep ] ] bi
 260     (( value -- c-ptr )) define-inline ;
 261
 262 : >c-bool ( ? -- int ) 1 0 ? ; inline
 263
 264 : c-bool> ( int -- ? ) 0 = not ; inline
 265
 266 : define-primitive-type ( type name -- )
 267     [ typedef ]
 268     [ define-deref ]
 269     [ define-out ]
 270     tri ;
 271
 272 : expand-constants ( c-type -- c-type' )
 273     dup array? [
 274         unclip [
 275             [
 276                 dup word? [
 277                     def>> call( -- object )
 278                 ] when
 279             ] map
 280         ] dip prefix
 281     ] when ;
 282
 283 : malloc-file-contents ( path -- alien len )
 284     binary file-contents [ malloc-byte-array ] [ length ] bi ;
 285
 286 : if-void ( type true false -- )
 287     pick "void" = [ drop nip call ] [ nip call ] if ; inline
 288
 289 CONSTANT: primitive-types
 290     {
 291         "char" "uchar"
 292         "short" "ushort"
 293         "int" "uint"
 294         "long" "ulong"
 295         "longlong" "ulonglong"
 296         "float" "double"
 297         "void*" "bool"
 298     }
 299
 300 [
 301     <c-type>
 302         c-ptr >>class
 303         [ alien-cell ] >>getter
 304         [ [ >c-ptr ] 2dip set-alien-cell ] >>setter
 305         bootstrap-cell >>size
 306         bootstrap-cell >>align
 307         [ >c-ptr ] >>unboxer-quot
 308         "box_alien" >>boxer
 309         "alien_offset" >>unboxer
 310     "void*" define-primitive-type
 311
 312     <long-long-type>
 313         integer >>class
 314         [ alien-signed-8 ] >>getter
 315         [ set-alien-signed-8 ] >>setter
 316         8 >>size
 317         8 >>align
 318         "box_signed_8" >>boxer
 319         "to_signed_8" >>unboxer
 320     "longlong" define-primitive-type
 321
 322     <long-long-type>
 323         integer >>class
 324         [ alien-unsigned-8 ] >>getter
 325         [ set-alien-unsigned-8 ] >>setter
 326         8 >>size
 327         8 >>align
 328         "box_unsigned_8" >>boxer
 329         "to_unsigned_8" >>unboxer
 330     "ulonglong" define-primitive-type
 331
 332     <c-type>
 333         integer >>class
 334         [ alien-signed-cell ] >>getter
 335         [ set-alien-signed-cell ] >>setter
 336         bootstrap-cell >>size
 337         bootstrap-cell >>align
 338         "box_signed_cell" >>boxer
 339         "to_fixnum" >>unboxer
 340     "long" define-primitive-type
 341
 342     <c-type>
 343         integer >>class
 344         [ alien-unsigned-cell ] >>getter
 345         [ set-alien-unsigned-cell ] >>setter
 346         bootstrap-cell >>size
 347         bootstrap-cell >>align
 348         "box_unsigned_cell" >>boxer
 349         "to_cell" >>unboxer
 350     "ulong" define-primitive-type
 351
 352     <c-type>
 353         integer >>class
 354         [ alien-signed-4 ] >>getter
 355         [ set-alien-signed-4 ] >>setter
 356         4 >>size
 357         4 >>align
 358         "box_signed_4" >>boxer
 359         "to_fixnum" >>unboxer
 360     "int" define-primitive-type
 361
 362     <c-type>
 363         integer >>class
 364         [ alien-unsigned-4 ] >>getter
 365         [ set-alien-unsigned-4 ] >>setter
 366         4 >>size
 367         4 >>align
 368         "box_unsigned_4" >>boxer
 369         "to_cell" >>unboxer
 370     "uint" define-primitive-type
 371
 372     <c-type>
 373         fixnum >>class
 374         [ alien-signed-2 ] >>getter
 375         [ set-alien-signed-2 ] >>setter
 376         2 >>size
 377         2 >>align
 378         "box_signed_2" >>boxer
 379         "to_fixnum" >>unboxer
 380     "short" define-primitive-type
 381
 382     <c-type>
 383         fixnum >>class
 384         [ alien-unsigned-2 ] >>getter
 385         [ set-alien-unsigned-2 ] >>setter
 386         2 >>size
 387         2 >>align
 388         "box_unsigned_2" >>boxer
 389         "to_cell" >>unboxer
 390     "ushort" define-primitive-type
 391
 392     <c-type>
 393         fixnum >>class
 394         [ alien-signed-1 ] >>getter
 395         [ set-alien-signed-1 ] >>setter
 396         1 >>size
 397         1 >>align
 398         "box_signed_1" >>boxer
 399         "to_fixnum" >>unboxer
 400     "char" define-primitive-type
 401
 402     <c-type>
 403         fixnum >>class
 404         [ alien-unsigned-1 ] >>getter
 405         [ set-alien-unsigned-1 ] >>setter
 406         1 >>size
 407         1 >>align
 408         "box_unsigned_1" >>boxer
 409         "to_cell" >>unboxer
 410     "uchar" define-primitive-type
 411
 412     <c-type>
 413         [ alien-unsigned-1 c-bool> ] >>getter
 414         [ [ >c-bool ] 2dip set-alien-unsigned-1 ] >>setter
 415         1 >>size
 416         1 >>align
 417         "box_boolean" >>boxer
 418         "to_boolean" >>unboxer
 419     "bool" define-primitive-type
 420
 421     <c-type>
 422         float >>class
 423         [ alien-float ] >>getter
 424         [ [ >float ] 2dip set-alien-float ] >>setter
 425         4 >>size
 426         4 >>align
 427         "box_float" >>boxer
 428         "to_float" >>unboxer
 429         single-float-regs >>reg-class
 430         [ >float ] >>unboxer-quot
 431     "float" define-primitive-type
 432
 433     <c-type>
 434         float >>class
 435         [ alien-double ] >>getter
 436         [ [ >float ] 2dip set-alien-double ] >>setter
 437         8 >>size
 438         8 >>align
 439         "box_double" >>boxer
 440         "to_double" >>unboxer
 441         double-float-regs >>reg-class
 442         [ >float ] >>unboxer-quot
 443     "double" define-primitive-type
 444
 445     "long" "ptrdiff_t" typedef
 446     "long" "intptr_t" typedef
 447     "ulong" "size_t" typedef
 448 ] with-compilation-unit