basis/alien/data/data-docs.factor

   1 USING: alien alien.c-types help.syntax help.markup libc
   2 kernel.private byte-arrays math strings hashtables alien.syntax
   3 alien.strings sequences io.encodings.string debugger destructors
   4 vocabs.loader classes.struct quotations kernel ;
   5 IN: alien.data
   6
   7 HELP: <c-array>
   8 { $values { "len" "a non-negative integer" } { "c-type" "a C type" } { "array" byte-array } }
   9 { $description "Creates a byte array large enough to hold " { $snippet "n" } " values of a C type." }
  10 { $notes "The appropriate specialized array vocabulary must be loaded; otherwise, an error will be thrown. See the " { $vocab-link "specialized-arrays" } " vocabulary for details on the underlying sequence type constructed." }
  11 { $errors "Throws an error if the type does not exist, the necessary specialized array vocabulary is not loaded, or the requested size is negative." } ;
  12
  13 HELP: memory>byte-array
  14 { $values { "alien" c-ptr } { "len" "a non-negative integer" } { "byte-array" byte-array } }
  15 { $description "Reads " { $snippet "len" } " bytes starting from " { $snippet "base" } " and stores them in a new byte array." } ;
  16
  17 HELP: malloc-array
  18 { $values { "n" "a non-negative integer" } { "type" "a C type" } { "array" "a specialized array" } }
  19 { $description "Allocates an unmanaged memory block large enough to hold " { $snippet "n" } " values of a C type, then wraps the memory in a sequence object using " { $link <c-direct-array> } "." }
  20 { $notes "The appropriate specialized array vocabulary must be loaded; otherwise, an error will be thrown. See the " { $vocab-link "specialized-arrays" } " vocabulary for details on the underlying sequence type constructed." }
  21 { $warning "Don't forget to deallocate the memory with a call to " { $link free } "." }
  22 { $errors "Throws an error if the type does not exist, if the requested size is negative, if a direct specialized array class appropriate to the type is not loaded, or if memory allocation fails." } ;
  23
  24 HELP: malloc-byte-array
  25 { $values { "byte-array" byte-array } { "alien" alien } }
  26 { $description "Allocates an unmanaged memory block of the same size as the byte array, and copies the contents of the byte array there." }
  27 { $warning "Don't forget to deallocate the memory with a call to " { $link free } "." }
  28 { $errors "Throws an error if memory allocation fails." } ;
  29
  30 { <c-array> <c-direct-array> malloc-array } related-words
  31
  32 { string>alien alien>string malloc-string } related-words
  33
  34 HELP: with-scoped-allocation
  35 { $values { "c-types" "a list of scoped allocation specifiers" } { "quot" quotation } }
  36 { $description "Allocates values on the call stack, calls the quotation, then deallocates the values as soon as the quotation returns."
  37 $nl
  38 "A scoped allocation specifier is either:"
  39 { $list
  40     "a C type name,"
  41     { "or a triple with shape " { $snippet "{ c-type initial: initial }" } ", where " { $snippet "c-type" } " is a C type name and " { $snippet "initial" } " is a literal value." }
  42 }
  43 "If no initial value is specified, the contents of the allocated memory are undefined." }
  44 { $warning "Reading or writing a scoped allocation buffer outside of the given quotation will cause memory corruption." }
  45 { $examples
  46     { $example
  47         "USING: accessors alien.c-types alien.data
  48 classes.struct kernel math math.functions
  49 prettyprint ;
  50 IN: scratchpad
  51
  52 STRUCT: point { x int } { y int } ;
  53
  54 : scoped-allocation-test ( -- x )
  55     { point } [
  56         3 >>x 4 >>y
  57         [ x>> sq ] [ y>> sq ] bi + sqrt
  58     ] with-scoped-allocation ;
  59
  60 scoped-allocation-test ."
  61 "5.0"
  62     }
  63 } ;
  64
  65 HELP: with-out-parameters
  66 { $values { "c-types" "a list of scoped allocation specifiers" } { "quot" quotation } { "values..." "zero or more values" } }
  67 { $description "Allocates values on the call stack, calls the quotation, then copies all stack allocated values to the data heap after the quotation returns."
  68 $nl
  69 "A scoped allocation specifier is either:"
  70 { $list
  71     "a C type name,"
  72     { "or a triple with shape " { $snippet "{ c-type initial: initial }" } ", where " { $snippet "c-type" } " is a C type name and " { $snippet "initial" } " is a literal value." }
  73 }
  74 "If no initial value is specified, the contents of the allocated memory are undefined." }
  75 { $warning "Reading or writing a scoped allocation buffer outside of the given quotation will cause memory corruption." } ;
  76
  77 ARTICLE: "malloc" "Manual memory management"
  78 "Sometimes data passed to C functions must be allocated at a fixed address. See " { $link "byte-arrays-gc" } " for an explanation of when this is the case."
  79 $nl
  80 "Allocating a C datum with a fixed address:"
  81 { $subsections
  82     malloc-byte-array
  83 }
  84 "The " { $vocab-link "libc" } " vocabulary defines several words which directly call C standard library memory management functions:"
  85 { $subsections
  86     malloc
  87     calloc
  88     realloc
  89 }
  90 "You must always free pointers returned by any of the above words when the block of memory is no longer in use:"
  91 { $subsections free }
  92 "The above words record memory allocations, to help catch double frees and track down memory leaks with " { $link "tools.destructors" } ". To free memory allocated by a C library, another word can be used:"
  93 { $subsections (free) }
  94 "Utilities for automatically freeing memory in conjunction with " { $link with-destructors } ":"
  95 { $subsections
  96     &free
  97     |free
  98 }
  99 "The " { $link &free } " and " { $link |free } " words are generated using " { $link "alien.destructors" } "."
 100 $nl
 101 "You can unsafely copy a range of bytes from one memory location to another:"
 102 { $subsections memcpy }
 103 "You can copy a range of bytes from memory into a byte array:"
 104 { $subsections memory>byte-array } ;
 105
 106 ARTICLE: "c-pointers" "Passing pointers to C functions"
 107 "The following Factor objects may be passed to C function parameters with pointer types:"
 108 { $list
 109     { "Instances of " { $link alien } "." }
 110     { "Instances of " { $link f } "; this is interpreted as a null pointer." }
 111     { "Instances of " { $link byte-array } "; the C function receives a pointer to the first element of the array." }
 112     { "Any data type which defines a method on " { $link >c-ptr } ". This includes " { $link "classes.struct" } " and " { $link "specialized-arrays" } "." }
 113 }
 114 "The class of primitive C pointer types:"
 115 { $subsections c-ptr }
 116 "A generic word for converting any object to a C pointer; user-defined types may add methods to this generic word:"
 117 { $subsections >c-ptr }
 118 "More about the " { $link alien } " type:"
 119 { $subsections "aliens" }
 120 { $warning
 121 "The Factor garbage collector can move byte arrays around, and code passing byte arrays, or objects backed by byte arrays, must obey important guidelines. See " { $link "byte-arrays-gc" } "." } ;
 122
 123 ARTICLE: "c-boxes" "C value boxes"
 124 "Sometimes it is useful to create a byte array storing a single C value, like a struct with a single field. A pair of utility macros exist to make this more convenient:"
 125 { $subsections <ref> deref } ;
 126
 127 ARTICLE: "c-data" "Passing data between Factor and C"
 128 "Two defining characteristics of Factor are dynamic typing and automatic memory management, which are somewhat incompatible with the machine-level data model exposed by C. Factor's C library interface defines its own set of C data types, distinct from Factor language types, together with automatic conversion between Factor values and C types. For example, C integer types must be declared and are fixed-width, whereas Factor supports arbitrary-precision integers."
 129 $nl
 130 "Furthermore, Factor's garbage collector can move objects in memory; for a discussion of the consequences, see " { $link "byte-arrays-gc" } "."
 131 { $subsections
 132     "c-types-specs"
 133     "c-pointers"
 134     "malloc"
 135     "c-strings"
 136     "c-out-params"
 137     "c-boxes"
 138 }
 139 "Important guidelines for passing data in byte arrays:"
 140 { $subsections "byte-arrays-gc" }
 141 "C-style enumerated types are supported:"
 142 { $subsections "alien.enums" }
 143 "A utility for defining " { $link "destructors" } " for deallocating memory:"
 144 { $subsections "alien.destructors" }
 145 "C struct and union types can be defined with " { $link POSTPONE: STRUCT: } " and " { $link POSTPONE: UNION: } ". See " { $link "classes.struct" } " for details. For passing arrays to and from C, use the " { $link "specialized-arrays" } " vocabulary." ;
 146
 147 HELP: malloc-string
 148 { $values { "string" string } { "encoding" "an encoding descriptor" } { "alien" c-ptr } }
 149 { $description "Encodes a string together with a trailing null code point using the given encoding, and stores the resulting bytes in a freshly-allocated unmanaged memory block." }
 150 { $warning "Don't forget to deallocate the memory with a call to " { $link free } "." }
 151 { $errors "Throws an error if one of the following conditions occurs:"
 152     { $list
 153         "the string contains null code points"
 154         "the string contains characters not representable using the encoding specified"
 155         "memory allocation fails"
 156     }
 157 } ;
 158
 159 HELP: <c-direct-array>
 160 { $values { "alien" c-ptr } { "len" integer } { "c-type" "a C type" } { "array" "a specialized direct array" } }
 161 { $description "Constructs a new specialized array of length " { $snippet "len" } " and element type " { $snippet "c-type" } " over the range of memory referenced by " { $snippet "alien" } "." }
 162 { $notes "The appropriate specialized array vocabulary must be loaded; otherwise, an error will be thrown. See the " { $vocab-link "specialized-arrays" } " vocabulary for details on the underlying sequence type constructed." } ;
 163
 164 ARTICLE: "c-strings" "C strings"
 165 "C string types are arrays with shape " { $snippet "{ c-string encoding }" } ", where " { $snippet "encoding" } " is an encoding descriptor. The type " { $link c-string } " is an alias for " { $snippet "{ c-string utf8 }" } ". See " { $link "encodings-descriptors" } " for information about encoding descriptors. In " { $link POSTPONE: TYPEDEF: } ", " { $link POSTPONE: FUNCTION: } ", " { $link POSTPONE: CALLBACK: } ", and " { $link POSTPONE: STRUCT: } " definitions, the shorthand syntax " { $snippet "c-string[encoding]" } " can be used to specify the string encoding."
 166 $nl
 167 "Passing a Factor string to a C function expecting a " { $link c-string } " allocates a " { $link byte-array } " in the Factor heap; the string is then converted to the requested format and a raw pointer is passed to the function."
 168 $nl
 169 "If the conversion fails, for example if the string contains null bytes or characters with values higher than 255, a " { $link c-string-error. } " is thrown."
 170 $nl
 171 "Care must be taken if the C function expects a pointer to a string with its length represented by another parameter rather than a null terminator. Passing the result of calling " { $link length } " on the string object will not suffice. This is because a Factor string of " { $emphasis "n" } " characters will not necessarily encode to " { $emphasis "n" } " bytes. The correct idiom for C functions which take a string with a length is to first encode the string using " { $link encode } ", and then pass the resulting byte array together with the length of this byte array."
 172 $nl
 173 "Sometimes a C function has a parameter type of " { $link void* } ", and various data types, among them strings, can be passed in. In this case, strings are not automatically converted to aliens, and instead you must call one of these words:"
 174 { $subsections
 175     string>alien
 176     malloc-string
 177 }
 178 "The first allocates " { $link byte-array } "s, and the latter allocates manually-managed memory which is not moved by the garbage collector and has to be explicitly freed by calling " { $link free } ". See " { $link "byte-arrays-gc" } " for a discussion of the two approaches."
 179 $nl
 180 "The C type " { $snippet "char*" } " represents a generic pointer to " { $snippet "char" } "; arguments with this type will expect and return " { $link alien } "s, and won't perform any implicit string conversion."
 181 $nl
 182 "A word to read strings from arbitrary addresses:"
 183 { $subsections alien>string }
 184 "For example, if a C function returns a " { $link c-string } " but stipulates that the caller must deallocate the memory afterward, you must define the function as returning " { $snippet "char*" } " and call " { $link (free) } " yourself." ;
 185
 186 HELP: <ref>
 187 { $values { "value" object } { "c-type" "a C type" } { "c-ptr" c-ptr } }
 188 { $description "Creates a new byte array to store a Factor object as a C value." }
 189 { $examples
 190     { $example "USING: alien.c-types alien.data prettyprint sequences ;" "123 int <ref> length ." "4" }
 191 } ;
 192
 193 HELP: deref
 194 { $values { "c-ptr" c-ptr } { "c-type" "a C type" } { "value" object } }
 195 { $description "Loads a C value from a byte array." }
 196 { $examples
 197     { $example "USING: alien.c-types alien.data prettyprint sequences ;" "321 int <ref> int deref ." "321" }
 198 } ;
 199
 200 ARTICLE: "c-out-params" "Output parameters in C"
 201 "A frequently-occurring idiom in C code is the \"out parameter\". If a C function returns more than one value, the caller passes pointers of the correct type, and the C function writes its return values to those locations."
 202 { $subsection with-out-parameters } ;