basis/alien/data/data.factor

   1 ! (c)2009, 2010 Slava Pestov, Joe Groff bsd license
   2 USING: accessors alien alien.c-types alien.arrays alien.strings
   3 arrays byte-arrays cpu.architecture fry io io.encodings.binary
   4 io.files io.streams.memory kernel libc math math.functions
   5 sequences words macros combinators generalizations
   6 stack-checker.dependencies combinators.short-circuit ;
   7 QUALIFIED: math
   8 IN: alien.data
   9
  10 GENERIC: require-c-array ( c-type -- )
  11
  12 M: array require-c-array first require-c-array ;
  13
  14 GENERIC: c-array-constructor ( c-type -- word ) foldable
  15
  16 GENERIC: c-(array)-constructor ( c-type -- word ) foldable
  17
  18 GENERIC: c-direct-array-constructor ( c-type -- word ) foldable
  19
  20 GENERIC: <c-array> ( len c-type -- array )
  21
  22 M: word <c-array>
  23     c-array-constructor execute( len -- array ) ; inline
  24
  25 GENERIC: (c-array) ( len c-type -- array )
  26
  27 M: word (c-array)
  28     c-(array)-constructor execute( len -- array ) ; inline
  29
  30 GENERIC: <c-direct-array> ( alien len c-type -- array )
  31
  32 M: word <c-direct-array>
  33     c-direct-array-constructor execute( alien len -- array ) ; inline
  34
  35 : malloc-array ( n type -- array )
  36     [ heap-size calloc ] [ <c-direct-array> ] 2bi ; inline
  37
  38 : (malloc-array) ( n type -- alien )
  39     [ heap-size * malloc ] [ <c-direct-array> ] 2bi ; inline
  40
  41 : <c-object> ( type -- array )
  42     heap-size <byte-array> ; inline
  43
  44 : (c-object) ( type -- array )
  45     heap-size (byte-array) ; inline
  46
  47 : malloc-object ( type -- alien )
  48     1 swap heap-size calloc ; inline
  49
  50 : (malloc-object) ( type -- alien )
  51     heap-size malloc ; inline
  52
  53 : malloc-byte-array ( byte-array -- alien )
  54     binary-object [ nip malloc dup ] 2keep memcpy ;
  55
  56 : memory>byte-array ( alien len -- byte-array )
  57     [ nip (byte-array) dup ] 2keep memcpy ;
  58
  59 : malloc-string ( string encoding -- alien )
  60     string>alien malloc-byte-array ;
  61
  62 M: memory-stream stream-read
  63     [
  64         [ index>> ] [ alien>> ] bi <displaced-alien>
  65         swap memory>byte-array
  66     ] [ [ + ] change-index drop ] 2bi ;
  67
  68 M: value-type c-type-rep drop int-rep ;
  69
  70 M: value-type c-type-getter
  71     drop [ swap <displaced-alien> ] ;
  72
  73 M: value-type c-type-copier
  74     heap-size '[ _ memory>byte-array ] ;
  75
  76 M: value-type c-type-setter
  77     [ c-type-getter ] [ heap-size ] bi '[ @ swap _ memcpy ] ;
  78
  79 M: array c-type-boxer-quot
  80     unclip [ array-length ] dip [ <c-direct-array> ] 2curry ;
  81
  82 M: array c-type-unboxer-quot drop [ >c-ptr ] ;
  83
  84 ERROR: local-allocation-error ;
  85
  86 <PRIVATE
  87
  88 : (local-allot) ( size align -- alien ) local-allocation-error ;
  89
  90 : (cleanup-allot) ( -- )
  91     ! Inhibit TCO in order for the last word in the quotation
  92     ! to still be abl to access scope-allocated data.
  93     ;
  94
  95 MACRO: (simple-local-allot) ( c-type -- quot )
  96     [ depends-on-c-type ]
  97     [ dup '[ _ heap-size _ c-type-align (local-allot) ] ] bi ;
  98
  99 : [hairy-local-allot] ( c-type initial -- quot )
 100     over '[ _ (simple-local-allot) _ over 0 _ set-alien-value ] ;
 101
 102 : hairy-local-allot? ( obj -- ? )
 103     {
 104         [ array? ]
 105         [ length 3 = ]
 106         [ second initial: eq? ]
 107     } 1&& ;
 108
 109 MACRO: (hairy-local-allot) ( obj -- quot )
 110     dup hairy-local-allot?
 111     [ first3 nip [hairy-local-allot] ]
 112     [ '[ _ (simple-local-allot) ] ]
 113     if ;
 114
 115 MACRO: (local-allots) ( c-types -- quot )
 116     [ '[ _ (hairy-local-allot) ] ] map [ ] join ;
 117
 118 MACRO: box-values ( c-types -- quot )
 119     [ c-type-boxer-quot ] map '[ _ spread ] ;
 120
 121 MACRO: out-parameters ( c-types -- quot )
 122     [ dup hairy-local-allot? [ first ] when ] map
 123     [ length ] [ [ '[ 0 _ alien-copy-value ] ] map ] bi
 124     '[ _ nkeep _ spread ] ;
 125
 126 PRIVATE>
 127
 128 : with-scoped-allocation ( c-types quot -- )
 129     [ [ (local-allots) ] [ box-values ] bi ] dip call
 130     (cleanup-allot) ; inline
 131
 132 : with-out-parameters ( c-types quot -- values... )
 133     [ drop (local-allots) ] [ swap out-parameters ] 2bi
 134     (cleanup-allot) ; inline
 135
 136 GENERIC: binary-zero? ( value -- ? )
 137
 138 M: object binary-zero? drop f ; inline
 139 M: f binary-zero? drop t ; inline
 140 M: integer binary-zero? zero? ; inline
 141 M: math:float binary-zero? double>bits zero? ; inline
 142 M: complex binary-zero? >rect [ binary-zero? ] both? ; inline